DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1187 Commits
7 Branches
62MB
Tree: bf156dd0ca
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'bf156dd0ca'
${ noResults }
DPF/cmake/DPF-plugin.cmake

663 lines
23KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   dpf__create_dummy_source_list(_no_srcs)

  177. 

  178.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  179.   dpf__add_plugin_main("${NAME}-jack" "jack")

  180.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  181.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  182.   set_target_properties("${NAME}-jack" PROPERTIES

  183.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  184.     OUTPUT_NAME "${NAME}")

  185. 

  186.   # Note: libjack will be linked at runtime

  187.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  188.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  189.   endif()

  190. endfunction()

  191. 

  192. # dpf__build_ladspa

  193. # ------------------------------------------------------------------------------

  194. #

  195. # Add build rules for a DSSI plugin.

  196. #

  197. function(dpf__build_ladspa NAME)

  198.   dpf__create_dummy_source_list(_no_srcs)

  199. 

  200.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  201.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  202.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  203.   set_target_properties("${NAME}-ladspa" PROPERTIES

  204.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  205.     OUTPUT_NAME "${NAME}-ladspa"

  206.     PREFIX "")

  207. endfunction()

  208. 

  209. # dpf__build_dssi

  210. # ------------------------------------------------------------------------------

  211. #

  212. # Add build rules for a DSSI plugin.

  213. #

  214. function(dpf__build_dssi NAME DGL_LIBRARY)

  215.   find_package(PkgConfig)

  216.   pkg_check_modules(LIBLO "liblo")

  217.   if(NOT LIBLO_FOUND)

  218.     dpf__warn_once_only(missing_liblo

  219.       "liblo is not found, skipping the `dssi` plugin targets")

  220.     return()

  221.   endif()

  222. 

  223.   link_directories(${LIBLO_LIBRARY_DIRS})

  224. 

  225.   dpf__create_dummy_source_list(_no_srcs)

  226. 

  227.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  228.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  229.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  230.   set_target_properties("${NAME}-dssi" PROPERTIES

  231.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  232.     OUTPUT_NAME "${NAME}-dssi"

  233.     PREFIX "")

  234. 

  235.   if(DGL_LIBRARY)

  236.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  237.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  238.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  239.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  240.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  241.       OUTPUT_NAME "${NAME}_ui")

  242. 

  243.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  244.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  245.   endif()

  246. endfunction()

  247. 

  248. # dpf__build_lv2

  249. # ------------------------------------------------------------------------------

  250. #

  251. # Add build rules for a LV2 plugin.

  252. #

  253. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  254.   dpf__create_dummy_source_list(_no_srcs)

  255. 

  256.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  257.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  258.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  259.   set_target_properties("${NAME}-lv2" PROPERTIES

  260.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  261.     OUTPUT_NAME "${NAME}_dsp"

  262.     PREFIX "")

  263. 

  264.   if(DGL_LIBRARY)

  265.     if(MONOLITHIC)

  266.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  267.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  268.       set_target_properties("${NAME}-lv2" PROPERTIES

  269.         OUTPUT_NAME "${NAME}")

  270.     else()

  271.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  272.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  273.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  274.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  275.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  276.         OUTPUT_NAME "${NAME}_ui"

  277.         PREFIX "")

  278.     endif()

  279.   endif()

  280. 

  281.   dpf__add_lv2_ttl_generator()

  282.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  283. 

  284.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  285.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  286.     "$<TARGET_FILE:lv2_ttl_generator>"

  287.     "$<TARGET_FILE:${NAME}-lv2>"

  288.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  289.     DEPENDS lv2_ttl_generator)

  290. endfunction()

  291. 

  292. # dpf__build_vst2

  293. # ------------------------------------------------------------------------------

  294. #

  295. # Add build rules for a VST2 plugin.

  296. #

  297. function(dpf__build_vst2 NAME DGL_LIBRARY)

  298.   dpf__create_dummy_source_list(_no_srcs)

  299. 

  300.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  301.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  302.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  303.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  304.   set_target_properties("${NAME}-vst2" PROPERTIES

  305.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  306.     OUTPUT_NAME "${NAME}-vst2"

  307.     PREFIX "")

  308. endfunction()

  309. 

  310. # dpf__add_dgl_cairo

  311. # ------------------------------------------------------------------------------

  312. #

  313. # Add the Cairo variant of DGL, if not already available.

  314. #

  315. function(dpf__add_dgl_cairo)

  316.   if(TARGET dgl-cairo)

  317.     return()

  318.   endif()

  319. 

  320.   find_package(PkgConfig)

  321.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  322. 

  323.   link_directories(${CAIRO_LIBRARY_DIRS})

  324. 

  325.   dpf__add_static_library(dgl-cairo STATIC

  326.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  327.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  328.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  329.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  330.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  331.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  333.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  343.   if(NOT APPLE)

  344.     target_sources(dgl-cairo PRIVATE

  345.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  346.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  347.     #target_sources(dgl-opengl PRIVATE

  348.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  349.   endif()

  350.   target_include_directories(dgl-cairo PUBLIC

  351.     "${DPF_ROOT_DIR}/dgl")

  352.   target_include_directories(dgl-cairo PUBLIC

  353.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  354. 

  355.   dpf__add_dgl_system_libs()

  356.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  357. 

  358.   add_library(dgl-cairo-definitions INTERFACE)

  359.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  360. 

  361.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  362.   if(MINGW)

  363.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  364.   else()

  365.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  366.   endif()

  367.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  368. endfunction()

  369. 

  370. # dpf__add_dgl_opengl

  371. # ------------------------------------------------------------------------------

  372. #

  373. # Add the OpenGL variant of DGL, if not already available.

  374. #

  375. function(dpf__add_dgl_opengl)

  376.   if(TARGET dgl-opengl)

  377.     return()

  378.   endif()

  379. 

  380.   if(NOT OpenGL_GL_PREFERENCE)

  381.     set(OpenGL_GL_PREFERENCE "LEGACY")

  382.   endif()

  383. 

  384.   find_package(OpenGL REQUIRED)

  385. 

  386.   dpf__add_static_library(dgl-opengl STATIC

  387.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  388.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  389.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  390.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  391.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  392.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  393.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  394.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  405.   if(NOT APPLE)

  406.     target_sources(dgl-opengl PRIVATE

  407.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  408.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  409.     #target_sources(dgl-opengl PRIVATE

  410.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  411.   endif()

  412.   target_include_directories(dgl-opengl PUBLIC

  413.     "${DPF_ROOT_DIR}/dgl")

  414.   target_include_directories(dgl-opengl PUBLIC

  415.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  416. 

  417.   if(APPLE)

  418.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  419.   endif()

  420. 

  421.   dpf__add_dgl_system_libs()

  422.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  423. 

  424.   add_library(dgl-opengl-definitions INTERFACE)

  425.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  426. 

  427.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  428.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  429. endfunction()

  430. 

  431. # dpf__add_plugin_specific_ui_sources

  432. # ------------------------------------------------------------------------------

  433. #

  434. # Compile plugin-specific UI sources into the target designated by the given

  435. # name. There are some special considerations here:

  436. # - On most platforms, sources can be compiled only once, as part of DGL;

  437. # - On macOS, for any sources which define Objective-C interfaces, these must

  438. #   be recompiled for each plugin under a unique namespace. In this case, the

  439. #   name must be a plugin-specific identifier, and it will be used for computing

  440. #   the unique ID along with the project version.

  441. function(dpf__add_plugin_specific_ui_sources NAME)

  442.   if(APPLE)

  443.     target_sources("${NAME}" PRIVATE

  444.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  445.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  446.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  447.   endif()

  448. endfunction()

  449. 

  450. # dpf__add_dgl_system_libs

  451. # ------------------------------------------------------------------------------

  452. #

  453. # Find system libraries required by DGL and add them as an interface target.

  454. #

  455. function(dpf__add_dgl_system_libs)

  456.   if(TARGET dgl-system-libs)

  457.     return()

  458.   endif()

  459.   add_library(dgl-system-libs INTERFACE)

  460.   add_library(dgl-system-libs-definitions INTERFACE)

  461.   if(HAIKU)

  462.     target_link_libraries(dgl-system-libs INTERFACE "be")

  463.   elseif(WIN32)

  464.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  465.   elseif(APPLE)

  466.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  467.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  468.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  469.   else()

  470.     find_package(X11 REQUIRED)

  471.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  472.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  473.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  474.     if(X11_Xext_FOUND)

  475.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  476.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  477.     endif()

  478.     if(X11_XSync_FOUND)

  479.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  480.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  481.     endif()

  482.     if(X11_Xrandr_FOUND)

  483.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  484.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  485.     endif()

  486.     #if(X11_Xcursor_FOUND)

  487.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  488.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  489.     #endif()

  490.    endif()

  491. 

  492.    if(MSVC)

  493.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  494.      foreach(_gl_header "glext.h")

  495.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  496.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  497.        endif()

  498.      endforeach()

  499.      foreach(_khr_header "khrplatform.h")

  500.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  501.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  502.        endif()

  503.      endforeach()

  504.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  505.    endif()

  506. 

  507.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  508. endfunction()

  509. 

  510. # dpf__add_executable

  511. # ------------------------------------------------------------------------------

  512. #

  513. # Adds an executable target, and set some default properties on the target.

  514. #

  515. function(dpf__add_executable NAME)

  516.   add_executable("${NAME}" ${ARGN})

  517.   dpf__set_target_defaults("${NAME}")

  518.   if(MINGW)

  519.     target_link_libraries("${NAME}" PRIVATE "-static")

  520.   endif()

  521. endfunction()

  522. 

  523. # dpf__add_module

  524. # ------------------------------------------------------------------------------

  525. #

  526. # Adds a module target, and set some default properties on the target.

  527. #

  528. function(dpf__add_module NAME)

  529.   add_library("${NAME}" MODULE ${ARGN})

  530.   dpf__set_target_defaults("${NAME}")

  531.   if(MINGW)

  532.     target_link_libraries("${NAME}" PRIVATE "-static")

  533.   endif()

  534. endfunction()

  535. 

  536. # dpf__add_static_library

  537. # ------------------------------------------------------------------------------

  538. #

  539. # Adds a static library target, and set some default properties on the target.

  540. #

  541. function(dpf__add_static_library NAME)

  542.   add_library("${NAME}" STATIC ${ARGN})

  543.   dpf__set_target_defaults("${NAME}")

  544. endfunction()

  545. 

  546. # dpf__set_target_defaults

  547. # ------------------------------------------------------------------------------

  548. #

  549. # Set default properties which must apply to all DPF-defined targets.

  550. #

  551. function(dpf__set_target_defaults NAME)

  552.   set_target_properties("${NAME}" PROPERTIES

  553.     POSITION_INDEPENDENT_CODE TRUE

  554.     C_VISIBILITY_PRESET "hidden"

  555.     CXX_VISIBILITY_PRESET "hidden"

  556.     VISIBILITY_INLINES_HIDDEN TRUE)

  557.   if(WIN32)

  558.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  559.   endif()

  560.   if (MINGW)

  561.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  562.   endif()

  563.   if (MSVC)

  564.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  565.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  566.   endif()

  567. endfunction()

  568. 

  569. # dpf__add_plugin_main

  570. # ------------------------------------------------------------------------------

  571. #

  572. # Adds plugin code to the given target.

  573. #

  574. function(dpf__add_plugin_main NAME TARGET)

  575.   target_sources("${NAME}" PRIVATE

  576.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  577.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  578. endfunction()

  579. 

  580. # dpf__add_ui_main

  581. # ------------------------------------------------------------------------------

  582. #

  583. # Adds UI code to the given target (only if the target has UI).

  584. #

  585. function(dpf__add_ui_main NAME TARGET HAS_UI)

  586.   if(HAS_UI)

  587.     target_sources("${NAME}" PRIVATE

  588.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  589.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  590.   endif()

  591. endfunction()

  592. 

  593. # dpf__add_plugin_target_definition

  594. # ------------------------------------------------------------------------------

  595. #

  596. # Adds the plugins target macro definition.

  597. # This selects which entry file is compiled according to the target type.

  598. #

  599. function(dpf__add_plugin_target_definition NAME TARGET)

  600.   string(TOUPPER "${TARGET}" _upperTarget)

  601.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  602. endfunction()

  603. 

  604. # dpf__add_lv2_ttl_generator

  605. # ------------------------------------------------------------------------------

  606. #

  607. # Build the LV2 TTL generator.

  608. #

  609. function(dpf__add_lv2_ttl_generator)

  610.   if(TARGET lv2_ttl_generator)

  611.     return()

  612.   endif()

  613.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  614.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  615.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  616.   endif()

  617. endfunction()

  618. 

  619. # dpf__ensure_sources_non_empty

  620. # ------------------------------------------------------------------------------

  621. #

  622. # Ensure the given source list contains at least one file.

  623. # The function appends an empty source file to the list if necessary.

  624. # This is useful when CMake does not permit to add targets without sources.

  625. #

  626. function(dpf__ensure_sources_non_empty VAR)

  627.   if(NOT "" STREQUAL "${${VAR}}")

  628.     return()

  629.   endif()

  630.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  631.   if(NOT EXISTS "${_file}")

  632.     file(WRITE "${_file}" "")

  633.   endif()

  634.   set("${VAR}" "${_file}" PARENT_SCOPE)

  635. endfunction()

  636. 

  637. # dpf__create_dummy_source_list

  638. # ------------------------------------------------------------------------------

  639. #

  640. # Create a dummy source list which is equivalent to compiling nothing.

  641. # This is only for compatibility with older CMake versions, which refuse to add

  642. # targets without any sources.

  643. #

  644. macro(dpf__create_dummy_source_list VAR)

  645.   set("${VAR}")

  646.   if(CMAKE_VERSION VERSION_LESS "3.11")

  647.     dpf__ensure_sources_non_empty("${VAR}")

  648.   endif()

  649. endmacro()

  650. 

  651. # dpf__warn_once

  652. # ------------------------------------------------------------------------------

  653. #

  654. # Prints a warning message once only.

  655. #

  656. function(dpf__warn_once_only TOKEN MESSAGE)

  657.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  658.   if(NOT _warned)

  659.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  660.     message(WARNING "${MESSAGE}")

  661.   endif()

  662. endfunction()