DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1097 Commits
7 Branches
295MB
Tree: a2958f228f
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'a2958f228f'
${ noResults }
DPF/cmake/DPF-plugin.cmake

676 lines
23KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   find_package(PkgConfig)

  177.   pkg_check_modules(JACK "jack")

  178.   if(NOT JACK_FOUND)

  179.     dpf__warn_once_only(missing_jack

  180.       "JACK is not found, skipping the `jack` plugin targets")

  181.     return()

  182.   endif()

  183. 

  184.   link_directories(${JACK_LIBRARY_DIRS})

  185. 

  186.   dpf__create_dummy_source_list(_no_srcs)

  187. 

  188.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  189.   dpf__add_plugin_main("${NAME}-jack" "jack")

  190.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  191.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  192.   set_target_properties("${NAME}-jack" PROPERTIES

  193.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  194.     OUTPUT_NAME "${NAME}")

  195. 

  196.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  197.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  198. endfunction()

  199. 

  200. # dpf__build_ladspa

  201. # ------------------------------------------------------------------------------

  202. #

  203. # Add build rules for a DSSI plugin.

  204. #

  205. function(dpf__build_ladspa NAME)

  206.   dpf__create_dummy_source_list(_no_srcs)

  207. 

  208.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  209.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  210.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  211.   set_target_properties("${NAME}-ladspa" PROPERTIES

  212.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  213.     OUTPUT_NAME "${NAME}-ladspa"

  214.     PREFIX "")

  215. endfunction()

  216. 

  217. # dpf__build_dssi

  218. # ------------------------------------------------------------------------------

  219. #

  220. # Add build rules for a DSSI plugin.

  221. #

  222. function(dpf__build_dssi NAME DGL_LIBRARY)

  223.   find_package(PkgConfig)

  224.   pkg_check_modules(LIBLO "liblo")

  225.   if(NOT LIBLO_FOUND)

  226.     dpf__warn_once_only(missing_liblo

  227.       "liblo is not found, skipping the `dssi` plugin targets")

  228.     return()

  229.   endif()

  230. 

  231.   link_directories(${LIBLO_LIBRARY_DIRS})

  232. 

  233.   dpf__create_dummy_source_list(_no_srcs)

  234. 

  235.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  236.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  237.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  238.   set_target_properties("${NAME}-dssi" PROPERTIES

  239.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  240.     OUTPUT_NAME "${NAME}-dssi"

  241.     PREFIX "")

  242. 

  243.   if(DGL_LIBRARY)

  244.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  245.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  246.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  247.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  248.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  249.       OUTPUT_NAME "${NAME}_ui")

  250. 

  251.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  252.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  253.   endif()

  254. endfunction()

  255. 

  256. # dpf__build_lv2

  257. # ------------------------------------------------------------------------------

  258. #

  259. # Add build rules for a LV2 plugin.

  260. #

  261. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  262.   dpf__create_dummy_source_list(_no_srcs)

  263. 

  264.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  265.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  266.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  267.   set_target_properties("${NAME}-lv2" PROPERTIES

  268.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  269.     OUTPUT_NAME "${NAME}_dsp"

  270.     PREFIX "")

  271. 

  272.   if(DGL_LIBRARY)

  273.     if(MONOLITHIC)

  274.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  275.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  276.       set_target_properties("${NAME}-lv2" PROPERTIES

  277.         OUTPUT_NAME "${NAME}")

  278.     else()

  279.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  280.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  281.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  282.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  283.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  284.         OUTPUT_NAME "${NAME}_ui"

  285.         PREFIX "")

  286.     endif()

  287.   endif()

  288. 

  289.   dpf__add_lv2_ttl_generator()

  290.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  291. 

  292.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  293.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  294.     "$<TARGET_FILE:lv2_ttl_generator>"

  295.     "$<TARGET_FILE:${NAME}-lv2>"

  296.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  297.     DEPENDS lv2_ttl_generator)

  298. endfunction()

  299. 

  300. # dpf__build_vst2

  301. # ------------------------------------------------------------------------------

  302. #

  303. # Add build rules for a VST2 plugin.

  304. #

  305. function(dpf__build_vst2 NAME DGL_LIBRARY)

  306.   dpf__create_dummy_source_list(_no_srcs)

  307. 

  308.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  309.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  310.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  311.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  312.   set_target_properties("${NAME}-vst2" PROPERTIES

  313.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  314.     OUTPUT_NAME "${NAME}-vst2"

  315.     PREFIX "")

  316. endfunction()

  317. 

  318. # dpf__add_dgl_cairo

  319. # ------------------------------------------------------------------------------

  320. #

  321. # Add the Cairo variant of DGL, if not already available.

  322. #

  323. function(dpf__add_dgl_cairo)

  324.   if(TARGET dgl-cairo)

  325.     return()

  326.   endif()

  327. 

  328.   find_package(PkgConfig)

  329.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  330. 

  331.   link_directories(${CAIRO_LIBRARY_DIRS})

  332. 

  333.   dpf__add_static_library(dgl-cairo STATIC

  334.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  343.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  344.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  345.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  346.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  347.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  348.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  349.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  350.   if(NOT APPLE)

  351.     target_sources(dgl-cairo PRIVATE

  352.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  353.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  354.     #target_sources(dgl-opengl PRIVATE

  355.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  356.   endif()

  357.   target_include_directories(dgl-cairo PUBLIC

  358.     "${DPF_ROOT_DIR}/dgl")

  359.   target_include_directories(dgl-cairo PUBLIC

  360.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  361. 

  362.   dpf__add_dgl_system_libs()

  363.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  364. 

  365.   add_library(dgl-cairo-definitions INTERFACE)

  366.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  367. 

  368.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  369.   if(MINGW)

  370.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  371.   else()

  372.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  373.   endif()

  374.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  375. endfunction()

  376. 

  377. # dpf__add_dgl_opengl

  378. # ------------------------------------------------------------------------------

  379. #

  380. # Add the OpenGL variant of DGL, if not already available.

  381. #

  382. function(dpf__add_dgl_opengl)

  383.   if(TARGET dgl-opengl)

  384.     return()

  385.   endif()

  386. 

  387.   if(NOT OpenGL_GL_PREFERENCE)

  388.     set(OpenGL_GL_PREFERENCE "LEGACY")

  389.   endif()

  390. 

  391.   find_package(OpenGL REQUIRED)

  392. 

  393.   dpf__add_static_library(dgl-opengl STATIC

  394.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  405.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  406.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  407.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  408.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  409.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  410.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  411.   if(NOT APPLE)

  412.     target_sources(dgl-opengl PRIVATE

  413.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  414.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  415.     #target_sources(dgl-opengl PRIVATE

  416.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  417.   endif()

  418.   target_include_directories(dgl-opengl PUBLIC

  419.     "${DPF_ROOT_DIR}/dgl")

  420.   target_include_directories(dgl-opengl PUBLIC

  421.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  422. 

  423.   if(APPLE)

  424.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  425.   endif()

  426. 

  427.   dpf__add_dgl_system_libs()

  428.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  429. 

  430.   add_library(dgl-opengl-definitions INTERFACE)

  431.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  432. 

  433.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  434.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  435. endfunction()

  436. 

  437. # dpf__add_plugin_specific_ui_sources

  438. # ------------------------------------------------------------------------------

  439. #

  440. # Compile plugin-specific UI sources into the target designated by the given

  441. # name. There are some special considerations here:

  442. # - On most platforms, sources can be compiled only once, as part of DGL;

  443. # - On macOS, for any sources which define Objective-C interfaces, these must

  444. #   be recompiled for each plugin under a unique namespace. In this case, the

  445. #   name must be a plugin-specific identifier, and it will be used for computing

  446. #   the unique ID along with the project version.

  447. function(dpf__add_plugin_specific_ui_sources NAME)

  448.   if(APPLE)

  449.     target_sources("${NAME}" PRIVATE

  450.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  451.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  452.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  453.   endif()

  454. endfunction()

  455. 

  456. # dpf__add_dgl_system_libs

  457. # ------------------------------------------------------------------------------

  458. #

  459. # Find system libraries required by DGL and add them as an interface target.

  460. #

  461. function(dpf__add_dgl_system_libs)

  462.   if(TARGET dgl-system-libs)

  463.     return()

  464.   endif()

  465.   add_library(dgl-system-libs INTERFACE)

  466.   add_library(dgl-system-libs-definitions INTERFACE)

  467.   if(HAIKU)

  468.     target_link_libraries(dgl-system-libs INTERFACE "be")

  469.   elseif(WIN32)

  470.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  471.   elseif(APPLE)

  472.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  473.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  474.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  475.   else()

  476.     find_package(X11 REQUIRED)

  477.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  478.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  479.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  480.     if(X11_Xext_FOUND)

  481.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  482.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  483.     endif()

  484.     if(X11_XSync_FOUND)

  485.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  486.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  487.     endif()

  488.     if(X11_Xrandr_FOUND)

  489.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  490.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  491.     endif()

  492.     #if(X11_Xcursor_FOUND)

  493.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  494.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  495.     #endif()

  496.    endif()

  497. 

  498.    if(MSVC)

  499.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  500.      foreach(_gl_header "glext.h")

  501.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  502.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  503.        endif()

  504.      endforeach()

  505.      foreach(_khr_header "khrplatform.h")

  506.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  507.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  508.        endif()

  509.      endforeach()

  510.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  511.    endif()

  512. 

  513.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  514. endfunction()

  515. 

  516. # dpf__add_executable

  517. # ------------------------------------------------------------------------------

  518. #

  519. # Adds an executable target, and set some default properties on the target.

  520. #

  521. function(dpf__add_executable NAME)

  522.   add_executable("${NAME}" ${ARGN})

  523.   dpf__set_target_defaults("${NAME}")

  524.   if(MINGW)

  525.     target_link_libraries("${NAME}" PRIVATE "-static")

  526.   endif()

  527. endfunction()

  528. 

  529. # dpf__add_module

  530. # ------------------------------------------------------------------------------

  531. #

  532. # Adds a module target, and set some default properties on the target.

  533. #

  534. function(dpf__add_module NAME)

  535.   add_library("${NAME}" MODULE ${ARGN})

  536.   dpf__set_target_defaults("${NAME}")

  537.   if(MINGW)

  538.     target_link_libraries("${NAME}" PRIVATE "-static")

  539.   endif()

  540. endfunction()

  541. 

  542. # dpf__add_static_library

  543. # ------------------------------------------------------------------------------

  544. #

  545. # Adds a static library target, and set some default properties on the target.

  546. #

  547. function(dpf__add_static_library NAME)

  548.   add_library("${NAME}" STATIC ${ARGN})

  549.   dpf__set_target_defaults("${NAME}")

  550. endfunction()

  551. 

  552. # dpf__set_target_defaults

  553. # ------------------------------------------------------------------------------

  554. #

  555. # Set default properties which must apply to all DPF-defined targets.

  556. #

  557. function(dpf__set_target_defaults NAME)

  558.   set_target_properties("${NAME}" PROPERTIES

  559.     POSITION_INDEPENDENT_CODE TRUE

  560.     C_VISIBILITY_PRESET "hidden"

  561.     CXX_VISIBILITY_PRESET "hidden"

  562.     VISIBILITY_INLINES_HIDDEN TRUE)

  563.   if(WIN32)

  564.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  565.   endif()

  566.   if (MINGW)

  567.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  568.   endif()

  569.   if (MSVC)

  570.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  571.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  572.   endif()

  573. endfunction()

  574. 

  575. # dpf__add_plugin_main

  576. # ------------------------------------------------------------------------------

  577. #

  578. # Adds plugin code to the given target.

  579. #

  580. function(dpf__add_plugin_main NAME TARGET)

  581.   target_sources("${NAME}" PRIVATE

  582.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  583.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  584. endfunction()

  585. 

  586. # dpf__add_ui_main

  587. # ------------------------------------------------------------------------------

  588. #

  589. # Adds UI code to the given target (only if the target has UI).

  590. #

  591. function(dpf__add_ui_main NAME TARGET HAS_UI)

  592.   if(HAS_UI)

  593.     target_sources("${NAME}" PRIVATE

  594.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  595.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  596.   endif()

  597. endfunction()

  598. 

  599. # dpf__add_plugin_target_definition

  600. # ------------------------------------------------------------------------------

  601. #

  602. # Adds the plugins target macro definition.

  603. # This selects which entry file is compiled according to the target type.

  604. #

  605. function(dpf__add_plugin_target_definition NAME TARGET)

  606.   string(TOUPPER "${TARGET}" _upperTarget)

  607. 

  608.   # resolve the alias into the proper name

  609.   # the name "vst2" is new, "vst" is legacy

  610.   if(_upperTarget STREQUAL "VST2")

  611.     set(_upperTarget "VST")

  612.   endif()

  613. 

  614.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  615. endfunction()

  616. 

  617. # dpf__add_lv2_ttl_generator

  618. # ------------------------------------------------------------------------------

  619. #

  620. # Build the LV2 TTL generator.

  621. #

  622. function(dpf__add_lv2_ttl_generator)

  623.   if(TARGET lv2_ttl_generator)

  624.     return()

  625.   endif()

  626.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  627.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  628.     target_link_libraries(lv2_ttl_generator "dl")

  629.   endif()

  630. endfunction()

  631. 

  632. # dpf__ensure_sources_non_empty

  633. # ------------------------------------------------------------------------------

  634. #

  635. # Ensure the given source list contains at least one file.

  636. # The function appends an empty source file to the list if necessary.

  637. # This is useful when CMake does not permit to add targets without sources.

  638. #

  639. function(dpf__ensure_sources_non_empty VAR)

  640.   if(NOT "" STREQUAL "${${VAR}}")

  641.     return()

  642.   endif()

  643.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  644.   if(NOT EXISTS "${_file}")

  645.     file(WRITE "${_file}" "")

  646.   endif()

  647.   set("${VAR}" "${_file}" PARENT_SCOPE)

  648. endfunction()

  649. 

  650. # dpf__create_dummy_source_list

  651. # ------------------------------------------------------------------------------

  652. #

  653. # Create a dummy source list which is equivalent to compiling nothing.

  654. # This is only for compatibility with older CMake versions, which refuse to add

  655. # targets without any sources.

  656. #

  657. macro(dpf__create_dummy_source_list VAR)

  658.   set("${VAR}")

  659.   if(CMAKE_VERSION VERSION_LESS "3.11")

  660.     dpf__ensure_sources_non_empty("${VAR}")

  661.   endif()

  662. endmacro()

  663. 

  664. # dpf__warn_once

  665. # ------------------------------------------------------------------------------

  666. #

  667. # Prints a warning message once only.

  668. #

  669. function(dpf__warn_once_only TOKEN MESSAGE)

  670.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  671.   if(NOT _warned)

  672.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  673.     message(WARNING "${MESSAGE}")

  674.   endif()

  675. endfunction()