DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2030 Commits
6 Branches
72MB
Tree: a8c8547a45
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a8c8547a45'
${ noResults }
DPF/cmake/DPF-plugin.cmake

879 lines
31KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS clap lv2 vst2 vst3

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  126.     target_link_libraries("${NAME}" PRIVATE "dl")

  127.   endif()

  128. 

  129.   if(_dgl_library)

  130.     # make sure that all code will see DGL_* definitions

  131.     target_link_libraries("${NAME}" PUBLIC

  132.       "${_dgl_library}-definitions"

  133.       dgl-system-libs-definitions)

  134.   endif()

  135. 

  136.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  137.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  138. 

  139.   if(_dgl_library)

  140.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  141.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  142.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  143.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  144.     endif()

  145.     # add the files containing Objective-C classes

  146.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  147.   else()

  148.     add_library("${NAME}-ui" INTERFACE)

  149.   endif()

  150. 

  151.   ###

  152.   foreach(_target ${_dpf_plugin_TARGETS})

  153.     if(_target STREQUAL "jack")

  154.       dpf__build_jack("${NAME}" "${_dgl_library}")

  155.     elseif(_target STREQUAL "ladspa")

  156.       dpf__build_ladspa("${NAME}")

  157.     elseif(_target STREQUAL "dssi")

  158.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  159.     elseif(_target STREQUAL "lv2")

  160.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  161.     elseif(_target STREQUAL "vst2")

  162.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  163.     elseif(_target STREQUAL "vst3")

  164.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  165.     elseif(_target STREQUAL "clap")

  166.       dpf__build_clap("${NAME}" "${_dgl_library}")

  167.     else()

  168.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  169.     endif()

  170.   endforeach()

  171. endfunction()

  172. 

  173. # ------------------------------------------------------------------------------

  174. # DPF private functions (prefixed with `dpf__`)

  175. # ------------------------------------------------------------------------------

  176. 

  177. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  178. #       to the output directory.

  179. #

  180. 

  181. # dpf__build_jack

  182. # ------------------------------------------------------------------------------

  183. #

  184. # Add build rules for a JACK/Standalone program.

  185. #

  186. function(dpf__build_jack NAME DGL_LIBRARY)

  187.   dpf__create_dummy_source_list(_no_srcs)

  188. 

  189.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  190.   dpf__add_plugin_main("${NAME}-jack" "jack")

  191.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  192.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  193.   set_target_properties("${NAME}-jack" PROPERTIES

  194.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  195.     OUTPUT_NAME "${NAME}")

  196. 

  197.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  198. 

  199.   find_package(PkgConfig)

  200.   pkg_check_modules(SDL2 "sdl2")

  201.   if(SDL2_FOUND)

  202.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  203.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  204.     target_link_directories("${NAME}-jack" PUBLIC ${SDL2_LIBRARY_DIRS})

  205.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  206.   endif()

  207. 

  208.   if(APPLE OR WIN32)

  209.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  210.   else()

  211.     pkg_check_modules(ALSA "alsa")

  212.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  213.     if(ALSA_FOUND)

  214.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  215.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  216.       target_link_directories("${NAME}-jack" PUBLIC ${ALSA_LIBRARY_DIRS})

  217.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES})

  218.     endif()

  219.     if(PULSEAUDIO_FOUND)

  220.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  221.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  222.       target_link_directories("${NAME}-jack" PUBLIC ${PULSEAUDIO_LIBRARY_DIRS})

  223.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES})

  224.     endif()

  225.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  226.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  227.     endif()

  228.   endif()

  229. 

  230.   # for RtAudio native fallback

  231.   if(APPLE)

  232.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  233.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  234.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  235.     target_link_libraries("${NAME}-jack" PRIVATE

  236.       "${APPLE_COREAUDIO_FRAMEWORK}"

  237.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  238.       "${APPLE_COREMIDI_FRAMEWORK}")

  239.   endif()

  240. endfunction()

  241. 

  242. # dpf__build_ladspa

  243. # ------------------------------------------------------------------------------

  244. #

  245. # Add build rules for a LADSPA plugin.

  246. #

  247. function(dpf__build_ladspa NAME)

  248.   dpf__create_dummy_source_list(_no_srcs)

  249. 

  250.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  251.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  252.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  253.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  254.   set_target_properties("${NAME}-ladspa" PROPERTIES

  255.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  256.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  257.     OUTPUT_NAME "${NAME}-ladspa"

  258.     PREFIX "")

  259. endfunction()

  260. 

  261. # dpf__build_dssi

  262. # ------------------------------------------------------------------------------

  263. #

  264. # Add build rules for a DSSI plugin.

  265. #

  266. function(dpf__build_dssi NAME DGL_LIBRARY)

  267.   find_package(PkgConfig)

  268.   pkg_check_modules(LIBLO "liblo")

  269.   if(NOT LIBLO_FOUND)

  270.     dpf__warn_once_only(missing_liblo

  271.       "liblo is not found, skipping the `dssi` plugin targets")

  272.     return()

  273.   endif()

  274. 

  275.   dpf__create_dummy_source_list(_no_srcs)

  276. 

  277.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  278.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  279.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  280.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  281.   set_target_properties("${NAME}-dssi" PROPERTIES

  282.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  283.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  284.     OUTPUT_NAME "${NAME}-dssi"

  285.     PREFIX "")

  286. 

  287.   if(DGL_LIBRARY)

  288.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  289.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  290.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  291.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  292.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  293.       OUTPUT_NAME "${NAME}_ui")

  294. 

  295.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  296.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  297.     target_link_directories("${NAME}-dssi-ui" PUBLIC ${LIBLO_LIBRARY_DIRS})

  298.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  299.   endif()

  300. endfunction()

  301. 

  302. # dpf__build_lv2

  303. # ------------------------------------------------------------------------------

  304. #

  305. # Add build rules for an LV2 plugin.

  306. #

  307. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  308.   dpf__create_dummy_source_list(_no_srcs)

  309. 

  310.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  311.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  312.   if(DGL_LIBRARY AND MONOLITHIC)

  313.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  314.   else()

  315.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  316.   endif()

  317.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  318.   set_target_properties("${NAME}-lv2" PROPERTIES

  319.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  320.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  321.     OUTPUT_NAME "${NAME}_dsp"

  322.     PREFIX "")

  323. 

  324.   if(DGL_LIBRARY)

  325.     if(MONOLITHIC)

  326.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  327.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  328.       set_target_properties("${NAME}-lv2" PROPERTIES

  329.         OUTPUT_NAME "${NAME}")

  330.     else()

  331.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  332.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  333.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  334.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  335.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  336.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  337.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  338.         OUTPUT_NAME "${NAME}_ui"

  339.         PREFIX "")

  340.     endif()

  341.   endif()

  342. 

  343.   dpf__add_lv2_ttl_generator()

  344.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  345. 

  346.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  347.     COMMAND

  348.     "$<TARGET_FILE:lv2_ttl_generator>"

  349.     "$<TARGET_FILE:${NAME}-lv2>"

  350.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  351.     DEPENDS lv2_ttl_generator)

  352. endfunction()

  353. 

  354. # dpf__build_vst2

  355. # ------------------------------------------------------------------------------

  356. #

  357. # Add build rules for a VST2 plugin.

  358. #

  359. function(dpf__build_vst2 NAME DGL_LIBRARY)

  360.   dpf__create_dummy_source_list(_no_srcs)

  361. 

  362.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  363.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  364.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  365.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  366.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  367.   set_target_properties("${NAME}-vst2" PROPERTIES

  368.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  369.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  370.     OUTPUT_NAME "${NAME}-vst2"

  371.     PREFIX "")

  372.   if(APPLE)

  373.     set_target_properties("${NAME}-vst2" PROPERTIES

  374.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  375.       OUTPUT_NAME "${NAME}"

  376.       SUFFIX "")

  377.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  378.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  379.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  380.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  381.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  382.   endif()

  383. endfunction()

  384. 

  385. # dpf__determine_vst3_package_architecture

  386. # ------------------------------------------------------------------------------

  387. #

  388. # Determines the package architecture for a VST3 plugin target.

  389. #

  390. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  391.   # if set by variable, override the detection

  392.   if(DPF_VST3_ARCHITECTURE)

  393.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  394.     return()

  395.   endif()

  396. 

  397.   # not used on Apple, which supports universal binary

  398.   if(APPLE)

  399.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  400.     return()

  401.   endif()

  402. 

  403.   # identify the target processor (special case of MSVC, problematic sometimes)

  404.   if(MSVC)

  405.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  406.   else()

  407.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  408.   endif()

  409. 

  410.   # transform the processor name to a format that VST3 recognizes

  411.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  412.     set(vst3_package_arch "x86_64")

  413.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  414.     if(WIN32)

  415.       set(vst3_package_arch "x86")

  416.     else()

  417.       set(vst3_package_arch "i386")

  418.     endif()

  419.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  420.     set(vst3_package_arch "${vst3_system_arch}")

  421.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  422.     set(vst3_package_arch "aarch64")

  423.   else()

  424.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  425.   endif()

  426. 

  427.   # TODO: the detections for Windows arm/arm64 when supported

  428. 

  429.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  430. endfunction()

  431. 

  432. # dpf__build_vst3

  433. # ------------------------------------------------------------------------------

  434. #

  435. # Add build rules for a VST3 plugin.

  436. #

  437. function(dpf__build_vst3 NAME DGL_LIBRARY)

  438.   dpf__determine_vst3_package_architecture(vst3_arch)

  439. 

  440.   dpf__create_dummy_source_list(_no_srcs)

  441. 

  442.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  443.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  444.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  445.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  446.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  447.   set_target_properties("${NAME}-vst3" PROPERTIES

  448.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  449.     OUTPUT_NAME "${NAME}"

  450.     PREFIX "")

  451. 

  452.   if(APPLE)

  453.     set_target_properties("${NAME}-vst3" PROPERTIES

  454.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  455.       SUFFIX "")

  456.   elseif(WIN32)

  457.     set_target_properties("${NAME}-vst3" PROPERTIES

  458.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  459.   else()

  460.     set_target_properties("${NAME}-vst3" PROPERTIES

  461.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  462.   endif()

  463. 

  464.   if(APPLE)

  465.     # Uses the same macOS bundle template as VST2

  466.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  467.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  468.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  469.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  470.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  471.   endif()

  472. endfunction()

  473. 

  474. # dpf__build_clap

  475. # ------------------------------------------------------------------------------

  476. #

  477. # Add build rules for a VST2 plugin.

  478. #

  479. function(dpf__build_clap NAME DGL_LIBRARY)

  480.   dpf__create_dummy_source_list(_no_srcs)

  481. 

  482.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  483.   dpf__add_plugin_main("${NAME}-clap" "clap")

  484.   dpf__add_ui_main("${NAME}-clap" "clap" "${DGL_LIBRARY}")

  485.   dpf__set_module_export_list("${NAME}-clap" "clap")

  486.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  487.   set_target_properties("${NAME}-clap" PROPERTIES

  488.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  489.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  490.     OUTPUT_NAME "${NAME}"

  491.     PREFIX ""

  492.     SUFFIX ".clap")

  493. 

  494.   if(APPLE)

  495.     set_target_properties("${NAME}-clap" PROPERTIES

  496.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  497.       OUTPUT_NAME "${NAME}"

  498.       SUFFIX "")

  499.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  500.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  501.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  502.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  503.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  504.   endif()

  505. endfunction()

  506. 

  507. # dpf__add_dgl_cairo

  508. # ------------------------------------------------------------------------------

  509. #

  510. # Add the Cairo variant of DGL, if not already available.

  511. #

  512. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  513.   if(TARGET dgl-cairo)

  514.     return()

  515.   endif()

  516. 

  517.   find_package(PkgConfig)

  518.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  519. 

  520.   link_directories(${CAIRO_LIBRARY_DIRS})

  521. 

  522.   dpf__add_static_library(dgl-cairo STATIC

  523.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  524.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  525.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  526.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  528.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  530.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  531.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  532.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  533.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  534.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  535.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  536.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  537.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  538.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  539.   if(NO_SHARED_RESOURCES)

  540.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  541.   else()

  542.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  543.   endif()

  544.   if(NOT APPLE)

  545.     target_sources(dgl-cairo PRIVATE

  546.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  547.   else()

  548.     target_sources(dgl-cairo PRIVATE

  549.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  550.   endif()

  551.   target_include_directories(dgl-cairo PUBLIC

  552.     "${DPF_ROOT_DIR}/dgl")

  553.   target_include_directories(dgl-cairo PUBLIC

  554.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  555. 

  556.   dpf__add_dgl_system_libs()

  557.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  558. 

  559.   add_library(dgl-cairo-definitions INTERFACE)

  560.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  561. 

  562.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  563.   if(MINGW)

  564.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  565.   else()

  566.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  567.   endif()

  568.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  569. endfunction()

  570. 

  571. # dpf__add_dgl_opengl

  572. # ------------------------------------------------------------------------------

  573. #

  574. # Add the OpenGL variant of DGL, if not already available.

  575. #

  576. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  577.   if(TARGET dgl-opengl)

  578.     return()

  579.   endif()

  580. 

  581.   if(NOT OpenGL_GL_PREFERENCE)

  582.     set(OpenGL_GL_PREFERENCE "LEGACY")

  583.   endif()

  584. 

  585.   find_package(OpenGL REQUIRED)

  586. 

  587.   dpf__add_static_library(dgl-opengl STATIC

  588.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  589.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  590.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  591.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  592.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  593.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  594.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  595.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  596.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  597.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  598.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  599.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  600.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  601.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  602.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  603.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  604.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  605.   if(NO_SHARED_RESOURCES)

  606.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  607.   else()

  608.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  609.   endif()

  610.   if(NOT APPLE)

  611.     target_sources(dgl-opengl PRIVATE

  612.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  613.   else()

  614.     target_sources(dgl-opengl PRIVATE

  615.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  616.   endif()

  617.   target_include_directories(dgl-opengl PUBLIC

  618.     "${DPF_ROOT_DIR}/dgl")

  619.   target_include_directories(dgl-opengl PUBLIC

  620.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  621. 

  622.   if(APPLE)

  623.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  624.   endif()

  625. 

  626.   dpf__add_dgl_system_libs()

  627.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  628. 

  629.   add_library(dgl-opengl-definitions INTERFACE)

  630.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  631. 

  632.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  633.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  634. endfunction()

  635. 

  636. # dpf__add_plugin_specific_ui_sources

  637. # ------------------------------------------------------------------------------

  638. #

  639. # Compile system specific files, for now it is just Objective-C code

  640. #

  641. function(dpf__add_plugin_specific_ui_sources NAME)

  642.   if(APPLE)

  643.     target_sources("${NAME}" PRIVATE

  644.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  645.   endif()

  646. endfunction()

  647. 

  648. # dpf__add_dgl_system_libs

  649. # ------------------------------------------------------------------------------

  650. #

  651. # Find system libraries required by DGL and add them as an interface target.

  652. #

  653. function(dpf__add_dgl_system_libs)

  654.   if(TARGET dgl-system-libs)

  655.     return()

  656.   endif()

  657.   add_library(dgl-system-libs INTERFACE)

  658.   add_library(dgl-system-libs-definitions INTERFACE)

  659.   if(HAIKU)

  660.     target_link_libraries(dgl-system-libs INTERFACE "be")

  661.   elseif(WIN32)

  662.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  663.   elseif(APPLE)

  664.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  665.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  666.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  667.   else()

  668.     find_package(X11 REQUIRED)

  669.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  670.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  671.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  672.     if(X11_Xcursor_FOUND)

  673.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  674.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  675.     endif()

  676.     if(X11_Xext_FOUND)

  677.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  678.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  679.     endif()

  680.     if(X11_Xrandr_FOUND)

  681.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  682.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  683.     endif()

  684.     if(X11_XSync_FOUND)

  685.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  686.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  687.     endif()

  688.    endif()

  689. 

  690.    if(MSVC)

  691.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  692.      foreach(_gl_header "glext.h")

  693.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  694.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  695.        endif()

  696.      endforeach()

  697.      foreach(_khr_header "khrplatform.h")

  698.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  699.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  700.        endif()

  701.      endforeach()

  702.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  703.    endif()

  704. 

  705.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  706. endfunction()

  707. 

  708. # dpf__add_executable

  709. # ------------------------------------------------------------------------------

  710. #

  711. # Adds an executable target, and set some default properties on the target.

  712. #

  713. function(dpf__add_executable NAME)

  714.   add_executable("${NAME}" ${ARGN})

  715.   dpf__set_target_defaults("${NAME}")

  716.   if(MINGW)

  717.     target_link_libraries("${NAME}" PRIVATE "-static")

  718.   endif()

  719. endfunction()

  720. 

  721. # dpf__add_module

  722. # ------------------------------------------------------------------------------

  723. #

  724. # Adds a module target, and set some default properties on the target.

  725. #

  726. function(dpf__add_module NAME)

  727.   add_library("${NAME}" MODULE ${ARGN})

  728.   dpf__set_target_defaults("${NAME}")

  729.   if(MINGW)

  730.     target_link_libraries("${NAME}" PRIVATE "-static")

  731.   endif()

  732. endfunction()

  733. 

  734. # dpf__add_static_library

  735. # ------------------------------------------------------------------------------

  736. #

  737. # Adds a static library target, and set some default properties on the target.

  738. #

  739. function(dpf__add_static_library NAME)

  740.   add_library("${NAME}" STATIC ${ARGN})

  741.   dpf__set_target_defaults("${NAME}")

  742. endfunction()

  743. 

  744. # dpf__set_module_export_list

  745. # ------------------------------------------------------------------------------

  746. #

  747. # Applies a list of exported symbols to the module target.

  748. #

  749. function(dpf__set_module_export_list NAME EXPORTS)

  750.   if(WIN32)

  751.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  752.   elseif(APPLE)

  753.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  754.       "-Xlinker" "-exported_symbols_list"

  755.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  756.   else()

  757.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  758.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  759.   endif()

  760. endfunction()

  761. 

  762. # dpf__set_target_defaults

  763. # ------------------------------------------------------------------------------

  764. #

  765. # Set default properties which must apply to all DPF-defined targets.

  766. #

  767. function(dpf__set_target_defaults NAME)

  768.   set_target_properties("${NAME}" PROPERTIES

  769.     POSITION_INDEPENDENT_CODE TRUE

  770.     C_VISIBILITY_PRESET "hidden"

  771.     CXX_VISIBILITY_PRESET "hidden"

  772.     VISIBILITY_INLINES_HIDDEN TRUE)

  773.   if(WIN32)

  774.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  775.   endif()

  776.   if (MINGW)

  777.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  778.   endif()

  779.   if (MSVC)

  780.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  781.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  782.   endif()

  783. endfunction()

  784. 

  785. # dpf__add_plugin_main

  786. # ------------------------------------------------------------------------------

  787. #

  788. # Adds plugin code to the given target.

  789. #

  790. function(dpf__add_plugin_main NAME TARGET)

  791.   target_sources("${NAME}" PRIVATE

  792.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  793.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  794. endfunction()

  795. 

  796. # dpf__add_ui_main

  797. # ------------------------------------------------------------------------------

  798. #

  799. # Adds UI code to the given target (only if the target has UI).

  800. #

  801. function(dpf__add_ui_main NAME TARGET HAS_UI)

  802.   if(HAS_UI)

  803.     target_sources("${NAME}" PRIVATE

  804.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  805.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  806.   endif()

  807. endfunction()

  808. 

  809. # dpf__add_plugin_target_definition

  810. # ------------------------------------------------------------------------------

  811. #

  812. # Adds the plugins target macro definition.

  813. # This selects which entry file is compiled according to the target type.

  814. #

  815. function(dpf__add_plugin_target_definition NAME TARGET)

  816.   string(TOUPPER "${TARGET}" _upperTarget)

  817.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  818. endfunction()

  819. 

  820. # dpf__add_lv2_ttl_generator

  821. # ------------------------------------------------------------------------------

  822. #

  823. # Build the LV2 TTL generator.

  824. #

  825. function(dpf__add_lv2_ttl_generator)

  826.   if(TARGET lv2_ttl_generator)

  827.     return()

  828.   endif()

  829.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  830.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  831.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  832.   endif()

  833. endfunction()

  834. 

  835. # dpf__ensure_sources_non_empty

  836. # ------------------------------------------------------------------------------

  837. #

  838. # Ensure the given source list contains at least one file.

  839. # The function appends an empty source file to the list if necessary.

  840. # This is useful when CMake does not permit to add targets without sources.

  841. #

  842. function(dpf__ensure_sources_non_empty VAR)

  843.   if(NOT "" STREQUAL "${${VAR}}")

  844.     return()

  845.   endif()

  846.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  847.   if(NOT EXISTS "${_file}")

  848.     file(WRITE "${_file}" "")

  849.   endif()

  850.   set("${VAR}" "${_file}" PARENT_SCOPE)

  851. endfunction()

  852. 

  853. # dpf__create_dummy_source_list

  854. # ------------------------------------------------------------------------------

  855. #

  856. # Create a dummy source list which is equivalent to compiling nothing.

  857. # This is only for compatibility with older CMake versions, which refuse to add

  858. # targets without any sources.

  859. #

  860. macro(dpf__create_dummy_source_list VAR)

  861.   set("${VAR}")

  862.   if(CMAKE_VERSION VERSION_LESS "3.11")

  863.     dpf__ensure_sources_non_empty("${VAR}")

  864.   endif()

  865. endmacro()

  866. 

  867. # dpf__warn_once

  868. # ------------------------------------------------------------------------------

  869. #

  870. # Prints a warning message once only.

  871. #

  872. function(dpf__warn_once_only TOKEN MESSAGE)

  873.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  874.   if(NOT _warned)

  875.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  876.     message(WARNING "${MESSAGE}")

  877.   endif()

  878. endfunction()