DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1074 Commits
7 Branches
89MB
Tree: a764e196cf
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a764e196cf'
${ noResults }
DPF/cmake/DPF-plugin.cmake

649 lines
22KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   find_package(PkgConfig)

  177.   pkg_check_modules(JACK "jack")

  178.   if(NOT JACK_FOUND)

  179.     dpf__warn_once_only(missing_jack

  180.       "JACK is not found, skipping the `jack` plugin targets")

  181.     return()

  182.   endif()

  183. 

  184.   link_directories(${JACK_LIBRARY_DIRS})

  185. 

  186.   dpf__create_dummy_source_list(_no_srcs)

  187. 

  188.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  189.   dpf__add_plugin_main("${NAME}-jack" "jack")

  190.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  191.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  192.   set_target_properties("${NAME}-jack" PROPERTIES

  193.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  194.     OUTPUT_NAME "${NAME}")

  195. 

  196.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  197.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  198. endfunction()

  199. 

  200. # dpf__build_ladspa

  201. # ------------------------------------------------------------------------------

  202. #

  203. # Add build rules for a DSSI plugin.

  204. #

  205. function(dpf__build_ladspa NAME)

  206.   dpf__create_dummy_source_list(_no_srcs)

  207. 

  208.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  209.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  210.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  211.   set_target_properties("${NAME}-ladspa" PROPERTIES

  212.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  213.     OUTPUT_NAME "${NAME}-ladspa"

  214.     PREFIX "")

  215. endfunction()

  216. 

  217. # dpf__build_dssi

  218. # ------------------------------------------------------------------------------

  219. #

  220. # Add build rules for a DSSI plugin.

  221. #

  222. function(dpf__build_dssi NAME DGL_LIBRARY)

  223.   find_package(PkgConfig)

  224.   pkg_check_modules(LIBLO "liblo")

  225.   if(NOT LIBLO_FOUND)

  226.     dpf__warn_once_only(missing_liblo

  227.       "liblo is not found, skipping the `dssi` plugin targets")

  228.     return()

  229.   endif()

  230. 

  231.   link_directories(${LIBLO_LIBRARY_DIRS})

  232. 

  233.   dpf__create_dummy_source_list(_no_srcs)

  234. 

  235.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  236.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  237.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  238.   set_target_properties("${NAME}-dssi" PROPERTIES

  239.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  240.     OUTPUT_NAME "${NAME}-dssi"

  241.     PREFIX "")

  242. 

  243.   if(DGL_LIBRARY)

  244.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  245.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  246.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  247.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  248.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  249.       OUTPUT_NAME "${NAME}_ui")

  250. 

  251.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  252.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  253.   endif()

  254. endfunction()

  255. 

  256. # dpf__build_lv2

  257. # ------------------------------------------------------------------------------

  258. #

  259. # Add build rules for a LV2 plugin.

  260. #

  261. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  262.   dpf__create_dummy_source_list(_no_srcs)

  263. 

  264.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  265.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  266.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  267.   set_target_properties("${NAME}-lv2" PROPERTIES

  268.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  269.     OUTPUT_NAME "${NAME}_dsp"

  270.     PREFIX "")

  271. 

  272.   if(DGL_LIBRARY)

  273.     if(MONOLITHIC)

  274.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  275.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  276.       set_target_properties("${NAME}-lv2" PROPERTIES

  277.         OUTPUT_NAME "${NAME}")

  278.     else()

  279.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  280.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  281.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  282.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  283.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  284.         OUTPUT_NAME "${NAME}_ui"

  285.         PREFIX "")

  286.     endif()

  287.   endif()

  288. 

  289.   dpf__add_lv2_ttl_generator()

  290.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  291. 

  292.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  293.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  294.     "$<TARGET_FILE:lv2_ttl_generator>"

  295.     "$<TARGET_FILE:${NAME}-lv2>"

  296.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  297. endfunction()

  298. 

  299. # dpf__build_vst2

  300. # ------------------------------------------------------------------------------

  301. #

  302. # Add build rules for a VST2 plugin.

  303. #

  304. function(dpf__build_vst2 NAME DGL_LIBRARY)

  305.   dpf__create_dummy_source_list(_no_srcs)

  306. 

  307.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  308.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  309.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  310.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  311.   set_target_properties("${NAME}-vst2" PROPERTIES

  312.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  313.     OUTPUT_NAME "${NAME}-vst2"

  314.     PREFIX "")

  315. endfunction()

  316. 

  317. # dpf__add_dgl_cairo

  318. # ------------------------------------------------------------------------------

  319. #

  320. # Add the Cairo variant of DGL, if not already available.

  321. #

  322. function(dpf__add_dgl_cairo)

  323.   if(TARGET dgl-cairo)

  324.     return()

  325.   endif()

  326. 

  327.   find_package(PkgConfig)

  328.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  329. 

  330.   link_directories(${CAIRO_LIBRARY_DIRS})

  331. 

  332.   dpf__add_static_library(dgl-cairo STATIC

  333.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  343.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  344.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  345.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  346.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  347.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  348.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  349.   if(NOT APPLE)

  350.     target_sources(dgl-cairo PRIVATE

  351.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  352.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  353.     #target_sources(dgl-opengl PRIVATE

  354.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  355.   endif()

  356.   target_include_directories(dgl-cairo PUBLIC

  357.     "${DPF_ROOT_DIR}/dgl")

  358.   target_include_directories(dgl-cairo PUBLIC

  359.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  360. 

  361.   dpf__add_dgl_system_libs()

  362.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  363. 

  364.   add_library(dgl-cairo-definitions INTERFACE)

  365.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  366. 

  367.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  368.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  369. endfunction()

  370. 

  371. # dpf__add_dgl_opengl

  372. # ------------------------------------------------------------------------------

  373. #

  374. # Add the OpenGL variant of DGL, if not already available.

  375. #

  376. function(dpf__add_dgl_opengl)

  377.   if(TARGET dgl-opengl)

  378.     return()

  379.   endif()

  380. 

  381.   if(NOT OpenGL_GL_PREFERENCE)

  382.     set(OpenGL_GL_PREFERENCE "LEGACY")

  383.   endif()

  384. 

  385.   find_package(OpenGL REQUIRED)

  386. 

  387.   dpf__add_static_library(dgl-opengl STATIC

  388.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  389.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  390.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  391.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  392.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  393.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  394.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  405.   if(NOT APPLE)

  406.     target_sources(dgl-opengl PRIVATE

  407.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  408.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  409.     #target_sources(dgl-opengl PRIVATE

  410.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  411.   endif()

  412.   target_include_directories(dgl-opengl PUBLIC

  413.     "${DPF_ROOT_DIR}/dgl")

  414.   target_include_directories(dgl-opengl PUBLIC

  415.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  416. 

  417.   if(APPLE)

  418.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  419.   endif()

  420. 

  421.   dpf__add_dgl_system_libs()

  422.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  423. 

  424.   add_library(dgl-opengl-definitions INTERFACE)

  425.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  426. 

  427.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  428.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  429. endfunction()

  430. 

  431. # dpf__add_plugin_specific_ui_sources

  432. # ------------------------------------------------------------------------------

  433. #

  434. # Compile plugin-specific UI sources into the target designated by the given

  435. # name. There are some special considerations here:

  436. # - On most platforms, sources can be compiled only once, as part of DGL;

  437. # - On macOS, for any sources which define Objective-C interfaces, these must

  438. #   be recompiled for each plugin under a unique namespace. In this case, the

  439. #   name must be a plugin-specific identifier, and it will be used for computing

  440. #   the unique ID along with the project version.

  441. function(dpf__add_plugin_specific_ui_sources NAME)

  442.   if(APPLE)

  443.     target_sources("${NAME}" PRIVATE

  444.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  445.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  446.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  447.   endif()

  448. endfunction()

  449. 

  450. # dpf__add_dgl_system_libs

  451. # ------------------------------------------------------------------------------

  452. #

  453. # Find system libraries required by DGL and add them as an interface target.

  454. #

  455. function(dpf__add_dgl_system_libs)

  456.   if(TARGET dgl-system-libs)

  457.     return()

  458.   endif()

  459.   add_library(dgl-system-libs INTERFACE)

  460.   add_library(dgl-system-libs-definitions INTERFACE)

  461.   if(HAIKU)

  462.     target_link_libraries(dgl-system-libs INTERFACE "be")

  463.   elseif(WIN32)

  464.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  465.   elseif(APPLE)

  466.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  467.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  468.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  469.   else()

  470.     find_package(X11 REQUIRED)

  471.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  472.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  473.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  474.     if(X11_Xext_FOUND)

  475.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  476.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  477.     endif()

  478.     if(X11_XSync_FOUND)

  479.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  480.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  481.     endif()

  482.     if(X11_Xrandr_FOUND)

  483.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  484.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  485.     endif()

  486.     #if(X11_Xcursor_FOUND)

  487.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  488.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  489.     #endif()

  490.    endif()

  491.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  492. endfunction()

  493. 

  494. # dpf__add_executable

  495. # ------------------------------------------------------------------------------

  496. #

  497. # Adds an executable target, and set some default properties on the target.

  498. #

  499. function(dpf__add_executable NAME)

  500.   add_executable("${NAME}" ${ARGN})

  501.   set_target_properties("${NAME}" PROPERTIES

  502.     POSITION_INDEPENDENT_CODE TRUE

  503.     C_VISIBILITY_PRESET "hidden"

  504.     CXX_VISIBILITY_PRESET "hidden"

  505.     VISIBILITY_INLINES_HIDDEN TRUE)

  506.   if (MINGW)

  507.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  508.   endif()

  509. endfunction()

  510. 

  511. # dpf__add_module

  512. # ------------------------------------------------------------------------------

  513. #

  514. # Adds a module target, and set some default properties on the target.

  515. #

  516. function(dpf__add_module NAME)

  517.   add_library("${NAME}" MODULE ${ARGN})

  518.   set_target_properties("${NAME}" PROPERTIES

  519.     POSITION_INDEPENDENT_CODE TRUE

  520.     C_VISIBILITY_PRESET "hidden"

  521.     CXX_VISIBILITY_PRESET "hidden"

  522.     VISIBILITY_INLINES_HIDDEN TRUE)

  523.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  524.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  525.   endif()

  526.   if (MINGW)

  527.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  528.   endif()

  529. endfunction()

  530. 

  531. # dpf__add_static_library

  532. # ------------------------------------------------------------------------------

  533. #

  534. # Adds a static library target, and set some default properties on the target.

  535. #

  536. function(dpf__add_static_library NAME)

  537.   add_library("${NAME}" STATIC ${ARGN})

  538.   set_target_properties("${NAME}" PROPERTIES

  539.     POSITION_INDEPENDENT_CODE TRUE

  540.     C_VISIBILITY_PRESET "hidden"

  541.     CXX_VISIBILITY_PRESET "hidden"

  542.     VISIBILITY_INLINES_HIDDEN TRUE)

  543.   if (MINGW)

  544.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  545.   endif()

  546. endfunction()

  547. 

  548. # dpf__add_plugin_main

  549. # ------------------------------------------------------------------------------

  550. #

  551. # Adds plugin code to the given target.

  552. #

  553. function(dpf__add_plugin_main NAME TARGET)

  554.   target_sources("${NAME}" PRIVATE

  555.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  556.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  557. endfunction()

  558. 

  559. # dpf__add_ui_main

  560. # ------------------------------------------------------------------------------

  561. #

  562. # Adds UI code to the given target (only if the target has UI).

  563. #

  564. function(dpf__add_ui_main NAME TARGET HAS_UI)

  565.   if(HAS_UI)

  566.     target_sources("${NAME}" PRIVATE

  567.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  568.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  569.   endif()

  570. endfunction()

  571. 

  572. # dpf__add_plugin_target_definition

  573. # ------------------------------------------------------------------------------

  574. #

  575. # Adds the plugins target macro definition.

  576. # This selects which entry file is compiled according to the target type.

  577. #

  578. function(dpf__add_plugin_target_definition NAME TARGET)

  579.   string(TOUPPER "${TARGET}" _upperTarget)

  580. 

  581.   # resolve the alias into the proper name

  582.   # the name "vst2" is new, "vst" is legacy

  583.   if(_upperTarget STREQUAL "VST2")

  584.     set(_upperTarget "VST")

  585.   endif()

  586. 

  587.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  588. endfunction()

  589. 

  590. # dpf__add_lv2_ttl_generator

  591. # ------------------------------------------------------------------------------

  592. #

  593. # Build the LV2 TTL generator.

  594. #

  595. function(dpf__add_lv2_ttl_generator)

  596.   if(TARGET lv2_ttl_generator)

  597.     return()

  598.   endif()

  599.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  600.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  601.     target_link_libraries(lv2_ttl_generator "dl")

  602.   endif()

  603. endfunction()

  604. 

  605. # dpf__ensure_sources_non_empty

  606. # ------------------------------------------------------------------------------

  607. #

  608. # Ensure the given source list contains at least one file.

  609. # The function appends an empty source file to the list if necessary.

  610. # This is useful when CMake does not permit to add targets without sources.

  611. #

  612. function(dpf__ensure_sources_non_empty VAR)

  613.   if(NOT "" STREQUAL "${${VAR}}")

  614.     return()

  615.   endif()

  616.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  617.   if(NOT EXISTS "${_file}")

  618.     file(WRITE "${_file}" "")

  619.   endif()

  620.   set("${VAR}" "${_file}" PARENT_SCOPE)

  621. endfunction()

  622. 

  623. # dpf__create_dummy_source_list

  624. # ------------------------------------------------------------------------------

  625. #

  626. # Create a dummy source list which is equivalent to compiling nothing.

  627. # This is only for compatibility with older CMake versions, which refuse to add

  628. # targets without any sources.

  629. #

  630. macro(dpf__create_dummy_source_list VAR)

  631.   set("${VAR}")

  632.   if(CMAKE_VERSION VERSION_LESS "3.11")

  633.     dpf__ensure_sources_non_empty("${VAR}")

  634.   endif()

  635. endmacro()

  636. 

  637. # dpf__warn_once

  638. # ------------------------------------------------------------------------------

  639. #

  640. # Prints a warning message once only.

  641. #

  642. function(dpf__warn_once_only TOKEN MESSAGE)

  643.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  644.   if(NOT _warned)

  645.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  646.     message(WARNING "${MESSAGE}")

  647.   endif()

  648. endfunction()