DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2037 Commits
7 Branches
49MB
Tree: ca571e3fdc
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'ca571e3fdc'
${ noResults }
DPF/cmake/DPF-plugin.cmake

896 lines
32KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`

  79. #

  80. #   `MONOLITHIC`

  81. #       build LV2 as a single binary for UI and DSP

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `FILES_COMMON` <file1>...<fileN>

  91. #       list of sources which are part of both DSP and UI

  92. #

  93. function(dpf_add_plugin NAME)

  94.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  95.   set(oneValueArgs UI_TYPE)

  96.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  97.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  98. 

  99.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  100.     set(_dpf_plugin_UI_TYPE "opengl")

  101.   endif()

  102. 

  103.   set(_dgl_library)

  104.   if(_dpf_plugin_FILES_UI)

  105.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  106.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  107.       set(_dgl_library dgl-cairo)

  108.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  109.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  110.       set(_dgl_library dgl-opengl)

  111.     else()

  112.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  113.     endif()

  114.   endif()

  115. 

  116.   ###

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  119.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  120. 

  121.   ###

  122.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  123.   target_include_directories("${NAME}" PUBLIC

  124.     "${DPF_ROOT_DIR}/distrho")

  125. 

  126.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  127.     target_link_libraries("${NAME}" PRIVATE "dl")

  128.   endif()

  129. 

  130.   if(_dgl_library)

  131.     # make sure that all code will see DGL_* definitions

  132.     target_link_libraries("${NAME}" PUBLIC

  133.       "${_dgl_library}-definitions"

  134.       dgl-system-libs-definitions)

  135.   endif()

  136. 

  137.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  138.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  139. 

  140.   if(_dgl_library)

  141.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  142.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  143.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  144.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  145.     endif()

  146.     # add the files containing Objective-C classes

  147.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  148.   else()

  149.     add_library("${NAME}-ui" INTERFACE)

  150.   endif()

  151. 

  152.   ###

  153.   foreach(_target ${_dpf_plugin_TARGETS})

  154.     if(_target STREQUAL "jack")

  155.       dpf__build_jack("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "ladspa")

  157.       dpf__build_ladspa("${NAME}")

  158.     elseif(_target STREQUAL "dssi")

  159.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  160.     elseif(_target STREQUAL "lv2")

  161.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  162.     elseif(_target STREQUAL "vst2")

  163.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  164.     elseif(_target STREQUAL "vst3")

  165.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  166.     elseif(_target STREQUAL "clap")

  167.       dpf__build_clap("${NAME}" "${_dgl_library}")

  168.     else()

  169.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  170.     endif()

  171.   endforeach()

  172. endfunction()

  173. 

  174. # ------------------------------------------------------------------------------

  175. # DPF private functions (prefixed with `dpf__`)

  176. # ------------------------------------------------------------------------------

  177. 

  178. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  179. #       to the output directory.

  180. #

  181. 

  182. # dpf__build_jack

  183. # ------------------------------------------------------------------------------

  184. #

  185. # Add build rules for a JACK/Standalone program.

  186. #

  187. function(dpf__build_jack NAME DGL_LIBRARY)

  188.   dpf__create_dummy_source_list(_no_srcs)

  189. 

  190.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  191.   dpf__add_plugin_main("${NAME}-jack" "jack")

  192.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  193.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  194.   set_target_properties("${NAME}-jack" PROPERTIES

  195.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  196.     OUTPUT_NAME "${NAME}")

  197. 

  198.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  199. 

  200.   find_package(PkgConfig)

  201.   pkg_check_modules(SDL2 "sdl2")

  202.   if(SDL2_FOUND)

  203.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  204.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  205.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  206.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  207.   endif()

  208. 

  209.   if(APPLE OR WIN32)

  210.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  211.   else()

  212.     find_package(Threads)

  213.     pkg_check_modules(ALSA "alsa")

  214.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  215.     if(ALSA_FOUND)

  216.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  217.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  218.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  219.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  220.     endif()

  221.     if(PULSEAUDIO_FOUND)

  222.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  223.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  224.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  225.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  226.     endif()

  227.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  228.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  229.     endif()

  230.   endif()

  231. 

  232.   # for RtAudio native fallback

  233.   if(APPLE)

  234.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  235.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  236.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  237.     target_link_libraries("${NAME}-jack" PRIVATE

  238.       "${APPLE_COREAUDIO_FRAMEWORK}"

  239.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  240.       "${APPLE_COREMIDI_FRAMEWORK}")

  241.   endif()

  242. endfunction()

  243. 

  244. # dpf__build_ladspa

  245. # ------------------------------------------------------------------------------

  246. #

  247. # Add build rules for a LADSPA plugin.

  248. #

  249. function(dpf__build_ladspa NAME)

  250.   dpf__create_dummy_source_list(_no_srcs)

  251. 

  252.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  253.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  254.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  255.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  256.   set_target_properties("${NAME}-ladspa" PROPERTIES

  257.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  258.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  259.     OUTPUT_NAME "${NAME}-ladspa"

  260.     PREFIX "")

  261. endfunction()

  262. 

  263. # dpf__build_dssi

  264. # ------------------------------------------------------------------------------

  265. #

  266. # Add build rules for a DSSI plugin.

  267. #

  268. function(dpf__build_dssi NAME DGL_LIBRARY)

  269.   find_package(PkgConfig)

  270.   pkg_check_modules(LIBLO "liblo")

  271.   if(NOT LIBLO_FOUND)

  272.     dpf__warn_once_only(missing_liblo

  273.       "liblo is not found, skipping the `dssi` plugin targets")

  274.     return()

  275.   endif()

  276. 

  277.   dpf__create_dummy_source_list(_no_srcs)

  278. 

  279.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  280.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  281.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  282.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  283.   set_target_properties("${NAME}-dssi" PROPERTIES

  284.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  285.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  286.     OUTPUT_NAME "${NAME}-dssi"

  287.     PREFIX "")

  288. 

  289.   if(DGL_LIBRARY)

  290.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  291.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  292.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  293.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  294.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  295.       OUTPUT_NAME "${NAME}_ui")

  296. 

  297.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  298.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  299.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  300.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  301.   endif()

  302. endfunction()

  303. 

  304. # dpf__build_lv2

  305. # ------------------------------------------------------------------------------

  306. #

  307. # Add build rules for an LV2 plugin.

  308. #

  309. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  310.   dpf__create_dummy_source_list(_no_srcs)

  311. 

  312.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  313.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  314.   if(DGL_LIBRARY AND MONOLITHIC)

  315.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  316.   else()

  317.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  318.   endif()

  319.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  320.   set_target_properties("${NAME}-lv2" PROPERTIES

  321.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  322.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  323.     OUTPUT_NAME "${NAME}_dsp"

  324.     PREFIX "")

  325. 

  326.   if(DGL_LIBRARY)

  327.     if(MONOLITHIC)

  328.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  329.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  330.       set_target_properties("${NAME}-lv2" PROPERTIES

  331.         OUTPUT_NAME "${NAME}")

  332.     else()

  333.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  334.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  335.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  336.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  337.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  338.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  339.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  340.         OUTPUT_NAME "${NAME}_ui"

  341.         PREFIX "")

  342.     endif()

  343.   endif()

  344. 

  345.   dpf__add_lv2_ttl_generator()

  346.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  347. 

  348.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  349.     COMMAND

  350.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  351.     "$<TARGET_FILE:lv2_ttl_generator>"

  352.     "$<TARGET_FILE:${NAME}-lv2>"

  353.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  354.     DEPENDS lv2_ttl_generator)

  355. endfunction()

  356. 

  357. # dpf__build_vst2

  358. # ------------------------------------------------------------------------------

  359. #

  360. # Add build rules for a VST2 plugin.

  361. #

  362. function(dpf__build_vst2 NAME DGL_LIBRARY)

  363.   dpf__create_dummy_source_list(_no_srcs)

  364. 

  365.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  366.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  367.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  368.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  369.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  370.   set_target_properties("${NAME}-vst2" PROPERTIES

  371.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  372.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  373.     OUTPUT_NAME "${NAME}-vst2"

  374.     PREFIX "")

  375.   if(APPLE)

  376.     set_target_properties("${NAME}-vst2" PROPERTIES

  377.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  378.       OUTPUT_NAME "${NAME}"

  379.       SUFFIX "")

  380.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  381.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  382.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  383.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  384.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  385.   endif()

  386. endfunction()

  387. 

  388. # dpf__determine_vst3_package_architecture

  389. # ------------------------------------------------------------------------------

  390. #

  391. # Determines the package architecture for a VST3 plugin target.

  392. #

  393. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  394.   # if set by variable, override the detection

  395.   if(DPF_VST3_ARCHITECTURE)

  396.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  397.     return()

  398.   endif()

  399. 

  400.   # not used on Apple, which supports universal binary

  401.   if(APPLE)

  402.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  403.     return()

  404.   endif()

  405. 

  406.   # identify the target processor (special case of MSVC, problematic sometimes)

  407.   if(MSVC)

  408.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  409.   else()

  410.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  411.   endif()

  412. 

  413.   # transform the processor name to a format that VST3 recognizes

  414.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  415.     set(vst3_package_arch "x86_64")

  416.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  417.     if(WIN32)

  418.       set(vst3_package_arch "x86")

  419.     else()

  420.       set(vst3_package_arch "i386")

  421.     endif()

  422.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  423.     set(vst3_package_arch "${vst3_system_arch}")

  424.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  425.     set(vst3_package_arch "aarch64")

  426.   else()

  427.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  428.   endif()

  429. 

  430.   # TODO: the detections for Windows arm/arm64 when supported

  431. 

  432.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  433. endfunction()

  434. 

  435. # dpf__build_vst3

  436. # ------------------------------------------------------------------------------

  437. #

  438. # Add build rules for a VST3 plugin.

  439. #

  440. function(dpf__build_vst3 NAME DGL_LIBRARY)

  441.   dpf__determine_vst3_package_architecture(vst3_arch)

  442. 

  443.   dpf__create_dummy_source_list(_no_srcs)

  444. 

  445.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  446.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  447.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  448.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  449.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  450.   set_target_properties("${NAME}-vst3" PROPERTIES

  451.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  452.     OUTPUT_NAME "${NAME}"

  453.     PREFIX "")

  454. 

  455.   if(APPLE)

  456.     set_target_properties("${NAME}-vst3" PROPERTIES

  457.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  458.       SUFFIX "")

  459.   elseif(WIN32)

  460.     set_target_properties("${NAME}-vst3" PROPERTIES

  461.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  462.   else()

  463.     set_target_properties("${NAME}-vst3" PROPERTIES

  464.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  465.   endif()

  466. 

  467.   if(APPLE)

  468.     # Uses the same macOS bundle template as VST2

  469.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  470.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  471.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  472.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  473.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  474.   endif()

  475. endfunction()

  476. 

  477. # dpf__build_clap

  478. # ------------------------------------------------------------------------------

  479. #

  480. # Add build rules for a VST2 plugin.

  481. #

  482. function(dpf__build_clap NAME DGL_LIBRARY)

  483.   dpf__create_dummy_source_list(_no_srcs)

  484. 

  485.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  486.   dpf__add_plugin_main("${NAME}-clap" "clap")

  487.   dpf__add_ui_main("${NAME}-clap" "clap" "${DGL_LIBRARY}")

  488.   dpf__set_module_export_list("${NAME}-clap" "clap")

  489.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  490.   set_target_properties("${NAME}-clap" PROPERTIES

  491.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  492.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  493.     OUTPUT_NAME "${NAME}"

  494.     PREFIX ""

  495.     SUFFIX ".clap")

  496. 

  497.   if(APPLE)

  498.     set_target_properties("${NAME}-clap" PROPERTIES

  499.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  500.       OUTPUT_NAME "${NAME}"

  501.       SUFFIX "")

  502.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  503.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  504.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  505.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  506.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  507.   endif()

  508. endfunction()

  509. 

  510. # dpf__add_dgl_cairo

  511. # ------------------------------------------------------------------------------

  512. #

  513. # Add the Cairo variant of DGL, if not already available.

  514. #

  515. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  516.   if(TARGET dgl-cairo)

  517.     return()

  518.   endif()

  519. 

  520.   find_package(PkgConfig)

  521.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  522. 

  523.   link_directories(${CAIRO_LIBRARY_DIRS})

  524. 

  525.   dpf__add_static_library(dgl-cairo STATIC

  526.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  528.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  530.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  531.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  532.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  533.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  534.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  535.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  536.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  537.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  538.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  539.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  540.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  541.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  542.   if(NO_SHARED_RESOURCES)

  543.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  544.   else()

  545.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  546.   endif()

  547.   if(NOT APPLE)

  548.     target_sources(dgl-cairo PRIVATE

  549.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  550.   else()

  551.     target_sources(dgl-cairo PRIVATE

  552.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  553.   endif()

  554.   target_include_directories(dgl-cairo PUBLIC

  555.     "${DPF_ROOT_DIR}/dgl")

  556.   target_include_directories(dgl-cairo PUBLIC

  557.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  558. 

  559.   dpf__add_dgl_system_libs()

  560.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  561. 

  562.   add_library(dgl-cairo-definitions INTERFACE)

  563.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  564. 

  565.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  566.   if(MINGW)

  567.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  568.   else()

  569.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  570.   endif()

  571.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  572. endfunction()

  573. 

  574. # dpf__add_dgl_opengl

  575. # ------------------------------------------------------------------------------

  576. #

  577. # Add the OpenGL variant of DGL, if not already available.

  578. #

  579. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  580.   if(TARGET dgl-opengl)

  581.     return()

  582.   endif()

  583. 

  584.   if(NOT OpenGL_GL_PREFERENCE)

  585.     set(OpenGL_GL_PREFERENCE "LEGACY")

  586.   endif()

  587. 

  588.   find_package(OpenGL REQUIRED)

  589. 

  590.   dpf__add_static_library(dgl-opengl STATIC

  591.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  592.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  593.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  594.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  595.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  596.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  597.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  598.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  599.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  600.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  601.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  602.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  603.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  604.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  605.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  606.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  607.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  608.   if(NO_SHARED_RESOURCES)

  609.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  610.   else()

  611.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  612.   endif()

  613.   if(NOT APPLE)

  614.     target_sources(dgl-opengl PRIVATE

  615.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  616.   else()

  617.     target_sources(dgl-opengl PRIVATE

  618.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  619.   endif()

  620.   target_include_directories(dgl-opengl PUBLIC

  621.     "${DPF_ROOT_DIR}/dgl")

  622.   target_include_directories(dgl-opengl PUBLIC

  623.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  624. 

  625.   if(APPLE)

  626.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  627.   endif()

  628. 

  629.   dpf__add_dgl_system_libs()

  630.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  631. 

  632.   add_library(dgl-opengl-definitions INTERFACE)

  633.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  634. 

  635.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  636.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  637. endfunction()

  638. 

  639. # dpf__add_plugin_specific_ui_sources

  640. # ------------------------------------------------------------------------------

  641. #

  642. # Compile system specific files, for now it is just Objective-C code

  643. #

  644. function(dpf__add_plugin_specific_ui_sources NAME)

  645.   if(APPLE)

  646.     target_sources("${NAME}" PRIVATE

  647.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  648.   endif()

  649. endfunction()

  650. 

  651. # dpf__add_dgl_system_libs

  652. # ------------------------------------------------------------------------------

  653. #

  654. # Find system libraries required by DGL and add them as an interface target.

  655. #

  656. function(dpf__add_dgl_system_libs)

  657.   if(TARGET dgl-system-libs)

  658.     return()

  659.   endif()

  660.   add_library(dgl-system-libs INTERFACE)

  661.   add_library(dgl-system-libs-definitions INTERFACE)

  662.   if(HAIKU)

  663.     target_link_libraries(dgl-system-libs INTERFACE "be")

  664.   elseif(WIN32)

  665.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  666.   elseif(APPLE)

  667.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  668.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  669.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  670.   else()

  671.     find_package(X11 REQUIRED)

  672.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  673.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  674.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  675.     if(X11_Xcursor_FOUND)

  676.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  677.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  678.     endif()

  679.     if(X11_Xext_FOUND)

  680.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  681.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  682.     endif()

  683.     if(X11_Xrandr_FOUND)

  684.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  685.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  686.     endif()

  687.     if(X11_XSync_FOUND)

  688.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  689.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  690.     endif()

  691.    endif()

  692. 

  693.    if(MSVC)

  694.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  695.      foreach(_gl_header "glext.h")

  696.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  697.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  698.        endif()

  699.      endforeach()

  700.      foreach(_khr_header "khrplatform.h")

  701.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  702.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  703.        endif()

  704.      endforeach()

  705.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  706.    endif()

  707. 

  708.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  709. endfunction()

  710. 

  711. # dpf__add_executable

  712. # ------------------------------------------------------------------------------

  713. #

  714. # Adds an executable target, and set some default properties on the target.

  715. #

  716. function(dpf__add_executable NAME)

  717.   add_executable("${NAME}" ${ARGN})

  718.   dpf__set_target_defaults("${NAME}")

  719.   if(MINGW)

  720.     target_link_libraries("${NAME}" PRIVATE "-static")

  721.   endif()

  722. endfunction()

  723. 

  724. # dpf__add_module

  725. # ------------------------------------------------------------------------------

  726. #

  727. # Adds a module target, and set some default properties on the target.

  728. #

  729. function(dpf__add_module NAME)

  730.   add_library("${NAME}" MODULE ${ARGN})

  731.   dpf__set_target_defaults("${NAME}")

  732.   if(MINGW)

  733.     target_link_libraries("${NAME}" PRIVATE "-static")

  734.   endif()

  735. endfunction()

  736. 

  737. # dpf__add_static_library

  738. # ------------------------------------------------------------------------------

  739. #

  740. # Adds a static library target, and set some default properties on the target.

  741. #

  742. function(dpf__add_static_library NAME)

  743.   add_library("${NAME}" STATIC ${ARGN})

  744.   dpf__set_target_defaults("${NAME}")

  745. endfunction()

  746. 

  747. # dpf__set_module_export_list

  748. # ------------------------------------------------------------------------------

  749. #

  750. # Applies a list of exported symbols to the module target.

  751. #

  752. function(dpf__set_module_export_list NAME EXPORTS)

  753.   if(WIN32)

  754.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  755.   elseif(APPLE)

  756.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  757.       "-Xlinker" "-exported_symbols_list"

  758.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  759.   else()

  760.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  761.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  762.   endif()

  763. endfunction()

  764. 

  765. # dpf__set_target_defaults

  766. # ------------------------------------------------------------------------------

  767. #

  768. # Set default properties which must apply to all DPF-defined targets.

  769. #

  770. function(dpf__set_target_defaults NAME)

  771.   set_target_properties("${NAME}" PROPERTIES

  772.     POSITION_INDEPENDENT_CODE TRUE

  773.     C_VISIBILITY_PRESET "hidden"

  774.     CXX_VISIBILITY_PRESET "hidden"

  775.     VISIBILITY_INLINES_HIDDEN TRUE)

  776.   if(WIN32)

  777.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  778.   endif()

  779.   if (MINGW)

  780.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  781.   endif()

  782.   if (MSVC)

  783.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  784.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  785.   endif()

  786. endfunction()

  787. 

  788. # dpf__add_plugin_main

  789. # ------------------------------------------------------------------------------

  790. #

  791. # Adds plugin code to the given target.

  792. #

  793. function(dpf__add_plugin_main NAME TARGET)

  794.   target_sources("${NAME}" PRIVATE

  795.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  796.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  797. endfunction()

  798. 

  799. # dpf__add_ui_main

  800. # ------------------------------------------------------------------------------

  801. #

  802. # Adds UI code to the given target (only if the target has UI).

  803. #

  804. function(dpf__add_ui_main NAME TARGET HAS_UI)

  805.   if(HAS_UI)

  806.     target_sources("${NAME}" PRIVATE

  807.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  808.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  809.   endif()

  810. endfunction()

  811. 

  812. # dpf__add_plugin_target_definition

  813. # ------------------------------------------------------------------------------

  814. #

  815. # Adds the plugins target macro definition.

  816. # This selects which entry file is compiled according to the target type.

  817. #

  818. function(dpf__add_plugin_target_definition NAME TARGET)

  819.   string(TOUPPER "${TARGET}" _upperTarget)

  820.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  821. endfunction()

  822. 

  823. # dpf__add_lv2_ttl_generator

  824. # ------------------------------------------------------------------------------

  825. #

  826. # Build the LV2 TTL generator.

  827. #

  828. function(dpf__add_lv2_ttl_generator)

  829.   if(TARGET lv2_ttl_generator)

  830.     return()

  831.   endif()

  832.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  833.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  834.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  835.   endif()

  836. endfunction()

  837. 

  838. # dpf__ensure_sources_non_empty

  839. # ------------------------------------------------------------------------------

  840. #

  841. # Ensure the given source list contains at least one file.

  842. # The function appends an empty source file to the list if necessary.

  843. # This is useful when CMake does not permit to add targets without sources.

  844. #

  845. function(dpf__ensure_sources_non_empty VAR)

  846.   if(NOT "" STREQUAL "${${VAR}}")

  847.     return()

  848.   endif()

  849.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  850.   if(NOT EXISTS "${_file}")

  851.     file(WRITE "${_file}" "")

  852.   endif()

  853.   set("${VAR}" "${_file}" PARENT_SCOPE)

  854. endfunction()

  855. 

  856. # dpf__create_dummy_source_list

  857. # ------------------------------------------------------------------------------

  858. #

  859. # Create a dummy source list which is equivalent to compiling nothing.

  860. # This is only for compatibility with older CMake versions, which refuse to add

  861. # targets without any sources.

  862. #

  863. macro(dpf__create_dummy_source_list VAR)

  864.   set("${VAR}")

  865.   if(CMAKE_VERSION VERSION_LESS "3.11")

  866.     dpf__ensure_sources_non_empty("${VAR}")

  867.   endif()

  868. endmacro()

  869. 

  870. # dpf__target_link_directories

  871. # ------------------------------------------------------------------------------

  872. #

  873. # Call `target_link_directories` if cmake >= 3.13,

  874. # otherwise fallback to global `link_directories`.

  875. #

  876. macro(dpf__target_link_directories NAME DIRS)

  877.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  878.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  879.   else()

  880.     link_directories(${DIRS})

  881.   endif()

  882. endmacro()

  883. 

  884. # dpf__warn_once

  885. # ------------------------------------------------------------------------------

  886. #

  887. # Prints a warning message once only.

  888. #

  889. function(dpf__warn_once_only TOKEN MESSAGE)

  890.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  891.   if(NOT _warned)

  892.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  893.     message(WARNING "${MESSAGE}")

  894.   endif()

  895. endfunction()