DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2054 Commits
7 Branches
295MB
Tree: c94b6feff6
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'c94b6feff6'
${ noResults }
DPF/cmake/DPF-plugin.cmake

917 lines
32KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`, `external`

  79. #

  80. #   `MONOLITHIC`

  81. #       build LV2 as a single binary for UI and DSP

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `FILES_COMMON` <file1>...<fileN>

  91. #       list of sources which are part of both DSP and UI

  92. #

  93. function(dpf_add_plugin NAME)

  94.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  95.   set(oneValueArgs UI_TYPE)

  96.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  97.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  98. 

  99.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  100.     set(_dpf_plugin_UI_TYPE "opengl")

  101.   endif()

  102. 

  103.   set(_dgl_library)

  104.   set(_dgl_external OFF)

  105.   if(_dpf_plugin_FILES_UI)

  106.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  107.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  108.       set(_dgl_library dgl-cairo)

  109.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  110.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  111.       set(_dgl_library dgl-opengl)

  112.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  113.       set(_dgl_external ON)

  114.     else()

  115.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  116.     endif()

  117.   endif()

  118. 

  119.   set(_dgl_has_ui OFF)

  120.   if(_dgl_library OR _dgl_external)

  121.     set(_dgl_has_ui ON)

  122.   endif()

  123. 

  124.   ###

  125.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  126.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  127.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  128. 

  129.   ###

  130.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  131.   target_include_directories("${NAME}" PUBLIC

  132.     "${DPF_ROOT_DIR}/distrho")

  133. 

  134.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  135.     target_link_libraries("${NAME}" PRIVATE "dl")

  136.   endif()

  137. 

  138.   if(_dgl_library AND NOT _dgl_external)

  139.     # make sure that all code will see DGL_* definitions

  140.     target_link_libraries("${NAME}" PUBLIC

  141.       "${_dgl_library}-definitions"

  142.       dgl-system-libs-definitions)

  143.   elseif(_dgl_external)

  144.     target_link_libraries("${NAME}" PUBLIC

  145.       dgl-system-libs-definitions)

  146.   endif()

  147. 

  148.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  149.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  150. 

  151.   if(_dgl_library AND NOT _dgl_external)

  152.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  153.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  154.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  155.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  156.     endif()

  157.     # add the files containing Objective-C classes

  158.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  159.   elseif(_dgl_external)

  160.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  161.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}")

  162.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  163.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  164.     endif()

  165.     # add the files containing Objective-C classes

  166.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  167.   else()

  168.     add_library("${NAME}-ui" INTERFACE)

  169.   endif()

  170. 

  171.   ###

  172.   foreach(_target ${_dpf_plugin_TARGETS})

  173.     if(_target STREQUAL "jack")

  174.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  175.     elseif(_target STREQUAL "ladspa")

  176.       dpf__build_ladspa("${NAME}")

  177.     elseif(_target STREQUAL "dssi")

  178.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  179.     elseif(_target STREQUAL "lv2")

  180.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  181.     elseif(_target STREQUAL "vst2")

  182.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  183.     elseif(_target STREQUAL "vst3")

  184.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  185.     elseif(_target STREQUAL "clap")

  186.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  187.     else()

  188.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  189.     endif()

  190.   endforeach()

  191. endfunction()

  192. 

  193. # ------------------------------------------------------------------------------

  194. # DPF private functions (prefixed with `dpf__`)

  195. # ------------------------------------------------------------------------------

  196. 

  197. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  198. #       to the output directory.

  199. #

  200. 

  201. # dpf__build_jack

  202. # ------------------------------------------------------------------------------

  203. #

  204. # Add build rules for a JACK/Standalone program.

  205. #

  206. function(dpf__build_jack NAME HAS_UI)

  207.   dpf__create_dummy_source_list(_no_srcs)

  208. 

  209.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  210.   dpf__add_plugin_main("${NAME}-jack" "jack")

  211.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  212.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  213.   set_target_properties("${NAME}-jack" PROPERTIES

  214.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  215.     OUTPUT_NAME "${NAME}")

  216. 

  217.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  218. 

  219.   find_package(PkgConfig)

  220.   pkg_check_modules(SDL2 "sdl2")

  221.   if(SDL2_FOUND)

  222.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  223.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  224.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  225.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  226.   endif()

  227. 

  228.   if(APPLE OR WIN32)

  229.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  230.   else()

  231.     find_package(Threads)

  232.     pkg_check_modules(ALSA "alsa")

  233.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  234.     if(ALSA_FOUND)

  235.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  236.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  237.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  238.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  239.     endif()

  240.     if(PULSEAUDIO_FOUND)

  241.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  242.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  243.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  244.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  245.     endif()

  246.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  247.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  248.     endif()

  249.   endif()

  250. 

  251.   # for RtAudio native fallback

  252.   if(APPLE)

  253.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  254.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  255.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  256.     target_link_libraries("${NAME}-jack" PRIVATE

  257.       "${APPLE_COREAUDIO_FRAMEWORK}"

  258.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  259.       "${APPLE_COREMIDI_FRAMEWORK}")

  260.   elseif(WIN32)

  261.     target_link_libraries("${NAME}-jack" PRIVATE "dsound" "ole32" "winmm")

  262.   endif()

  263. endfunction()

  264. 

  265. # dpf__build_ladspa

  266. # ------------------------------------------------------------------------------

  267. #

  268. # Add build rules for a LADSPA plugin.

  269. #

  270. function(dpf__build_ladspa NAME)

  271.   dpf__create_dummy_source_list(_no_srcs)

  272. 

  273.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  274.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  275.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  276.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  277.   set_target_properties("${NAME}-ladspa" PROPERTIES

  278.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  279.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  280.     OUTPUT_NAME "${NAME}-ladspa"

  281.     PREFIX "")

  282. endfunction()

  283. 

  284. # dpf__build_dssi

  285. # ------------------------------------------------------------------------------

  286. #

  287. # Add build rules for a DSSI plugin.

  288. #

  289. function(dpf__build_dssi NAME HAS_UI)

  290.   find_package(PkgConfig)

  291.   pkg_check_modules(LIBLO "liblo")

  292.   if(NOT LIBLO_FOUND)

  293.     dpf__warn_once_only(missing_liblo

  294.       "liblo is not found, skipping the `dssi` plugin targets")

  295.     return()

  296.   endif()

  297. 

  298.   dpf__create_dummy_source_list(_no_srcs)

  299. 

  300.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  301.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  302.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  303.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  304.   set_target_properties("${NAME}-dssi" PROPERTIES

  305.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  306.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  307.     OUTPUT_NAME "${NAME}-dssi"

  308.     PREFIX "")

  309. 

  310.   if(HAS_UI)

  311.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  312.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  313.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  314.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  315.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  316.       OUTPUT_NAME "${NAME}_ui")

  317. 

  318.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  319.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  320.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  321.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  322.   endif()

  323. endfunction()

  324. 

  325. # dpf__build_lv2

  326. # ------------------------------------------------------------------------------

  327. #

  328. # Add build rules for an LV2 plugin.

  329. #

  330. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  331.   dpf__create_dummy_source_list(_no_srcs)

  332. 

  333.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  334.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  335.   if(HAS_UI AND MONOLITHIC)

  336.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  337.   else()

  338.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  339.   endif()

  340.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  341.   set_target_properties("${NAME}-lv2" PROPERTIES

  342.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  343.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  344.     OUTPUT_NAME "${NAME}_dsp"

  345.     PREFIX "")

  346. 

  347.   if(HAS_UI)

  348.     if(MONOLITHIC)

  349.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  350.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  351.       set_target_properties("${NAME}-lv2" PROPERTIES

  352.         OUTPUT_NAME "${NAME}")

  353.     else()

  354.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  355.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  356.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  357.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  358.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  359.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  360.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  361.         OUTPUT_NAME "${NAME}_ui"

  362.         PREFIX "")

  363.     endif()

  364.   endif()

  365. 

  366.   dpf__add_lv2_ttl_generator()

  367.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  368. 

  369.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  370.     COMMAND

  371.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  372.     "$<TARGET_FILE:lv2_ttl_generator>"

  373.     "$<TARGET_FILE:${NAME}-lv2>"

  374.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  375.     DEPENDS lv2_ttl_generator)

  376. endfunction()

  377. 

  378. # dpf__build_vst2

  379. # ------------------------------------------------------------------------------

  380. #

  381. # Add build rules for a VST2 plugin.

  382. #

  383. function(dpf__build_vst2 NAME HAS_UI)

  384.   dpf__create_dummy_source_list(_no_srcs)

  385. 

  386.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  387.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  388.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  389.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  390.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  391.   set_target_properties("${NAME}-vst2" PROPERTIES

  392.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  393.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  394.     OUTPUT_NAME "${NAME}-vst2"

  395.     PREFIX "")

  396.   if(APPLE)

  397.     set_target_properties("${NAME}-vst2" PROPERTIES

  398.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  399.       OUTPUT_NAME "${NAME}"

  400.       SUFFIX "")

  401.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  402.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  403.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  404.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  405.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  406.   endif()

  407. endfunction()

  408. 

  409. # dpf__determine_vst3_package_architecture

  410. # ------------------------------------------------------------------------------

  411. #

  412. # Determines the package architecture for a VST3 plugin target.

  413. #

  414. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  415.   # if set by variable, override the detection

  416.   if(DPF_VST3_ARCHITECTURE)

  417.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  418.     return()

  419.   endif()

  420. 

  421.   # not used on Apple, which supports universal binary

  422.   if(APPLE)

  423.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  424.     return()

  425.   endif()

  426. 

  427.   # identify the target processor (special case of MSVC, problematic sometimes)

  428.   if(MSVC)

  429.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  430.   else()

  431.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  432.   endif()

  433. 

  434.   # transform the processor name to a format that VST3 recognizes

  435.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  436.     set(vst3_package_arch "x86_64")

  437.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  438.     if(WIN32)

  439.       set(vst3_package_arch "x86")

  440.     else()

  441.       set(vst3_package_arch "i386")

  442.     endif()

  443.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  444.     set(vst3_package_arch "${vst3_system_arch}")

  445.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  446.     set(vst3_package_arch "aarch64")

  447.   else()

  448.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  449.   endif()

  450. 

  451.   # TODO: the detections for Windows arm/arm64 when supported

  452. 

  453.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  454. endfunction()

  455. 

  456. # dpf__build_vst3

  457. # ------------------------------------------------------------------------------

  458. #

  459. # Add build rules for a VST3 plugin.

  460. #

  461. function(dpf__build_vst3 NAME HAS_UI)

  462.   dpf__determine_vst3_package_architecture(vst3_arch)

  463. 

  464.   dpf__create_dummy_source_list(_no_srcs)

  465. 

  466.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  467.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  468.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  469.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  470.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  471.   set_target_properties("${NAME}-vst3" PROPERTIES

  472.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  473.     OUTPUT_NAME "${NAME}"

  474.     PREFIX "")

  475. 

  476.   if(APPLE)

  477.     set_target_properties("${NAME}-vst3" PROPERTIES

  478.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  479.       SUFFIX "")

  480.   elseif(WIN32)

  481.     set_target_properties("${NAME}-vst3" PROPERTIES

  482.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  483.   else()

  484.     set_target_properties("${NAME}-vst3" PROPERTIES

  485.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  486.   endif()

  487. 

  488.   if(APPLE)

  489.     # Uses the same macOS bundle template as VST2

  490.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  491.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  492.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  493.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  494.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  495.   endif()

  496. endfunction()

  497. 

  498. # dpf__build_clap

  499. # ------------------------------------------------------------------------------

  500. #

  501. # Add build rules for a VST2 plugin.

  502. #

  503. function(dpf__build_clap NAME HAS_UI)

  504.   dpf__create_dummy_source_list(_no_srcs)

  505. 

  506.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  507.   dpf__add_plugin_main("${NAME}-clap" "clap")

  508.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  509.   dpf__set_module_export_list("${NAME}-clap" "clap")

  510.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  511.   set_target_properties("${NAME}-clap" PROPERTIES

  512.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  513.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  514.     OUTPUT_NAME "${NAME}"

  515.     PREFIX ""

  516.     SUFFIX ".clap")

  517. 

  518.   if(APPLE)

  519.     set_target_properties("${NAME}-clap" PROPERTIES

  520.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  521.       OUTPUT_NAME "${NAME}"

  522.       SUFFIX "")

  523.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  524.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  525.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  526.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  527.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  528.   endif()

  529. endfunction()

  530. 

  531. # dpf__add_dgl_cairo

  532. # ------------------------------------------------------------------------------

  533. #

  534. # Add the Cairo variant of DGL, if not already available.

  535. #

  536. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  537.   if(TARGET dgl-cairo)

  538.     return()

  539.   endif()

  540. 

  541.   find_package(PkgConfig)

  542.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  543. 

  544.   link_directories(${CAIRO_LIBRARY_DIRS})

  545. 

  546.   dpf__add_static_library(dgl-cairo STATIC

  547.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  548.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  549.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  550.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  551.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  552.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  553.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  554.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  555.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  556.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  557.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  558.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  559.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  560.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  561.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  562.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  563.   if(NO_SHARED_RESOURCES)

  564.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  565.   else()

  566.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  567.   endif()

  568.   if(NOT APPLE)

  569.     target_sources(dgl-cairo PRIVATE

  570.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  571.   else()

  572.     target_sources(dgl-cairo PRIVATE

  573.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  574.   endif()

  575.   target_include_directories(dgl-cairo PUBLIC

  576.     "${DPF_ROOT_DIR}/dgl")

  577.   target_include_directories(dgl-cairo PUBLIC

  578.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  579. 

  580.   dpf__add_dgl_system_libs()

  581.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  582. 

  583.   add_library(dgl-cairo-definitions INTERFACE)

  584.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  585. 

  586.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  587.   if(MINGW)

  588.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  589.   else()

  590.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  591.   endif()

  592.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  593. endfunction()

  594. 

  595. # dpf__add_dgl_opengl

  596. # ------------------------------------------------------------------------------

  597. #

  598. # Add the OpenGL variant of DGL, if not already available.

  599. #

  600. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  601.   if(TARGET dgl-opengl)

  602.     return()

  603.   endif()

  604. 

  605.   if(NOT OpenGL_GL_PREFERENCE)

  606.     set(OpenGL_GL_PREFERENCE "LEGACY")

  607.   endif()

  608. 

  609.   find_package(OpenGL REQUIRED)

  610. 

  611.   dpf__add_static_library(dgl-opengl STATIC

  612.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  613.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  614.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  615.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  616.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  617.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  618.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  619.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  620.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  621.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  622.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  623.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  624.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  625.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  626.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  627.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  628.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  629.   if(NO_SHARED_RESOURCES)

  630.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  631.   else()

  632.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  633.   endif()

  634.   if(NOT APPLE)

  635.     target_sources(dgl-opengl PRIVATE

  636.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  637.   else()

  638.     target_sources(dgl-opengl PRIVATE

  639.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  640.   endif()

  641.   target_include_directories(dgl-opengl PUBLIC

  642.     "${DPF_ROOT_DIR}/dgl")

  643.   target_include_directories(dgl-opengl PUBLIC

  644.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  645. 

  646.   if(APPLE)

  647.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  648.   endif()

  649. 

  650.   dpf__add_dgl_system_libs()

  651.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  652. 

  653.   add_library(dgl-opengl-definitions INTERFACE)

  654.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  655. 

  656.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  657.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  658. endfunction()

  659. 

  660. # dpf__add_plugin_specific_ui_sources

  661. # ------------------------------------------------------------------------------

  662. #

  663. # Compile system specific files, for now it is just Objective-C code

  664. #

  665. function(dpf__add_plugin_specific_ui_sources NAME)

  666.   if(APPLE)

  667.     target_sources("${NAME}" PRIVATE

  668.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  669.   endif()

  670. endfunction()

  671. 

  672. # dpf__add_dgl_system_libs

  673. # ------------------------------------------------------------------------------

  674. #

  675. # Find system libraries required by DGL and add them as an interface target.

  676. #

  677. function(dpf__add_dgl_system_libs)

  678.   if(TARGET dgl-system-libs)

  679.     return()

  680.   endif()

  681.   add_library(dgl-system-libs INTERFACE)

  682.   add_library(dgl-system-libs-definitions INTERFACE)

  683.   if(HAIKU)

  684.     target_link_libraries(dgl-system-libs INTERFACE "be")

  685.   elseif(WIN32)

  686.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  687.   elseif(APPLE)

  688.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  689.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  690.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  691.   else()

  692.     find_package(X11 REQUIRED)

  693.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  694.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  695.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  696.     if(X11_Xcursor_FOUND)

  697.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  698.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  699.     endif()

  700.     if(X11_Xext_FOUND)

  701.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  702.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  703.     endif()

  704.     if(X11_Xrandr_FOUND)

  705.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  706.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  707.     endif()

  708.     if(X11_XSync_FOUND)

  709.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  710.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  711.     endif()

  712.    endif()

  713. 

  714.    if(MSVC)

  715.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  716.      foreach(_gl_header "glext.h")

  717.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  718.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  719.        endif()

  720.      endforeach()

  721.      foreach(_khr_header "khrplatform.h")

  722.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  723.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  724.        endif()

  725.      endforeach()

  726.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  727.    endif()

  728. 

  729.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  730. endfunction()

  731. 

  732. # dpf__add_executable

  733. # ------------------------------------------------------------------------------

  734. #

  735. # Adds an executable target, and set some default properties on the target.

  736. #

  737. function(dpf__add_executable NAME)

  738.   add_executable("${NAME}" ${ARGN})

  739.   dpf__set_target_defaults("${NAME}")

  740.   if(MINGW)

  741.     target_link_libraries("${NAME}" PRIVATE "-static")

  742.   endif()

  743. endfunction()

  744. 

  745. # dpf__add_module

  746. # ------------------------------------------------------------------------------

  747. #

  748. # Adds a module target, and set some default properties on the target.

  749. #

  750. function(dpf__add_module NAME)

  751.   add_library("${NAME}" MODULE ${ARGN})

  752.   dpf__set_target_defaults("${NAME}")

  753.   if(MINGW)

  754.     target_link_libraries("${NAME}" PRIVATE "-static")

  755.   endif()

  756. endfunction()

  757. 

  758. # dpf__add_static_library

  759. # ------------------------------------------------------------------------------

  760. #

  761. # Adds a static library target, and set some default properties on the target.

  762. #

  763. function(dpf__add_static_library NAME)

  764.   add_library("${NAME}" STATIC ${ARGN})

  765.   dpf__set_target_defaults("${NAME}")

  766. endfunction()

  767. 

  768. # dpf__set_module_export_list

  769. # ------------------------------------------------------------------------------

  770. #

  771. # Applies a list of exported symbols to the module target.

  772. #

  773. function(dpf__set_module_export_list NAME EXPORTS)

  774.   if(WIN32)

  775.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  776.   elseif(APPLE)

  777.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  778.       "-Xlinker" "-exported_symbols_list"

  779.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  780.   else()

  781.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  782.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  783.   endif()

  784. endfunction()

  785. 

  786. # dpf__set_target_defaults

  787. # ------------------------------------------------------------------------------

  788. #

  789. # Set default properties which must apply to all DPF-defined targets.

  790. #

  791. function(dpf__set_target_defaults NAME)

  792.   set_target_properties("${NAME}" PROPERTIES

  793.     POSITION_INDEPENDENT_CODE TRUE

  794.     C_VISIBILITY_PRESET "hidden"

  795.     CXX_VISIBILITY_PRESET "hidden"

  796.     VISIBILITY_INLINES_HIDDEN TRUE)

  797.   if(WIN32)

  798.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  799.   endif()

  800.   if (MINGW)

  801.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  802.   endif()

  803.   if (MSVC)

  804.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  805.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  806.   endif()

  807. endfunction()

  808. 

  809. # dpf__add_plugin_main

  810. # ------------------------------------------------------------------------------

  811. #

  812. # Adds plugin code to the given target.

  813. #

  814. function(dpf__add_plugin_main NAME TARGET)

  815.   target_sources("${NAME}" PRIVATE

  816.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  817.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  818. endfunction()

  819. 

  820. # dpf__add_ui_main

  821. # ------------------------------------------------------------------------------

  822. #

  823. # Adds UI code to the given target (only if the target has UI).

  824. #

  825. function(dpf__add_ui_main NAME TARGET HAS_UI)

  826.   if(HAS_UI)

  827.     target_sources("${NAME}" PRIVATE

  828.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  829.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  830.   endif()

  831. endfunction()

  832. 

  833. # dpf__add_plugin_target_definition

  834. # ------------------------------------------------------------------------------

  835. #

  836. # Adds the plugins target macro definition.

  837. # This selects which entry file is compiled according to the target type.

  838. #

  839. function(dpf__add_plugin_target_definition NAME TARGET)

  840.   string(TOUPPER "${TARGET}" _upperTarget)

  841.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  842. endfunction()

  843. 

  844. # dpf__add_lv2_ttl_generator

  845. # ------------------------------------------------------------------------------

  846. #

  847. # Build the LV2 TTL generator.

  848. #

  849. function(dpf__add_lv2_ttl_generator)

  850.   if(TARGET lv2_ttl_generator)

  851.     return()

  852.   endif()

  853.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  854.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  855.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  856.   endif()

  857. endfunction()

  858. 

  859. # dpf__ensure_sources_non_empty

  860. # ------------------------------------------------------------------------------

  861. #

  862. # Ensure the given source list contains at least one file.

  863. # The function appends an empty source file to the list if necessary.

  864. # This is useful when CMake does not permit to add targets without sources.

  865. #

  866. function(dpf__ensure_sources_non_empty VAR)

  867.   if(NOT "" STREQUAL "${${VAR}}")

  868.     return()

  869.   endif()

  870.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  871.   if(NOT EXISTS "${_file}")

  872.     file(WRITE "${_file}" "")

  873.   endif()

  874.   set("${VAR}" "${_file}" PARENT_SCOPE)

  875. endfunction()

  876. 

  877. # dpf__create_dummy_source_list

  878. # ------------------------------------------------------------------------------

  879. #

  880. # Create a dummy source list which is equivalent to compiling nothing.

  881. # This is only for compatibility with older CMake versions, which refuse to add

  882. # targets without any sources.

  883. #

  884. macro(dpf__create_dummy_source_list VAR)

  885.   set("${VAR}")

  886.   if(CMAKE_VERSION VERSION_LESS "3.11")

  887.     dpf__ensure_sources_non_empty("${VAR}")

  888.   endif()

  889. endmacro()

  890. 

  891. # dpf__target_link_directories

  892. # ------------------------------------------------------------------------------

  893. #

  894. # Call `target_link_directories` if cmake >= 3.13,

  895. # otherwise fallback to global `link_directories`.

  896. #

  897. macro(dpf__target_link_directories NAME DIRS)

  898.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  899.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  900.   else()

  901.     link_directories(${DIRS})

  902.   endif()

  903. endmacro()

  904. 

  905. # dpf__warn_once

  906. # ------------------------------------------------------------------------------

  907. #

  908. # Prints a warning message once only.

  909. #

  910. function(dpf__warn_once_only TOKEN MESSAGE)

  911.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  912.   if(NOT _warned)

  913.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  914.     message(WARNING "${MESSAGE}")

  915.   endif()

  916. endfunction()