DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2450 Commits
7 Branches
52MB
Tree: a56ff9799e
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a56ff9799e'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1718 lines
61KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `FORCE_NATIVE_AUDIO_FALLBACK`

  108. #       force the JACK/Standalone format to use native audio fallback instead of JACK

  109. #

  110. #   `SKIP_NATIVE_AUDIO_FALLBACK`

  111. #       force the JACK/Standalone format to always use JACK, skipping native audio fallback

  112. #

  113. #   `USE_FILE_BROWSER`

  114. #       enable file browser dialog APIs

  115. #

  116. #   `USE_WEB_VIEW`

  117. #       enable web browser view APIs

  118. #

  119. function(dpf_add_plugin NAME)

  120.   set(options MONOLITHIC NO_SHARED_RESOURCES FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER USE_WEB_VIEW)

  121.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  122.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  123.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  124. 

  125.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  126.     set(_dpf_plugin_UI_TYPE "opengl")

  127.   endif()

  128. 

  129.   set(_dgl_library)

  130.   if(_dpf_plugin_FILES_UI)

  131.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  132.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  133.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  134.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  135.       set(_dgl_library dgl-cairo)

  136.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  137.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  138.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  139.       set(_dgl_library dgl-external)

  140.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  141.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  142.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  143.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  144.       set(_dgl_library dgl-gles2)

  145.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  146.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  147.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  148.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  149.       set(_dgl_library dgl-gles3)

  150.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  151.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  152.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  153.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  154.       set(_dgl_library dgl-opengl)

  155.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  156.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  157.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  158.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  159.       set(_dgl_library dgl-opengl3)

  160.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  161.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  162.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  163.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  164.       set(_dgl_library dgl-vulkan)

  165.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  166.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  167.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  168.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  169.       set(_dgl_library dgl-external)

  170.     else()

  171.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  172.     endif()

  173.   else()

  174.     set(_dpf_plugin_UI_TYPE "")

  175.   endif()

  176. 

  177.   set(_dgl_has_ui OFF)

  178.   if(_dgl_library)

  179.     set(_dgl_has_ui ON)

  180.   endif()

  181. 

  182.   ###

  183.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  184.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  185.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  186. 

  187.   ###

  188.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  189.   target_include_directories("${NAME}" PUBLIC

  190.     "${DPF_ROOT_DIR}/distrho")

  191. 

  192.   if(_dpf_plugin_USE_FILE_BROWSER)

  193.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  194.   endif()

  195. 

  196.   if(_dpf_plugin_USE_WEB_VIEW)

  197.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  198.   endif()

  199. 

  200.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  201.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  202.   endif()

  203. 

  204.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  205.     target_link_libraries("${NAME}" PRIVATE "dl")

  206.   endif()

  207. 

  208.   if(_dgl_library)

  209.     # make sure that all code will see DGL_* definitions

  210.     target_link_libraries("${NAME}" PUBLIC

  211.       "${_dgl_library}-definitions"

  212.       dgl-system-libs-definitions

  213.       dgl-system-libs)

  214.   endif()

  215. 

  216.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  217.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  218. 

  219.   if(_dgl_library)

  220.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  221.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  222.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  223.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  224.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  225.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  226.           OUTPUT_STRIP_TRAILING_WHITESPACE

  227.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  228.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  229.       endif()

  230.     endif()

  231.     # add the files containing C++17 or Objective-C classes

  232.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  233.   else()

  234.     add_library("${NAME}-ui" INTERFACE)

  235.   endif()

  236. 

  237.   ###

  238.   foreach(_target ${_dpf_plugin_TARGETS})

  239.     if(_target STREQUAL "jack")

  240.       dpf__build_jack("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_FORCE_NATIVE_AUDIO_FALLBACK}" "${_dpf_plugin_SKIP_NATIVE_AUDIO_FALLBACK}")

  241.     elseif(_target STREQUAL "ladspa")

  242.       dpf__build_ladspa("${NAME}")

  243.     elseif(_target STREQUAL "dssi")

  244.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  245.     elseif(_target STREQUAL "lv2")

  246.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  247.     elseif(_target STREQUAL "vst2")

  248.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  249.     elseif(_target STREQUAL "vst3")

  250.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  251.     elseif(_target STREQUAL "clap")

  252.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  253.     elseif(_target STREQUAL "au")

  254.       if (APPLE)

  255.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  256.       endif()

  257.     elseif(_target STREQUAL "static")

  258.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  259.     else()

  260.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  261.     endif()

  262.   endforeach()

  263. endfunction()

  264. 

  265. # dpf_add_executable(target <args...>)

  266. # ------------------------------------------------------------------------------

  267. #

  268. # Add a simple executable built using the DISTRHO Plugin Framework.

  269. #

  270. # ------------------------------------------------------------------------------

  271. # Arguments:

  272. #

  273. #   `UI_TYPE` <type>

  274. #       the user interface type, can be one of the following:

  275. #          - cairo

  276. #          - external

  277. #          - gles2

  278. #          - gles3

  279. #          - opengl (default)

  280. #          - opengl3

  281. #          - vulkan

  282. #          - webview

  283. #

  284. #   `NO_SHARED_RESOURCES`

  285. #       do not build DPF shared resources (fonts, etc)

  286. #

  287. #   `USE_FILE_BROWSER`

  288. #       enable file browser dialog APIs

  289. #

  290. #   `USE_WEB_VIEW`

  291. #       enable web browser view APIs

  292. #

  293. function(dpf_add_executable NAME)

  294.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  295.   set(oneValueArgs UI_TYPE)

  296.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  297. 

  298.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  299.     set(_dpf_plugin_UI_TYPE "opengl")

  300.   endif()

  301. 

  302.   set(_dgl_library)

  303.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  304.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  305.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  306.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  307.     set(_dgl_library dgl-cairo)

  308.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  309.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  310.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  311.     set(_dgl_library dgl-external)

  312.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  313.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  314.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  315.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  316.     set(_dgl_library dgl-gles2)

  317.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  318.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  319.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  320.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  321.     set(_dgl_library dgl-gles3)

  322.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  323.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  324.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  325.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  326.     set(_dgl_library dgl-opengl)

  327.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  328.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  329.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  330.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  331.     set(_dgl_library dgl-opengl3)

  332.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  333.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  334.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  335.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  336.     set(_dgl_library dgl-vulkan)

  337.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  338.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  339.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  340.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  341.     set(_dgl_library dgl-external)

  342.   else()

  343.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  344.   endif()

  345. 

  346.   set(_dgl_has_ui OFF)

  347.   if(_dgl_library)

  348.     set(_dgl_has_ui ON)

  349.   endif()

  350. 

  351.   dpf__create_dummy_source_list(_no_srcs)

  352.   dpf__add_executable("${NAME}" ${_no_srcs})

  353.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  354. 

  355.   if(_dpf_plugin_USE_FILE_BROWSER)

  356.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  357.   endif()

  358. 

  359.   if(_dpf_plugin_USE_WEB_VIEW)

  360.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  361.   endif()

  362. 

  363.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  364.     target_link_libraries("${NAME}" PRIVATE "dl")

  365.   endif()

  366. 

  367.   if(_dgl_library)

  368.     # make sure that all code will see DGL_* definitions

  369.     target_link_libraries("${NAME}" PUBLIC

  370.       "${_dgl_library}"

  371.       "${_dgl_library}-definitions"

  372.       dgl-system-libs-definitions

  373.       dgl-system-libs)

  374.     # extra linkage for linux web view

  375.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  376.       target_link_libraries("${NAME}" PRIVATE "rt")

  377.     endif()

  378.     # add the files containing C++17 or Objective-C classes

  379.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  380.   endif()

  381. endfunction()

  382. 

  383. # ------------------------------------------------------------------------------

  384. # DPF private functions (prefixed with `dpf__`)

  385. # ------------------------------------------------------------------------------

  386. 

  387. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  388. #       to the output directory.

  389. #

  390. 

  391. # dpf__build_jack

  392. # ------------------------------------------------------------------------------

  393. #

  394. # Add build rules for a JACK/Standalone program.

  395. #

  396. function(dpf__build_jack NAME HAS_UI FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK)

  397.   dpf__create_dummy_source_list(_no_srcs)

  398. 

  399.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  400.   dpf__add_plugin_main("${NAME}-jack" "jack")

  401.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  402.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  403.   set_target_properties("${NAME}-jack" PROPERTIES

  404.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  405.     OUTPUT_NAME "${NAME}")

  406. 

  407.   if(NOT FORCE_NATIVE_AUDIO_FALLBACK)

  408.     target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  409.     target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  410.   endif()

  411. 

  412.   if(SKIP_NATIVE_AUDIO_FALLBACK)

  413.     return()

  414.   endif()

  415. 

  416.   find_package(PkgConfig QUIET)

  417.   if(PKG_CONFIG_FOUND)

  418.     pkg_check_modules(SDL2 "sdl2")

  419.   else()

  420.     set(SDL2_FOUND FALSE)

  421.   endif()

  422.   if(SDL2_FOUND)

  423.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  424.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  425.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  426.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  427.   endif()

  428. 

  429.   if(APPLE OR WIN32)

  430.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  431.   else()

  432.     find_package(Threads)

  433.     pkg_check_modules(ALSA "alsa")

  434.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  435.     if(ALSA_FOUND)

  436.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  437.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  438.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  439.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  440.     endif()

  441.     if(PULSEAUDIO_FOUND)

  442.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  443.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  444.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  445.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  446.     endif()

  447.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  448.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  449.     endif()

  450.   endif()

  451. 

  452.   # for RtAudio native fallback

  453.   if(APPLE)

  454.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  455.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  456.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  457.     target_link_libraries("${NAME}-jack" PRIVATE

  458.       "${APPLE_COREAUDIO_FRAMEWORK}"

  459.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  460.       "${APPLE_COREMIDI_FRAMEWORK}")

  461.   elseif(WIN32)

  462.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  463.     if(HAS_UI AND MINGW)

  464.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  465.     endif()

  466.   endif()

  467. endfunction()

  468. 

  469. # dpf__build_ladspa

  470. # ------------------------------------------------------------------------------

  471. #

  472. # Add build rules for a LADSPA plugin.

  473. #

  474. function(dpf__build_ladspa NAME)

  475.   dpf__create_dummy_source_list(_no_srcs)

  476. 

  477.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  478.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  479.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  480.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  481.   set_target_properties("${NAME}-ladspa" PROPERTIES

  482.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  483.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  484.     OUTPUT_NAME "${NAME}-ladspa"

  485.     PREFIX "")

  486. endfunction()

  487. 

  488. # dpf__build_dssi

  489. # ------------------------------------------------------------------------------

  490. #

  491. # Add build rules for a DSSI plugin.

  492. #

  493. function(dpf__build_dssi NAME HAS_UI)

  494.   find_package(PkgConfig QUIET)

  495.   if(PKG_CONFIG_FOUND)

  496.     pkg_check_modules(LIBLO "liblo")

  497.   else()

  498.     set(LIBLO_FOUND FALSE)

  499.   endif()

  500.   if(NOT LIBLO_FOUND)

  501.     dpf__warn_once_only(missing_liblo

  502.       "liblo is not found, skipping the `dssi` plugin targets")

  503.     return()

  504.   endif()

  505. 

  506.   dpf__create_dummy_source_list(_no_srcs)

  507. 

  508.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  509.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  510.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  511.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  512.   set_target_properties("${NAME}-dssi" PROPERTIES

  513.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  514.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  515.     OUTPUT_NAME "${NAME}-dssi"

  516.     PREFIX "")

  517. 

  518.   if(HAS_UI)

  519.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  520.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  521.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  522.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  523.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  524.       OUTPUT_NAME "${NAME}_ui")

  525. 

  526.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  527.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  528.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  529.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  530.   endif()

  531. endfunction()

  532. 

  533. # dpf__build_lv2

  534. # ------------------------------------------------------------------------------

  535. #

  536. # Add build rules for an LV2 plugin.

  537. #

  538. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  539.   dpf__create_dummy_source_list(_no_srcs)

  540. 

  541.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  542.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  543.   if(HAS_UI AND MONOLITHIC)

  544.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  545.   else()

  546.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  547.   endif()

  548.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  549.   set_target_properties("${NAME}-lv2" PROPERTIES

  550.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  551.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  552.     OUTPUT_NAME "${NAME}_dsp"

  553.     PREFIX "")

  554. 

  555.   if(HAS_UI)

  556.     if(MONOLITHIC)

  557.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  558.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  559.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  560.       set_target_properties("${NAME}-lv2" PROPERTIES

  561.         OUTPUT_NAME "${NAME}")

  562.     else()

  563.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  564.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  565.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  566.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  567.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  568.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  569.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  570.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  571.         OUTPUT_NAME "${NAME}_ui"

  572.         PREFIX "")

  573.     endif()

  574.   endif()

  575. 

  576.   dpf__add_lv2_ttl_generator()

  577.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  578. 

  579.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  580. 

  581.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  582.     COMMAND

  583.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  584.     "$<TARGET_FILE:lv2_ttl_generator>"

  585.     "$<TARGET_FILE:${NAME}-lv2>"

  586.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  587. endfunction()

  588. 

  589. # dpf__build_vst2

  590. # ------------------------------------------------------------------------------

  591. #

  592. # Add build rules for a VST2 plugin.

  593. #

  594. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  595.   dpf__create_dummy_source_list(_no_srcs)

  596. 

  597.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  598.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  599.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  600.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  601.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  602.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  603.   set_target_properties("${NAME}-vst2" PROPERTIES

  604.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  605.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  606.     OUTPUT_NAME "${NAME}-vst2"

  607.     PREFIX "")

  608.   if(APPLE)

  609.     set_target_properties("${NAME}-vst2" PROPERTIES

  610.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  611.       OUTPUT_NAME "${NAME}"

  612.       SUFFIX "")

  613.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  614.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  615.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  616.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  617.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  618.   endif()

  619. endfunction()

  620. 

  621. # dpf__determine_vst3_package_architecture

  622. # ------------------------------------------------------------------------------

  623. #

  624. # Determines the package architecture for a VST3 plugin target.

  625. #

  626. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  627.   # if set by variable, override the detection

  628.   if(DPF_VST3_ARCHITECTURE)

  629.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  630.     return()

  631.   endif()

  632. 

  633.   # not used on Apple, which supports universal binary

  634.   if(APPLE)

  635.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  636.     return()

  637.   endif()

  638. 

  639.   # identify the target processor (special case of MSVC, problematic sometimes)

  640.   if(MSVC)

  641.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  642.   else()

  643.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  644.   endif()

  645. 

  646.   # transform the processor name to a format that VST3 recognizes

  647.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  648.     set(vst3_package_arch "x86_64")

  649.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  650.     if(WIN32)

  651.       set(vst3_package_arch "x86")

  652.     else()

  653.       set(vst3_package_arch "i386")

  654.     endif()

  655.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  656.     set(vst3_package_arch "${vst3_system_arch}")

  657.   else()

  658.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  659.   endif()

  660. 

  661.   # TODO: the detections for Windows arm/arm64 when supported

  662. 

  663.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  664. endfunction()

  665. 

  666. # dpf__build_vst3

  667. # ------------------------------------------------------------------------------

  668. #

  669. # Add build rules for a VST3 plugin.

  670. #

  671. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  672.   dpf__determine_vst3_package_architecture(vst3_arch)

  673. 

  674.   dpf__create_dummy_source_list(_no_srcs)

  675. 

  676.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  677.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  678.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  679.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  680.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  681.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  682.   set_target_properties("${NAME}-vst3" PROPERTIES

  683.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  684.     OUTPUT_NAME "${NAME}"

  685.     PREFIX "")

  686. 

  687.   if(APPLE)

  688.     set_target_properties("${NAME}-vst3" PROPERTIES

  689.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  690.       SUFFIX "")

  691.   elseif(WIN32)

  692.     set_target_properties("${NAME}-vst3" PROPERTIES

  693.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  694.   else()

  695.     set_target_properties("${NAME}-vst3" PROPERTIES

  696.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  697.   endif()

  698. 

  699.   if(APPLE)

  700.     # Uses the same macOS bundle template as VST2

  701.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  702.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  703.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  704.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  705.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  706.   endif()

  707. endfunction()

  708. 

  709. # dpf__build_clap

  710. # ------------------------------------------------------------------------------

  711. #

  712. # Add build rules for a CLAP plugin.

  713. #

  714. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  715.   dpf__create_dummy_source_list(_no_srcs)

  716. 

  717.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  718.   dpf__add_plugin_main("${NAME}-clap" "clap")

  719.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  720.   dpf__set_module_export_list("${NAME}-clap" "clap")

  721.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  722.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  723.   set_target_properties("${NAME}-clap" PROPERTIES

  724.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  725.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  726.     OUTPUT_NAME "${NAME}"

  727.     PREFIX ""

  728.     SUFFIX ".clap")

  729. 

  730.   if(APPLE)

  731.     set_target_properties("${NAME}-clap" PROPERTIES

  732.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  733.       OUTPUT_NAME "${NAME}"

  734.       SUFFIX "")

  735.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  736.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  737.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  738.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  739.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  740.   endif()

  741. endfunction()

  742. 

  743. # dpf__build_au

  744. # ------------------------------------------------------------------------------

  745. #

  746. # Add build rules for an AUv2 plugin.

  747. #

  748. function(dpf__build_au NAME HAS_UI)

  749.   dpf__create_dummy_source_list(_no_srcs)

  750. 

  751.   dpf__add_module("${NAME}-au" ${_no_srcs})

  752.   dpf__add_plugin_main("${NAME}-au" "au")

  753.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  754.   dpf__set_module_export_list("${NAME}-au" "au")

  755.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  756.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  757.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  758.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  759.   target_link_libraries("${NAME}-au" PRIVATE

  760.     "${NAME}-dsp"

  761.     "${NAME}-ui"

  762.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  763.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  764.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  765.   set_target_properties("${NAME}-au" PROPERTIES

  766.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  767.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  768.     OUTPUT_NAME "${NAME}"

  769.     PREFIX ""

  770.     SUFFIX "")

  771. 

  772.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  773.   dpf__add_plugin_main("${NAME}-export" "export")

  774.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  775.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  776. 

  777.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  778. 

  779.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  780.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  781.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  782. 

  783.   add_dependencies("${NAME}-au" "${NAME}-export")

  784. 

  785.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  786.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  787. endfunction()

  788. 

  789. # dpf__build_static

  790. # ------------------------------------------------------------------------------

  791. #

  792. # Add build rules for a static library.

  793. #

  794. function(dpf__build_static NAME HAS_UI)

  795.   dpf__create_dummy_source_list(_no_srcs)

  796. 

  797.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  798.   dpf__add_plugin_main("${NAME}-static" "static")

  799.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  800.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  801. 

  802.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  803.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  804.   foreach(src ${dsp_srcs})

  805.     target_sources("${NAME}-static" PRIVATE ${src})

  806.   endforeach()

  807.   foreach(src ${ui_srcs})

  808.     target_sources("${NAME}-static" PRIVATE ${src})

  809.   endforeach()

  810. 

  811.   set_target_properties("${NAME}-static" PROPERTIES

  812.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  813.     OUTPUT_NAME "${NAME}"

  814.     PREFIX "")

  815. endfunction()

  816. 

  817. # dpf__add_dgl_cairo

  818. # ------------------------------------------------------------------------------

  819. #

  820. # Add the Cairo variant of DGL, if not already available.

  821. #

  822. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  823.   if(TARGET dgl-cairo)

  824.     return()

  825.   endif()

  826. 

  827.   find_package(PkgConfig REQUIRED)

  828.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  829. 

  830.   link_directories(${CAIRO_LIBRARY_DIRS})

  831. 

  832.   dpf__add_static_library(dgl-cairo STATIC

  833.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  834.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  835.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  836.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  837.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  838.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  839.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  840.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  841.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  842.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  843.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  844.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  845.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  846.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  847.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  848.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  849.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  850.   if(SHARED_RESOURCES)

  851.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  852.   else()

  853.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  854.   endif()

  855.   if(APPLE)

  856.     target_sources(dgl-cairo PRIVATE

  857.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  858.   else()

  859.     target_sources(dgl-cairo PRIVATE

  860.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  861.   endif()

  862.   target_include_directories(dgl-cairo PUBLIC

  863.     "${DPF_ROOT_DIR}/dgl")

  864.   target_include_directories(dgl-cairo PUBLIC

  865.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  866. 

  867.   if(USE_FILE_BROWSER)

  868.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  869.   endif()

  870. 

  871.   if(USE_WEB_VIEW)

  872.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  873.     if(APPLE)

  874.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  875.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  876.     elseif(WIN32)

  877.       target_sources(dgl-cairo PRIVATE

  878.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  879.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  880.         PROPERTIES

  881.           COMPILE_FLAGS

  882.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  883.     endif()

  884.   endif()

  885. 

  886.   dpf__add_dgl_system_libs()

  887.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  888. 

  889.   add_library(dgl-cairo-definitions INTERFACE)

  890.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  891. 

  892.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  893.   if(MINGW)

  894.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  895.   else()

  896.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  897.   endif()

  898.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  899. endfunction()

  900. 

  901. # dpf__add_dgl_external

  902. # ------------------------------------------------------------------------------

  903. #

  904. # Add the external variant of DGL, if not already available.

  905. #

  906. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  907.   if(TARGET dgl-external)

  908.     return()

  909.   endif()

  910. 

  911.   dpf__add_static_library(dgl-external STATIC

  912.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  913.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  914.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  915.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  916.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  917.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  918.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  919.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  920.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  921.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  922.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  923.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  924.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  925.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  926.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  927.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  928.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  929. 

  930.   if(APPLE)

  931.     target_sources(dgl-external PRIVATE

  932.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  933.   else()

  934.     target_sources(dgl-external PRIVATE

  935.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  936.   endif()

  937.   target_include_directories(dgl-external PUBLIC

  938.     "${DPF_ROOT_DIR}/dgl")

  939.   target_include_directories(dgl-external PUBLIC

  940.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  941. 

  942.   if(USE_FILE_BROWSER)

  943.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  944.   endif()

  945. 

  946.   if(USE_WEB_VIEW)

  947.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  948.     if(APPLE)

  949.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  950.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  951.     elseif(WIN32)

  952.       target_sources(dgl-external PRIVATE

  953.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  954.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  955.         PROPERTIES

  956.           COMPILE_FLAGS

  957.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  958.     endif()

  959.   endif()

  960. 

  961.   dpf__add_dgl_system_libs()

  962.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  963.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  964. 

  965.   add_library(dgl-external-definitions INTERFACE)

  966.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  967. 

  968.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  969.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  970. endfunction()

  971. 

  972. # dpf__add_dgl_gles2

  973. # ------------------------------------------------------------------------------

  974. #

  975. # Add the GLESv2 variant of DGL, if not already available.

  976. #

  977. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  978.   if(TARGET dgl-gles2)

  979.     return()

  980.   endif()

  981. 

  982.   if(NOT OpenGL_GL_PREFERENCE)

  983.     set(OpenGL_GL_PREFERENCE "LEGACY")

  984.   endif()

  985. 

  986.   find_package(OpenGL REQUIRED)

  987. 

  988.   dpf__add_static_library(dgl-gles2 STATIC

  989.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  990.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  991.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  992.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  993.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  994.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  995.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  996.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  997.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  998.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  999.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1000.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1001.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1002.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1003.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1004.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1005.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1006.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1007.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1008.   if(SHARED_RESOURCES)

  1009.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1010.   else()

  1011.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1012.   endif()

  1013.   if(APPLE)

  1014.     target_sources(dgl-gles2 PRIVATE

  1015.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1016.   else()

  1017.     target_sources(dgl-gles2 PRIVATE

  1018.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1019.   endif()

  1020.   target_include_directories(dgl-gles2 PUBLIC

  1021.     "${DPF_ROOT_DIR}/dgl")

  1022.   target_include_directories(dgl-gles2 PUBLIC

  1023.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1024. 

  1025.   if(APPLE)

  1026.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1027.   endif()

  1028. 

  1029.   if(USE_FILE_BROWSER)

  1030.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1031.   endif()

  1032. 

  1033.   if(USE_WEB_VIEW)

  1034.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1035.     if(APPLE)

  1036.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1037.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1038.     elseif(WIN32)

  1039.       target_sources(dgl-gles2 PRIVATE

  1040.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1041.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1042.         PROPERTIES

  1043.           COMPILE_FLAGS

  1044.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1045.     endif()

  1046.   endif()

  1047. 

  1048.   dpf__add_dgl_system_libs()

  1049.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1050.   target_link_options(dgl-gles2

  1051.     INTERFACE

  1052.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1053.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1054.   )

  1055. 

  1056.   add_library(dgl-gles2-definitions INTERFACE)

  1057.   target_compile_definitions(dgl-gles2-definitions

  1058.     INTERFACE

  1059.       DGL_USE_OPENGL3

  1060.       DGL_USE_GLES

  1061.       DGL_USE_GLES2

  1062.       DGL_OPENGL

  1063.       HAVE_OPENGL

  1064.       HAVE_DGL

  1065.   )

  1066. 

  1067.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1068.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1069. endfunction()

  1070. 

  1071. # dpf__add_dgl_gles3

  1072. # ------------------------------------------------------------------------------

  1073. #

  1074. # Add the GLESv3 variant of DGL, if not already available.

  1075. #

  1076. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1077.   if(TARGET dgl-gles3)

  1078.     return()

  1079.   endif()

  1080. 

  1081.   if(NOT OpenGL_GL_PREFERENCE)

  1082.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1083.   endif()

  1084. 

  1085.   find_package(OpenGL REQUIRED)

  1086. 

  1087.   dpf__add_static_library(dgl-gles3 STATIC

  1088.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1089.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1090.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1091.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1092.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1093.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1094.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1095.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1096.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1097.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1098.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1099.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1100.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1101.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1102.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1103.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1104.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1105.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1106.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1107.   if(SHARED_RESOURCES)

  1108.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1109.   else()

  1110.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1111.   endif()

  1112.   if(APPLE)

  1113.     target_sources(dgl-gles3 PRIVATE

  1114.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1115.   else()

  1116.     target_sources(dgl-gles3 PRIVATE

  1117.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1118.   endif()

  1119.   target_include_directories(dgl-gles3 PUBLIC

  1120.     "${DPF_ROOT_DIR}/dgl")

  1121.   target_include_directories(dgl-gles3 PUBLIC

  1122.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1123. 

  1124.   if(APPLE)

  1125.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1126.   endif()

  1127. 

  1128.   if(USE_FILE_BROWSER)

  1129.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1130.   endif()

  1131. 

  1132.   if(USE_WEB_VIEW)

  1133.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1134.     if(APPLE)

  1135.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1136.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1137.     elseif(WIN32)

  1138.       target_sources(dgl-gles3 PRIVATE

  1139.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1140.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1141.         PROPERTIES

  1142.           COMPILE_FLAGS

  1143.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1144.     endif()

  1145.   endif()

  1146. 

  1147.   dpf__add_dgl_system_libs()

  1148.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1149. 

  1150.   add_library(dgl-gles3-definitions INTERFACE)

  1151.   target_compile_definitions(dgl-gles3-definitions

  1152.     INTERFACE

  1153.       DGL_USE_OPENGL3

  1154.       DGL_USE_GLES

  1155.       DGL_USE_GLES3

  1156.       DGL_OPENGL

  1157.       HAVE_OPENGL

  1158.       HAVE_DGL

  1159.   )

  1160. 

  1161.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1162.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1163. endfunction()

  1164. 

  1165. # dpf__add_dgl_opengl

  1166. # ------------------------------------------------------------------------------

  1167. #

  1168. # Add the OpenGL variant of DGL, if not already available.

  1169. #

  1170. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1171.   if(TARGET dgl-opengl)

  1172.     return()

  1173.   endif()

  1174. 

  1175.   if(NOT OpenGL_GL_PREFERENCE)

  1176.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1177.   endif()

  1178. 

  1179.   find_package(OpenGL REQUIRED)

  1180. 

  1181.   dpf__add_static_library(dgl-opengl STATIC

  1182.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1183.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1184.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1185.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1186.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1187.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1188.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1189.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1190.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1191.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1192.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1193.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1194.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1195.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1196.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1197.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1198.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1199.     "${DPF_ROOT_DIR}/dgl/src/OpenGL2.cpp"

  1200.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1201.   if(SHARED_RESOURCES)

  1202.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1203.   else()

  1204.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1205.   endif()

  1206.   if(APPLE)

  1207.     target_sources(dgl-opengl PRIVATE

  1208.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1209.   else()

  1210.     target_sources(dgl-opengl PRIVATE

  1211.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1212.   endif()

  1213.   target_include_directories(dgl-opengl PUBLIC

  1214.     "${DPF_ROOT_DIR}/dgl")

  1215.   target_include_directories(dgl-opengl PUBLIC

  1216.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1217. 

  1218.   if(APPLE)

  1219.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1220.   endif()

  1221. 

  1222.   if(USE_FILE_BROWSER)

  1223.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1224.   endif()

  1225. 

  1226.   if(USE_WEB_VIEW)

  1227.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1228.     if(APPLE)

  1229.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1230.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1231.     elseif(WIN32)

  1232.       target_sources(dgl-opengl PRIVATE

  1233.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1234.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1235.         PROPERTIES

  1236.           COMPILE_FLAGS

  1237.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1238.     endif()

  1239.   endif()

  1240. 

  1241.   dpf__add_dgl_system_libs()

  1242.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1243.   target_link_options(dgl-opengl

  1244.     INTERFACE

  1245.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1246.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1247.   )

  1248. 

  1249.   add_library(dgl-opengl-definitions INTERFACE)

  1250.   target_compile_definitions(dgl-opengl-definitions

  1251.     INTERFACE

  1252.       DGL_OPENGL

  1253.       HAVE_OPENGL

  1254.       HAVE_DGL

  1255.   )

  1256. 

  1257.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1258.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1259. endfunction()

  1260. 

  1261. # dpf__add_dgl_opengl3

  1262. # ------------------------------------------------------------------------------

  1263. #

  1264. # Add the OpenGL3 variant of DGL, if not already available.

  1265. #

  1266. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1267.   if(TARGET dgl-opengl3)

  1268.     return()

  1269.   endif()

  1270. 

  1271.   if(NOT OpenGL_GL_PREFERENCE)

  1272.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1273.   endif()

  1274. 

  1275.   find_package(OpenGL REQUIRED)

  1276. 

  1277.   dpf__add_static_library(dgl-opengl3 STATIC

  1278.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1279.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1280.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1281.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1282.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1283.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1284.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1285.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1286.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1287.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1288.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1289.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1290.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1291.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1292.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1293.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1294.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1295.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1296.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1297.   if(SHARED_RESOURCES)

  1298.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1299.   else()

  1300.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1301.   endif()

  1302.   if(APPLE)

  1303.     target_sources(dgl-opengl3 PRIVATE

  1304.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1305.   else()

  1306.     target_sources(dgl-opengl3 PRIVATE

  1307.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1308.   endif()

  1309.   target_include_directories(dgl-opengl3 PUBLIC

  1310.     "${DPF_ROOT_DIR}/dgl")

  1311.   target_include_directories(dgl-opengl3 PUBLIC

  1312.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1313. 

  1314.   if(APPLE)

  1315.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1316.   endif()

  1317. 

  1318.   if(USE_FILE_BROWSER)

  1319.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1320.   endif()

  1321. 

  1322.   if(USE_WEB_VIEW)

  1323.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1324.     if(APPLE)

  1325.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1326.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1327.     elseif(WIN32)

  1328.       target_sources(dgl-opengl3 PRIVATE

  1329.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1330.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1331.         PROPERTIES

  1332.           COMPILE_FLAGS

  1333.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1334.     endif()

  1335.   endif()

  1336. 

  1337.   dpf__add_dgl_system_libs()

  1338.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1339. 

  1340.   add_library(dgl-opengl3-definitions INTERFACE)

  1341.   target_compile_definitions(dgl-opengl3-definitions

  1342.     INTERFACE

  1343.       DGL_USE_OPENGL3

  1344.       DGL_OPENGL

  1345.       HAVE_OPENGL

  1346.       HAVE_DGL

  1347.   )

  1348. 

  1349.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1350.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1351. endfunction()

  1352. 

  1353. # dpf__add_dgl_vulkan

  1354. # ------------------------------------------------------------------------------

  1355. #

  1356. # Add the Vulkan variant of DGL, if not already available.

  1357. #

  1358. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1359.   if(TARGET dgl-vulkan)

  1360.     return()

  1361.   endif()

  1362. 

  1363.   find_package(Vulkan REQUIRED)

  1364. 

  1365.   dpf__add_static_library(dgl-vulkan STATIC

  1366.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1367.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1368.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1369.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1370.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1371.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1372.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1373.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1374.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1375.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1376.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1377.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1378.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1379.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1380.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1381.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1382.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1383.   if(NO_SHARED_RESOURCES)

  1384.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1385.   else()

  1386.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1387.   endif()

  1388.   if(APPLE)

  1389.     target_sources(dgl-vulkan PRIVATE

  1390.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1391.   else()

  1392.     target_sources(dgl-vulkan PRIVATE

  1393.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1394.   endif()

  1395.   target_include_directories(dgl-vulkan PUBLIC

  1396.     "${DPF_ROOT_DIR}/dgl")

  1397.   target_include_directories(dgl-vulkan PUBLIC

  1398.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1399. 

  1400.   if(APPLE)

  1401.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1402.   endif()

  1403. 

  1404.   if(USE_FILE_BROWSER)

  1405.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1406.   endif()

  1407. 

  1408.   if(USE_WEB_VIEW)

  1409.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1410.     if(APPLE)

  1411.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1412.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1413.     elseif(WIN32)

  1414.       target_sources(dgl-vulkan PRIVATE

  1415.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1416.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1417.         PROPERTIES

  1418.           COMPILE_FLAGS

  1419.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1420.     endif()

  1421.   endif()

  1422. 

  1423.   dpf__add_dgl_system_libs()

  1424.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1425. 

  1426.   add_library(dgl-vulkan-definitions INTERFACE)

  1427.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1428. 

  1429.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1430.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1431. endfunction()

  1432. 

  1433. # dpf__add_plugin_specific_ui_sources

  1434. # ------------------------------------------------------------------------------

  1435. #

  1436. # Compile system specific files

  1437. #

  1438. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1439.   if(APPLE)

  1440.     target_sources("${NAME}" PRIVATE

  1441.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1442.     if(USE_WEB_VIEW)

  1443.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1444.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1445.     endif()

  1446.   elseif(WIN32 AND USE_WEB_VIEW)

  1447.     target_sources("${NAME}" PRIVATE

  1448.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1449.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1450.       PROPERTIES

  1451.         COMPILE_FLAGS

  1452.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1453.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1454.   endif()

  1455. endfunction()

  1456. 

  1457. # dpf__add_dgl_system_libs

  1458. # ------------------------------------------------------------------------------

  1459. #

  1460. # Find system libraries required by DGL and add them as an interface target.

  1461. #

  1462. function(dpf__add_dgl_system_libs)

  1463.   if(TARGET dgl-system-libs)

  1464.     return()

  1465.   endif()

  1466.   add_library(dgl-system-libs INTERFACE)

  1467.   add_library(dgl-system-libs-definitions INTERFACE)

  1468.   if(APPLE)

  1469.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1470.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1471.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1472.   elseif(EMSCRIPTEN)

  1473.   elseif(HAIKU)

  1474.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1475.   elseif(WIN32)

  1476.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1477.   else()

  1478.     find_package(PkgConfig REQUIRED)

  1479.     pkg_check_modules(DBUS "dbus-1")

  1480.     if(DBUS_FOUND)

  1481.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1482.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1483.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1484.     endif()

  1485.     find_package(X11 REQUIRED)

  1486.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1487.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1488.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1489.     if(X11_Xcursor_FOUND)

  1490.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1491.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1492.     endif()

  1493.     if(X11_Xext_FOUND)

  1494.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1495.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1496.     endif()

  1497.     if(X11_Xrandr_FOUND)

  1498.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1499.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1500.     endif()

  1501.     if(X11_XSync_FOUND)

  1502.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1503.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1504.     endif()

  1505.    endif()

  1506. 

  1507.    if(MSVC)

  1508.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1509.      foreach(_gl_header "glext.h")

  1510.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1511.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1512.        endif()

  1513.      endforeach()

  1514.      foreach(_khr_header "khrplatform.h")

  1515.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1516.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1517.        endif()

  1518.      endforeach()

  1519.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1520.    endif()

  1521. 

  1522.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1523. endfunction()

  1524. 

  1525. # dpf__add_executable

  1526. # ------------------------------------------------------------------------------

  1527. #

  1528. # Adds an executable target, and set some default properties on the target.

  1529. #

  1530. function(dpf__add_executable NAME)

  1531.   add_executable("${NAME}" ${ARGN})

  1532.   dpf__set_target_defaults("${NAME}")

  1533.   if(MINGW)

  1534.     target_link_libraries("${NAME}" PRIVATE "-static")

  1535.   endif()

  1536. endfunction()

  1537. 

  1538. # dpf__add_module

  1539. # ------------------------------------------------------------------------------

  1540. #

  1541. # Adds a module target, and set some default properties on the target.

  1542. #

  1543. function(dpf__add_module NAME)

  1544.   add_library("${NAME}" MODULE ${ARGN})

  1545.   dpf__set_target_defaults("${NAME}")

  1546.   if(APPLE)

  1547.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1548.   elseif(MINGW)

  1549.     target_link_libraries("${NAME}" PRIVATE "-static")

  1550.   endif()

  1551. endfunction()

  1552. 

  1553. # dpf__add_static_library

  1554. # ------------------------------------------------------------------------------

  1555. #

  1556. # Adds a static library target, and set some default properties on the target.

  1557. #

  1558. function(dpf__add_static_library NAME)

  1559.   add_library("${NAME}" STATIC ${ARGN})

  1560.   dpf__set_target_defaults("${NAME}")

  1561. endfunction()

  1562. 

  1563. # dpf__set_module_export_list

  1564. # ------------------------------------------------------------------------------

  1565. #

  1566. # Applies a list of exported symbols to the module target.

  1567. #

  1568. function(dpf__set_module_export_list NAME EXPORTS)

  1569.   if(WIN32)

  1570.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1571.   elseif(APPLE)

  1572.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1573.       "-Xlinker" "-exported_symbols_list"

  1574.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1575.   else()

  1576.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1577.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1578.   endif()

  1579. endfunction()

  1580. 

  1581. # dpf__set_target_defaults

  1582. # ------------------------------------------------------------------------------

  1583. #

  1584. # Set default properties which must apply to all DPF-defined targets.

  1585. #

  1586. function(dpf__set_target_defaults NAME)

  1587.   set_target_properties("${NAME}" PROPERTIES

  1588.     POSITION_INDEPENDENT_CODE TRUE

  1589.     C_VISIBILITY_PRESET "hidden"

  1590.     CXX_VISIBILITY_PRESET "hidden"

  1591.     VISIBILITY_INLINES_HIDDEN TRUE)

  1592.   if(WIN32)

  1593.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1594.   endif()

  1595.   if (MINGW)

  1596.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1597.   endif()

  1598.   if (MSVC)

  1599.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1600.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1601.   endif()

  1602.   if (CMAKE_COMPILER_IS_GNUCXX)

  1603.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1604.   endif()

  1605.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1606.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1607.   endif()

  1608. endfunction()

  1609. 

  1610. # dpf__add_plugin_main

  1611. # ------------------------------------------------------------------------------

  1612. #

  1613. # Adds plugin code to the given target.

  1614. #

  1615. function(dpf__add_plugin_main NAME TARGET)

  1616.   target_sources("${NAME}" PRIVATE

  1617.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1618.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1619. endfunction()

  1620. 

  1621. # dpf__add_ui_main

  1622. # ------------------------------------------------------------------------------

  1623. #

  1624. # Adds UI code to the given target (only if the target has UI).

  1625. #

  1626. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1627.   if(HAS_UI)

  1628.     target_sources("${NAME}" PRIVATE

  1629.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1630.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1631.   endif()

  1632. endfunction()

  1633. 

  1634. # dpf__add_plugin_target_definition

  1635. # ------------------------------------------------------------------------------

  1636. #

  1637. # Adds the plugins target macro definition.

  1638. # This selects which entry file is compiled according to the target type.

  1639. #

  1640. function(dpf__add_plugin_target_definition NAME TARGET)

  1641.   string(TOUPPER "${TARGET}" _upperTarget)

  1642.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1643. endfunction()

  1644. 

  1645. # dpf__add_lv2_ttl_generator

  1646. # ------------------------------------------------------------------------------

  1647. #

  1648. # Build the LV2 TTL generator.

  1649. #

  1650. function(dpf__add_lv2_ttl_generator)

  1651.   if(TARGET lv2_ttl_generator)

  1652.     return()

  1653.   endif()

  1654.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1655.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1656.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1657.   endif()

  1658. endfunction()

  1659. 

  1660. # dpf__ensure_sources_non_empty

  1661. # ------------------------------------------------------------------------------

  1662. #

  1663. # Ensure the given source list contains at least one file.

  1664. # The function appends an empty source file to the list if necessary.

  1665. # This is useful when CMake does not permit to add targets without sources.

  1666. #

  1667. function(dpf__ensure_sources_non_empty VAR)

  1668.   if(NOT "" STREQUAL "${${VAR}}")

  1669.     return()

  1670.   endif()

  1671.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1672.   if(NOT EXISTS "${_file}")

  1673.     file(WRITE "${_file}" "")

  1674.   endif()

  1675.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1676. endfunction()

  1677. 

  1678. # dpf__create_dummy_source_list

  1679. # ------------------------------------------------------------------------------

  1680. #

  1681. # Create a dummy source list which is equivalent to compiling nothing.

  1682. # This is only for compatibility with older CMake versions, which refuse to add

  1683. # targets without any sources.

  1684. #

  1685. macro(dpf__create_dummy_source_list VAR)

  1686.   set("${VAR}")

  1687.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1688.     dpf__ensure_sources_non_empty("${VAR}")

  1689.   endif()

  1690. endmacro()

  1691. 

  1692. # dpf__target_link_directories

  1693. # ------------------------------------------------------------------------------

  1694. #

  1695. # Call `target_link_directories` if cmake >= 3.13,

  1696. # otherwise fallback to global `link_directories`.

  1697. #

  1698. macro(dpf__target_link_directories NAME DIRS)

  1699.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1700.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1701.   else()

  1702.     link_directories(${DIRS})

  1703.   endif()

  1704. endmacro()

  1705. 

  1706. # dpf__warn_once

  1707. # ------------------------------------------------------------------------------

  1708. #

  1709. # Prints a warning message once only.

  1710. #

  1711. function(dpf__warn_once_only TOKEN MESSAGE)

  1712.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1713.   if(NOT _warned)

  1714.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1715.     message(WARNING "${MESSAGE}")

  1716.   endif()

  1717. endfunction()