DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
882 Commits
7 Branches
295MB
Tree: a4d8eb903c
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a4d8eb903c'
${ noResults }
DPF/cmake/DPF-plugin.cmake

524 lines
17KB
Raw Blame History 

  1. include(CMakeParseArguments)

  2. 

  3. # ------------------------------------------------------------------------------

  4. # DPF public functions

  5. # ------------------------------------------------------------------------------

  6. 

  7. # dpf_add_plugin(name <args...>)

  8. # ------------------------------------------------------------------------------

  9. #

  10. # Add a plugin built using the DISTRHO Plugin Framework.

  11. #

  12. # ------------------------------------------------------------------------------

  13. # Created targets:

  14. #

  15. #   `<name>`

  16. #       static library: the common part of the plugin

  17. #       The public properties set on this target apply to both DSP and UI.

  18. #

  19. #   `<name>-dsp`

  20. #       static library: the DSP part of the plugin

  21. #       The public properties set on this target apply to the DSP only.

  22. #

  23. #   `<name>-ui`

  24. #       static library: the UI part of the plugin

  25. #       The public properties set on this target apply to the UI only.

  26. #

  27. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  28. #       This is target-dependent and not intended for public use.

  29. #

  30. # ------------------------------------------------------------------------------

  31. # Arguments:

  32. #

  33. #   `TARGETS` <tgt1>...<tgtN>

  34. #       a list of one of more of the following target types:

  35. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst`

  36. #

  37. #   `UI_TYPE` <type>

  38. #       the user interface type: `opengl` (default), `cairo`

  39. #

  40. #   `MONOLITHIC`

  41. #       build LV2 as a single binary for UI and DSP

  42. #

  43. #   `FILES_DSP` <file1>...<fileN>

  44. #       list of sources which are part of the DSP

  45. #

  46. #   `FILES_UI` <file1>...<fileN>

  47. #       list of sources which are part of the UI

  48. #       empty indicates the plugin does not have UI

  49. #

  50. #   `FILES_COMMON` <file1>...<fileN>

  51. #       list of sources which are part of both DSP and UI

  52. #

  53. function(dpf_add_plugin NAME)

  54.   set(options MONOLITHIC)

  55.   set(oneValueArgs UI_TYPE)

  56.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  57.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  58. 

  59.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  60.     set(_dpf_plugin_UI_TYPE "opengl")

  61.   endif()

  62. 

  63.   set(_dgl_library)

  64.   if(_dpf_plugin_FILES_UI)

  65.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  66.       dpf__add_dgl_cairo()

  67.       set(_dgl_library dgl-cairo)

  68.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  69.       dpf__add_dgl_opengl()

  70.       set(_dgl_library dgl-opengl)

  71.     else()

  72.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  73.     endif()

  74.   endif()

  75. 

  76.   ###

  77.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  78.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  79.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  80. 

  81.   ###

  82.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  83.   target_include_directories("${NAME}" PUBLIC

  84.     "${DPF_ROOT_DIR}/distrho")

  85. 

  86.   if(_dgl_library)

  87.     # make sure that all code will see DGL_* definitions

  88.     target_link_libraries("${NAME}" PUBLIC "${_dgl_library}-definitions")

  89.   endif()

  90. 

  91.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  92.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  93. 

  94.   if(_dgl_library)

  95.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  96.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  97.   else()

  98.     add_library("${NAME}-ui" INTERFACE)

  99.   endif()

  100. 

  101.   ###

  102.   foreach(_target ${_dpf_plugin_TARGETS})

  103.     if(_target STREQUAL "jack")

  104.       dpf__build_jack("${NAME}" "${_dgl_library}")

  105.     elseif(_target STREQUAL "ladspa")

  106.       dpf__build_ladspa("${NAME}")

  107.     elseif(_target STREQUAL "dssi")

  108.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  109.     elseif(_target STREQUAL "lv2")

  110.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  111.     elseif(_target STREQUAL "vst")

  112.       dpf__build_vst("${NAME}" "${_dgl_library}")

  113.     endif()

  114.   endforeach()

  115. endfunction()

  116. 

  117. # ------------------------------------------------------------------------------

  118. # DPF private functions (prefixed with `dpf__`)

  119. # ------------------------------------------------------------------------------

  120. 

  121. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  122. #       to the output directory.

  123. #

  124. 

  125. # dpf__build_jack

  126. # ------------------------------------------------------------------------------

  127. #

  128. # Add build rules for a JACK program.

  129. #

  130. function(dpf__build_jack NAME DGL_LIBRARY)

  131.   find_package(PkgConfig)

  132.   pkg_check_modules(JACK "jack")

  133.   if(NOT JACK_FOUND)

  134.     dpf__warn_once_only(missing_jack

  135.       "JACK is not found, skipping the `jack` plugin targets")

  136.     return()

  137.   endif()

  138. 

  139.   dpf__create_dummy_source_list(_no_srcs)

  140. 

  141.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  142.   dpf__add_plugin_main("${NAME}-jack" "jack")

  143.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  144.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  145.   set_target_properties("${NAME}-jack" PROPERTIES

  146.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  147.     OUTPUT_NAME "${NAME}")

  148. 

  149.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  150.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  151.   link_directories(${JACK_LIBRARY_DIRS})

  152. endfunction()

  153. 

  154. # dpf__build_ladspa

  155. # ------------------------------------------------------------------------------

  156. #

  157. # Add build rules for a DSSI plugin.

  158. #

  159. function(dpf__build_ladspa NAME)

  160.   dpf__create_dummy_source_list(_no_srcs)

  161. 

  162.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  163.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  164.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  165.   set_target_properties("${NAME}-ladspa" PROPERTIES

  166.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  167.     OUTPUT_NAME "${NAME}-ladspa"

  168.     PREFIX "")

  169. endfunction()

  170. 

  171. # dpf__build_dssi

  172. # ------------------------------------------------------------------------------

  173. #

  174. # Add build rules for a DSSI plugin.

  175. #

  176. function(dpf__build_dssi NAME DGL_LIBRARY)

  177.   find_package(PkgConfig)

  178.   pkg_check_modules(LIBLO "liblo")

  179.   if(NOT LIBLO_FOUND)

  180.     dpf__warn_once_only(missing_liblo

  181.       "liblo is not found, skipping the `dssi` plugin targets")

  182.     return()

  183.   endif()

  184. 

  185.   dpf__create_dummy_source_list(_no_srcs)

  186. 

  187.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  188.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  189.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  190.   set_target_properties("${NAME}-dssi" PROPERTIES

  191.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  192.     OUTPUT_NAME "${NAME}-dssi"

  193.     PREFIX "")

  194. 

  195.   if(DGL_LIBRARY)

  196.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  197.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  198.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  199.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  200.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  201.       OUTPUT_NAME "${NAME}_ui")

  202. 

  203.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  204.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  205.     link_directories(${LIBLO_LIBRARY_DIRS})

  206.   endif()

  207. endfunction()

  208. 

  209. # dpf__build_lv2

  210. # ------------------------------------------------------------------------------

  211. #

  212. # Add build rules for a LV2 plugin.

  213. #

  214. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  215.   dpf__create_dummy_source_list(_no_srcs)

  216. 

  217.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  218.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  219.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  220.   set_target_properties("${NAME}-lv2" PROPERTIES

  221.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  222.     OUTPUT_NAME "${NAME}_dsp"

  223.     PREFIX "")

  224. 

  225.   if(DGL_LIBRARY)

  226.     if(MONOLITHIC)

  227.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  228.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  229.       set_target_properties("${NAME}-lv2" PROPERTIES

  230.         OUTPUT_NAME "${NAME}")

  231.     else()

  232.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  233.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  234.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  235.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  236.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  237.         OUTPUT_NAME "${NAME}_ui"

  238.         PREFIX "")

  239.     endif()

  240.   endif()

  241. 

  242.   dpf__add_lv2_ttl_generator()

  243.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  244. 

  245.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  246.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  247.     "$<TARGET_FILE:lv2_ttl_generator>"

  248.     "$<TARGET_FILE:${NAME}-lv2>"

  249.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  250. endfunction()

  251. 

  252. # dpf__build_vst

  253. # ------------------------------------------------------------------------------

  254. #

  255. # Add build rules for a VST plugin.

  256. #

  257. function(dpf__build_vst NAME DGL_LIBRARY)

  258.   dpf__create_dummy_source_list(_no_srcs)

  259. 

  260.   dpf__add_module("${NAME}-vst" ${_no_srcs})

  261.   dpf__add_plugin_main("${NAME}-vst" "vst")

  262.   dpf__add_ui_main("${NAME}-vst" "vst" "${DGL_LIBRARY}")

  263.   target_link_libraries("${NAME}-vst" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  264.   set_target_properties("${NAME}-vst" PROPERTIES

  265.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  266.     OUTPUT_NAME "${NAME}-vst"

  267.     PREFIX "")

  268. endfunction()

  269. 

  270. # dpf__add_dgl_cairo

  271. # ------------------------------------------------------------------------------

  272. #

  273. # Add the Cairo variant of DGL, if not already available.

  274. #

  275. function(dpf__add_dgl_cairo)

  276.   if(TARGET dgl-cairo)

  277.     return()

  278.   endif()

  279. 

  280.   find_package(PkgConfig)

  281.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  282. 

  283.   dpf__add_static_library(dgl-cairo EXCLUDE_FROM_ALL

  284.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  285.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  286.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  287.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  288.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  289.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  290.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp"

  291.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  292.   if(NOT APPLE)

  293.     target_sources(dgl-cairo PRIVATE

  294.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  295.   else()

  296.     target_sources(dgl-cairo PRIVATE

  297.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  298.   endif()

  299.   target_include_directories(dgl-cairo PUBLIC

  300.     "${DPF_ROOT_DIR}/dgl")

  301. 

  302.   dpf__add_dgl_system_libs()

  303.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  304. 

  305.   add_library(dgl-cairo-definitions INTERFACE)

  306.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  307. 

  308.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  309.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  310.   link_directories(${CAIRO_LIBRARY_DIRS})

  311. endfunction()

  312. 

  313. # dpf__add_dgl_opengl

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add the OpenGL variant of DGL, if not already available.

  317. #

  318. function(dpf__add_dgl_opengl)

  319.   if(TARGET dgl-opengl)

  320.     return()

  321.   endif()

  322. 

  323.   if(NOT OpenGL_GL_PREFERENCE)

  324.     set(OpenGL_GL_PREFERENCE "LEGACY")

  325.   endif()

  326. 

  327.   find_package(OpenGL REQUIRED)

  328. 

  329.   dpf__add_static_library(dgl-opengl EXCLUDE_FROM_ALL

  330.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  331.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  333.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/Image.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/ImageWidgets.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  341.   if(NOT APPLE)

  342.     target_sources(dgl-opengl PRIVATE

  343.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  344.   else()

  345.     target_sources(dgl-opengl PRIVATE

  346.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  347.   endif()

  348.   target_include_directories(dgl-opengl PUBLIC

  349.     "${DPF_ROOT_DIR}/dgl")

  350. 

  351.   dpf__add_dgl_system_libs()

  352.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  353. 

  354.   add_library(dgl-opengl-definitions INTERFACE)

  355.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  356. 

  357.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  358.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  359. endfunction()

  360. 

  361. # dpf__add_dgl_system_libs

  362. # ------------------------------------------------------------------------------

  363. #

  364. # Find system libraries required by DGL and add them as an interface target.

  365. #

  366. function(dpf__add_dgl_system_libs)

  367.   if(TARGET dgl-system-libs)

  368.     return()

  369.   endif()

  370.   add_library(dgl-system-libs INTERFACE)

  371.   if(HAIKU)

  372.     target_link_libraries(dgl-system-libs INTERFACE "be")

  373.   elseif(WIN32)

  374.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  375.   elseif(APPLE)

  376.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  377.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}")

  378.   else()

  379.     find_package(X11 REQUIRED)

  380.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  381.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  382.   endif()

  383. endfunction()

  384. 

  385. # dpf__add_executable

  386. # ------------------------------------------------------------------------------

  387. #

  388. # Adds an executable target, and set some default properties on the target.

  389. #

  390. function(dpf__add_executable NAME)

  391.   add_executable("${NAME}" ${ARGN})

  392.   set_target_properties("${NAME}" PROPERTIES

  393.     POSITION_INDEPENDENT_CODE TRUE

  394.     C_VISIBILITY_PRESET "hidden"

  395.     CXX_VISIBILITY_PRESET "hidden"

  396.     VISIBILITY_INLINES_HIDDEN TRUE)

  397. endfunction()

  398. 

  399. # dpf__add_module

  400. # ------------------------------------------------------------------------------

  401. #

  402. # Adds a module target, and set some default properties on the target.

  403. #

  404. function(dpf__add_module NAME)

  405.   add_library("${NAME}" MODULE ${ARGN})

  406.   set_target_properties("${NAME}" PROPERTIES

  407.     POSITION_INDEPENDENT_CODE TRUE

  408.     C_VISIBILITY_PRESET "hidden"

  409.     CXX_VISIBILITY_PRESET "hidden"

  410.     VISIBILITY_INLINES_HIDDEN TRUE)

  411.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  412.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  413.   endif()

  414. endfunction()

  415. 

  416. # dpf__add_static_library

  417. # ------------------------------------------------------------------------------

  418. #

  419. # Adds a module target, and set some default properties on the target.

  420. #

  421. function(dpf__add_static_library NAME)

  422.   add_library("${NAME}" STATIC ${ARGN})

  423.   set_target_properties("${NAME}" PROPERTIES

  424.     POSITION_INDEPENDENT_CODE TRUE

  425.     C_VISIBILITY_PRESET "hidden"

  426.     CXX_VISIBILITY_PRESET "hidden"

  427.     VISIBILITY_INLINES_HIDDEN TRUE)

  428. endfunction()

  429. 

  430. # dpf__add_plugin_main

  431. # ------------------------------------------------------------------------------

  432. #

  433. # Adds plugin code to the given target.

  434. #

  435. function(dpf__add_plugin_main NAME TARGET)

  436.   target_sources("${NAME}" PRIVATE

  437.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  438.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  439. endfunction()

  440. 

  441. # dpf__add_ui_main

  442. # ------------------------------------------------------------------------------

  443. #

  444. # Adds UI code to the given target (only if the target has UI).

  445. #

  446. function(dpf__add_ui_main NAME TARGET HAS_UI)

  447.   if(HAS_UI)

  448.     target_sources("${NAME}" PRIVATE

  449.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  450.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  451.   endif()

  452. endfunction()

  453. 

  454. # dpf__add_plugin_target_definition

  455. # ------------------------------------------------------------------------------

  456. #

  457. # Adds the plugins target macro definition.

  458. # This selects which entry file is compiled according to the target type.

  459. #

  460. function(dpf__add_plugin_target_definition NAME TARGET)

  461.   string(TOUPPER "${TARGET}" _upperTarget)

  462.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  463. endfunction()

  464. 

  465. # dpf__add_lv2_ttl_generator

  466. # ------------------------------------------------------------------------------

  467. #

  468. # Build the LV2 TTL generator.

  469. #

  470. function(dpf__add_lv2_ttl_generator)

  471.   if(TARGET lv2_ttl_generator)

  472.     return()

  473.   endif()

  474.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  475.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  476.     target_link_libraries(lv2_ttl_generator "dl")

  477.   endif()

  478. endfunction()

  479. 

  480. # dpf__ensure_sources_non_empty

  481. # ------------------------------------------------------------------------------

  482. #

  483. # Ensure the given source list contains at least one file.

  484. # The function appends an empty source file to the list if necessary.

  485. # This is useful when CMake does not permit to add targets without sources.

  486. #

  487. function(dpf__ensure_sources_non_empty VAR)

  488.   if(NOT "" STREQUAL "${${VAR}}")

  489.     return()

  490.   endif()

  491.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  492.   if(NOT EXISTS "${_file}")

  493.     file(WRITE "${_file}" "")

  494.   endif()

  495.   set("${VAR}" "${_file}" PARENT_SCOPE)

  496. endfunction()

  497. 

  498. # dpf__create_dummy_source_list

  499. # ------------------------------------------------------------------------------

  500. #

  501. # Create a dummy source list which is equivalent to compiling nothing.

  502. # This is only for compatibility with older CMake versions, which refuse to add

  503. # targets without any sources.

  504. #

  505. macro(dpf__create_dummy_source_list VAR)

  506.   set("${VAR}")

  507.   if(CMAKE_VERSION VERSION_LESS "3.11")

  508.     dpf__ensure_sources_non_empty("${VAR}")

  509.   endif()

  510. endmacro()

  511. 

  512. # dpf__warn_once

  513. # ------------------------------------------------------------------------------

  514. #

  515. # Prints a warning message once only.

  516. #

  517. function(dpf__warn_once_only TOKEN MESSAGE)

  518.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  519.   if(NOT _warned)

  520.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  521.     message(WARNING "${MESSAGE}")

  522.   endif()

  523. endfunction()