DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2436 Commits
6 Branches
56MB
Tree: d2d85f3cac
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'd2d85f3cac'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1696 lines
60KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `USE_FILE_BROWSER`

  108. #       enable file browser dialog APIs

  109. #

  110. #   `USE_WEB_VIEW`

  111. #       enable web browser view APIs

  112. #

  113. function(dpf_add_plugin NAME)

  114.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  115.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  116.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  117.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  118. 

  119.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  120.     set(_dpf_plugin_UI_TYPE "opengl")

  121.   endif()

  122. 

  123.   set(_dgl_library)

  124.   if(_dpf_plugin_FILES_UI)

  125.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  126.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  127.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  128.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  129.       set(_dgl_library dgl-cairo)

  130.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  131.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  132.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  133.       set(_dgl_library dgl-external)

  134.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  135.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  136.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  137.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  138.       set(_dgl_library dgl-gles2)

  139.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  140.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  141.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  142.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  143.       set(_dgl_library dgl-gles3)

  144.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  145.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  146.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  147.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  148.       set(_dgl_library dgl-opengl)

  149.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  150.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  151.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  152.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  153.       set(_dgl_library dgl-opengl3)

  154.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  155.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  156.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  157.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  158.       set(_dgl_library dgl-vulkan)

  159.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  160.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  161.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  162.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  163.       set(_dgl_library dgl-external)

  164.     else()

  165.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  166.     endif()

  167.   else()

  168.     set(_dpf_plugin_UI_TYPE "")

  169.   endif()

  170. 

  171.   set(_dgl_has_ui OFF)

  172.   if(_dgl_library)

  173.     set(_dgl_has_ui ON)

  174.   endif()

  175. 

  176.   ###

  177.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  178.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  179.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  180. 

  181.   ###

  182.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  183.   target_include_directories("${NAME}" PUBLIC

  184.     "${DPF_ROOT_DIR}/distrho")

  185. 

  186.   if(_dpf_plugin_USE_FILE_BROWSER)

  187.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  188.   endif()

  189. 

  190.   if(_dpf_plugin_USE_WEB_VIEW)

  191.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  192.   endif()

  193. 

  194.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  195.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  196.   endif()

  197. 

  198.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  199.     target_link_libraries("${NAME}" PRIVATE "dl")

  200.   endif()

  201. 

  202.   if(_dgl_library)

  203.     # make sure that all code will see DGL_* definitions

  204.     target_link_libraries("${NAME}" PUBLIC

  205.       "${_dgl_library}-definitions"

  206.       dgl-system-libs-definitions

  207.       dgl-system-libs)

  208.   endif()

  209. 

  210.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  211.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  212. 

  213.   if(_dgl_library)

  214.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  215.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  216.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  217.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  218.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  219.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  220.           OUTPUT_STRIP_TRAILING_WHITESPACE

  221.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  222.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  223.       endif()

  224.     endif()

  225.     # add the files containing C++17 or Objective-C classes

  226.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  227.   else()

  228.     add_library("${NAME}-ui" INTERFACE)

  229.   endif()

  230. 

  231.   ###

  232.   foreach(_target ${_dpf_plugin_TARGETS})

  233.     if(_target STREQUAL "jack")

  234.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  235.     elseif(_target STREQUAL "ladspa")

  236.       dpf__build_ladspa("${NAME}")

  237.     elseif(_target STREQUAL "dssi")

  238.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  239.     elseif(_target STREQUAL "lv2")

  240.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  241.     elseif(_target STREQUAL "vst2")

  242.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  243.     elseif(_target STREQUAL "vst3")

  244.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  245.     elseif(_target STREQUAL "clap")

  246.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  247.     elseif(_target STREQUAL "au")

  248.       if (APPLE)

  249.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  250.       endif()

  251.     elseif(_target STREQUAL "static")

  252.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  253.     else()

  254.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  255.     endif()

  256.   endforeach()

  257. endfunction()

  258. 

  259. # dpf_add_executable(target <args...>)

  260. # ------------------------------------------------------------------------------

  261. #

  262. # Add a simple executable built using the DISTRHO Plugin Framework.

  263. #

  264. # ------------------------------------------------------------------------------

  265. # Arguments:

  266. #

  267. #   `UI_TYPE` <type>

  268. #       the user interface type, can be one of the following:

  269. #          - cairo

  270. #          - external

  271. #          - gles2

  272. #          - gles3

  273. #          - opengl (default)

  274. #          - opengl3

  275. #          - vulkan

  276. #          - webview

  277. #

  278. #   `NO_SHARED_RESOURCES`

  279. #       do not build DPF shared resources (fonts, etc)

  280. #

  281. #   `USE_FILE_BROWSER`

  282. #       enable file browser dialog APIs

  283. #

  284. #   `USE_WEB_VIEW`

  285. #       enable web browser view APIs

  286. #

  287. function(dpf_add_executable NAME)

  288.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  289.   set(oneValueArgs UI_TYPE)

  290.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  291. 

  292.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  293.     set(_dpf_plugin_UI_TYPE "opengl")

  294.   endif()

  295. 

  296.   set(_dgl_library)

  297.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  298.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  299.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  300.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  301.     set(_dgl_library dgl-cairo)

  302.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  303.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  304.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  305.     set(_dgl_library dgl-external)

  306.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  307.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  308.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  309.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  310.     set(_dgl_library dgl-gles2)

  311.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  312.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  313.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  314.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  315.     set(_dgl_library dgl-gles3)

  316.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  317.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  318.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  319.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  320.     set(_dgl_library dgl-opengl)

  321.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  322.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  323.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  324.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  325.     set(_dgl_library dgl-opengl3)

  326.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  327.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  328.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  329.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  330.     set(_dgl_library dgl-vulkan)

  331.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  332.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  333.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  334.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  335.     set(_dgl_library dgl-external)

  336.   else()

  337.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  338.   endif()

  339. 

  340.   set(_dgl_has_ui OFF)

  341.   if(_dgl_library)

  342.     set(_dgl_has_ui ON)

  343.   endif()

  344. 

  345.   dpf__create_dummy_source_list(_no_srcs)

  346.   dpf__add_executable("${NAME}" ${_no_srcs})

  347.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  348. 

  349.   if(_dpf_plugin_USE_FILE_BROWSER)

  350.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  351.   endif()

  352. 

  353.   if(_dpf_plugin_USE_WEB_VIEW)

  354.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  355.   endif()

  356. 

  357.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  358.     target_link_libraries("${NAME}" PRIVATE "dl")

  359.   endif()

  360. 

  361.   if(_dgl_library)

  362.     # make sure that all code will see DGL_* definitions

  363.     target_link_libraries("${NAME}" PUBLIC

  364.       "${_dgl_library}"

  365.       "${_dgl_library}-definitions"

  366.       dgl-system-libs-definitions

  367.       dgl-system-libs)

  368.     # extra linkage for linux web view

  369.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  370.       target_link_libraries("${NAME}" PRIVATE "rt")

  371.     endif()

  372.     # add the files containing C++17 or Objective-C classes

  373.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  374.   endif()

  375. endfunction()

  376. 

  377. # ------------------------------------------------------------------------------

  378. # DPF private functions (prefixed with `dpf__`)

  379. # ------------------------------------------------------------------------------

  380. 

  381. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  382. #       to the output directory.

  383. #

  384. 

  385. # dpf__build_jack

  386. # ------------------------------------------------------------------------------

  387. #

  388. # Add build rules for a JACK/Standalone program.

  389. #

  390. function(dpf__build_jack NAME HAS_UI)

  391.   dpf__create_dummy_source_list(_no_srcs)

  392. 

  393.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  394.   dpf__add_plugin_main("${NAME}-jack" "jack")

  395.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  396.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  397.   set_target_properties("${NAME}-jack" PROPERTIES

  398.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  399.     OUTPUT_NAME "${NAME}")

  400. 

  401.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  402.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  403. 

  404.   find_package(PkgConfig)

  405.   pkg_check_modules(SDL2 "sdl2")

  406.   if(SDL2_FOUND)

  407.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  408.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  409.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  410.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  411.   endif()

  412. 

  413.   if(APPLE OR WIN32)

  414.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  415.   else()

  416.     find_package(Threads)

  417.     pkg_check_modules(ALSA "alsa")

  418.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  419.     if(ALSA_FOUND)

  420.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  421.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  422.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  423.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  424.     endif()

  425.     if(PULSEAUDIO_FOUND)

  426.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  427.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  428.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  429.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  430.     endif()

  431.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  432.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  433.     endif()

  434.   endif()

  435. 

  436.   # for RtAudio native fallback

  437.   if(APPLE)

  438.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  439.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  440.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  441.     target_link_libraries("${NAME}-jack" PRIVATE

  442.       "${APPLE_COREAUDIO_FRAMEWORK}"

  443.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  444.       "${APPLE_COREMIDI_FRAMEWORK}")

  445.   elseif(WIN32)

  446.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  447.     if(HAS_UI AND MINGW)

  448.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  449.     endif()

  450.   endif()

  451. endfunction()

  452. 

  453. # dpf__build_ladspa

  454. # ------------------------------------------------------------------------------

  455. #

  456. # Add build rules for a LADSPA plugin.

  457. #

  458. function(dpf__build_ladspa NAME)

  459.   dpf__create_dummy_source_list(_no_srcs)

  460. 

  461.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  462.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  463.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  464.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  465.   set_target_properties("${NAME}-ladspa" PROPERTIES

  466.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  467.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  468.     OUTPUT_NAME "${NAME}-ladspa"

  469.     PREFIX "")

  470. endfunction()

  471. 

  472. # dpf__build_dssi

  473. # ------------------------------------------------------------------------------

  474. #

  475. # Add build rules for a DSSI plugin.

  476. #

  477. function(dpf__build_dssi NAME HAS_UI)

  478.   find_package(PkgConfig)

  479.   pkg_check_modules(LIBLO "liblo")

  480.   if(NOT LIBLO_FOUND)

  481.     dpf__warn_once_only(missing_liblo

  482.       "liblo is not found, skipping the `dssi` plugin targets")

  483.     return()

  484.   endif()

  485. 

  486.   dpf__create_dummy_source_list(_no_srcs)

  487. 

  488.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  489.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  490.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  491.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  492.   set_target_properties("${NAME}-dssi" PROPERTIES

  493.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  494.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  495.     OUTPUT_NAME "${NAME}-dssi"

  496.     PREFIX "")

  497. 

  498.   if(HAS_UI)

  499.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  500.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  501.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  502.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  503.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  504.       OUTPUT_NAME "${NAME}_ui")

  505. 

  506.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  507.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  508.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  509.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  510.   endif()

  511. endfunction()

  512. 

  513. # dpf__build_lv2

  514. # ------------------------------------------------------------------------------

  515. #

  516. # Add build rules for an LV2 plugin.

  517. #

  518. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  519.   dpf__create_dummy_source_list(_no_srcs)

  520. 

  521.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  522.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  523.   if(HAS_UI AND MONOLITHIC)

  524.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  525.   else()

  526.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  527.   endif()

  528.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  529.   set_target_properties("${NAME}-lv2" PROPERTIES

  530.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  531.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  532.     OUTPUT_NAME "${NAME}_dsp"

  533.     PREFIX "")

  534. 

  535.   if(HAS_UI)

  536.     if(MONOLITHIC)

  537.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  538.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  539.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  540.       set_target_properties("${NAME}-lv2" PROPERTIES

  541.         OUTPUT_NAME "${NAME}")

  542.     else()

  543.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  544.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  545.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  546.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  547.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  548.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  549.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  550.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  551.         OUTPUT_NAME "${NAME}_ui"

  552.         PREFIX "")

  553.     endif()

  554.   endif()

  555. 

  556.   dpf__add_lv2_ttl_generator()

  557.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  558. 

  559.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  560. 

  561.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  562.     COMMAND

  563.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  564.     "$<TARGET_FILE:lv2_ttl_generator>"

  565.     "$<TARGET_FILE:${NAME}-lv2>"

  566.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  567.     DEPENDS lv2_ttl_generator)

  568. endfunction()

  569. 

  570. # dpf__build_vst2

  571. # ------------------------------------------------------------------------------

  572. #

  573. # Add build rules for a VST2 plugin.

  574. #

  575. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  576.   dpf__create_dummy_source_list(_no_srcs)

  577. 

  578.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  579.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  580.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  581.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  582.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  583.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  584.   set_target_properties("${NAME}-vst2" PROPERTIES

  585.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  586.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  587.     OUTPUT_NAME "${NAME}-vst2"

  588.     PREFIX "")

  589.   if(APPLE)

  590.     set_target_properties("${NAME}-vst2" PROPERTIES

  591.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  592.       OUTPUT_NAME "${NAME}"

  593.       SUFFIX "")

  594.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  595.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  596.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  597.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  598.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  599.   endif()

  600. endfunction()

  601. 

  602. # dpf__determine_vst3_package_architecture

  603. # ------------------------------------------------------------------------------

  604. #

  605. # Determines the package architecture for a VST3 plugin target.

  606. #

  607. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  608.   # if set by variable, override the detection

  609.   if(DPF_VST3_ARCHITECTURE)

  610.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  611.     return()

  612.   endif()

  613. 

  614.   # not used on Apple, which supports universal binary

  615.   if(APPLE)

  616.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  617.     return()

  618.   endif()

  619. 

  620.   # identify the target processor (special case of MSVC, problematic sometimes)

  621.   if(MSVC)

  622.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  623.   else()

  624.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  625.   endif()

  626. 

  627.   # transform the processor name to a format that VST3 recognizes

  628.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  629.     set(vst3_package_arch "x86_64")

  630.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  631.     if(WIN32)

  632.       set(vst3_package_arch "x86")

  633.     else()

  634.       set(vst3_package_arch "i386")

  635.     endif()

  636.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  637.     set(vst3_package_arch "${vst3_system_arch}")

  638.   else()

  639.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  640.   endif()

  641. 

  642.   # TODO: the detections for Windows arm/arm64 when supported

  643. 

  644.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  645. endfunction()

  646. 

  647. # dpf__build_vst3

  648. # ------------------------------------------------------------------------------

  649. #

  650. # Add build rules for a VST3 plugin.

  651. #

  652. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  653.   dpf__determine_vst3_package_architecture(vst3_arch)

  654. 

  655.   dpf__create_dummy_source_list(_no_srcs)

  656. 

  657.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  658.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  659.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  660.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  661.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  662.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  663.   set_target_properties("${NAME}-vst3" PROPERTIES

  664.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  665.     OUTPUT_NAME "${NAME}"

  666.     PREFIX "")

  667. 

  668.   if(APPLE)

  669.     set_target_properties("${NAME}-vst3" PROPERTIES

  670.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  671.       SUFFIX "")

  672.   elseif(WIN32)

  673.     set_target_properties("${NAME}-vst3" PROPERTIES

  674.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  675.   else()

  676.     set_target_properties("${NAME}-vst3" PROPERTIES

  677.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  678.   endif()

  679. 

  680.   if(APPLE)

  681.     # Uses the same macOS bundle template as VST2

  682.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  683.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  684.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  685.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  686.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  687.   endif()

  688. endfunction()

  689. 

  690. # dpf__build_clap

  691. # ------------------------------------------------------------------------------

  692. #

  693. # Add build rules for a CLAP plugin.

  694. #

  695. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  696.   dpf__create_dummy_source_list(_no_srcs)

  697. 

  698.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  699.   dpf__add_plugin_main("${NAME}-clap" "clap")

  700.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  701.   dpf__set_module_export_list("${NAME}-clap" "clap")

  702.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  703.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  704.   set_target_properties("${NAME}-clap" PROPERTIES

  705.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  706.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  707.     OUTPUT_NAME "${NAME}"

  708.     PREFIX ""

  709.     SUFFIX ".clap")

  710. 

  711.   if(APPLE)

  712.     set_target_properties("${NAME}-clap" PROPERTIES

  713.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  714.       OUTPUT_NAME "${NAME}"

  715.       SUFFIX "")

  716.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  717.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  718.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  719.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  720.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  721.   endif()

  722. endfunction()

  723. 

  724. # dpf__build_au

  725. # ------------------------------------------------------------------------------

  726. #

  727. # Add build rules for an AUv2 plugin.

  728. #

  729. function(dpf__build_au NAME HAS_UI)

  730.   dpf__create_dummy_source_list(_no_srcs)

  731. 

  732.   dpf__add_module("${NAME}-au" ${_no_srcs})

  733.   dpf__add_plugin_main("${NAME}-au" "au")

  734.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  735.   dpf__set_module_export_list("${NAME}-au" "au")

  736.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  737.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  738.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  739.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  740.   target_link_libraries("${NAME}-au" PRIVATE

  741.     "${NAME}-dsp"

  742.     "${NAME}-ui"

  743.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  744.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  745.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  746.   set_target_properties("${NAME}-au" PROPERTIES

  747.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  748.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  749.     OUTPUT_NAME "${NAME}"

  750.     PREFIX ""

  751.     SUFFIX "")

  752. 

  753.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  754.   dpf__add_plugin_main("${NAME}-export" "export")

  755.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  756.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  757. 

  758.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  759. 

  760.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  761.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  762.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  763.     DEPENDS "${NAME}-export")

  764. 

  765.   add_dependencies("${NAME}-au" "${NAME}-export")

  766. 

  767.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  768.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  769. endfunction()

  770. 

  771. # dpf__build_static

  772. # ------------------------------------------------------------------------------

  773. #

  774. # Add build rules for a static library.

  775. #

  776. function(dpf__build_static NAME HAS_UI)

  777.   dpf__create_dummy_source_list(_no_srcs)

  778. 

  779.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  780.   dpf__add_plugin_main("${NAME}-static" "static")

  781.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  782.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  783. 

  784.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  785.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  786.   foreach(src ${dsp_srcs})

  787.     target_sources("${NAME}-static" PRIVATE ${src})

  788.   endforeach()

  789.   foreach(src ${ui_srcs})

  790.     target_sources("${NAME}-static" PRIVATE ${src})

  791.   endforeach()

  792. 

  793.   set_target_properties("${NAME}-static" PROPERTIES

  794.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  795.     OUTPUT_NAME "${NAME}"

  796.     PREFIX "")

  797. endfunction()

  798. 

  799. # dpf__add_dgl_cairo

  800. # ------------------------------------------------------------------------------

  801. #

  802. # Add the Cairo variant of DGL, if not already available.

  803. #

  804. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  805.   if(TARGET dgl-cairo)

  806.     return()

  807.   endif()

  808. 

  809.   find_package(PkgConfig)

  810.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  811. 

  812.   link_directories(${CAIRO_LIBRARY_DIRS})

  813. 

  814.   dpf__add_static_library(dgl-cairo STATIC

  815.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  816.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  817.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  818.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  819.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  820.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  821.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  822.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  823.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  824.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  825.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  826.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  827.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  828.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  829.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  830.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  831.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  832.   if(SHARED_RESOURCES)

  833.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  834.   else()

  835.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  836.   endif()

  837.   if(APPLE)

  838.     target_sources(dgl-cairo PRIVATE

  839.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  840.   else()

  841.     target_sources(dgl-cairo PRIVATE

  842.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  843.   endif()

  844.   target_include_directories(dgl-cairo PUBLIC

  845.     "${DPF_ROOT_DIR}/dgl")

  846.   target_include_directories(dgl-cairo PUBLIC

  847.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  848. 

  849.   if(USE_FILE_BROWSER)

  850.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  851.   endif()

  852. 

  853.   if(USE_WEB_VIEW)

  854.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  855.     if(APPLE)

  856.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  857.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  858.     elseif(WIN32)

  859.       target_sources(dgl-cairo PRIVATE

  860.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  861.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  862.         PROPERTIES

  863.           COMPILE_FLAGS

  864.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  865.     endif()

  866.   endif()

  867. 

  868.   dpf__add_dgl_system_libs()

  869.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  870. 

  871.   add_library(dgl-cairo-definitions INTERFACE)

  872.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  873. 

  874.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  875.   if(MINGW)

  876.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  877.   else()

  878.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  879.   endif()

  880.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  881. endfunction()

  882. 

  883. # dpf__add_dgl_external

  884. # ------------------------------------------------------------------------------

  885. #

  886. # Add the external variant of DGL, if not already available.

  887. #

  888. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  889.   if(TARGET dgl-external)

  890.     return()

  891.   endif()

  892. 

  893.   dpf__add_static_library(dgl-external STATIC

  894.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  895.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  896.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  897.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  898.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  899.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  900.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  901.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  902.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  903.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  904.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  905.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  906.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  907.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  908.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  909.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  910.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  911. 

  912.   if(APPLE)

  913.     target_sources(dgl-external PRIVATE

  914.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  915.   else()

  916.     target_sources(dgl-external PRIVATE

  917.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  918.   endif()

  919.   target_include_directories(dgl-external PUBLIC

  920.     "${DPF_ROOT_DIR}/dgl")

  921.   target_include_directories(dgl-external PUBLIC

  922.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  923. 

  924.   if(USE_FILE_BROWSER)

  925.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  926.   endif()

  927. 

  928.   if(USE_WEB_VIEW)

  929.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  930.     if(APPLE)

  931.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  932.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  933.     elseif(WIN32)

  934.       target_sources(dgl-external PRIVATE

  935.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  936.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  937.         PROPERTIES

  938.           COMPILE_FLAGS

  939.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  940.     endif()

  941.   endif()

  942. 

  943.   dpf__add_dgl_system_libs()

  944.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  945.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  946. 

  947.   add_library(dgl-external-definitions INTERFACE)

  948.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  949. 

  950.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  951.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  952. endfunction()

  953. 

  954. # dpf__add_dgl_gles2

  955. # ------------------------------------------------------------------------------

  956. #

  957. # Add the GLESv2 variant of DGL, if not already available.

  958. #

  959. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  960.   if(TARGET dgl-gles2)

  961.     return()

  962.   endif()

  963. 

  964.   if(NOT OpenGL_GL_PREFERENCE)

  965.     set(OpenGL_GL_PREFERENCE "LEGACY")

  966.   endif()

  967. 

  968.   find_package(OpenGL REQUIRED)

  969. 

  970.   dpf__add_static_library(dgl-gles2 STATIC

  971.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  972.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  973.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  974.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  975.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  976.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  977.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  978.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  979.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  980.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  981.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  982.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  983.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  984.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  985.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  986.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  987.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  988.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  989.   if(SHARED_RESOURCES)

  990.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  991.   else()

  992.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  993.   endif()

  994.   if(APPLE)

  995.     target_sources(dgl-gles2 PRIVATE

  996.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  997.   else()

  998.     target_sources(dgl-gles2 PRIVATE

  999.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1000.   endif()

  1001.   target_include_directories(dgl-gles2 PUBLIC

  1002.     "${DPF_ROOT_DIR}/dgl")

  1003.   target_include_directories(dgl-gles2 PUBLIC

  1004.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1005. 

  1006.   if(APPLE)

  1007.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1008.   endif()

  1009. 

  1010.   if(USE_FILE_BROWSER)

  1011.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1012.   endif()

  1013. 

  1014.   if(USE_WEB_VIEW)

  1015.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1016.     if(APPLE)

  1017.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1018.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1019.     elseif(WIN32)

  1020.       target_sources(dgl-gles2 PRIVATE

  1021.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1022.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1023.         PROPERTIES

  1024.           COMPILE_FLAGS

  1025.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1026.     endif()

  1027.   endif()

  1028. 

  1029.   dpf__add_dgl_system_libs()

  1030.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1031.   target_link_options(dgl-gles2

  1032.     INTERFACE

  1033.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1034.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1035.   )

  1036. 

  1037.   add_library(dgl-gles2-definitions INTERFACE)

  1038.   target_compile_definitions(dgl-gles2-definitions

  1039.     INTERFACE

  1040.       DGL_USE_OPENGL3

  1041.       DGL_USE_GLES

  1042.       DGL_USE_GLES2

  1043.       DGL_OPENGL

  1044.       HAVE_OPENGL

  1045.       HAVE_DGL

  1046.   )

  1047. 

  1048.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1049.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1050. endfunction()

  1051. 

  1052. # dpf__add_dgl_gles3

  1053. # ------------------------------------------------------------------------------

  1054. #

  1055. # Add the GLESv3 variant of DGL, if not already available.

  1056. #

  1057. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1058.   if(TARGET dgl-gles3)

  1059.     return()

  1060.   endif()

  1061. 

  1062.   if(NOT OpenGL_GL_PREFERENCE)

  1063.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1064.   endif()

  1065. 

  1066.   find_package(OpenGL REQUIRED)

  1067. 

  1068.   dpf__add_static_library(dgl-gles3 STATIC

  1069.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1070.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1071.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1072.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1073.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1074.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1075.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1076.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1077.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1078.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1079.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1080.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1081.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1082.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1083.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1084.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1085.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1086.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1087.   if(SHARED_RESOURCES)

  1088.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1089.   else()

  1090.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1091.   endif()

  1092.   if(APPLE)

  1093.     target_sources(dgl-gles3 PRIVATE

  1094.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1095.   else()

  1096.     target_sources(dgl-gles3 PRIVATE

  1097.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1098.   endif()

  1099.   target_include_directories(dgl-gles3 PUBLIC

  1100.     "${DPF_ROOT_DIR}/dgl")

  1101.   target_include_directories(dgl-gles3 PUBLIC

  1102.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1103. 

  1104.   if(APPLE)

  1105.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1106.   endif()

  1107. 

  1108.   if(USE_FILE_BROWSER)

  1109.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1110.   endif()

  1111. 

  1112.   if(USE_WEB_VIEW)

  1113.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1114.     if(APPLE)

  1115.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1116.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1117.     elseif(WIN32)

  1118.       target_sources(dgl-gles3 PRIVATE

  1119.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1120.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1121.         PROPERTIES

  1122.           COMPILE_FLAGS

  1123.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1124.     endif()

  1125.   endif()

  1126. 

  1127.   dpf__add_dgl_system_libs()

  1128.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1129. 

  1130.   add_library(dgl-gles3-definitions INTERFACE)

  1131.   target_compile_definitions(dgl-gles3-definitions

  1132.     INTERFACE

  1133.       DGL_USE_OPENGL3

  1134.       DGL_USE_GLES

  1135.       DGL_USE_GLES3

  1136.       DGL_OPENGL

  1137.       HAVE_OPENGL

  1138.       HAVE_DGL

  1139.   )

  1140. 

  1141.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1142.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1143. endfunction()

  1144. 

  1145. # dpf__add_dgl_opengl

  1146. # ------------------------------------------------------------------------------

  1147. #

  1148. # Add the OpenGL variant of DGL, if not already available.

  1149. #

  1150. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1151.   if(TARGET dgl-opengl)

  1152.     return()

  1153.   endif()

  1154. 

  1155.   if(NOT OpenGL_GL_PREFERENCE)

  1156.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1157.   endif()

  1158. 

  1159.   find_package(OpenGL REQUIRED)

  1160. 

  1161.   dpf__add_static_library(dgl-opengl STATIC

  1162.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1163.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1164.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1165.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1166.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1167.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1168.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1169.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1170.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1171.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1172.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1173.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1174.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1175.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1176.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1177.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1178.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1179.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1180.   if(SHARED_RESOURCES)

  1181.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1182.   else()

  1183.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1184.   endif()

  1185.   if(APPLE)

  1186.     target_sources(dgl-opengl PRIVATE

  1187.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1188.   else()

  1189.     target_sources(dgl-opengl PRIVATE

  1190.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1191.   endif()

  1192.   target_include_directories(dgl-opengl PUBLIC

  1193.     "${DPF_ROOT_DIR}/dgl")

  1194.   target_include_directories(dgl-opengl PUBLIC

  1195.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1196. 

  1197.   if(APPLE)

  1198.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1199.   endif()

  1200. 

  1201.   if(USE_FILE_BROWSER)

  1202.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1203.   endif()

  1204. 

  1205.   if(USE_WEB_VIEW)

  1206.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1207.     if(APPLE)

  1208.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1209.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1210.     elseif(WIN32)

  1211.       target_sources(dgl-opengl PRIVATE

  1212.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1213.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1214.         PROPERTIES

  1215.           COMPILE_FLAGS

  1216.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1217.     endif()

  1218.   endif()

  1219. 

  1220.   dpf__add_dgl_system_libs()

  1221.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1222.   target_link_options(dgl-opengl

  1223.     INTERFACE

  1224.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1225.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1226.   )

  1227. 

  1228.   add_library(dgl-opengl-definitions INTERFACE)

  1229.   target_compile_definitions(dgl-opengl-definitions

  1230.     INTERFACE

  1231.       DGL_OPENGL

  1232.       HAVE_OPENGL

  1233.       HAVE_DGL

  1234.   )

  1235. 

  1236.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1237.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1238. endfunction()

  1239. 

  1240. # dpf__add_dgl_opengl3

  1241. # ------------------------------------------------------------------------------

  1242. #

  1243. # Add the OpenGL3 variant of DGL, if not already available.

  1244. #

  1245. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1246.   if(TARGET dgl-opengl3)

  1247.     return()

  1248.   endif()

  1249. 

  1250.   if(NOT OpenGL_GL_PREFERENCE)

  1251.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1252.   endif()

  1253. 

  1254.   find_package(OpenGL REQUIRED)

  1255. 

  1256.   dpf__add_static_library(dgl-opengl3 STATIC

  1257.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1258.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1259.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1260.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1261.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1262.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1263.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1264.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1265.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1266.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1267.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1268.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1269.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1270.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1271.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1272.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1273.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1274.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1275.   if(SHARED_RESOURCES)

  1276.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1277.   else()

  1278.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1279.   endif()

  1280.   if(APPLE)

  1281.     target_sources(dgl-opengl3 PRIVATE

  1282.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1283.   else()

  1284.     target_sources(dgl-opengl3 PRIVATE

  1285.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1286.   endif()

  1287.   target_include_directories(dgl-opengl3 PUBLIC

  1288.     "${DPF_ROOT_DIR}/dgl")

  1289.   target_include_directories(dgl-opengl3 PUBLIC

  1290.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1291. 

  1292.   if(APPLE)

  1293.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1294.   endif()

  1295. 

  1296.   if(USE_FILE_BROWSER)

  1297.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1298.   endif()

  1299. 

  1300.   if(USE_WEB_VIEW)

  1301.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1302.     if(APPLE)

  1303.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1304.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1305.     elseif(WIN32)

  1306.       target_sources(dgl-opengl3 PRIVATE

  1307.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1308.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1309.         PROPERTIES

  1310.           COMPILE_FLAGS

  1311.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1312.     endif()

  1313.   endif()

  1314. 

  1315.   dpf__add_dgl_system_libs()

  1316.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1317. 

  1318.   add_library(dgl-opengl3-definitions INTERFACE)

  1319.   target_compile_definitions(dgl-opengl3-definitions

  1320.     INTERFACE

  1321.       DGL_USE_OPENGL3

  1322.       DGL_OPENGL

  1323.       HAVE_OPENGL

  1324.       HAVE_DGL

  1325.   )

  1326. 

  1327.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1328.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1329. endfunction()

  1330. 

  1331. # dpf__add_dgl_vulkan

  1332. # ------------------------------------------------------------------------------

  1333. #

  1334. # Add the Vulkan variant of DGL, if not already available.

  1335. #

  1336. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1337.   if(TARGET dgl-vulkan)

  1338.     return()

  1339.   endif()

  1340. 

  1341.   find_package(Vulkan REQUIRED)

  1342. 

  1343.   dpf__add_static_library(dgl-vulkan STATIC

  1344.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1345.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1346.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1347.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1348.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1349.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1350.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1351.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1352.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1353.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1354.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1355.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1356.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1357.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1358.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1359.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1360.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1361.   if(NO_SHARED_RESOURCES)

  1362.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1363.   else()

  1364.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1365.   endif()

  1366.   if(APPLE)

  1367.     target_sources(dgl-vulkan PRIVATE

  1368.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1369.   else()

  1370.     target_sources(dgl-vulkan PRIVATE

  1371.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1372.   endif()

  1373.   target_include_directories(dgl-vulkan PUBLIC

  1374.     "${DPF_ROOT_DIR}/dgl")

  1375.   target_include_directories(dgl-vulkan PUBLIC

  1376.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1377. 

  1378.   if(APPLE)

  1379.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1380.   endif()

  1381. 

  1382.   if(USE_FILE_BROWSER)

  1383.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1384.   endif()

  1385. 

  1386.   if(USE_WEB_VIEW)

  1387.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1388.     if(APPLE)

  1389.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1390.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1391.     elseif(WIN32)

  1392.       target_sources(dgl-vulkan PRIVATE

  1393.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1394.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1395.         PROPERTIES

  1396.           COMPILE_FLAGS

  1397.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1398.     endif()

  1399.   endif()

  1400. 

  1401.   dpf__add_dgl_system_libs()

  1402.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1403. 

  1404.   add_library(dgl-vulkan-definitions INTERFACE)

  1405.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1406. 

  1407.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1408.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1409. endfunction()

  1410. 

  1411. # dpf__add_plugin_specific_ui_sources

  1412. # ------------------------------------------------------------------------------

  1413. #

  1414. # Compile system specific files

  1415. #

  1416. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1417.   if(APPLE)

  1418.     target_sources("${NAME}" PRIVATE

  1419.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1420.     if(USE_WEB_VIEW)

  1421.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1422.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1423.     endif()

  1424.   elseif(WIN32 AND USE_WEB_VIEW)

  1425.     target_sources("${NAME}" PRIVATE

  1426.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1427.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1428.       PROPERTIES

  1429.         COMPILE_FLAGS

  1430.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1431.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1432.   endif()

  1433. endfunction()

  1434. 

  1435. # dpf__add_dgl_system_libs

  1436. # ------------------------------------------------------------------------------

  1437. #

  1438. # Find system libraries required by DGL and add them as an interface target.

  1439. #

  1440. function(dpf__add_dgl_system_libs)

  1441.   if(TARGET dgl-system-libs)

  1442.     return()

  1443.   endif()

  1444.   add_library(dgl-system-libs INTERFACE)

  1445.   add_library(dgl-system-libs-definitions INTERFACE)

  1446.   if(APPLE)

  1447.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1448.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1449.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1450.   elseif(EMSCRIPTEN)

  1451.   elseif(HAIKU)

  1452.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1453.   elseif(WIN32)

  1454.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1455.   else()

  1456.     find_package(PkgConfig)

  1457.     pkg_check_modules(DBUS "dbus-1")

  1458.     if(DBUS_FOUND)

  1459.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1460.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1461.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1462.     endif()

  1463.     find_package(X11 REQUIRED)

  1464.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1465.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1466.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1467.     if(X11_Xcursor_FOUND)

  1468.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1469.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1470.     endif()

  1471.     if(X11_Xext_FOUND)

  1472.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1473.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1474.     endif()

  1475.     if(X11_Xrandr_FOUND)

  1476.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1477.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1478.     endif()

  1479.     if(X11_XSync_FOUND)

  1480.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1481.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1482.     endif()

  1483.    endif()

  1484. 

  1485.    if(MSVC)

  1486.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1487.      foreach(_gl_header "glext.h")

  1488.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1489.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1490.        endif()

  1491.      endforeach()

  1492.      foreach(_khr_header "khrplatform.h")

  1493.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1494.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1495.        endif()

  1496.      endforeach()

  1497.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1498.    endif()

  1499. 

  1500.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1501. endfunction()

  1502. 

  1503. # dpf__add_executable

  1504. # ------------------------------------------------------------------------------

  1505. #

  1506. # Adds an executable target, and set some default properties on the target.

  1507. #

  1508. function(dpf__add_executable NAME)

  1509.   add_executable("${NAME}" ${ARGN})

  1510.   dpf__set_target_defaults("${NAME}")

  1511.   if(MINGW)

  1512.     target_link_libraries("${NAME}" PRIVATE "-static")

  1513.   endif()

  1514. endfunction()

  1515. 

  1516. # dpf__add_module

  1517. # ------------------------------------------------------------------------------

  1518. #

  1519. # Adds a module target, and set some default properties on the target.

  1520. #

  1521. function(dpf__add_module NAME)

  1522.   add_library("${NAME}" MODULE ${ARGN})

  1523.   dpf__set_target_defaults("${NAME}")

  1524.   if(APPLE)

  1525.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1526.   elseif(MINGW)

  1527.     target_link_libraries("${NAME}" PRIVATE "-static")

  1528.   endif()

  1529. endfunction()

  1530. 

  1531. # dpf__add_static_library

  1532. # ------------------------------------------------------------------------------

  1533. #

  1534. # Adds a static library target, and set some default properties on the target.

  1535. #

  1536. function(dpf__add_static_library NAME)

  1537.   add_library("${NAME}" STATIC ${ARGN})

  1538.   dpf__set_target_defaults("${NAME}")

  1539. endfunction()

  1540. 

  1541. # dpf__set_module_export_list

  1542. # ------------------------------------------------------------------------------

  1543. #

  1544. # Applies a list of exported symbols to the module target.

  1545. #

  1546. function(dpf__set_module_export_list NAME EXPORTS)

  1547.   if(WIN32)

  1548.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1549.   elseif(APPLE)

  1550.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1551.       "-Xlinker" "-exported_symbols_list"

  1552.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1553.   else()

  1554.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1555.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1556.   endif()

  1557. endfunction()

  1558. 

  1559. # dpf__set_target_defaults

  1560. # ------------------------------------------------------------------------------

  1561. #

  1562. # Set default properties which must apply to all DPF-defined targets.

  1563. #

  1564. function(dpf__set_target_defaults NAME)

  1565.   set_target_properties("${NAME}" PROPERTIES

  1566.     POSITION_INDEPENDENT_CODE TRUE

  1567.     C_VISIBILITY_PRESET "hidden"

  1568.     CXX_VISIBILITY_PRESET "hidden"

  1569.     VISIBILITY_INLINES_HIDDEN TRUE)

  1570.   if(WIN32)

  1571.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1572.   endif()

  1573.   if (MINGW)

  1574.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1575.   endif()

  1576.   if (MSVC)

  1577.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1578.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1579.   endif()

  1580.   if (CMAKE_COMPILER_IS_GNUCXX)

  1581.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1582.   endif()

  1583.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1584.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1585.   endif()

  1586. endfunction()

  1587. 

  1588. # dpf__add_plugin_main

  1589. # ------------------------------------------------------------------------------

  1590. #

  1591. # Adds plugin code to the given target.

  1592. #

  1593. function(dpf__add_plugin_main NAME TARGET)

  1594.   target_sources("${NAME}" PRIVATE

  1595.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1596.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1597. endfunction()

  1598. 

  1599. # dpf__add_ui_main

  1600. # ------------------------------------------------------------------------------

  1601. #

  1602. # Adds UI code to the given target (only if the target has UI).

  1603. #

  1604. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1605.   if(HAS_UI)

  1606.     target_sources("${NAME}" PRIVATE

  1607.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1608.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1609.   endif()

  1610. endfunction()

  1611. 

  1612. # dpf__add_plugin_target_definition

  1613. # ------------------------------------------------------------------------------

  1614. #

  1615. # Adds the plugins target macro definition.

  1616. # This selects which entry file is compiled according to the target type.

  1617. #

  1618. function(dpf__add_plugin_target_definition NAME TARGET)

  1619.   string(TOUPPER "${TARGET}" _upperTarget)

  1620.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1621. endfunction()

  1622. 

  1623. # dpf__add_lv2_ttl_generator

  1624. # ------------------------------------------------------------------------------

  1625. #

  1626. # Build the LV2 TTL generator.

  1627. #

  1628. function(dpf__add_lv2_ttl_generator)

  1629.   if(TARGET lv2_ttl_generator)

  1630.     return()

  1631.   endif()

  1632.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1633.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1634.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1635.   endif()

  1636. endfunction()

  1637. 

  1638. # dpf__ensure_sources_non_empty

  1639. # ------------------------------------------------------------------------------

  1640. #

  1641. # Ensure the given source list contains at least one file.

  1642. # The function appends an empty source file to the list if necessary.

  1643. # This is useful when CMake does not permit to add targets without sources.

  1644. #

  1645. function(dpf__ensure_sources_non_empty VAR)

  1646.   if(NOT "" STREQUAL "${${VAR}}")

  1647.     return()

  1648.   endif()

  1649.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1650.   if(NOT EXISTS "${_file}")

  1651.     file(WRITE "${_file}" "")

  1652.   endif()

  1653.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1654. endfunction()

  1655. 

  1656. # dpf__create_dummy_source_list

  1657. # ------------------------------------------------------------------------------

  1658. #

  1659. # Create a dummy source list which is equivalent to compiling nothing.

  1660. # This is only for compatibility with older CMake versions, which refuse to add

  1661. # targets without any sources.

  1662. #

  1663. macro(dpf__create_dummy_source_list VAR)

  1664.   set("${VAR}")

  1665.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1666.     dpf__ensure_sources_non_empty("${VAR}")

  1667.   endif()

  1668. endmacro()

  1669. 

  1670. # dpf__target_link_directories

  1671. # ------------------------------------------------------------------------------

  1672. #

  1673. # Call `target_link_directories` if cmake >= 3.13,

  1674. # otherwise fallback to global `link_directories`.

  1675. #

  1676. macro(dpf__target_link_directories NAME DIRS)

  1677.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1678.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1679.   else()

  1680.     link_directories(${DIRS})

  1681.   endif()

  1682. endmacro()

  1683. 

  1684. # dpf__warn_once

  1685. # ------------------------------------------------------------------------------

  1686. #

  1687. # Prints a warning message once only.

  1688. #

  1689. function(dpf__warn_once_only TOKEN MESSAGE)

  1690.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1691.   if(NOT _warned)

  1692.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1693.     message(WARNING "${MESSAGE}")

  1694.   endif()

  1695. endfunction()