DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2421 Commits
7 Branches
91MB
Tree: c5ae6e71b0
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'c5ae6e71b0'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1359 lines
49KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  125.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  126.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  127.       set(_dgl_library dgl-cairo)

  128.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  129.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  130.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  131.       set(_dgl_library dgl-external)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  133.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  134.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  135.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  136.       set(_dgl_library dgl-opengl)

  137.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  138.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  139.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  140.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  141.       set(_dgl_library dgl-opengl3)

  142.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  143.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  144.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  145.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  146.       set(_dgl_library dgl-vulkan)

  147.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  148.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  149.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  150.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  151.       set(_dgl_library dgl-external)

  152.     else()

  153.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  154.     endif()

  155.   else()

  156.     set(_dpf_plugin_UI_TYPE "")

  157.   endif()

  158. 

  159.   set(_dgl_has_ui OFF)

  160.   if(_dgl_library)

  161.     set(_dgl_has_ui ON)

  162.   endif()

  163. 

  164.   ###

  165.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  166.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  167.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  168. 

  169.   ###

  170.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  171.   target_include_directories("${NAME}" PUBLIC

  172.     "${DPF_ROOT_DIR}/distrho")

  173. 

  174.   if(_dpf_plugin_USE_FILE_BROWSER)

  175.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  176.   endif()

  177. 

  178.   if(_dpf_plugin_USE_WEB_VIEW)

  179.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  180.   endif()

  181. 

  182.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  183.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  184.   endif()

  185. 

  186.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  187.     target_link_libraries("${NAME}" PRIVATE "dl")

  188.   endif()

  189. 

  190.   if(_dgl_library)

  191.     # make sure that all code will see DGL_* definitions

  192.     target_link_libraries("${NAME}" PUBLIC

  193.       "${_dgl_library}-definitions"

  194.       dgl-system-libs-definitions

  195.       dgl-system-libs)

  196.   endif()

  197. 

  198.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  199.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  200. 

  201.   if(_dgl_library)

  202.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  203.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  204.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  205.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  206.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  207.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  208.           OUTPUT_STRIP_TRAILING_WHITESPACE

  209.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  210.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  211.       endif()

  212.     endif()

  213.     # add the files containing C++17 or Objective-C classes

  214.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  215.   else()

  216.     add_library("${NAME}-ui" INTERFACE)

  217.   endif()

  218. 

  219.   ###

  220.   foreach(_target ${_dpf_plugin_TARGETS})

  221.     if(_target STREQUAL "jack")

  222.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  223.     elseif(_target STREQUAL "ladspa")

  224.       dpf__build_ladspa("${NAME}")

  225.     elseif(_target STREQUAL "dssi")

  226.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  227.     elseif(_target STREQUAL "lv2")

  228.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  229.     elseif(_target STREQUAL "vst2")

  230.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  231.     elseif(_target STREQUAL "vst3")

  232.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  233.     elseif(_target STREQUAL "clap")

  234.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  235.     elseif(_target STREQUAL "au")

  236.       if (APPLE)

  237.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  238.       endif()

  239.     elseif(_target STREQUAL "static")

  240.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  241.     else()

  242.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  243.     endif()

  244.   endforeach()

  245. endfunction()

  246. 

  247. # ------------------------------------------------------------------------------

  248. # DPF private functions (prefixed with `dpf__`)

  249. # ------------------------------------------------------------------------------

  250. 

  251. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  252. #       to the output directory.

  253. #

  254. 

  255. # dpf__build_jack

  256. # ------------------------------------------------------------------------------

  257. #

  258. # Add build rules for a JACK/Standalone program.

  259. #

  260. function(dpf__build_jack NAME HAS_UI)

  261.   dpf__create_dummy_source_list(_no_srcs)

  262. 

  263.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  264.   dpf__add_plugin_main("${NAME}-jack" "jack")

  265.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  266.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  267.   set_target_properties("${NAME}-jack" PROPERTIES

  268.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  269.     OUTPUT_NAME "${NAME}")

  270. 

  271.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  272.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  273. 

  274.   find_package(PkgConfig)

  275.   pkg_check_modules(SDL2 "sdl2")

  276.   if(SDL2_FOUND)

  277.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  278.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  279.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  280.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  281.   endif()

  282. 

  283.   if(APPLE OR WIN32)

  284.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  285.   else()

  286.     find_package(Threads)

  287.     pkg_check_modules(ALSA "alsa")

  288.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  289.     if(ALSA_FOUND)

  290.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  291.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  292.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  293.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  294.     endif()

  295.     if(PULSEAUDIO_FOUND)

  296.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  297.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  298.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  299.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  300.     endif()

  301.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  302.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  303.     endif()

  304.   endif()

  305. 

  306.   # for RtAudio native fallback

  307.   if(APPLE)

  308.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  309.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  310.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  311.     target_link_libraries("${NAME}-jack" PRIVATE

  312.       "${APPLE_COREAUDIO_FRAMEWORK}"

  313.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  314.       "${APPLE_COREMIDI_FRAMEWORK}")

  315.   elseif(WIN32)

  316.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  317.     if(HAS_UI AND MINGW)

  318.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  319.     endif()

  320.   endif()

  321. endfunction()

  322. 

  323. # dpf__build_ladspa

  324. # ------------------------------------------------------------------------------

  325. #

  326. # Add build rules for a LADSPA plugin.

  327. #

  328. function(dpf__build_ladspa NAME)

  329.   dpf__create_dummy_source_list(_no_srcs)

  330. 

  331.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  332.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  333.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  334.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  335.   set_target_properties("${NAME}-ladspa" PROPERTIES

  336.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  337.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  338.     OUTPUT_NAME "${NAME}-ladspa"

  339.     PREFIX "")

  340. endfunction()

  341. 

  342. # dpf__build_dssi

  343. # ------------------------------------------------------------------------------

  344. #

  345. # Add build rules for a DSSI plugin.

  346. #

  347. function(dpf__build_dssi NAME HAS_UI)

  348.   find_package(PkgConfig)

  349.   pkg_check_modules(LIBLO "liblo")

  350.   if(NOT LIBLO_FOUND)

  351.     dpf__warn_once_only(missing_liblo

  352.       "liblo is not found, skipping the `dssi` plugin targets")

  353.     return()

  354.   endif()

  355. 

  356.   dpf__create_dummy_source_list(_no_srcs)

  357. 

  358.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  359.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  360.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  361.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  362.   set_target_properties("${NAME}-dssi" PROPERTIES

  363.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  364.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  365.     OUTPUT_NAME "${NAME}-dssi"

  366.     PREFIX "")

  367. 

  368.   if(HAS_UI)

  369.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  370.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  371.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  372.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  373.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  374.       OUTPUT_NAME "${NAME}_ui")

  375. 

  376.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  377.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  378.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  379.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  380.   endif()

  381. endfunction()

  382. 

  383. # dpf__build_lv2

  384. # ------------------------------------------------------------------------------

  385. #

  386. # Add build rules for an LV2 plugin.

  387. #

  388. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  389.   dpf__create_dummy_source_list(_no_srcs)

  390. 

  391.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  392.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  393.   if(HAS_UI AND MONOLITHIC)

  394.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  395.   else()

  396.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  397.   endif()

  398.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  399.   set_target_properties("${NAME}-lv2" PROPERTIES

  400.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  401.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  402.     OUTPUT_NAME "${NAME}_dsp"

  403.     PREFIX "")

  404. 

  405.   if(HAS_UI)

  406.     if(MONOLITHIC)

  407.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  408.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  409.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  410.       set_target_properties("${NAME}-lv2" PROPERTIES

  411.         OUTPUT_NAME "${NAME}")

  412.     else()

  413.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  414.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  415.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  416.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  417.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  418.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  419.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  420.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  421.         OUTPUT_NAME "${NAME}_ui"

  422.         PREFIX "")

  423.     endif()

  424.   endif()

  425. 

  426.   dpf__add_lv2_ttl_generator()

  427.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  428. 

  429.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  430. 

  431.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  432.     COMMAND

  433.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  434.     "$<TARGET_FILE:lv2_ttl_generator>"

  435.     "$<TARGET_FILE:${NAME}-lv2>"

  436.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  437.     DEPENDS lv2_ttl_generator)

  438. endfunction()

  439. 

  440. # dpf__build_vst2

  441. # ------------------------------------------------------------------------------

  442. #

  443. # Add build rules for a VST2 plugin.

  444. #

  445. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  446.   dpf__create_dummy_source_list(_no_srcs)

  447. 

  448.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  449.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  450.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  451.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  452.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  453.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  454.   set_target_properties("${NAME}-vst2" PROPERTIES

  455.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  456.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  457.     OUTPUT_NAME "${NAME}-vst2"

  458.     PREFIX "")

  459.   if(APPLE)

  460.     set_target_properties("${NAME}-vst2" PROPERTIES

  461.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  462.       OUTPUT_NAME "${NAME}"

  463.       SUFFIX "")

  464.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  465.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  466.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  467.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  468.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  469.   endif()

  470. endfunction()

  471. 

  472. # dpf__determine_vst3_package_architecture

  473. # ------------------------------------------------------------------------------

  474. #

  475. # Determines the package architecture for a VST3 plugin target.

  476. #

  477. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  478.   # if set by variable, override the detection

  479.   if(DPF_VST3_ARCHITECTURE)

  480.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  481.     return()

  482.   endif()

  483. 

  484.   # not used on Apple, which supports universal binary

  485.   if(APPLE)

  486.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  487.     return()

  488.   endif()

  489. 

  490.   # identify the target processor (special case of MSVC, problematic sometimes)

  491.   if(MSVC)

  492.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  493.   else()

  494.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  495.   endif()

  496. 

  497.   # transform the processor name to a format that VST3 recognizes

  498.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  499.     set(vst3_package_arch "x86_64")

  500.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  501.     if(WIN32)

  502.       set(vst3_package_arch "x86")

  503.     else()

  504.       set(vst3_package_arch "i386")

  505.     endif()

  506.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  507.     set(vst3_package_arch "${vst3_system_arch}")

  508.   else()

  509.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  510.   endif()

  511. 

  512.   # TODO: the detections for Windows arm/arm64 when supported

  513. 

  514.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  515. endfunction()

  516. 

  517. # dpf__build_vst3

  518. # ------------------------------------------------------------------------------

  519. #

  520. # Add build rules for a VST3 plugin.

  521. #

  522. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  523.   dpf__determine_vst3_package_architecture(vst3_arch)

  524. 

  525.   dpf__create_dummy_source_list(_no_srcs)

  526. 

  527.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  528.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  529.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  530.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  531.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  532.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  533.   set_target_properties("${NAME}-vst3" PROPERTIES

  534.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  535.     OUTPUT_NAME "${NAME}"

  536.     PREFIX "")

  537. 

  538.   if(APPLE)

  539.     set_target_properties("${NAME}-vst3" PROPERTIES

  540.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  541.       SUFFIX "")

  542.   elseif(WIN32)

  543.     set_target_properties("${NAME}-vst3" PROPERTIES

  544.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  545.   else()

  546.     set_target_properties("${NAME}-vst3" PROPERTIES

  547.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  548.   endif()

  549. 

  550.   if(APPLE)

  551.     # Uses the same macOS bundle template as VST2

  552.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  553.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  554.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  555.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  556.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  557.   endif()

  558. endfunction()

  559. 

  560. # dpf__build_clap

  561. # ------------------------------------------------------------------------------

  562. #

  563. # Add build rules for a CLAP plugin.

  564. #

  565. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  566.   dpf__create_dummy_source_list(_no_srcs)

  567. 

  568.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  569.   dpf__add_plugin_main("${NAME}-clap" "clap")

  570.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  571.   dpf__set_module_export_list("${NAME}-clap" "clap")

  572.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  573.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  574.   set_target_properties("${NAME}-clap" PROPERTIES

  575.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  576.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  577.     OUTPUT_NAME "${NAME}"

  578.     PREFIX ""

  579.     SUFFIX ".clap")

  580. 

  581.   if(APPLE)

  582.     set_target_properties("${NAME}-clap" PROPERTIES

  583.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  584.       OUTPUT_NAME "${NAME}"

  585.       SUFFIX "")

  586.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  587.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  588.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  589.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  590.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  591.   endif()

  592. endfunction()

  593. 

  594. # dpf__build_au

  595. # ------------------------------------------------------------------------------

  596. #

  597. # Add build rules for an AUv2 plugin.

  598. #

  599. function(dpf__build_au NAME HAS_UI)

  600.   dpf__create_dummy_source_list(_no_srcs)

  601. 

  602.   dpf__add_module("${NAME}-au" ${_no_srcs})

  603.   dpf__add_plugin_main("${NAME}-au" "au")

  604.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  605.   dpf__set_module_export_list("${NAME}-au" "au")

  606.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  607.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  608.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  609.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  610.   target_link_libraries("${NAME}-au" PRIVATE

  611.     "${NAME}-dsp"

  612.     "${NAME}-ui"

  613.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  614.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  615.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  616.   set_target_properties("${NAME}-au" PROPERTIES

  617.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  618.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  619.     OUTPUT_NAME "${NAME}"

  620.     PREFIX ""

  621.     SUFFIX "")

  622. 

  623.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  624.   dpf__add_plugin_main("${NAME}-export" "export")

  625.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  626.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  627. 

  628.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  629. 

  630.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  631.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  632.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  633.     DEPENDS "${NAME}-export")

  634. 

  635.   add_dependencies("${NAME}-au" "${NAME}-export")

  636. 

  637.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  638.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  639. endfunction()

  640. 

  641. # dpf__build_static

  642. # ------------------------------------------------------------------------------

  643. #

  644. # Add build rules for a static library.

  645. #

  646. function(dpf__build_static NAME HAS_UI)

  647.   dpf__create_dummy_source_list(_no_srcs)

  648. 

  649.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  650.   dpf__add_plugin_main("${NAME}-static" "static")

  651.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  652.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  653. 

  654.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  655.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  656.   foreach(src ${dsp_srcs})

  657.     target_sources("${NAME}-static" PRIVATE ${src})

  658.   endforeach()

  659.   foreach(src ${ui_srcs})

  660.     target_sources("${NAME}-static" PRIVATE ${src})

  661.   endforeach()

  662. 

  663.   set_target_properties("${NAME}-static" PROPERTIES

  664.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  665.     OUTPUT_NAME "${NAME}"

  666.     PREFIX "")

  667. endfunction()

  668. 

  669. # dpf__add_dgl_cairo

  670. # ------------------------------------------------------------------------------

  671. #

  672. # Add the Cairo variant of DGL, if not already available.

  673. #

  674. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  675.   if(TARGET dgl-cairo)

  676.     return()

  677.   endif()

  678. 

  679.   find_package(PkgConfig)

  680.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  681. 

  682.   link_directories(${CAIRO_LIBRARY_DIRS})

  683. 

  684.   dpf__add_static_library(dgl-cairo STATIC

  685.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  686.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  687.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  688.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  689.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  690.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  691.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  692.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  693.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  694.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  695.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  696.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  697.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  698.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  699.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  700.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  701.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  702.   if(SHARED_RESOURCES)

  703.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  704.   else()

  705.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  706.   endif()

  707.   if(APPLE)

  708.     target_sources(dgl-cairo PRIVATE

  709.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  710.   else()

  711.     target_sources(dgl-cairo PRIVATE

  712.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  713.   endif()

  714.   target_include_directories(dgl-cairo PUBLIC

  715.     "${DPF_ROOT_DIR}/dgl")

  716.   target_include_directories(dgl-cairo PUBLIC

  717.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  718. 

  719.   if(USE_FILE_BROWSER)

  720.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  721.   endif()

  722. 

  723.   if(USE_WEB_VIEW)

  724.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  725.     if(APPLE)

  726.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  727.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  728.     elseif(WIN32)

  729.       target_sources(dgl-cairo PRIVATE

  730.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  731.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  732.         PROPERTIES

  733.           COMPILE_FLAGS

  734.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  735.     endif()

  736.   endif()

  737. 

  738.   dpf__add_dgl_system_libs()

  739.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  740. 

  741.   add_library(dgl-cairo-definitions INTERFACE)

  742.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  743. 

  744.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  745.   if(MINGW)

  746.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  747.   else()

  748.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  749.   endif()

  750.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  751. endfunction()

  752. 

  753. # dpf__add_dgl_external

  754. # ------------------------------------------------------------------------------

  755. #

  756. # Add the external variant of DGL, if not already available.

  757. #

  758. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  759.   if(TARGET dgl-external)

  760.     return()

  761.   endif()

  762. 

  763.   dpf__add_static_library(dgl-external STATIC

  764.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  765.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  766.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  767.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  768.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  769.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  770.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  771.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  772.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  773.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  774.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  775.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  776.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  777.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  778.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  779.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  780.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  781. 

  782.   if(APPLE)

  783.     target_sources(dgl-external PRIVATE

  784.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  785.   else()

  786.     target_sources(dgl-external PRIVATE

  787.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  788.   endif()

  789.   target_include_directories(dgl-external PUBLIC

  790.     "${DPF_ROOT_DIR}/dgl")

  791.   target_include_directories(dgl-external PUBLIC

  792.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  793. 

  794.   if(USE_FILE_BROWSER)

  795.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  796.   endif()

  797. 

  798.   if(USE_WEB_VIEW)

  799.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  800.     if(APPLE)

  801.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  802.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  803.     elseif(WIN32)

  804.       target_sources(dgl-external PRIVATE

  805.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  806.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  807.         PROPERTIES

  808.           COMPILE_FLAGS

  809.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  810.     endif()

  811.   endif()

  812. 

  813.   dpf__add_dgl_system_libs()

  814.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  815.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  816. 

  817.   add_library(dgl-external-definitions INTERFACE)

  818.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  819. 

  820.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  821.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  822. endfunction()

  823. 

  824. # dpf__add_dgl_opengl

  825. # ------------------------------------------------------------------------------

  826. #

  827. # Add the OpenGL variant of DGL, if not already available.

  828. #

  829. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  830.   if(TARGET dgl-opengl)

  831.     return()

  832.   endif()

  833. 

  834.   if(NOT OpenGL_GL_PREFERENCE)

  835.     set(OpenGL_GL_PREFERENCE "LEGACY")

  836.   endif()

  837. 

  838.   find_package(OpenGL REQUIRED)

  839. 

  840.   dpf__add_static_library(dgl-opengl STATIC

  841.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  842.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  843.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  844.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  845.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  846.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  847.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  848.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  849.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  850.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  851.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  852.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  853.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  854.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  855.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  856.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  857.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  858.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  859.   if(SHARED_RESOURCES)

  860.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  861.   else()

  862.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  863.   endif()

  864.   if(APPLE)

  865.     target_sources(dgl-opengl PRIVATE

  866.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  867.   else()

  868.     target_sources(dgl-opengl PRIVATE

  869.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  870.   endif()

  871.   target_include_directories(dgl-opengl PUBLIC

  872.     "${DPF_ROOT_DIR}/dgl")

  873.   target_include_directories(dgl-opengl PUBLIC

  874.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  875. 

  876.   if(APPLE)

  877.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  878.   endif()

  879. 

  880.   if(USE_FILE_BROWSER)

  881.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  882.   endif()

  883. 

  884.   if(USE_WEB_VIEW)

  885.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  886.     if(APPLE)

  887.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  888.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  889.     elseif(WIN32)

  890.       target_sources(dgl-opengl PRIVATE

  891.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  892.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  893.         PROPERTIES

  894.           COMPILE_FLAGS

  895.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  896.     endif()

  897.   endif()

  898. 

  899.   dpf__add_dgl_system_libs()

  900.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  901. 

  902.   add_library(dgl-opengl-definitions INTERFACE)

  903.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  904. 

  905.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  906.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  907. endfunction()

  908. 

  909. # dpf__add_dgl_opengl3

  910. # ------------------------------------------------------------------------------

  911. #

  912. # Add the OpenGL3 variant of DGL, if not already available.

  913. #

  914. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  915.   if(TARGET dgl-opengl3)

  916.     return()

  917.   endif()

  918. 

  919.   if(NOT OpenGL_GL_PREFERENCE)

  920.     set(OpenGL_GL_PREFERENCE "LEGACY")

  921.   endif()

  922. 

  923.   find_package(OpenGL REQUIRED)

  924. 

  925.   dpf__add_static_library(dgl-opengl3 STATIC

  926.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  927.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  928.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  929.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  930.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  931.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  932.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  933.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  934.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  935.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  936.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  937.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  938.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  939.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  940.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  941.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  944.   if(SHARED_RESOURCES)

  945.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  946.   else()

  947.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  948.   endif()

  949.   if(APPLE)

  950.     target_sources(dgl-opengl3 PRIVATE

  951.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  952.   else()

  953.     target_sources(dgl-opengl3 PRIVATE

  954.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  955.   endif()

  956.   target_include_directories(dgl-opengl3 PUBLIC

  957.     "${DPF_ROOT_DIR}/dgl")

  958.   target_include_directories(dgl-opengl3 PUBLIC

  959.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  960. 

  961.   if(APPLE)

  962.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  963.   endif()

  964. 

  965.   if(USE_FILE_BROWSER)

  966.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  967.   endif()

  968. 

  969.   if(USE_WEB_VIEW)

  970.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  971.     if(APPLE)

  972.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  973.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  974.     elseif(WIN32)

  975.       target_sources(dgl-opengl3 PRIVATE

  976.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  977.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  978.         PROPERTIES

  979.           COMPILE_FLAGS

  980.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  981.     endif()

  982.   endif()

  983. 

  984.   dpf__add_dgl_system_libs()

  985.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  986. 

  987.   add_library(dgl-opengl3-definitions INTERFACE)

  988.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  989. 

  990.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  991.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  992. endfunction()

  993. 

  994. # dpf__add_dgl_vulkan

  995. # ------------------------------------------------------------------------------

  996. #

  997. # Add the Vulkan variant of DGL, if not already available.

  998. #

  999. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1000.   if(TARGET dgl-vulkan)

  1001.     return()

  1002.   endif()

  1003. 

  1004.   find_package(Vulkan REQUIRED)

  1005. 

  1006.   dpf__add_static_library(dgl-vulkan STATIC

  1007.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1008.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1009.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1010.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1011.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1012.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1013.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1014.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1015.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1016.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1017.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1018.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1019.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1020.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1021.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1022.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1023.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1024.   if(NO_SHARED_RESOURCES)

  1025.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1026.   else()

  1027.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1028.   endif()

  1029.   if(APPLE)

  1030.     target_sources(dgl-vulkan PRIVATE

  1031.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1032.   else()

  1033.     target_sources(dgl-vulkan PRIVATE

  1034.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1035.   endif()

  1036.   target_include_directories(dgl-vulkan PUBLIC

  1037.     "${DPF_ROOT_DIR}/dgl")

  1038.   target_include_directories(dgl-vulkan PUBLIC

  1039.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1040. 

  1041.   if(APPLE)

  1042.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1043.   endif()

  1044. 

  1045.   if(USE_FILE_BROWSER)

  1046.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1047.   endif()

  1048. 

  1049.   if(USE_WEB_VIEW)

  1050.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1051.     if(APPLE)

  1052.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1053.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1054.     elseif(WIN32)

  1055.       target_sources(dgl-vulkan PRIVATE

  1056.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1057.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1058.         PROPERTIES

  1059.           COMPILE_FLAGS

  1060.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1061.     endif()

  1062.   endif()

  1063. 

  1064.   dpf__add_dgl_system_libs()

  1065.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1066. 

  1067.   add_library(dgl-vulkan-definitions INTERFACE)

  1068.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1069. 

  1070.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1071.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1072. endfunction()

  1073. 

  1074. # dpf__add_plugin_specific_ui_sources

  1075. # ------------------------------------------------------------------------------

  1076. #

  1077. # Compile system specific files

  1078. #

  1079. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1080.   if(APPLE)

  1081.     target_sources("${NAME}" PRIVATE

  1082.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1083.     if(USE_WEB_VIEW)

  1084.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1085.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1086.     endif()

  1087.   elseif(WIN32 AND USE_WEB_VIEW)

  1088.     target_sources("${NAME}" PRIVATE

  1089.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1090.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1091.       PROPERTIES

  1092.         COMPILE_FLAGS

  1093.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1094.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1095.   endif()

  1096. endfunction()

  1097. 

  1098. # dpf__add_dgl_system_libs

  1099. # ------------------------------------------------------------------------------

  1100. #

  1101. # Find system libraries required by DGL and add them as an interface target.

  1102. #

  1103. function(dpf__add_dgl_system_libs)

  1104.   if(TARGET dgl-system-libs)

  1105.     return()

  1106.   endif()

  1107.   add_library(dgl-system-libs INTERFACE)

  1108.   add_library(dgl-system-libs-definitions INTERFACE)

  1109.   if(APPLE)

  1110.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1111.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1112.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1113.   elseif(EMSCRIPTEN)

  1114.   elseif(HAIKU)

  1115.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1116.   elseif(WIN32)

  1117.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1118.   else()

  1119.     find_package(PkgConfig)

  1120.     pkg_check_modules(DBUS "dbus-1")

  1121.     if(DBUS_FOUND)

  1122.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1123.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1124.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1125.     endif()

  1126.     find_package(X11 REQUIRED)

  1127.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1128.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1129.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1130.     if(X11_Xcursor_FOUND)

  1131.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1132.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1133.     endif()

  1134.     if(X11_Xext_FOUND)

  1135.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1136.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1137.     endif()

  1138.     if(X11_Xrandr_FOUND)

  1139.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1140.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1141.     endif()

  1142.     if(X11_XSync_FOUND)

  1143.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1144.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1145.     endif()

  1146.    endif()

  1147. 

  1148.    if(MSVC)

  1149.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1150.      foreach(_gl_header "glext.h")

  1151.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1152.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1153.        endif()

  1154.      endforeach()

  1155.      foreach(_khr_header "khrplatform.h")

  1156.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1157.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1158.        endif()

  1159.      endforeach()

  1160.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1161.    endif()

  1162. 

  1163.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1164. endfunction()

  1165. 

  1166. # dpf__add_executable

  1167. # ------------------------------------------------------------------------------

  1168. #

  1169. # Adds an executable target, and set some default properties on the target.

  1170. #

  1171. function(dpf__add_executable NAME)

  1172.   add_executable("${NAME}" ${ARGN})

  1173.   dpf__set_target_defaults("${NAME}")

  1174.   if(MINGW)

  1175.     target_link_libraries("${NAME}" PRIVATE "-static")

  1176.   endif()

  1177. endfunction()

  1178. 

  1179. # dpf__add_module

  1180. # ------------------------------------------------------------------------------

  1181. #

  1182. # Adds a module target, and set some default properties on the target.

  1183. #

  1184. function(dpf__add_module NAME)

  1185.   add_library("${NAME}" MODULE ${ARGN})

  1186.   dpf__set_target_defaults("${NAME}")

  1187.   if(APPLE)

  1188.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1189.   elseif(MINGW)

  1190.     target_link_libraries("${NAME}" PRIVATE "-static")

  1191.   endif()

  1192. endfunction()

  1193. 

  1194. # dpf__add_static_library

  1195. # ------------------------------------------------------------------------------

  1196. #

  1197. # Adds a static library target, and set some default properties on the target.

  1198. #

  1199. function(dpf__add_static_library NAME)

  1200.   add_library("${NAME}" STATIC ${ARGN})

  1201.   dpf__set_target_defaults("${NAME}")

  1202. endfunction()

  1203. 

  1204. # dpf__set_module_export_list

  1205. # ------------------------------------------------------------------------------

  1206. #

  1207. # Applies a list of exported symbols to the module target.

  1208. #

  1209. function(dpf__set_module_export_list NAME EXPORTS)

  1210.   if(WIN32)

  1211.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1212.   elseif(APPLE)

  1213.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1214.       "-Xlinker" "-exported_symbols_list"

  1215.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1216.   else()

  1217.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1218.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1219.   endif()

  1220. endfunction()

  1221. 

  1222. # dpf__set_target_defaults

  1223. # ------------------------------------------------------------------------------

  1224. #

  1225. # Set default properties which must apply to all DPF-defined targets.

  1226. #

  1227. function(dpf__set_target_defaults NAME)

  1228.   set_target_properties("${NAME}" PROPERTIES

  1229.     POSITION_INDEPENDENT_CODE TRUE

  1230.     C_VISIBILITY_PRESET "hidden"

  1231.     CXX_VISIBILITY_PRESET "hidden"

  1232.     VISIBILITY_INLINES_HIDDEN TRUE)

  1233.   if(WIN32)

  1234.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1235.   endif()

  1236.   if (MINGW)

  1237.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1238.   endif()

  1239.   if (MSVC)

  1240.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1241.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1242.   endif()

  1243.   if (CMAKE_COMPILER_IS_GNUCXX)

  1244.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1245.   endif()

  1246.   if ((NOT APPLE) AND (NOT MSVC))

  1247.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1248.   endif()

  1249. endfunction()

  1250. 

  1251. # dpf__add_plugin_main

  1252. # ------------------------------------------------------------------------------

  1253. #

  1254. # Adds plugin code to the given target.

  1255. #

  1256. function(dpf__add_plugin_main NAME TARGET)

  1257.   target_sources("${NAME}" PRIVATE

  1258.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1259.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1260. endfunction()

  1261. 

  1262. # dpf__add_ui_main

  1263. # ------------------------------------------------------------------------------

  1264. #

  1265. # Adds UI code to the given target (only if the target has UI).

  1266. #

  1267. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1268.   if(HAS_UI)

  1269.     target_sources("${NAME}" PRIVATE

  1270.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1271.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1272.   endif()

  1273. endfunction()

  1274. 

  1275. # dpf__add_plugin_target_definition

  1276. # ------------------------------------------------------------------------------

  1277. #

  1278. # Adds the plugins target macro definition.

  1279. # This selects which entry file is compiled according to the target type.

  1280. #

  1281. function(dpf__add_plugin_target_definition NAME TARGET)

  1282.   string(TOUPPER "${TARGET}" _upperTarget)

  1283.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1284. endfunction()

  1285. 

  1286. # dpf__add_lv2_ttl_generator

  1287. # ------------------------------------------------------------------------------

  1288. #

  1289. # Build the LV2 TTL generator.

  1290. #

  1291. function(dpf__add_lv2_ttl_generator)

  1292.   if(TARGET lv2_ttl_generator)

  1293.     return()

  1294.   endif()

  1295.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1296.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1297.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1298.   endif()

  1299. endfunction()

  1300. 

  1301. # dpf__ensure_sources_non_empty

  1302. # ------------------------------------------------------------------------------

  1303. #

  1304. # Ensure the given source list contains at least one file.

  1305. # The function appends an empty source file to the list if necessary.

  1306. # This is useful when CMake does not permit to add targets without sources.

  1307. #

  1308. function(dpf__ensure_sources_non_empty VAR)

  1309.   if(NOT "" STREQUAL "${${VAR}}")

  1310.     return()

  1311.   endif()

  1312.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1313.   if(NOT EXISTS "${_file}")

  1314.     file(WRITE "${_file}" "")

  1315.   endif()

  1316.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1317. endfunction()

  1318. 

  1319. # dpf__create_dummy_source_list

  1320. # ------------------------------------------------------------------------------

  1321. #

  1322. # Create a dummy source list which is equivalent to compiling nothing.

  1323. # This is only for compatibility with older CMake versions, which refuse to add

  1324. # targets without any sources.

  1325. #

  1326. macro(dpf__create_dummy_source_list VAR)

  1327.   set("${VAR}")

  1328.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1329.     dpf__ensure_sources_non_empty("${VAR}")

  1330.   endif()

  1331. endmacro()

  1332. 

  1333. # dpf__target_link_directories

  1334. # ------------------------------------------------------------------------------

  1335. #

  1336. # Call `target_link_directories` if cmake >= 3.13,

  1337. # otherwise fallback to global `link_directories`.

  1338. #

  1339. macro(dpf__target_link_directories NAME DIRS)

  1340.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1341.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1342.   else()

  1343.     link_directories(${DIRS})

  1344.   endif()

  1345. endmacro()

  1346. 

  1347. # dpf__warn_once

  1348. # ------------------------------------------------------------------------------

  1349. #

  1350. # Prints a warning message once only.

  1351. #

  1352. function(dpf__warn_once_only TOKEN MESSAGE)

  1353.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1354.   if(NOT _warned)

  1355.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1356.     message(WARNING "${MESSAGE}")

  1357.   endif()

  1358. endfunction()