DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2331 Commits
7 Branches
295MB
Tree: 9a8b49d126
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '9a8b49d126'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1249 lines
44KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  125.       set(_dgl_library dgl-cairo)

  126.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  127.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  128.       set(_dgl_library dgl-external)

  129.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  130.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  131.       set(_dgl_library dgl-opengl)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  133.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  134.       set(_dgl_library dgl-opengl3)

  135.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  136.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  137.       set(_dgl_library dgl-vulkan)

  138.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  139.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  140.       set(_dgl_library dgl-external)

  141.     else()

  142.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  143.     endif()

  144.   else()

  145.     set(_dpf_plugin_UI_TYPE "")

  146.   endif()

  147. 

  148.   set(_dgl_has_ui OFF)

  149.   if(_dgl_library)

  150.     set(_dgl_has_ui ON)

  151.   endif()

  152. 

  153.   ###

  154.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  155.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  156.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  157. 

  158.   ###

  159.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  160.   target_include_directories("${NAME}" PUBLIC

  161.     "${DPF_ROOT_DIR}/distrho")

  162. 

  163.   if(_dpf_plugin_USE_FILE_BROWSER)

  164.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  165.   endif()

  166. 

  167.   if(_dpf_plugin_USE_WEB_VIEW OR _dpf_plugin_UI_TYPE STREQUAL "webview")

  168.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  169.   endif()

  170. 

  171.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  172.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  173.   endif()

  174. 

  175.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  176.     target_link_libraries("${NAME}" PRIVATE "dl")

  177.   endif()

  178. 

  179.   if(_dgl_library)

  180.     # make sure that all code will see DGL_* definitions

  181.     target_link_libraries("${NAME}" PUBLIC

  182.       "${_dgl_library}-definitions"

  183.       dgl-system-libs-definitions

  184.       dgl-system-libs)

  185.   endif()

  186. 

  187.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  188.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  189. 

  190.   if(_dgl_library)

  191.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  192.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  193.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  194.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  195.     endif()

  196.     # add the files containing Objective-C classes

  197.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  198.   else()

  199.     add_library("${NAME}-ui" INTERFACE)

  200.   endif()

  201. 

  202.   ###

  203.   foreach(_target ${_dpf_plugin_TARGETS})

  204.     if(_target STREQUAL "jack")

  205.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  206.     elseif(_target STREQUAL "ladspa")

  207.       dpf__build_ladspa("${NAME}")

  208.     elseif(_target STREQUAL "dssi")

  209.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  210.     elseif(_target STREQUAL "lv2")

  211.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  212.     elseif(_target STREQUAL "vst2")

  213.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  214.     elseif(_target STREQUAL "vst3")

  215.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  216.     elseif(_target STREQUAL "clap")

  217.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  218.     elseif(_target STREQUAL "au")

  219.       if (APPLE)

  220.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  221.       endif()

  222.     elseif(_target STREQUAL "static")

  223.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  224.     else()

  225.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  226.     endif()

  227.   endforeach()

  228. endfunction()

  229. 

  230. # ------------------------------------------------------------------------------

  231. # DPF private functions (prefixed with `dpf__`)

  232. # ------------------------------------------------------------------------------

  233. 

  234. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  235. #       to the output directory.

  236. #

  237. 

  238. # dpf__build_jack

  239. # ------------------------------------------------------------------------------

  240. #

  241. # Add build rules for a JACK/Standalone program.

  242. #

  243. function(dpf__build_jack NAME HAS_UI)

  244.   dpf__create_dummy_source_list(_no_srcs)

  245. 

  246.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  247.   dpf__add_plugin_main("${NAME}-jack" "jack")

  248.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  249.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  250.   set_target_properties("${NAME}-jack" PROPERTIES

  251.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  252.     OUTPUT_NAME "${NAME}")

  253. 

  254.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  255.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  256. 

  257.   find_package(PkgConfig)

  258.   pkg_check_modules(SDL2 "sdl2")

  259.   if(SDL2_FOUND)

  260.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  261.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  262.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  263.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  264.   endif()

  265. 

  266.   if(APPLE OR WIN32)

  267.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  268.   else()

  269.     find_package(Threads)

  270.     pkg_check_modules(ALSA "alsa")

  271.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  272.     if(ALSA_FOUND)

  273.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  274.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  275.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  276.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  277.     endif()

  278.     if(PULSEAUDIO_FOUND)

  279.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  280.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  281.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  282.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  283.     endif()

  284.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  285.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  286.     endif()

  287.   endif()

  288. 

  289.   # for RtAudio native fallback

  290.   if(APPLE)

  291.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  292.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  293.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  294.     target_link_libraries("${NAME}-jack" PRIVATE

  295.       "${APPLE_COREAUDIO_FRAMEWORK}"

  296.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  297.       "${APPLE_COREMIDI_FRAMEWORK}")

  298.   elseif(WIN32)

  299.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  300.     if(HAS_UI AND MINGW)

  301.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  302.     endif()

  303.   endif()

  304. endfunction()

  305. 

  306. # dpf__build_ladspa

  307. # ------------------------------------------------------------------------------

  308. #

  309. # Add build rules for a LADSPA plugin.

  310. #

  311. function(dpf__build_ladspa NAME)

  312.   dpf__create_dummy_source_list(_no_srcs)

  313. 

  314.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  315.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  316.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  317.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  318.   set_target_properties("${NAME}-ladspa" PROPERTIES

  319.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  320.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  321.     OUTPUT_NAME "${NAME}-ladspa"

  322.     PREFIX "")

  323. endfunction()

  324. 

  325. # dpf__build_dssi

  326. # ------------------------------------------------------------------------------

  327. #

  328. # Add build rules for a DSSI plugin.

  329. #

  330. function(dpf__build_dssi NAME HAS_UI)

  331.   find_package(PkgConfig)

  332.   pkg_check_modules(LIBLO "liblo")

  333.   if(NOT LIBLO_FOUND)

  334.     dpf__warn_once_only(missing_liblo

  335.       "liblo is not found, skipping the `dssi` plugin targets")

  336.     return()

  337.   endif()

  338. 

  339.   dpf__create_dummy_source_list(_no_srcs)

  340. 

  341.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  342.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  343.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  344.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  345.   set_target_properties("${NAME}-dssi" PROPERTIES

  346.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  347.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  348.     OUTPUT_NAME "${NAME}-dssi"

  349.     PREFIX "")

  350. 

  351.   if(HAS_UI)

  352.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  353.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  354.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  355.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  356.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  357.       OUTPUT_NAME "${NAME}_ui")

  358. 

  359.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  360.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  361.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  362.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  363.   endif()

  364. endfunction()

  365. 

  366. # dpf__build_lv2

  367. # ------------------------------------------------------------------------------

  368. #

  369. # Add build rules for an LV2 plugin.

  370. #

  371. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  372.   dpf__create_dummy_source_list(_no_srcs)

  373. 

  374.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  375.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  376.   if(HAS_UI AND MONOLITHIC)

  377.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  378.   else()

  379.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  380.   endif()

  381.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  382.   set_target_properties("${NAME}-lv2" PROPERTIES

  383.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  384.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  385.     OUTPUT_NAME "${NAME}_dsp"

  386.     PREFIX "")

  387. 

  388.   if(HAS_UI)

  389.     if(MONOLITHIC)

  390.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  391.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  392.       set_target_properties("${NAME}-lv2" PROPERTIES

  393.         OUTPUT_NAME "${NAME}")

  394.     else()

  395.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  396.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  397.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  398.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  399.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  400.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  401.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  402.         OUTPUT_NAME "${NAME}_ui"

  403.         PREFIX "")

  404.     endif()

  405.   endif()

  406. 

  407.   dpf__add_lv2_ttl_generator()

  408.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  409. 

  410.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  411. 

  412.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  413.     COMMAND

  414.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  415.     "$<TARGET_FILE:lv2_ttl_generator>"

  416.     "$<TARGET_FILE:${NAME}-lv2>"

  417.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  418.     DEPENDS lv2_ttl_generator)

  419. endfunction()

  420. 

  421. # dpf__build_vst2

  422. # ------------------------------------------------------------------------------

  423. #

  424. # Add build rules for a VST2 plugin.

  425. #

  426. function(dpf__build_vst2 NAME HAS_UI)

  427.   dpf__create_dummy_source_list(_no_srcs)

  428. 

  429.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  430.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  431.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  432.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  433.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  434.   set_target_properties("${NAME}-vst2" PROPERTIES

  435.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  436.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  437.     OUTPUT_NAME "${NAME}-vst2"

  438.     PREFIX "")

  439.   if(APPLE)

  440.     set_target_properties("${NAME}-vst2" PROPERTIES

  441.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  442.       OUTPUT_NAME "${NAME}"

  443.       SUFFIX "")

  444.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  445.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  446.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  447.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  448.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  449.   endif()

  450. endfunction()

  451. 

  452. # dpf__determine_vst3_package_architecture

  453. # ------------------------------------------------------------------------------

  454. #

  455. # Determines the package architecture for a VST3 plugin target.

  456. #

  457. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  458.   # if set by variable, override the detection

  459.   if(DPF_VST3_ARCHITECTURE)

  460.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  461.     return()

  462.   endif()

  463. 

  464.   # not used on Apple, which supports universal binary

  465.   if(APPLE)

  466.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  467.     return()

  468.   endif()

  469. 

  470.   # identify the target processor (special case of MSVC, problematic sometimes)

  471.   if(MSVC)

  472.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  473.   else()

  474.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  475.   endif()

  476. 

  477.   # transform the processor name to a format that VST3 recognizes

  478.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  479.     set(vst3_package_arch "x86_64")

  480.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  481.     if(WIN32)

  482.       set(vst3_package_arch "x86")

  483.     else()

  484.       set(vst3_package_arch "i386")

  485.     endif()

  486.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*|ppc(64)?(le)?)$")

  487.     set(vst3_package_arch "${vst3_system_arch}")

  488.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  489.     set(vst3_package_arch "aarch64")

  490.   else()

  491.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  492.   endif()

  493. 

  494.   # TODO: the detections for Windows arm/arm64 when supported

  495. 

  496.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  497. endfunction()

  498. 

  499. # dpf__build_vst3

  500. # ------------------------------------------------------------------------------

  501. #

  502. # Add build rules for a VST3 plugin.

  503. #

  504. function(dpf__build_vst3 NAME HAS_UI)

  505.   dpf__determine_vst3_package_architecture(vst3_arch)

  506. 

  507.   dpf__create_dummy_source_list(_no_srcs)

  508. 

  509.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  510.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  511.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  512.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  513.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  514.   set_target_properties("${NAME}-vst3" PROPERTIES

  515.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  516.     OUTPUT_NAME "${NAME}"

  517.     PREFIX "")

  518. 

  519.   if(APPLE)

  520.     set_target_properties("${NAME}-vst3" PROPERTIES

  521.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  522.       SUFFIX "")

  523.   elseif(WIN32)

  524.     set_target_properties("${NAME}-vst3" PROPERTIES

  525.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  526.   else()

  527.     set_target_properties("${NAME}-vst3" PROPERTIES

  528.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  529.   endif()

  530. 

  531.   if(APPLE)

  532.     # Uses the same macOS bundle template as VST2

  533.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  534.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  535.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  536.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  537.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  538.   endif()

  539. endfunction()

  540. 

  541. # dpf__build_clap

  542. # ------------------------------------------------------------------------------

  543. #

  544. # Add build rules for a CLAP plugin.

  545. #

  546. function(dpf__build_clap NAME HAS_UI)

  547.   dpf__create_dummy_source_list(_no_srcs)

  548. 

  549.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  550.   dpf__add_plugin_main("${NAME}-clap" "clap")

  551.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  552.   dpf__set_module_export_list("${NAME}-clap" "clap")

  553.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  554.   set_target_properties("${NAME}-clap" PROPERTIES

  555.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  556.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  557.     OUTPUT_NAME "${NAME}"

  558.     PREFIX ""

  559.     SUFFIX ".clap")

  560. 

  561.   if(APPLE)

  562.     set_target_properties("${NAME}-clap" PROPERTIES

  563.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  564.       OUTPUT_NAME "${NAME}"

  565.       SUFFIX "")

  566.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  567.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  568.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  569.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  570.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  571.   endif()

  572. endfunction()

  573. 

  574. # dpf__build_au

  575. # ------------------------------------------------------------------------------

  576. #

  577. # Add build rules for an AUv2 plugin.

  578. #

  579. function(dpf__build_au NAME HAS_UI)

  580.   dpf__create_dummy_source_list(_no_srcs)

  581. 

  582.   dpf__add_module("${NAME}-au" ${_no_srcs})

  583.   dpf__add_plugin_main("${NAME}-au" "au")

  584.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  585.   dpf__set_module_export_list("${NAME}-au" "au")

  586.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  587.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  588.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  589.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  590.   target_link_libraries("${NAME}-au" PRIVATE

  591.     "${NAME}-dsp"

  592.     "${NAME}-ui"

  593.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  594.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  595.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  596.   set_target_properties("${NAME}-au" PROPERTIES

  597.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  598.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  599.     OUTPUT_NAME "${NAME}"

  600.     PREFIX ""

  601.     SUFFIX "")

  602. 

  603.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  604.   dpf__add_plugin_main("${NAME}-export" "export")

  605.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  606.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  607. 

  608.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  609. 

  610.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  611.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  612.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  613.     DEPENDS "${NAME}-export")

  614. 

  615.   add_dependencies("${NAME}-au" "${NAME}-export")

  616. 

  617.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  618.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  619. endfunction()

  620. 

  621. # dpf__build_static

  622. # ------------------------------------------------------------------------------

  623. #

  624. # Add build rules for a static library.

  625. #

  626. function(dpf__build_static NAME HAS_UI)

  627.   dpf__create_dummy_source_list(_no_srcs)

  628. 

  629.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  630.   dpf__add_plugin_main("${NAME}-static" "static")

  631.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  632.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  633. 

  634.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  635.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  636.   foreach(src ${dsp_srcs})

  637.     target_sources("${NAME}-static" PRIVATE ${src})

  638.   endforeach()

  639.   foreach(src ${ui_srcs})

  640.     target_sources("${NAME}-static" PRIVATE ${src})

  641.   endforeach()

  642. 

  643.   set_target_properties("${NAME}-static" PROPERTIES

  644.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  645.     OUTPUT_NAME "${NAME}"

  646.     PREFIX "")

  647. endfunction()

  648. 

  649. # dpf__add_dgl_cairo

  650. # ------------------------------------------------------------------------------

  651. #

  652. # Add the Cairo variant of DGL, if not already available.

  653. #

  654. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER)

  655.   if(TARGET dgl-cairo)

  656.     return()

  657.   endif()

  658. 

  659.   find_package(PkgConfig)

  660.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  661. 

  662.   link_directories(${CAIRO_LIBRARY_DIRS})

  663. 

  664.   dpf__add_static_library(dgl-cairo STATIC

  665.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  666.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  667.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  668.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  669.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  670.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  671.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  672.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  673.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  674.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  675.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  676.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  677.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  678.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  679.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  680.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  681.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  682.   if(SHARED_RESOURCES)

  683.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  684.   else()

  685.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  686.   endif()

  687.   if(APPLE)

  688.     target_sources(dgl-cairo PRIVATE

  689.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  690.   else()

  691.     target_sources(dgl-cairo PRIVATE

  692.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  693.   endif()

  694.   target_include_directories(dgl-cairo PUBLIC

  695.     "${DPF_ROOT_DIR}/dgl")

  696.   target_include_directories(dgl-cairo PUBLIC

  697.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  698. 

  699.   if(USE_FILE_BROWSER)

  700.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  701.   endif()

  702. 

  703.   dpf__add_dgl_system_libs()

  704.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  705. 

  706.   add_library(dgl-cairo-definitions INTERFACE)

  707.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  708. 

  709.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  710.   if(MINGW)

  711.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  712.   else()

  713.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  714.   endif()

  715.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  716. endfunction()

  717. 

  718. # dpf__add_dgl_external

  719. # ------------------------------------------------------------------------------

  720. #

  721. # Add the external variant of DGL, if not already available.

  722. #

  723. function(dpf__add_dgl_external USE_FILE_BROWSER)

  724.   if(TARGET dgl-external)

  725.     return()

  726.   endif()

  727. 

  728.   dpf__add_static_library(dgl-external STATIC

  729.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  730.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  731.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  732.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  733.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  734.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  735.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  736.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  737.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  738.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  739.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  740.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  741.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  742.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  743.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  744.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  745.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  746. 

  747.   if(APPLE)

  748.     target_sources(dgl-external PRIVATE

  749.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  750.   else()

  751.     target_sources(dgl-external PRIVATE

  752.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  753.   endif()

  754.   target_include_directories(dgl-external PUBLIC

  755.     "${DPF_ROOT_DIR}/dgl")

  756.   target_include_directories(dgl-external PUBLIC

  757.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  758. 

  759.   if(USE_FILE_BROWSER)

  760.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  761.   endif()

  762. 

  763.   dpf__add_dgl_system_libs()

  764.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  765.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  766. 

  767.   add_library(dgl-external-definitions INTERFACE)

  768.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  769. 

  770.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  771.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  772. endfunction()

  773. 

  774. # dpf__add_dgl_opengl

  775. # ------------------------------------------------------------------------------

  776. #

  777. # Add the OpenGL variant of DGL, if not already available.

  778. #

  779. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER)

  780.   if(TARGET dgl-opengl)

  781.     return()

  782.   endif()

  783. 

  784.   if(NOT OpenGL_GL_PREFERENCE)

  785.     set(OpenGL_GL_PREFERENCE "LEGACY")

  786.   endif()

  787. 

  788.   find_package(OpenGL REQUIRED)

  789. 

  790.   dpf__add_static_library(dgl-opengl STATIC

  791.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  792.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  793.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  794.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  795.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  796.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  797.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  798.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  799.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  800.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  801.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  802.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  803.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  804.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  805.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  806.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  807.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  808.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  809.   if(SHARED_RESOURCES)

  810.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  811.   else()

  812.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  813.   endif()

  814.   if(APPLE)

  815.     target_sources(dgl-opengl PRIVATE

  816.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  817.   else()

  818.     target_sources(dgl-opengl PRIVATE

  819.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  820.   endif()

  821.   target_include_directories(dgl-opengl PUBLIC

  822.     "${DPF_ROOT_DIR}/dgl")

  823.   target_include_directories(dgl-opengl PUBLIC

  824.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  825. 

  826.   if(APPLE)

  827.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  828.   endif()

  829. 

  830.   if(USE_FILE_BROWSER)

  831.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  832.   endif()

  833. 

  834.   dpf__add_dgl_system_libs()

  835.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  836. 

  837.   add_library(dgl-opengl-definitions INTERFACE)

  838.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  839. 

  840.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  841.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  842. endfunction()

  843. 

  844. # dpf__add_dgl_opengl3

  845. # ------------------------------------------------------------------------------

  846. #

  847. # Add the OpenGL3 variant of DGL, if not already available.

  848. #

  849. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER)

  850.   if(TARGET dgl-opengl3)

  851.     return()

  852.   endif()

  853. 

  854.   if(NOT OpenGL_GL_PREFERENCE)

  855.     set(OpenGL_GL_PREFERENCE "LEGACY")

  856.   endif()

  857. 

  858.   find_package(OpenGL REQUIRED)

  859. 

  860.   dpf__add_static_library(dgl-opengl3 STATIC

  861.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  862.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  863.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  864.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  865.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  866.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  867.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  868.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  869.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  870.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  871.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  879.   if(SHARED_RESOURCES)

  880.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  881.   else()

  882.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  883.   endif()

  884.   if(APPLE)

  885.     target_sources(dgl-opengl3 PRIVATE

  886.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  887.   else()

  888.     target_sources(dgl-opengl3 PRIVATE

  889.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  890.   endif()

  891.   target_include_directories(dgl-opengl3 PUBLIC

  892.     "${DPF_ROOT_DIR}/dgl")

  893.   target_include_directories(dgl-opengl3 PUBLIC

  894.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  895. 

  896.   if(APPLE)

  897.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  898.   endif()

  899. 

  900.   if(USE_FILE_BROWSER)

  901.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  902.   endif()

  903. 

  904.   dpf__add_dgl_system_libs()

  905.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  906. 

  907.   add_library(dgl-opengl3-definitions INTERFACE)

  908.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  909. 

  910.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  911.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  912. endfunction()

  913. 

  914. # dpf__add_dgl_vulkan

  915. # ------------------------------------------------------------------------------

  916. #

  917. # Add the Vulkan variant of DGL, if not already available.

  918. #

  919. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER)

  920.   if(TARGET dgl-vulkan)

  921.     return()

  922.   endif()

  923. 

  924.   find_package(Vulkan REQUIRED)

  925. 

  926.   dpf__add_static_library(dgl-vulkan STATIC

  927.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  928.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  929.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  930.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  931.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  932.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  933.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  934.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  935.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  936.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  937.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  938.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  939.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  940.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  941.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  944.   if(NO_SHARED_RESOURCES)

  945.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  946.   else()

  947.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  948.   endif()

  949.   if(APPLE)

  950.     target_sources(dgl-vulkan PRIVATE

  951.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  952.   else()

  953.     target_sources(dgl-vulkan PRIVATE

  954.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  955.   endif()

  956.   target_include_directories(dgl-vulkan PUBLIC

  957.     "${DPF_ROOT_DIR}/dgl")

  958.   target_include_directories(dgl-vulkan PUBLIC

  959.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  960. 

  961.   if(APPLE)

  962.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  963.   endif()

  964. 

  965.   if(USE_FILE_BROWSER)

  966.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  967.   endif()

  968. 

  969.   dpf__add_dgl_system_libs()

  970.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  971. 

  972.   add_library(dgl-vulkan-definitions INTERFACE)

  973.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  974. 

  975.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  976.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  977. endfunction()

  978. 

  979. # dpf__add_plugin_specific_ui_sources

  980. # ------------------------------------------------------------------------------

  981. #

  982. # Compile system specific files, for now it is just Objective-C code

  983. #

  984. function(dpf__add_plugin_specific_ui_sources NAME)

  985.   if(APPLE)

  986.     target_sources("${NAME}" PRIVATE

  987.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  988.   endif()

  989. endfunction()

  990. 

  991. # dpf__add_dgl_system_libs

  992. # ------------------------------------------------------------------------------

  993. #

  994. # Find system libraries required by DGL and add them as an interface target.

  995. #

  996. function(dpf__add_dgl_system_libs)

  997.   if(TARGET dgl-system-libs)

  998.     return()

  999.   endif()

  1000.   add_library(dgl-system-libs INTERFACE)

  1001.   add_library(dgl-system-libs-definitions INTERFACE)

  1002.   if(APPLE)

  1003.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1004.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1005.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1006.   elseif(EMSCRIPTEN)

  1007.   elseif(HAIKU)

  1008.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1009.   elseif(WIN32)

  1010.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1011.   else()

  1012.     find_package(PkgConfig)

  1013.     pkg_check_modules(DBUS "dbus-1")

  1014.     if(DBUS_FOUND)

  1015.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1016.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1017.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1018.     endif()

  1019.     find_package(X11 REQUIRED)

  1020.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1021.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1022.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1023.     if(X11_Xcursor_FOUND)

  1024.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1025.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1026.     endif()

  1027.     if(X11_Xext_FOUND)

  1028.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1029.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1030.     endif()

  1031.     if(X11_Xrandr_FOUND)

  1032.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1033.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1034.     endif()

  1035.     if(X11_XSync_FOUND)

  1036.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1037.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1038.     endif()

  1039.    endif()

  1040. 

  1041.    if(MSVC)

  1042.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1043.      foreach(_gl_header "glext.h")

  1044.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1045.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1046.        endif()

  1047.      endforeach()

  1048.      foreach(_khr_header "khrplatform.h")

  1049.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1050.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1051.        endif()

  1052.      endforeach()

  1053.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1054.    endif()

  1055. 

  1056.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1057. endfunction()

  1058. 

  1059. # dpf__add_executable

  1060. # ------------------------------------------------------------------------------

  1061. #

  1062. # Adds an executable target, and set some default properties on the target.

  1063. #

  1064. function(dpf__add_executable NAME)

  1065.   add_executable("${NAME}" ${ARGN})

  1066.   dpf__set_target_defaults("${NAME}")

  1067.   if(MINGW)

  1068.     target_link_libraries("${NAME}" PRIVATE "-static")

  1069.   endif()

  1070. endfunction()

  1071. 

  1072. # dpf__add_module

  1073. # ------------------------------------------------------------------------------

  1074. #

  1075. # Adds a module target, and set some default properties on the target.

  1076. #

  1077. function(dpf__add_module NAME)

  1078.   add_library("${NAME}" MODULE ${ARGN})

  1079.   dpf__set_target_defaults("${NAME}")

  1080.   if(APPLE)

  1081.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1082.   elseif(MINGW)

  1083.     target_link_libraries("${NAME}" PRIVATE "-static")

  1084.   endif()

  1085. endfunction()

  1086. 

  1087. # dpf__add_static_library

  1088. # ------------------------------------------------------------------------------

  1089. #

  1090. # Adds a static library target, and set some default properties on the target.

  1091. #

  1092. function(dpf__add_static_library NAME)

  1093.   add_library("${NAME}" STATIC ${ARGN})

  1094.   dpf__set_target_defaults("${NAME}")

  1095. endfunction()

  1096. 

  1097. # dpf__set_module_export_list

  1098. # ------------------------------------------------------------------------------

  1099. #

  1100. # Applies a list of exported symbols to the module target.

  1101. #

  1102. function(dpf__set_module_export_list NAME EXPORTS)

  1103.   if(WIN32)

  1104.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1105.   elseif(APPLE)

  1106.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1107.       "-Xlinker" "-exported_symbols_list"

  1108.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1109.   else()

  1110.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1111.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1112.   endif()

  1113. endfunction()

  1114. 

  1115. # dpf__set_target_defaults

  1116. # ------------------------------------------------------------------------------

  1117. #

  1118. # Set default properties which must apply to all DPF-defined targets.

  1119. #

  1120. function(dpf__set_target_defaults NAME)

  1121.   set_target_properties("${NAME}" PROPERTIES

  1122.     POSITION_INDEPENDENT_CODE TRUE

  1123.     C_VISIBILITY_PRESET "hidden"

  1124.     CXX_VISIBILITY_PRESET "hidden"

  1125.     VISIBILITY_INLINES_HIDDEN TRUE)

  1126.   if(WIN32)

  1127.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1128.   endif()

  1129.   if (MINGW)

  1130.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1131.   endif()

  1132.   if (MSVC)

  1133.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1134.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1135.   endif()

  1136.   if (CMAKE_COMPILER_IS_GNUCXX)

  1137.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1138.   endif()

  1139. endfunction()

  1140. 

  1141. # dpf__add_plugin_main

  1142. # ------------------------------------------------------------------------------

  1143. #

  1144. # Adds plugin code to the given target.

  1145. #

  1146. function(dpf__add_plugin_main NAME TARGET)

  1147.   target_sources("${NAME}" PRIVATE

  1148.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1149.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1150. endfunction()

  1151. 

  1152. # dpf__add_ui_main

  1153. # ------------------------------------------------------------------------------

  1154. #

  1155. # Adds UI code to the given target (only if the target has UI).

  1156. #

  1157. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1158.   if(HAS_UI)

  1159.     target_sources("${NAME}" PRIVATE

  1160.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1161.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1162.   endif()

  1163. endfunction()

  1164. 

  1165. # dpf__add_plugin_target_definition

  1166. # ------------------------------------------------------------------------------

  1167. #

  1168. # Adds the plugins target macro definition.

  1169. # This selects which entry file is compiled according to the target type.

  1170. #

  1171. function(dpf__add_plugin_target_definition NAME TARGET)

  1172.   string(TOUPPER "${TARGET}" _upperTarget)

  1173.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1174. endfunction()

  1175. 

  1176. # dpf__add_lv2_ttl_generator

  1177. # ------------------------------------------------------------------------------

  1178. #

  1179. # Build the LV2 TTL generator.

  1180. #

  1181. function(dpf__add_lv2_ttl_generator)

  1182.   if(TARGET lv2_ttl_generator)

  1183.     return()

  1184.   endif()

  1185.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1186.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1187.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1188.   endif()

  1189. endfunction()

  1190. 

  1191. # dpf__ensure_sources_non_empty

  1192. # ------------------------------------------------------------------------------

  1193. #

  1194. # Ensure the given source list contains at least one file.

  1195. # The function appends an empty source file to the list if necessary.

  1196. # This is useful when CMake does not permit to add targets without sources.

  1197. #

  1198. function(dpf__ensure_sources_non_empty VAR)

  1199.   if(NOT "" STREQUAL "${${VAR}}")

  1200.     return()

  1201.   endif()

  1202.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1203.   if(NOT EXISTS "${_file}")

  1204.     file(WRITE "${_file}" "")

  1205.   endif()

  1206.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1207. endfunction()

  1208. 

  1209. # dpf__create_dummy_source_list

  1210. # ------------------------------------------------------------------------------

  1211. #

  1212. # Create a dummy source list which is equivalent to compiling nothing.

  1213. # This is only for compatibility with older CMake versions, which refuse to add

  1214. # targets without any sources.

  1215. #

  1216. macro(dpf__create_dummy_source_list VAR)

  1217.   set("${VAR}")

  1218.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1219.     dpf__ensure_sources_non_empty("${VAR}")

  1220.   endif()

  1221. endmacro()

  1222. 

  1223. # dpf__target_link_directories

  1224. # ------------------------------------------------------------------------------

  1225. #

  1226. # Call `target_link_directories` if cmake >= 3.13,

  1227. # otherwise fallback to global `link_directories`.

  1228. #

  1229. macro(dpf__target_link_directories NAME DIRS)

  1230.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1231.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1232.   else()

  1233.     link_directories(${DIRS})

  1234.   endif()

  1235. endmacro()

  1236. 

  1237. # dpf__warn_once

  1238. # ------------------------------------------------------------------------------

  1239. #

  1240. # Prints a warning message once only.

  1241. #

  1242. function(dpf__warn_once_only TOKEN MESSAGE)

  1243.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1244.   if(NOT _warned)

  1245.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1246.     message(WARNING "${MESSAGE}")

  1247.   endif()

  1248. endfunction()