DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2374 Commits
7 Branches
295MB
Tree: cc35a95d59
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'cc35a95d59'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1277 lines
46KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  125.       set(_dgl_library dgl-cairo)

  126.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  127.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  128.       set(_dgl_library dgl-external)

  129.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  130.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  131.       set(_dgl_library dgl-opengl)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  133.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  134.       set(_dgl_library dgl-opengl3)

  135.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  136.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  137.       set(_dgl_library dgl-vulkan)

  138.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  139.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  140.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  141.       set(_dgl_library dgl-external)

  142.     else()

  143.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  144.     endif()

  145.   else()

  146.     set(_dpf_plugin_UI_TYPE "")

  147.   endif()

  148. 

  149.   set(_dgl_has_ui OFF)

  150.   if(_dgl_library)

  151.     set(_dgl_has_ui ON)

  152.   endif()

  153. 

  154.   ###

  155.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  156.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  157.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  158. 

  159.   ###

  160.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  161.   target_include_directories("${NAME}" PUBLIC

  162.     "${DPF_ROOT_DIR}/distrho")

  163. 

  164.   if(_dpf_plugin_USE_FILE_BROWSER)

  165.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  166.   endif()

  167. 

  168.   if(_dpf_plugin_USE_WEB_VIEW)

  169.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  170.   endif()

  171. 

  172.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  173.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  174.   endif()

  175. 

  176.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  177.     target_link_libraries("${NAME}" PRIVATE "dl")

  178.   endif()

  179. 

  180.   if(_dgl_library)

  181.     # make sure that all code will see DGL_* definitions

  182.     target_link_libraries("${NAME}" PUBLIC

  183.       "${_dgl_library}-definitions"

  184.       dgl-system-libs-definitions

  185.       dgl-system-libs)

  186.   endif()

  187. 

  188.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  189.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  190. 

  191.   if(_dgl_library)

  192.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  193.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  194.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  195.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  196.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  197.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  198.           OUTPUT_STRIP_TRAILING_WHITESPACE

  199.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  200.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  201.       endif()

  202.     endif()

  203.     # add the files containing C++17 or Objective-C classes

  204.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  205.   else()

  206.     add_library("${NAME}-ui" INTERFACE)

  207.   endif()

  208. 

  209.   ###

  210.   foreach(_target ${_dpf_plugin_TARGETS})

  211.     if(_target STREQUAL "jack")

  212.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  213.     elseif(_target STREQUAL "ladspa")

  214.       dpf__build_ladspa("${NAME}")

  215.     elseif(_target STREQUAL "dssi")

  216.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  217.     elseif(_target STREQUAL "lv2")

  218.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  219.     elseif(_target STREQUAL "vst2")

  220.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  221.     elseif(_target STREQUAL "vst3")

  222.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  223.     elseif(_target STREQUAL "clap")

  224.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  225.     elseif(_target STREQUAL "au")

  226.       if (APPLE)

  227.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  228.       endif()

  229.     elseif(_target STREQUAL "static")

  230.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  231.     else()

  232.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  233.     endif()

  234.   endforeach()

  235. endfunction()

  236. 

  237. # ------------------------------------------------------------------------------

  238. # DPF private functions (prefixed with `dpf__`)

  239. # ------------------------------------------------------------------------------

  240. 

  241. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  242. #       to the output directory.

  243. #

  244. 

  245. # dpf__build_jack

  246. # ------------------------------------------------------------------------------

  247. #

  248. # Add build rules for a JACK/Standalone program.

  249. #

  250. function(dpf__build_jack NAME HAS_UI)

  251.   dpf__create_dummy_source_list(_no_srcs)

  252. 

  253.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  254.   dpf__add_plugin_main("${NAME}-jack" "jack")

  255.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  256.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  257.   set_target_properties("${NAME}-jack" PROPERTIES

  258.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  259.     OUTPUT_NAME "${NAME}")

  260. 

  261.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  262.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  263. 

  264.   find_package(PkgConfig)

  265.   pkg_check_modules(SDL2 "sdl2")

  266.   if(SDL2_FOUND)

  267.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  268.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  269.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  270.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  271.   endif()

  272. 

  273.   if(APPLE OR WIN32)

  274.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  275.   else()

  276.     find_package(Threads)

  277.     pkg_check_modules(ALSA "alsa")

  278.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  279.     if(ALSA_FOUND)

  280.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  281.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  282.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  283.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  284.     endif()

  285.     if(PULSEAUDIO_FOUND)

  286.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  287.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  288.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  289.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  290.     endif()

  291.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  292.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  293.     endif()

  294.   endif()

  295. 

  296.   # for RtAudio native fallback

  297.   if(APPLE)

  298.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  299.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  300.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  301.     target_link_libraries("${NAME}-jack" PRIVATE

  302.       "${APPLE_COREAUDIO_FRAMEWORK}"

  303.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  304.       "${APPLE_COREMIDI_FRAMEWORK}")

  305.   elseif(WIN32)

  306.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  307.     if(HAS_UI AND MINGW)

  308.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  309.     endif()

  310.   endif()

  311. endfunction()

  312. 

  313. # dpf__build_ladspa

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add build rules for a LADSPA plugin.

  317. #

  318. function(dpf__build_ladspa NAME)

  319.   dpf__create_dummy_source_list(_no_srcs)

  320. 

  321.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  322.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  323.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  324.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  325.   set_target_properties("${NAME}-ladspa" PROPERTIES

  326.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  327.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  328.     OUTPUT_NAME "${NAME}-ladspa"

  329.     PREFIX "")

  330. endfunction()

  331. 

  332. # dpf__build_dssi

  333. # ------------------------------------------------------------------------------

  334. #

  335. # Add build rules for a DSSI plugin.

  336. #

  337. function(dpf__build_dssi NAME HAS_UI)

  338.   find_package(PkgConfig)

  339.   pkg_check_modules(LIBLO "liblo")

  340.   if(NOT LIBLO_FOUND)

  341.     dpf__warn_once_only(missing_liblo

  342.       "liblo is not found, skipping the `dssi` plugin targets")

  343.     return()

  344.   endif()

  345. 

  346.   dpf__create_dummy_source_list(_no_srcs)

  347. 

  348.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  349.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  350.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  351.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  352.   set_target_properties("${NAME}-dssi" PROPERTIES

  353.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  354.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  355.     OUTPUT_NAME "${NAME}-dssi"

  356.     PREFIX "")

  357. 

  358.   if(HAS_UI)

  359.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  360.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  361.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  362.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  363.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  364.       OUTPUT_NAME "${NAME}_ui")

  365. 

  366.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  367.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  368.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  369.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  370.   endif()

  371. endfunction()

  372. 

  373. # dpf__build_lv2

  374. # ------------------------------------------------------------------------------

  375. #

  376. # Add build rules for an LV2 plugin.

  377. #

  378. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  379.   dpf__create_dummy_source_list(_no_srcs)

  380. 

  381.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  382.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  383.   if(HAS_UI AND MONOLITHIC)

  384.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  385.   else()

  386.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  387.   endif()

  388.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  389.   set_target_properties("${NAME}-lv2" PROPERTIES

  390.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  391.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  392.     OUTPUT_NAME "${NAME}_dsp"

  393.     PREFIX "")

  394. 

  395.   if(HAS_UI)

  396.     if(MONOLITHIC)

  397.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  398.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  399.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  400.       set_target_properties("${NAME}-lv2" PROPERTIES

  401.         OUTPUT_NAME "${NAME}")

  402.     else()

  403.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  404.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  405.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  406.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  407.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  408.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  409.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  410.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  411.         OUTPUT_NAME "${NAME}_ui"

  412.         PREFIX "")

  413.     endif()

  414.   endif()

  415. 

  416.   dpf__add_lv2_ttl_generator()

  417.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  418. 

  419.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  420. 

  421.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  422.     COMMAND

  423.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  424.     "$<TARGET_FILE:lv2_ttl_generator>"

  425.     "$<TARGET_FILE:${NAME}-lv2>"

  426.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  427.     DEPENDS lv2_ttl_generator)

  428. endfunction()

  429. 

  430. # dpf__build_vst2

  431. # ------------------------------------------------------------------------------

  432. #

  433. # Add build rules for a VST2 plugin.

  434. #

  435. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  436.   dpf__create_dummy_source_list(_no_srcs)

  437. 

  438.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  439.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  440.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  441.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  442.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  443.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  444.   set_target_properties("${NAME}-vst2" PROPERTIES

  445.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  446.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  447.     OUTPUT_NAME "${NAME}-vst2"

  448.     PREFIX "")

  449.   if(APPLE)

  450.     set_target_properties("${NAME}-vst2" PROPERTIES

  451.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  452.       OUTPUT_NAME "${NAME}"

  453.       SUFFIX "")

  454.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  455.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  456.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  457.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  458.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  459.   endif()

  460. endfunction()

  461. 

  462. # dpf__determine_vst3_package_architecture

  463. # ------------------------------------------------------------------------------

  464. #

  465. # Determines the package architecture for a VST3 plugin target.

  466. #

  467. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  468.   # if set by variable, override the detection

  469.   if(DPF_VST3_ARCHITECTURE)

  470.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  471.     return()

  472.   endif()

  473. 

  474.   # not used on Apple, which supports universal binary

  475.   if(APPLE)

  476.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  477.     return()

  478.   endif()

  479. 

  480.   # identify the target processor (special case of MSVC, problematic sometimes)

  481.   if(MSVC)

  482.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  483.   else()

  484.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  485.   endif()

  486. 

  487.   # transform the processor name to a format that VST3 recognizes

  488.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  489.     set(vst3_package_arch "x86_64")

  490.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  491.     if(WIN32)

  492.       set(vst3_package_arch "x86")

  493.     else()

  494.       set(vst3_package_arch "i386")

  495.     endif()

  496.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  497.     set(vst3_package_arch "${vst3_system_arch}")

  498.   else()

  499.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  500.   endif()

  501. 

  502.   # TODO: the detections for Windows arm/arm64 when supported

  503. 

  504.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  505. endfunction()

  506. 

  507. # dpf__build_vst3

  508. # ------------------------------------------------------------------------------

  509. #

  510. # Add build rules for a VST3 plugin.

  511. #

  512. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  513.   dpf__determine_vst3_package_architecture(vst3_arch)

  514. 

  515.   dpf__create_dummy_source_list(_no_srcs)

  516. 

  517.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  518.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  519.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  520.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  521.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  522.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  523.   set_target_properties("${NAME}-vst3" PROPERTIES

  524.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  525.     OUTPUT_NAME "${NAME}"

  526.     PREFIX "")

  527. 

  528.   if(APPLE)

  529.     set_target_properties("${NAME}-vst3" PROPERTIES

  530.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  531.       SUFFIX "")

  532.   elseif(WIN32)

  533.     set_target_properties("${NAME}-vst3" PROPERTIES

  534.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  535.   else()

  536.     set_target_properties("${NAME}-vst3" PROPERTIES

  537.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  538.   endif()

  539. 

  540.   if(APPLE)

  541.     # Uses the same macOS bundle template as VST2

  542.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  543.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  544.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  545.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  546.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  547.   endif()

  548. endfunction()

  549. 

  550. # dpf__build_clap

  551. # ------------------------------------------------------------------------------

  552. #

  553. # Add build rules for a CLAP plugin.

  554. #

  555. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  556.   dpf__create_dummy_source_list(_no_srcs)

  557. 

  558.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  559.   dpf__add_plugin_main("${NAME}-clap" "clap")

  560.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  561.   dpf__set_module_export_list("${NAME}-clap" "clap")

  562.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  563.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  564.   set_target_properties("${NAME}-clap" PROPERTIES

  565.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  566.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  567.     OUTPUT_NAME "${NAME}"

  568.     PREFIX ""

  569.     SUFFIX ".clap")

  570. 

  571.   if(APPLE)

  572.     set_target_properties("${NAME}-clap" PROPERTIES

  573.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  574.       OUTPUT_NAME "${NAME}"

  575.       SUFFIX "")

  576.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  577.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  578.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  579.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  580.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  581.   endif()

  582. endfunction()

  583. 

  584. # dpf__build_au

  585. # ------------------------------------------------------------------------------

  586. #

  587. # Add build rules for an AUv2 plugin.

  588. #

  589. function(dpf__build_au NAME HAS_UI)

  590.   dpf__create_dummy_source_list(_no_srcs)

  591. 

  592.   dpf__add_module("${NAME}-au" ${_no_srcs})

  593.   dpf__add_plugin_main("${NAME}-au" "au")

  594.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  595.   dpf__set_module_export_list("${NAME}-au" "au")

  596.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  597.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  598.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  599.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  600.   target_link_libraries("${NAME}-au" PRIVATE

  601.     "${NAME}-dsp"

  602.     "${NAME}-ui"

  603.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  604.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  605.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  606.   set_target_properties("${NAME}-au" PROPERTIES

  607.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  608.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  609.     OUTPUT_NAME "${NAME}"

  610.     PREFIX ""

  611.     SUFFIX "")

  612. 

  613.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  614.   dpf__add_plugin_main("${NAME}-export" "export")

  615.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  616.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  617. 

  618.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  619. 

  620.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  621.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  622.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  623.     DEPENDS "${NAME}-export")

  624. 

  625.   add_dependencies("${NAME}-au" "${NAME}-export")

  626. 

  627.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  628.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  629. endfunction()

  630. 

  631. # dpf__build_static

  632. # ------------------------------------------------------------------------------

  633. #

  634. # Add build rules for a static library.

  635. #

  636. function(dpf__build_static NAME HAS_UI)

  637.   dpf__create_dummy_source_list(_no_srcs)

  638. 

  639.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  640.   dpf__add_plugin_main("${NAME}-static" "static")

  641.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  642.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  643. 

  644.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  645.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  646.   foreach(src ${dsp_srcs})

  647.     target_sources("${NAME}-static" PRIVATE ${src})

  648.   endforeach()

  649.   foreach(src ${ui_srcs})

  650.     target_sources("${NAME}-static" PRIVATE ${src})

  651.   endforeach()

  652. 

  653.   set_target_properties("${NAME}-static" PROPERTIES

  654.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  655.     OUTPUT_NAME "${NAME}"

  656.     PREFIX "")

  657. endfunction()

  658. 

  659. # dpf__add_dgl_cairo

  660. # ------------------------------------------------------------------------------

  661. #

  662. # Add the Cairo variant of DGL, if not already available.

  663. #

  664. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER)

  665.   if(TARGET dgl-cairo)

  666.     return()

  667.   endif()

  668. 

  669.   find_package(PkgConfig)

  670.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  671. 

  672.   link_directories(${CAIRO_LIBRARY_DIRS})

  673. 

  674.   dpf__add_static_library(dgl-cairo STATIC

  675.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  676.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  677.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  678.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  679.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  680.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  681.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  682.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  683.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  684.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  685.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  686.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  687.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  688.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  689.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  690.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  691.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  692.   if(SHARED_RESOURCES)

  693.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  694.   else()

  695.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  696.   endif()

  697.   if(APPLE)

  698.     target_sources(dgl-cairo PRIVATE

  699.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  700.   else()

  701.     target_sources(dgl-cairo PRIVATE

  702.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  703.   endif()

  704.   target_include_directories(dgl-cairo PUBLIC

  705.     "${DPF_ROOT_DIR}/dgl")

  706.   target_include_directories(dgl-cairo PUBLIC

  707.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  708. 

  709.   if(USE_FILE_BROWSER)

  710.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  711.   endif()

  712. 

  713.   dpf__add_dgl_system_libs()

  714.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  715. 

  716.   add_library(dgl-cairo-definitions INTERFACE)

  717.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  718. 

  719.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  720.   if(MINGW)

  721.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  722.   else()

  723.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  724.   endif()

  725.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  726. endfunction()

  727. 

  728. # dpf__add_dgl_external

  729. # ------------------------------------------------------------------------------

  730. #

  731. # Add the external variant of DGL, if not already available.

  732. #

  733. function(dpf__add_dgl_external USE_FILE_BROWSER)

  734.   if(TARGET dgl-external)

  735.     return()

  736.   endif()

  737. 

  738.   dpf__add_static_library(dgl-external STATIC

  739.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  740.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  741.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  742.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  743.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  744.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  745.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  746.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  747.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  748.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  749.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  750.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  751.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  752.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  753.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  754.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  755.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  756. 

  757.   if(APPLE)

  758.     target_sources(dgl-external PRIVATE

  759.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  760.   else()

  761.     target_sources(dgl-external PRIVATE

  762.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  763.   endif()

  764.   target_include_directories(dgl-external PUBLIC

  765.     "${DPF_ROOT_DIR}/dgl")

  766.   target_include_directories(dgl-external PUBLIC

  767.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  768. 

  769.   if(USE_FILE_BROWSER)

  770.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  771.   endif()

  772. 

  773.   dpf__add_dgl_system_libs()

  774.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  775.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  776. 

  777.   add_library(dgl-external-definitions INTERFACE)

  778.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  779. 

  780.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  781.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  782. endfunction()

  783. 

  784. # dpf__add_dgl_opengl

  785. # ------------------------------------------------------------------------------

  786. #

  787. # Add the OpenGL variant of DGL, if not already available.

  788. #

  789. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER)

  790.   if(TARGET dgl-opengl)

  791.     return()

  792.   endif()

  793. 

  794.   if(NOT OpenGL_GL_PREFERENCE)

  795.     set(OpenGL_GL_PREFERENCE "LEGACY")

  796.   endif()

  797. 

  798.   find_package(OpenGL REQUIRED)

  799. 

  800.   dpf__add_static_library(dgl-opengl STATIC

  801.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  802.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  803.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  804.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  805.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  806.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  807.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  808.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  809.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  810.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  811.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  812.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  813.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  814.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  815.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  816.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  817.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  818.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  819.   if(SHARED_RESOURCES)

  820.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  821.   else()

  822.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  823.   endif()

  824.   if(APPLE)

  825.     target_sources(dgl-opengl PRIVATE

  826.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  827.   else()

  828.     target_sources(dgl-opengl PRIVATE

  829.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  830.   endif()

  831.   target_include_directories(dgl-opengl PUBLIC

  832.     "${DPF_ROOT_DIR}/dgl")

  833.   target_include_directories(dgl-opengl PUBLIC

  834.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  835. 

  836.   if(APPLE)

  837.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  838.   endif()

  839. 

  840.   if(USE_FILE_BROWSER)

  841.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  842.   endif()

  843. 

  844.   dpf__add_dgl_system_libs()

  845.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  846. 

  847.   add_library(dgl-opengl-definitions INTERFACE)

  848.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  849. 

  850.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  851.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  852. endfunction()

  853. 

  854. # dpf__add_dgl_opengl3

  855. # ------------------------------------------------------------------------------

  856. #

  857. # Add the OpenGL3 variant of DGL, if not already available.

  858. #

  859. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER)

  860.   if(TARGET dgl-opengl3)

  861.     return()

  862.   endif()

  863. 

  864.   if(NOT OpenGL_GL_PREFERENCE)

  865.     set(OpenGL_GL_PREFERENCE "LEGACY")

  866.   endif()

  867. 

  868.   find_package(OpenGL REQUIRED)

  869. 

  870.   dpf__add_static_library(dgl-opengl3 STATIC

  871.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  883.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  884.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  885.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  886.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  887.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  888.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  889.   if(SHARED_RESOURCES)

  890.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  891.   else()

  892.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  893.   endif()

  894.   if(APPLE)

  895.     target_sources(dgl-opengl3 PRIVATE

  896.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  897.   else()

  898.     target_sources(dgl-opengl3 PRIVATE

  899.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  900.   endif()

  901.   target_include_directories(dgl-opengl3 PUBLIC

  902.     "${DPF_ROOT_DIR}/dgl")

  903.   target_include_directories(dgl-opengl3 PUBLIC

  904.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  905. 

  906.   if(APPLE)

  907.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  908.   endif()

  909. 

  910.   if(USE_FILE_BROWSER)

  911.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  912.   endif()

  913. 

  914.   dpf__add_dgl_system_libs()

  915.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  916. 

  917.   add_library(dgl-opengl3-definitions INTERFACE)

  918.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  919. 

  920.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  921.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  922. endfunction()

  923. 

  924. # dpf__add_dgl_vulkan

  925. # ------------------------------------------------------------------------------

  926. #

  927. # Add the Vulkan variant of DGL, if not already available.

  928. #

  929. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER)

  930.   if(TARGET dgl-vulkan)

  931.     return()

  932.   endif()

  933. 

  934.   find_package(Vulkan REQUIRED)

  935. 

  936.   dpf__add_static_library(dgl-vulkan STATIC

  937.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  938.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  939.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  940.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  941.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  944.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  945.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  946.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  954.   if(NO_SHARED_RESOURCES)

  955.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  956.   else()

  957.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  958.   endif()

  959.   if(APPLE)

  960.     target_sources(dgl-vulkan PRIVATE

  961.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  962.   else()

  963.     target_sources(dgl-vulkan PRIVATE

  964.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  965.   endif()

  966.   target_include_directories(dgl-vulkan PUBLIC

  967.     "${DPF_ROOT_DIR}/dgl")

  968.   target_include_directories(dgl-vulkan PUBLIC

  969.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  970. 

  971.   if(APPLE)

  972.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  973.   endif()

  974. 

  975.   if(USE_FILE_BROWSER)

  976.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  977.   endif()

  978. 

  979.   dpf__add_dgl_system_libs()

  980.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  981. 

  982.   add_library(dgl-vulkan-definitions INTERFACE)

  983.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  984. 

  985.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  986.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  987. endfunction()

  988. 

  989. # dpf__add_plugin_specific_ui_sources

  990. # ------------------------------------------------------------------------------

  991. #

  992. # Compile system specific files

  993. #

  994. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  995.   if(APPLE)

  996.     target_sources("${NAME}" PRIVATE

  997.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  998.     if(USE_WEB_VIEW)

  999.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1000.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1001.     endif()

  1002.   elseif(WIN32 AND USE_WEB_VIEW)

  1003.     target_sources("${NAME}" PRIVATE

  1004.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1005.     if (MSVC)

  1006.       set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1007.         PROPERTIES COMPILE_FLAGS /std:c++17)

  1008.     else()

  1009.       set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1010.         PROPERTIES COMPILE_FLAGS -std=gnu++17)

  1011.     endif()

  1012.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1013.   endif()

  1014. endfunction()

  1015. 

  1016. # dpf__add_dgl_system_libs

  1017. # ------------------------------------------------------------------------------

  1018. #

  1019. # Find system libraries required by DGL and add them as an interface target.

  1020. #

  1021. function(dpf__add_dgl_system_libs)

  1022.   if(TARGET dgl-system-libs)

  1023.     return()

  1024.   endif()

  1025.   add_library(dgl-system-libs INTERFACE)

  1026.   add_library(dgl-system-libs-definitions INTERFACE)

  1027.   if(APPLE)

  1028.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1029.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1030.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1031.   elseif(EMSCRIPTEN)

  1032.   elseif(HAIKU)

  1033.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1034.   elseif(WIN32)

  1035.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1036.   else()

  1037.     find_package(PkgConfig)

  1038.     pkg_check_modules(DBUS "dbus-1")

  1039.     if(DBUS_FOUND)

  1040.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1041.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1042.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1043.     endif()

  1044.     find_package(X11 REQUIRED)

  1045.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1046.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1047.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1048.     if(X11_Xcursor_FOUND)

  1049.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1050.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1051.     endif()

  1052.     if(X11_Xext_FOUND)

  1053.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1054.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1055.     endif()

  1056.     if(X11_Xrandr_FOUND)

  1057.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1058.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1059.     endif()

  1060.     if(X11_XSync_FOUND)

  1061.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1062.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1063.     endif()

  1064.    endif()

  1065. 

  1066.    if(MSVC)

  1067.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1068.      foreach(_gl_header "glext.h")

  1069.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1070.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1071.        endif()

  1072.      endforeach()

  1073.      foreach(_khr_header "khrplatform.h")

  1074.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1075.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1076.        endif()

  1077.      endforeach()

  1078.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1079.    endif()

  1080. 

  1081.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1082. endfunction()

  1083. 

  1084. # dpf__add_executable

  1085. # ------------------------------------------------------------------------------

  1086. #

  1087. # Adds an executable target, and set some default properties on the target.

  1088. #

  1089. function(dpf__add_executable NAME)

  1090.   add_executable("${NAME}" ${ARGN})

  1091.   dpf__set_target_defaults("${NAME}")

  1092.   if(MINGW)

  1093.     target_link_libraries("${NAME}" PRIVATE "-static")

  1094.   endif()

  1095. endfunction()

  1096. 

  1097. # dpf__add_module

  1098. # ------------------------------------------------------------------------------

  1099. #

  1100. # Adds a module target, and set some default properties on the target.

  1101. #

  1102. function(dpf__add_module NAME)

  1103.   add_library("${NAME}" MODULE ${ARGN})

  1104.   dpf__set_target_defaults("${NAME}")

  1105.   if(APPLE)

  1106.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1107.   elseif(MINGW)

  1108.     target_link_libraries("${NAME}" PRIVATE "-static")

  1109.   endif()

  1110. endfunction()

  1111. 

  1112. # dpf__add_static_library

  1113. # ------------------------------------------------------------------------------

  1114. #

  1115. # Adds a static library target, and set some default properties on the target.

  1116. #

  1117. function(dpf__add_static_library NAME)

  1118.   add_library("${NAME}" STATIC ${ARGN})

  1119.   dpf__set_target_defaults("${NAME}")

  1120. endfunction()

  1121. 

  1122. # dpf__set_module_export_list

  1123. # ------------------------------------------------------------------------------

  1124. #

  1125. # Applies a list of exported symbols to the module target.

  1126. #

  1127. function(dpf__set_module_export_list NAME EXPORTS)

  1128.   if(WIN32)

  1129.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1130.   elseif(APPLE)

  1131.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1132.       "-Xlinker" "-exported_symbols_list"

  1133.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1134.   else()

  1135.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1136.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1137.   endif()

  1138. endfunction()

  1139. 

  1140. # dpf__set_target_defaults

  1141. # ------------------------------------------------------------------------------

  1142. #

  1143. # Set default properties which must apply to all DPF-defined targets.

  1144. #

  1145. function(dpf__set_target_defaults NAME)

  1146.   set_target_properties("${NAME}" PROPERTIES

  1147.     POSITION_INDEPENDENT_CODE TRUE

  1148.     C_VISIBILITY_PRESET "hidden"

  1149.     CXX_VISIBILITY_PRESET "hidden"

  1150.     VISIBILITY_INLINES_HIDDEN TRUE)

  1151.   if(WIN32)

  1152.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1153.   endif()

  1154.   if (MINGW)

  1155.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1156.   endif()

  1157.   if (MSVC)

  1158.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1159.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1160.   endif()

  1161.   if (CMAKE_COMPILER_IS_GNUCXX)

  1162.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1163.   endif()

  1164.   if ((NOT APPLE) AND (NOT MSVC))

  1165.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1166.   endif()

  1167. endfunction()

  1168. 

  1169. # dpf__add_plugin_main

  1170. # ------------------------------------------------------------------------------

  1171. #

  1172. # Adds plugin code to the given target.

  1173. #

  1174. function(dpf__add_plugin_main NAME TARGET)

  1175.   target_sources("${NAME}" PRIVATE

  1176.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1177.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1178. endfunction()

  1179. 

  1180. # dpf__add_ui_main

  1181. # ------------------------------------------------------------------------------

  1182. #

  1183. # Adds UI code to the given target (only if the target has UI).

  1184. #

  1185. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1186.   if(HAS_UI)

  1187.     target_sources("${NAME}" PRIVATE

  1188.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1189.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1190.   endif()

  1191. endfunction()

  1192. 

  1193. # dpf__add_plugin_target_definition

  1194. # ------------------------------------------------------------------------------

  1195. #

  1196. # Adds the plugins target macro definition.

  1197. # This selects which entry file is compiled according to the target type.

  1198. #

  1199. function(dpf__add_plugin_target_definition NAME TARGET)

  1200.   string(TOUPPER "${TARGET}" _upperTarget)

  1201.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1202. endfunction()

  1203. 

  1204. # dpf__add_lv2_ttl_generator

  1205. # ------------------------------------------------------------------------------

  1206. #

  1207. # Build the LV2 TTL generator.

  1208. #

  1209. function(dpf__add_lv2_ttl_generator)

  1210.   if(TARGET lv2_ttl_generator)

  1211.     return()

  1212.   endif()

  1213.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1214.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1215.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1216.   endif()

  1217. endfunction()

  1218. 

  1219. # dpf__ensure_sources_non_empty

  1220. # ------------------------------------------------------------------------------

  1221. #

  1222. # Ensure the given source list contains at least one file.

  1223. # The function appends an empty source file to the list if necessary.

  1224. # This is useful when CMake does not permit to add targets without sources.

  1225. #

  1226. function(dpf__ensure_sources_non_empty VAR)

  1227.   if(NOT "" STREQUAL "${${VAR}}")

  1228.     return()

  1229.   endif()

  1230.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1231.   if(NOT EXISTS "${_file}")

  1232.     file(WRITE "${_file}" "")

  1233.   endif()

  1234.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1235. endfunction()

  1236. 

  1237. # dpf__create_dummy_source_list

  1238. # ------------------------------------------------------------------------------

  1239. #

  1240. # Create a dummy source list which is equivalent to compiling nothing.

  1241. # This is only for compatibility with older CMake versions, which refuse to add

  1242. # targets without any sources.

  1243. #

  1244. macro(dpf__create_dummy_source_list VAR)

  1245.   set("${VAR}")

  1246.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1247.     dpf__ensure_sources_non_empty("${VAR}")

  1248.   endif()

  1249. endmacro()

  1250. 

  1251. # dpf__target_link_directories

  1252. # ------------------------------------------------------------------------------

  1253. #

  1254. # Call `target_link_directories` if cmake >= 3.13,

  1255. # otherwise fallback to global `link_directories`.

  1256. #

  1257. macro(dpf__target_link_directories NAME DIRS)

  1258.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1259.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1260.   else()

  1261.     link_directories(${DIRS})

  1262.   endif()

  1263. endmacro()

  1264. 

  1265. # dpf__warn_once

  1266. # ------------------------------------------------------------------------------

  1267. #

  1268. # Prints a warning message once only.

  1269. #

  1270. function(dpf__warn_once_only TOKEN MESSAGE)

  1271.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1272.   if(NOT _warned)

  1273.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1274.     message(WARNING "${MESSAGE}")

  1275.   endif()

  1276. endfunction()