DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1484 Commits
7 Branches
60MB
Tree: a4aa2d83c8
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a4aa2d83c8'
${ noResults }
DPF/cmake/DPF-plugin.cmake

747 lines
26KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2 vst3

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "vst3")

  157.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  158.     else()

  159.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  160.     endif()

  161.   endforeach()

  162. endfunction()

  163. 

  164. # ------------------------------------------------------------------------------

  165. # DPF private functions (prefixed with `dpf__`)

  166. # ------------------------------------------------------------------------------

  167. 

  168. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  169. #       to the output directory.

  170. #

  171. 

  172. # dpf__build_jack

  173. # ------------------------------------------------------------------------------

  174. #

  175. # Add build rules for a JACK program.

  176. #

  177. function(dpf__build_jack NAME DGL_LIBRARY)

  178.   dpf__create_dummy_source_list(_no_srcs)

  179. 

  180.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  181.   dpf__add_plugin_main("${NAME}-jack" "jack")

  182.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  183.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  184.   set_target_properties("${NAME}-jack" PROPERTIES

  185.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  186.     OUTPUT_NAME "${NAME}")

  187. 

  188.   # Note: libjack will be linked at runtime

  189.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  190.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  191.   endif()

  192. 

  193.   # for RtAudio native fallback

  194.   if(APPLE)

  195.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  196.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  197.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  198.   endif()

  199. endfunction()

  200. 

  201. # dpf__build_ladspa

  202. # ------------------------------------------------------------------------------

  203. #

  204. # Add build rules for a LADSPA plugin.

  205. #

  206. function(dpf__build_ladspa NAME)

  207.   dpf__create_dummy_source_list(_no_srcs)

  208. 

  209.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  210.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  211.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  212.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  213.   set_target_properties("${NAME}-ladspa" PROPERTIES

  214.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  215.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  216.     OUTPUT_NAME "${NAME}-ladspa"

  217.     PREFIX "")

  218. endfunction()

  219. 

  220. # dpf__build_dssi

  221. # ------------------------------------------------------------------------------

  222. #

  223. # Add build rules for a DSSI plugin.

  224. #

  225. function(dpf__build_dssi NAME DGL_LIBRARY)

  226.   find_package(PkgConfig)

  227.   pkg_check_modules(LIBLO "liblo")

  228.   if(NOT LIBLO_FOUND)

  229.     dpf__warn_once_only(missing_liblo

  230.       "liblo is not found, skipping the `dssi` plugin targets")

  231.     return()

  232.   endif()

  233. 

  234.   link_directories(${LIBLO_LIBRARY_DIRS})

  235. 

  236.   dpf__create_dummy_source_list(_no_srcs)

  237. 

  238.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  239.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  240.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  241.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  242.   set_target_properties("${NAME}-dssi" PROPERTIES

  243.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  244.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  245.     OUTPUT_NAME "${NAME}-dssi"

  246.     PREFIX "")

  247. 

  248.   if(DGL_LIBRARY)

  249.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  250.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  251.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  252.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  253.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  254.       OUTPUT_NAME "${NAME}_ui")

  255. 

  256.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  257.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  258.   endif()

  259. endfunction()

  260. 

  261. # dpf__build_lv2

  262. # ------------------------------------------------------------------------------

  263. #

  264. # Add build rules for an LV2 plugin.

  265. #

  266. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  267.   dpf__create_dummy_source_list(_no_srcs)

  268. 

  269.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  270.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  271.   if(DGL_LIBRARY AND MONOLITHIC)

  272.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  273.   else()

  274.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  275.   endif()

  276.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  277.   set_target_properties("${NAME}-lv2" PROPERTIES

  278.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  279.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  280.     OUTPUT_NAME "${NAME}_dsp"

  281.     PREFIX "")

  282. 

  283.   if(DGL_LIBRARY)

  284.     if(MONOLITHIC)

  285.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  286.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  287.       set_target_properties("${NAME}-lv2" PROPERTIES

  288.         OUTPUT_NAME "${NAME}")

  289.     else()

  290.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  291.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  292.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  293.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  294.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  295.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  296.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  297.         OUTPUT_NAME "${NAME}_ui"

  298.         PREFIX "")

  299.     endif()

  300.   endif()

  301. 

  302.   dpf__add_lv2_ttl_generator()

  303.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  304. 

  305.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  306.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  307.     "$<TARGET_FILE:lv2_ttl_generator>"

  308.     "$<TARGET_FILE:${NAME}-lv2>"

  309.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  310.     DEPENDS lv2_ttl_generator)

  311. endfunction()

  312. 

  313. # dpf__build_vst2

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add build rules for a VST2 plugin.

  317. #

  318. function(dpf__build_vst2 NAME DGL_LIBRARY)

  319.   dpf__create_dummy_source_list(_no_srcs)

  320. 

  321.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  322.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  323.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  324.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  325.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  326.   set_target_properties("${NAME}-vst2" PROPERTIES

  327.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  328.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  329.     OUTPUT_NAME "${NAME}-vst2"

  330.     PREFIX "")

  331.   if(APPLE)

  332.     set_target_properties("${NAME}-vst2" PROPERTIES

  333.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  334.       OUTPUT_NAME "${NAME}"

  335.       SUFFIX "")

  336.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  337.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  338.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  339.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  340.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  341.   endif()

  342. endfunction()

  343. 

  344. # dpf__build_vst3

  345. # ------------------------------------------------------------------------------

  346. #

  347. # Add build rules for a VST3 plugin.

  348. #

  349. function(dpf__build_vst3 NAME DGL_LIBRARY)

  350.   dpf__create_dummy_source_list(_no_srcs)

  351. 

  352.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  353.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  354.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  355.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  356.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  357.   set_target_properties("${NAME}-vst3" PROPERTIES

  358.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  359.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  360.     OUTPUT_NAME "${NAME}-vst3"

  361.     PREFIX "")

  362.   # TODO set correct output directory for VST3 packaging

  363.   #if(APPLE)

  364.     #set_target_properties("${NAME}-vst3" PROPERTIES

  365.       #LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  366.       #OUTPUT_NAME "${NAME}"

  367.       #SUFFIX "")

  368.     #set(INFO_PLIST_PROJECT_NAME "${NAME}")

  369.     #configure_file("${DPF_ROOT_DIR}/utils/plugin.vst3/Contents/Info.plist"

  370.       #"${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  371.     #file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst3/Contents/PkgInfo"

  372.       #DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  373.   #endif()

  374. endfunction()

  375. 

  376. # dpf__add_dgl_cairo

  377. # ------------------------------------------------------------------------------

  378. #

  379. # Add the Cairo variant of DGL, if not already available.

  380. #

  381. function(dpf__add_dgl_cairo)

  382.   if(TARGET dgl-cairo)

  383.     return()

  384.   endif()

  385. 

  386.   find_package(PkgConfig)

  387.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  388. 

  389.   link_directories(${CAIRO_LIBRARY_DIRS})

  390. 

  391.   dpf__add_static_library(dgl-cairo STATIC

  392.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  393.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  394.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  405.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  406.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  407.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  408.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  409.   if(NOT APPLE)

  410.     target_sources(dgl-cairo PRIVATE

  411.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  412.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  413.     #target_sources(dgl-opengl PRIVATE

  414.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  415.   endif()

  416.   target_include_directories(dgl-cairo PUBLIC

  417.     "${DPF_ROOT_DIR}/dgl")

  418.   target_include_directories(dgl-cairo PUBLIC

  419.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  420. 

  421.   dpf__add_dgl_system_libs()

  422.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  423. 

  424.   add_library(dgl-cairo-definitions INTERFACE)

  425.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  426. 

  427.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  428.   if(MINGW)

  429.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  430.   else()

  431.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  432.   endif()

  433.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  434. endfunction()

  435. 

  436. # dpf__add_dgl_opengl

  437. # ------------------------------------------------------------------------------

  438. #

  439. # Add the OpenGL variant of DGL, if not already available.

  440. #

  441. function(dpf__add_dgl_opengl)

  442.   if(TARGET dgl-opengl)

  443.     return()

  444.   endif()

  445. 

  446.   if(NOT OpenGL_GL_PREFERENCE)

  447.     set(OpenGL_GL_PREFERENCE "LEGACY")

  448.   endif()

  449. 

  450.   find_package(OpenGL REQUIRED)

  451. 

  452.   dpf__add_static_library(dgl-opengl STATIC

  453.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  454.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  455.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  456.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  457.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  458.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  459.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  460.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  461.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  462.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  463.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  464.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  465.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  466.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  467.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  468.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  469.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  470.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  471.   if(NOT APPLE)

  472.     target_sources(dgl-opengl PRIVATE

  473.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  474.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  475.     #target_sources(dgl-opengl PRIVATE

  476.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  477.   endif()

  478.   target_include_directories(dgl-opengl PUBLIC

  479.     "${DPF_ROOT_DIR}/dgl")

  480.   target_include_directories(dgl-opengl PUBLIC

  481.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  482. 

  483.   if(APPLE)

  484.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  485.   endif()

  486. 

  487.   dpf__add_dgl_system_libs()

  488.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  489. 

  490.   add_library(dgl-opengl-definitions INTERFACE)

  491.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  492. 

  493.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  494.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  495. endfunction()

  496. 

  497. # dpf__add_plugin_specific_ui_sources

  498. # ------------------------------------------------------------------------------

  499. #

  500. # Compile plugin-specific UI sources into the target designated by the given

  501. # name. There are some special considerations here:

  502. # - On most platforms, sources can be compiled only once, as part of DGL;

  503. # - On macOS, for any sources which define Objective-C interfaces, these must

  504. #   be recompiled for each plugin under a unique namespace. In this case, the

  505. #   name must be a plugin-specific identifier, and it will be used for computing

  506. #   the unique ID along with the project version.

  507. function(dpf__add_plugin_specific_ui_sources NAME)

  508.   if(APPLE)

  509.     target_sources("${NAME}" PRIVATE

  510.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  511.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  512.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  513.   endif()

  514. endfunction()

  515. 

  516. # dpf__add_dgl_system_libs

  517. # ------------------------------------------------------------------------------

  518. #

  519. # Find system libraries required by DGL and add them as an interface target.

  520. #

  521. function(dpf__add_dgl_system_libs)

  522.   if(TARGET dgl-system-libs)

  523.     return()

  524.   endif()

  525.   add_library(dgl-system-libs INTERFACE)

  526.   add_library(dgl-system-libs-definitions INTERFACE)

  527.   if(HAIKU)

  528.     target_link_libraries(dgl-system-libs INTERFACE "be")

  529.   elseif(WIN32)

  530.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  531.   elseif(APPLE)

  532.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  533.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  534.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  535.   else()

  536.     find_package(X11 REQUIRED)

  537.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  538.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  539.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  540.     if(X11_Xext_FOUND)

  541.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  542.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  543.     endif()

  544.     if(X11_XSync_FOUND)

  545.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  546.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  547.     endif()

  548.     if(X11_Xrandr_FOUND)

  549.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  550.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  551.     endif()

  552.     #if(X11_Xcursor_FOUND)

  553.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  554.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  555.     #endif()

  556.    endif()

  557. 

  558.    if(MSVC)

  559.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  560.      foreach(_gl_header "glext.h")

  561.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  562.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  563.        endif()

  564.      endforeach()

  565.      foreach(_khr_header "khrplatform.h")

  566.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  567.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  568.        endif()

  569.      endforeach()

  570.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  571.    endif()

  572. 

  573.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  574. endfunction()

  575. 

  576. # dpf__add_executable

  577. # ------------------------------------------------------------------------------

  578. #

  579. # Adds an executable target, and set some default properties on the target.

  580. #

  581. function(dpf__add_executable NAME)

  582.   add_executable("${NAME}" ${ARGN})

  583.   dpf__set_target_defaults("${NAME}")

  584.   if(MINGW)

  585.     target_link_libraries("${NAME}" PRIVATE "-static")

  586.   endif()

  587. endfunction()

  588. 

  589. # dpf__add_module

  590. # ------------------------------------------------------------------------------

  591. #

  592. # Adds a module target, and set some default properties on the target.

  593. #

  594. function(dpf__add_module NAME)

  595.   add_library("${NAME}" MODULE ${ARGN})

  596.   dpf__set_target_defaults("${NAME}")

  597.   if(MINGW)

  598.     target_link_libraries("${NAME}" PRIVATE "-static")

  599.   endif()

  600. endfunction()

  601. 

  602. # dpf__add_static_library

  603. # ------------------------------------------------------------------------------

  604. #

  605. # Adds a static library target, and set some default properties on the target.

  606. #

  607. function(dpf__add_static_library NAME)

  608.   add_library("${NAME}" STATIC ${ARGN})

  609.   dpf__set_target_defaults("${NAME}")

  610. endfunction()

  611. 

  612. # dpf__set_module_export_list

  613. # ------------------------------------------------------------------------------

  614. #

  615. # Applies a list of exported symbols to the module target.

  616. #

  617. function(dpf__set_module_export_list NAME EXPORTS)

  618.   if(WIN32)

  619.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  620.   elseif(APPLE)

  621.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  622.       "-Xlinker" "-exported_symbols_list"

  623.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  624.   else()

  625.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  626.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  627.   endif()

  628. endfunction()

  629. 

  630. # dpf__set_target_defaults

  631. # ------------------------------------------------------------------------------

  632. #

  633. # Set default properties which must apply to all DPF-defined targets.

  634. #

  635. function(dpf__set_target_defaults NAME)

  636.   set_target_properties("${NAME}" PROPERTIES

  637.     POSITION_INDEPENDENT_CODE TRUE

  638.     C_VISIBILITY_PRESET "hidden"

  639.     CXX_VISIBILITY_PRESET "hidden"

  640.     VISIBILITY_INLINES_HIDDEN TRUE)

  641.   if(WIN32)

  642.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  643.   endif()

  644.   if (MINGW)

  645.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  646.   endif()

  647.   if (MSVC)

  648.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  649.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  650.   endif()

  651. endfunction()

  652. 

  653. # dpf__add_plugin_main

  654. # ------------------------------------------------------------------------------

  655. #

  656. # Adds plugin code to the given target.

  657. #

  658. function(dpf__add_plugin_main NAME TARGET)

  659.   target_sources("${NAME}" PRIVATE

  660.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  661.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  662. endfunction()

  663. 

  664. # dpf__add_ui_main

  665. # ------------------------------------------------------------------------------

  666. #

  667. # Adds UI code to the given target (only if the target has UI).

  668. #

  669. function(dpf__add_ui_main NAME TARGET HAS_UI)

  670.   if(HAS_UI)

  671.     target_sources("${NAME}" PRIVATE

  672.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  673.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  674.   endif()

  675. endfunction()

  676. 

  677. # dpf__add_plugin_target_definition

  678. # ------------------------------------------------------------------------------

  679. #

  680. # Adds the plugins target macro definition.

  681. # This selects which entry file is compiled according to the target type.

  682. #

  683. function(dpf__add_plugin_target_definition NAME TARGET)

  684.   string(TOUPPER "${TARGET}" _upperTarget)

  685.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  686. endfunction()

  687. 

  688. # dpf__add_lv2_ttl_generator

  689. # ------------------------------------------------------------------------------

  690. #

  691. # Build the LV2 TTL generator.

  692. #

  693. function(dpf__add_lv2_ttl_generator)

  694.   if(TARGET lv2_ttl_generator)

  695.     return()

  696.   endif()

  697.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  698.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  699.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  700.   endif()

  701. endfunction()

  702. 

  703. # dpf__ensure_sources_non_empty

  704. # ------------------------------------------------------------------------------

  705. #

  706. # Ensure the given source list contains at least one file.

  707. # The function appends an empty source file to the list if necessary.

  708. # This is useful when CMake does not permit to add targets without sources.

  709. #

  710. function(dpf__ensure_sources_non_empty VAR)

  711.   if(NOT "" STREQUAL "${${VAR}}")

  712.     return()

  713.   endif()

  714.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  715.   if(NOT EXISTS "${_file}")

  716.     file(WRITE "${_file}" "")

  717.   endif()

  718.   set("${VAR}" "${_file}" PARENT_SCOPE)

  719. endfunction()

  720. 

  721. # dpf__create_dummy_source_list

  722. # ------------------------------------------------------------------------------

  723. #

  724. # Create a dummy source list which is equivalent to compiling nothing.

  725. # This is only for compatibility with older CMake versions, which refuse to add

  726. # targets without any sources.

  727. #

  728. macro(dpf__create_dummy_source_list VAR)

  729.   set("${VAR}")

  730.   if(CMAKE_VERSION VERSION_LESS "3.11")

  731.     dpf__ensure_sources_non_empty("${VAR}")

  732.   endif()

  733. endmacro()

  734. 

  735. # dpf__warn_once

  736. # ------------------------------------------------------------------------------

  737. #

  738. # Prints a warning message once only.

  739. #

  740. function(dpf__warn_once_only TOKEN MESSAGE)

  741.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  742.   if(NOT _warned)

  743.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  744.     message(WARNING "${MESSAGE}")

  745.   endif()

  746. endfunction()