DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1500 Commits
7 Branches
69MB
Tree: db30d87c48
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'db30d87c48'
${ noResults }
DPF/cmake/DPF-plugin.cmake

808 lines
28KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2 vst3

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "vst3")

  157.       if(MSVC)

  158.         message(WARNING "TODO: VST3 is not supported on MSVC yet")

  159.       else()

  160.         dpf__build_vst3("${NAME}" "${_dgl_library}")

  161.       endif()

  162.     else()

  163.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  164.     endif()

  165.   endforeach()

  166. endfunction()

  167. 

  168. # ------------------------------------------------------------------------------

  169. # DPF private functions (prefixed with `dpf__`)

  170. # ------------------------------------------------------------------------------

  171. 

  172. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  173. #       to the output directory.

  174. #

  175. 

  176. # dpf__build_jack

  177. # ------------------------------------------------------------------------------

  178. #

  179. # Add build rules for a JACK program.

  180. #

  181. function(dpf__build_jack NAME DGL_LIBRARY)

  182.   dpf__create_dummy_source_list(_no_srcs)

  183. 

  184.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  185.   dpf__add_plugin_main("${NAME}-jack" "jack")

  186.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  187.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  188.   set_target_properties("${NAME}-jack" PROPERTIES

  189.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  190.     OUTPUT_NAME "${NAME}")

  191. 

  192.   # Note: libjack will be linked at runtime

  193.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  194.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  195.   endif()

  196. 

  197.   # for RtAudio native fallback

  198.   if(APPLE)

  199.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  200.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  201.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  202.   endif()

  203. endfunction()

  204. 

  205. # dpf__build_ladspa

  206. # ------------------------------------------------------------------------------

  207. #

  208. # Add build rules for a LADSPA plugin.

  209. #

  210. function(dpf__build_ladspa NAME)

  211.   dpf__create_dummy_source_list(_no_srcs)

  212. 

  213.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  214.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  215.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  216.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  217.   set_target_properties("${NAME}-ladspa" PROPERTIES

  218.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  219.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  220.     OUTPUT_NAME "${NAME}-ladspa"

  221.     PREFIX "")

  222. endfunction()

  223. 

  224. # dpf__build_dssi

  225. # ------------------------------------------------------------------------------

  226. #

  227. # Add build rules for a DSSI plugin.

  228. #

  229. function(dpf__build_dssi NAME DGL_LIBRARY)

  230.   find_package(PkgConfig)

  231.   pkg_check_modules(LIBLO "liblo")

  232.   if(NOT LIBLO_FOUND)

  233.     dpf__warn_once_only(missing_liblo

  234.       "liblo is not found, skipping the `dssi` plugin targets")

  235.     return()

  236.   endif()

  237. 

  238.   link_directories(${LIBLO_LIBRARY_DIRS})

  239. 

  240.   dpf__create_dummy_source_list(_no_srcs)

  241. 

  242.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  243.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  244.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  245.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  246.   set_target_properties("${NAME}-dssi" PROPERTIES

  247.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  248.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  249.     OUTPUT_NAME "${NAME}-dssi"

  250.     PREFIX "")

  251. 

  252.   if(DGL_LIBRARY)

  253.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  254.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  255.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  256.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  257.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  258.       OUTPUT_NAME "${NAME}_ui")

  259. 

  260.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  261.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  262.   endif()

  263. endfunction()

  264. 

  265. # dpf__build_lv2

  266. # ------------------------------------------------------------------------------

  267. #

  268. # Add build rules for an LV2 plugin.

  269. #

  270. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  271.   dpf__create_dummy_source_list(_no_srcs)

  272. 

  273.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  274.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  275.   if(DGL_LIBRARY AND MONOLITHIC)

  276.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  277.   else()

  278.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  279.   endif()

  280.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  281.   set_target_properties("${NAME}-lv2" PROPERTIES

  282.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  283.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  284.     OUTPUT_NAME "${NAME}_dsp"

  285.     PREFIX "")

  286. 

  287.   if(DGL_LIBRARY)

  288.     if(MONOLITHIC)

  289.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  290.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  291.       set_target_properties("${NAME}-lv2" PROPERTIES

  292.         OUTPUT_NAME "${NAME}")

  293.     else()

  294.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  295.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  296.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  297.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  298.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  299.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  300.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  301.         OUTPUT_NAME "${NAME}_ui"

  302.         PREFIX "")

  303.     endif()

  304.   endif()

  305. 

  306.   dpf__add_lv2_ttl_generator()

  307.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  308. 

  309.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  310.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  311.     "$<TARGET_FILE:lv2_ttl_generator>"

  312.     "$<TARGET_FILE:${NAME}-lv2>"

  313.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  314.     DEPENDS lv2_ttl_generator)

  315. endfunction()

  316. 

  317. # dpf__build_vst2

  318. # ------------------------------------------------------------------------------

  319. #

  320. # Add build rules for a VST2 plugin.

  321. #

  322. function(dpf__build_vst2 NAME DGL_LIBRARY)

  323.   dpf__create_dummy_source_list(_no_srcs)

  324. 

  325.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  326.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  327.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  328.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  329.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  330.   set_target_properties("${NAME}-vst2" PROPERTIES

  331.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  332.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  333.     OUTPUT_NAME "${NAME}-vst2"

  334.     PREFIX "")

  335.   if(APPLE)

  336.     set_target_properties("${NAME}-vst2" PROPERTIES

  337.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  338.       OUTPUT_NAME "${NAME}"

  339.       SUFFIX "")

  340.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  341.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  342.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  343.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  344.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  345.   endif()

  346. endfunction()

  347. 

  348. # dpf__determine_vst3_package_architecture

  349. # ------------------------------------------------------------------------------

  350. #

  351. # Determines the package architecture for a VST3 plugin target.

  352. #

  353. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  354.   # if set by variable, override the detection

  355.   if(DPF_VST3_ARCHITECTURE)

  356.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  357.     return()

  358.   endif()

  359. 

  360.   # not used on Apple, which supports universal binary

  361.   if(APPLE)

  362.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  363.     return()

  364.   endif()

  365. 

  366.   # identify the target processor (special case of MSVC, problematic sometimes)

  367.   if(MSVC)

  368.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  369.   else()

  370.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  371.   endif()

  372. 

  373.   # transform the processor name to a format that VST3 recognizes

  374.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  375.     set(vst3_package_arch "x86_64")

  376.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  377.     if(WIN32)

  378.       set(vst3_package_arch "x86")

  379.     else()

  380.       set(vst3_package_arch "i386")

  381.     endif()

  382.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  383.     set(vst3_package_arch "${vst3_system_arch}")

  384.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  385.     set(vst3_package_arch "aarch64")

  386.   else()

  387.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  388.   endif()

  389. 

  390.   # TODO: the detections for Windows arm/arm64 when supported

  391. 

  392.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  393. endfunction()

  394. 

  395. # dpf__build_vst3

  396. # ------------------------------------------------------------------------------

  397. #

  398. # Add build rules for a VST3 plugin.

  399. #

  400. function(dpf__build_vst3 NAME DGL_LIBRARY)

  401.   dpf__determine_vst3_package_architecture(vst3_arch)

  402. 

  403.   dpf__create_dummy_source_list(_no_srcs)

  404. 

  405.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  406.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  407.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  408.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  409.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  410.   set_target_properties("${NAME}-vst3" PROPERTIES

  411.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  412.     OUTPUT_NAME "${NAME}"

  413.     PREFIX "")

  414. 

  415.   if(APPLE)

  416.     set_target_properties("${NAME}-vst3" PROPERTIES

  417.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  418.       SUFFIX "")

  419.   elseif(WIN32)

  420.     set_target_properties("${NAME}-vst3" PROPERTIES

  421.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>")

  422.   else()

  423.     set_target_properties("${NAME}-vst3" PROPERTIES

  424.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  425.   endif()

  426. 

  427.   if(APPLE)

  428.     # Uses the same macOS bundle template as VST2

  429.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  430.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  431.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  432.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  433.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  434.   endif()

  435. endfunction()

  436. 

  437. # dpf__add_dgl_cairo

  438. # ------------------------------------------------------------------------------

  439. #

  440. # Add the Cairo variant of DGL, if not already available.

  441. #

  442. function(dpf__add_dgl_cairo)

  443.   if(TARGET dgl-cairo)

  444.     return()

  445.   endif()

  446. 

  447.   find_package(PkgConfig)

  448.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  449. 

  450.   link_directories(${CAIRO_LIBRARY_DIRS})

  451. 

  452.   dpf__add_static_library(dgl-cairo STATIC

  453.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  454.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  455.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  456.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  457.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  458.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  459.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  460.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  461.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  462.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  463.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  464.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  465.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  466.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  467.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  468.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  469.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  470.   if(NOT APPLE)

  471.     target_sources(dgl-cairo PRIVATE

  472.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  473.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  474.     #target_sources(dgl-opengl PRIVATE

  475.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  476.   endif()

  477.   target_include_directories(dgl-cairo PUBLIC

  478.     "${DPF_ROOT_DIR}/dgl")

  479.   target_include_directories(dgl-cairo PUBLIC

  480.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  481. 

  482.   dpf__add_dgl_system_libs()

  483.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  484. 

  485.   add_library(dgl-cairo-definitions INTERFACE)

  486.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  487. 

  488.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  489.   if(MINGW)

  490.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  491.   else()

  492.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  493.   endif()

  494.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  495. endfunction()

  496. 

  497. # dpf__add_dgl_opengl

  498. # ------------------------------------------------------------------------------

  499. #

  500. # Add the OpenGL variant of DGL, if not already available.

  501. #

  502. function(dpf__add_dgl_opengl)

  503.   if(TARGET dgl-opengl)

  504.     return()

  505.   endif()

  506. 

  507.   if(NOT OpenGL_GL_PREFERENCE)

  508.     set(OpenGL_GL_PREFERENCE "LEGACY")

  509.   endif()

  510. 

  511.   find_package(OpenGL REQUIRED)

  512. 

  513.   dpf__add_static_library(dgl-opengl STATIC

  514.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  515.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  516.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  517.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  518.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  519.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  520.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  521.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  522.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  523.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  524.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  525.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  526.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  528.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  530.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  531.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  532.   if(NOT APPLE)

  533.     target_sources(dgl-opengl PRIVATE

  534.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  535.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  536.     #target_sources(dgl-opengl PRIVATE

  537.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  538.   endif()

  539.   target_include_directories(dgl-opengl PUBLIC

  540.     "${DPF_ROOT_DIR}/dgl")

  541.   target_include_directories(dgl-opengl PUBLIC

  542.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  543. 

  544.   if(APPLE)

  545.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  546.   endif()

  547. 

  548.   dpf__add_dgl_system_libs()

  549.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  550. 

  551.   add_library(dgl-opengl-definitions INTERFACE)

  552.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  553. 

  554.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  555.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  556. endfunction()

  557. 

  558. # dpf__add_plugin_specific_ui_sources

  559. # ------------------------------------------------------------------------------

  560. #

  561. # Compile plugin-specific UI sources into the target designated by the given

  562. # name. There are some special considerations here:

  563. # - On most platforms, sources can be compiled only once, as part of DGL;

  564. # - On macOS, for any sources which define Objective-C interfaces, these must

  565. #   be recompiled for each plugin under a unique namespace. In this case, the

  566. #   name must be a plugin-specific identifier, and it will be used for computing

  567. #   the unique ID along with the project version.

  568. function(dpf__add_plugin_specific_ui_sources NAME)

  569.   if(APPLE)

  570.     target_sources("${NAME}" PRIVATE

  571.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  572.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  573.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  574.   endif()

  575. endfunction()

  576. 

  577. # dpf__add_dgl_system_libs

  578. # ------------------------------------------------------------------------------

  579. #

  580. # Find system libraries required by DGL and add them as an interface target.

  581. #

  582. function(dpf__add_dgl_system_libs)

  583.   if(TARGET dgl-system-libs)

  584.     return()

  585.   endif()

  586.   add_library(dgl-system-libs INTERFACE)

  587.   add_library(dgl-system-libs-definitions INTERFACE)

  588.   if(HAIKU)

  589.     target_link_libraries(dgl-system-libs INTERFACE "be")

  590.   elseif(WIN32)

  591.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  592.   elseif(APPLE)

  593.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  594.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  595.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  596.   else()

  597.     find_package(X11 REQUIRED)

  598.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  599.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  600.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  601.     if(X11_Xext_FOUND)

  602.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  603.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  604.     endif()

  605.     if(X11_XSync_FOUND)

  606.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  607.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  608.     endif()

  609.     if(X11_Xrandr_FOUND)

  610.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  611.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  612.     endif()

  613.     #if(X11_Xcursor_FOUND)

  614.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  615.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  616.     #endif()

  617.    endif()

  618. 

  619.    if(MSVC)

  620.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  621.      foreach(_gl_header "glext.h")

  622.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  623.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  624.        endif()

  625.      endforeach()

  626.      foreach(_khr_header "khrplatform.h")

  627.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  628.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  629.        endif()

  630.      endforeach()

  631.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  632.    endif()

  633. 

  634.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  635. endfunction()

  636. 

  637. # dpf__add_executable

  638. # ------------------------------------------------------------------------------

  639. #

  640. # Adds an executable target, and set some default properties on the target.

  641. #

  642. function(dpf__add_executable NAME)

  643.   add_executable("${NAME}" ${ARGN})

  644.   dpf__set_target_defaults("${NAME}")

  645.   if(MINGW)

  646.     target_link_libraries("${NAME}" PRIVATE "-static")

  647.   endif()

  648. endfunction()

  649. 

  650. # dpf__add_module

  651. # ------------------------------------------------------------------------------

  652. #

  653. # Adds a module target, and set some default properties on the target.

  654. #

  655. function(dpf__add_module NAME)

  656.   add_library("${NAME}" MODULE ${ARGN})

  657.   dpf__set_target_defaults("${NAME}")

  658.   if(MINGW)

  659.     target_link_libraries("${NAME}" PRIVATE "-static")

  660.   endif()

  661. endfunction()

  662. 

  663. # dpf__add_static_library

  664. # ------------------------------------------------------------------------------

  665. #

  666. # Adds a static library target, and set some default properties on the target.

  667. #

  668. function(dpf__add_static_library NAME)

  669.   add_library("${NAME}" STATIC ${ARGN})

  670.   dpf__set_target_defaults("${NAME}")

  671. endfunction()

  672. 

  673. # dpf__set_module_export_list

  674. # ------------------------------------------------------------------------------

  675. #

  676. # Applies a list of exported symbols to the module target.

  677. #

  678. function(dpf__set_module_export_list NAME EXPORTS)

  679.   if(WIN32)

  680.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  681.   elseif(APPLE)

  682.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  683.       "-Xlinker" "-exported_symbols_list"

  684.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  685.   else()

  686.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  687.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  688.   endif()

  689. endfunction()

  690. 

  691. # dpf__set_target_defaults

  692. # ------------------------------------------------------------------------------

  693. #

  694. # Set default properties which must apply to all DPF-defined targets.

  695. #

  696. function(dpf__set_target_defaults NAME)

  697.   set_target_properties("${NAME}" PROPERTIES

  698.     POSITION_INDEPENDENT_CODE TRUE

  699.     C_VISIBILITY_PRESET "hidden"

  700.     CXX_VISIBILITY_PRESET "hidden"

  701.     VISIBILITY_INLINES_HIDDEN TRUE)

  702.   if(WIN32)

  703.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  704.   endif()

  705.   if (MINGW)

  706.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  707.   endif()

  708.   if (MSVC)

  709.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  710.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  711.   endif()

  712. endfunction()

  713. 

  714. # dpf__add_plugin_main

  715. # ------------------------------------------------------------------------------

  716. #

  717. # Adds plugin code to the given target.

  718. #

  719. function(dpf__add_plugin_main NAME TARGET)

  720.   target_sources("${NAME}" PRIVATE

  721.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  722.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  723. endfunction()

  724. 

  725. # dpf__add_ui_main

  726. # ------------------------------------------------------------------------------

  727. #

  728. # Adds UI code to the given target (only if the target has UI).

  729. #

  730. function(dpf__add_ui_main NAME TARGET HAS_UI)

  731.   if(HAS_UI)

  732.     target_sources("${NAME}" PRIVATE

  733.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  734.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  735.   endif()

  736. endfunction()

  737. 

  738. # dpf__add_plugin_target_definition

  739. # ------------------------------------------------------------------------------

  740. #

  741. # Adds the plugins target macro definition.

  742. # This selects which entry file is compiled according to the target type.

  743. #

  744. function(dpf__add_plugin_target_definition NAME TARGET)

  745.   string(TOUPPER "${TARGET}" _upperTarget)

  746.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  747. endfunction()

  748. 

  749. # dpf__add_lv2_ttl_generator

  750. # ------------------------------------------------------------------------------

  751. #

  752. # Build the LV2 TTL generator.

  753. #

  754. function(dpf__add_lv2_ttl_generator)

  755.   if(TARGET lv2_ttl_generator)

  756.     return()

  757.   endif()

  758.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  759.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  760.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  761.   endif()

  762. endfunction()

  763. 

  764. # dpf__ensure_sources_non_empty

  765. # ------------------------------------------------------------------------------

  766. #

  767. # Ensure the given source list contains at least one file.

  768. # The function appends an empty source file to the list if necessary.

  769. # This is useful when CMake does not permit to add targets without sources.

  770. #

  771. function(dpf__ensure_sources_non_empty VAR)

  772.   if(NOT "" STREQUAL "${${VAR}}")

  773.     return()

  774.   endif()

  775.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  776.   if(NOT EXISTS "${_file}")

  777.     file(WRITE "${_file}" "")

  778.   endif()

  779.   set("${VAR}" "${_file}" PARENT_SCOPE)

  780. endfunction()

  781. 

  782. # dpf__create_dummy_source_list

  783. # ------------------------------------------------------------------------------

  784. #

  785. # Create a dummy source list which is equivalent to compiling nothing.

  786. # This is only for compatibility with older CMake versions, which refuse to add

  787. # targets without any sources.

  788. #

  789. macro(dpf__create_dummy_source_list VAR)

  790.   set("${VAR}")

  791.   if(CMAKE_VERSION VERSION_LESS "3.11")

  792.     dpf__ensure_sources_non_empty("${VAR}")

  793.   endif()

  794. endmacro()

  795. 

  796. # dpf__warn_once

  797. # ------------------------------------------------------------------------------

  798. #

  799. # Prints a warning message once only.

  800. #

  801. function(dpf__warn_once_only TOKEN MESSAGE)

  802.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  803.   if(NOT _warned)

  804.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  805.     message(WARNING "${MESSAGE}")

  806.   endif()

  807. endfunction()