DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1363 Commits
6 Branches
65MB
Tree: 953841754f
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '953841754f'
${ noResults }
DPF/cmake/DPF-plugin.cmake

686 lines
24KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   dpf__create_dummy_source_list(_no_srcs)

  177. 

  178.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  179.   dpf__add_plugin_main("${NAME}-jack" "jack")

  180.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  181.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  182.   set_target_properties("${NAME}-jack" PROPERTIES

  183.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  184.     OUTPUT_NAME "${NAME}")

  185. 

  186.   # Note: libjack will be linked at runtime

  187.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  188.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  189.   endif()

  190. 

  191.   # for RtAudio native fallback

  192.   if(APPLE)

  193.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  194.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  195.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  196.   endif()

  197. endfunction()

  198. 

  199. # dpf__build_ladspa

  200. # ------------------------------------------------------------------------------

  201. #

  202. # Add build rules for a DSSI plugin.

  203. #

  204. function(dpf__build_ladspa NAME)

  205.   dpf__create_dummy_source_list(_no_srcs)

  206. 

  207.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  208.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  209.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  210.   set_target_properties("${NAME}-ladspa" PROPERTIES

  211.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  212.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  213.     OUTPUT_NAME "${NAME}-ladspa"

  214.     PREFIX "")

  215. endfunction()

  216. 

  217. # dpf__build_dssi

  218. # ------------------------------------------------------------------------------

  219. #

  220. # Add build rules for a DSSI plugin.

  221. #

  222. function(dpf__build_dssi NAME DGL_LIBRARY)

  223.   find_package(PkgConfig)

  224.   pkg_check_modules(LIBLO "liblo")

  225.   if(NOT LIBLO_FOUND)

  226.     dpf__warn_once_only(missing_liblo

  227.       "liblo is not found, skipping the `dssi` plugin targets")

  228.     return()

  229.   endif()

  230. 

  231.   link_directories(${LIBLO_LIBRARY_DIRS})

  232. 

  233.   dpf__create_dummy_source_list(_no_srcs)

  234. 

  235.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  236.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  237.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  238.   set_target_properties("${NAME}-dssi" PROPERTIES

  239.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  240.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  241.     OUTPUT_NAME "${NAME}-dssi"

  242.     PREFIX "")

  243. 

  244.   if(DGL_LIBRARY)

  245.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  246.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  247.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  248.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  249.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  250.       OUTPUT_NAME "${NAME}_ui")

  251. 

  252.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  253.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  254.   endif()

  255. endfunction()

  256. 

  257. # dpf__build_lv2

  258. # ------------------------------------------------------------------------------

  259. #

  260. # Add build rules for a LV2 plugin.

  261. #

  262. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  263.   dpf__create_dummy_source_list(_no_srcs)

  264. 

  265.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  266.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  267.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  268.   set_target_properties("${NAME}-lv2" PROPERTIES

  269.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  270.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  271.     OUTPUT_NAME "${NAME}_dsp"

  272.     PREFIX "")

  273. 

  274.   if(DGL_LIBRARY)

  275.     if(MONOLITHIC)

  276.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  277.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  278.       set_target_properties("${NAME}-lv2" PROPERTIES

  279.         OUTPUT_NAME "${NAME}")

  280.     else()

  281.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  282.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  283.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  284.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  285.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  286.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  287.         OUTPUT_NAME "${NAME}_ui"

  288.         PREFIX "")

  289.     endif()

  290.   endif()

  291. 

  292.   dpf__add_lv2_ttl_generator()

  293.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  294. 

  295.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  296.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  297.     "$<TARGET_FILE:lv2_ttl_generator>"

  298.     "$<TARGET_FILE:${NAME}-lv2>"

  299.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  300.     DEPENDS lv2_ttl_generator)

  301. endfunction()

  302. 

  303. # dpf__build_vst2

  304. # ------------------------------------------------------------------------------

  305. #

  306. # Add build rules for a VST2 plugin.

  307. #

  308. function(dpf__build_vst2 NAME DGL_LIBRARY)

  309.   dpf__create_dummy_source_list(_no_srcs)

  310. 

  311.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  312.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  313.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  314.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  315.   set_target_properties("${NAME}-vst2" PROPERTIES

  316.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  317.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  318.     OUTPUT_NAME "${NAME}-vst2"

  319.     PREFIX "")

  320.   if(APPLE)

  321.     set_target_properties("${NAME}-vst2" PROPERTIES

  322.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  323.       OUTPUT_NAME "${NAME}"

  324.       SUFFIX "")

  325.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  326.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  327.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  328.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  329.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  330.   endif()

  331. endfunction()

  332. 

  333. # dpf__add_dgl_cairo

  334. # ------------------------------------------------------------------------------

  335. #

  336. # Add the Cairo variant of DGL, if not already available.

  337. #

  338. function(dpf__add_dgl_cairo)

  339.   if(TARGET dgl-cairo)

  340.     return()

  341.   endif()

  342. 

  343.   find_package(PkgConfig)

  344.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  345. 

  346.   link_directories(${CAIRO_LIBRARY_DIRS})

  347. 

  348.   dpf__add_static_library(dgl-cairo STATIC

  349.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  350.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  351.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  352.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  353.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  354.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  355.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  356.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  357.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  358.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  359.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  360.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  361.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  362.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  363.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  364.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  365.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  366.   if(NOT APPLE)

  367.     target_sources(dgl-cairo PRIVATE

  368.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  369.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  370.     #target_sources(dgl-opengl PRIVATE

  371.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  372.   endif()

  373.   target_include_directories(dgl-cairo PUBLIC

  374.     "${DPF_ROOT_DIR}/dgl")

  375.   target_include_directories(dgl-cairo PUBLIC

  376.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  377. 

  378.   dpf__add_dgl_system_libs()

  379.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  380. 

  381.   add_library(dgl-cairo-definitions INTERFACE)

  382.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  383. 

  384.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  385.   if(MINGW)

  386.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  387.   else()

  388.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  389.   endif()

  390.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  391. endfunction()

  392. 

  393. # dpf__add_dgl_opengl

  394. # ------------------------------------------------------------------------------

  395. #

  396. # Add the OpenGL variant of DGL, if not already available.

  397. #

  398. function(dpf__add_dgl_opengl)

  399.   if(TARGET dgl-opengl)

  400.     return()

  401.   endif()

  402. 

  403.   if(NOT OpenGL_GL_PREFERENCE)

  404.     set(OpenGL_GL_PREFERENCE "LEGACY")

  405.   endif()

  406. 

  407.   find_package(OpenGL REQUIRED)

  408. 

  409.   dpf__add_static_library(dgl-opengl STATIC

  410.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  411.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  412.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  413.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  414.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  415.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  416.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  417.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  418.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  419.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  420.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  421.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  422.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  423.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  424.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  425.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  426.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  427.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  428.   if(NOT APPLE)

  429.     target_sources(dgl-opengl PRIVATE

  430.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  431.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  432.     #target_sources(dgl-opengl PRIVATE

  433.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  434.   endif()

  435.   target_include_directories(dgl-opengl PUBLIC

  436.     "${DPF_ROOT_DIR}/dgl")

  437.   target_include_directories(dgl-opengl PUBLIC

  438.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  439. 

  440.   if(APPLE)

  441.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  442.   endif()

  443. 

  444.   dpf__add_dgl_system_libs()

  445.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  446. 

  447.   add_library(dgl-opengl-definitions INTERFACE)

  448.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  449. 

  450.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  451.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  452. endfunction()

  453. 

  454. # dpf__add_plugin_specific_ui_sources

  455. # ------------------------------------------------------------------------------

  456. #

  457. # Compile plugin-specific UI sources into the target designated by the given

  458. # name. There are some special considerations here:

  459. # - On most platforms, sources can be compiled only once, as part of DGL;

  460. # - On macOS, for any sources which define Objective-C interfaces, these must

  461. #   be recompiled for each plugin under a unique namespace. In this case, the

  462. #   name must be a plugin-specific identifier, and it will be used for computing

  463. #   the unique ID along with the project version.

  464. function(dpf__add_plugin_specific_ui_sources NAME)

  465.   if(APPLE)

  466.     target_sources("${NAME}" PRIVATE

  467.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  468.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  469.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  470.   endif()

  471. endfunction()

  472. 

  473. # dpf__add_dgl_system_libs

  474. # ------------------------------------------------------------------------------

  475. #

  476. # Find system libraries required by DGL and add them as an interface target.

  477. #

  478. function(dpf__add_dgl_system_libs)

  479.   if(TARGET dgl-system-libs)

  480.     return()

  481.   endif()

  482.   add_library(dgl-system-libs INTERFACE)

  483.   add_library(dgl-system-libs-definitions INTERFACE)

  484.   if(HAIKU)

  485.     target_link_libraries(dgl-system-libs INTERFACE "be")

  486.   elseif(WIN32)

  487.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  488.   elseif(APPLE)

  489.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  490.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  491.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  492.   else()

  493.     find_package(X11 REQUIRED)

  494.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  495.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  496.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  497.     if(X11_Xext_FOUND)

  498.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  499.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  500.     endif()

  501.     if(X11_XSync_FOUND)

  502.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  503.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  504.     endif()

  505.     if(X11_Xrandr_FOUND)

  506.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  507.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  508.     endif()

  509.     #if(X11_Xcursor_FOUND)

  510.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  511.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  512.     #endif()

  513.    endif()

  514. 

  515.    if(MSVC)

  516.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  517.      foreach(_gl_header "glext.h")

  518.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  519.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  520.        endif()

  521.      endforeach()

  522.      foreach(_khr_header "khrplatform.h")

  523.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  524.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  525.        endif()

  526.      endforeach()

  527.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  528.    endif()

  529. 

  530.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  531. endfunction()

  532. 

  533. # dpf__add_executable

  534. # ------------------------------------------------------------------------------

  535. #

  536. # Adds an executable target, and set some default properties on the target.

  537. #

  538. function(dpf__add_executable NAME)

  539.   add_executable("${NAME}" ${ARGN})

  540.   dpf__set_target_defaults("${NAME}")

  541.   if(MINGW)

  542.     target_link_libraries("${NAME}" PRIVATE "-static")

  543.   endif()

  544. endfunction()

  545. 

  546. # dpf__add_module

  547. # ------------------------------------------------------------------------------

  548. #

  549. # Adds a module target, and set some default properties on the target.

  550. #

  551. function(dpf__add_module NAME)

  552.   add_library("${NAME}" MODULE ${ARGN})

  553.   dpf__set_target_defaults("${NAME}")

  554.   if(MINGW)

  555.     target_link_libraries("${NAME}" PRIVATE "-static")

  556.   endif()

  557. endfunction()

  558. 

  559. # dpf__add_static_library

  560. # ------------------------------------------------------------------------------

  561. #

  562. # Adds a static library target, and set some default properties on the target.

  563. #

  564. function(dpf__add_static_library NAME)

  565.   add_library("${NAME}" STATIC ${ARGN})

  566.   dpf__set_target_defaults("${NAME}")

  567. endfunction()

  568. 

  569. # dpf__set_target_defaults

  570. # ------------------------------------------------------------------------------

  571. #

  572. # Set default properties which must apply to all DPF-defined targets.

  573. #

  574. function(dpf__set_target_defaults NAME)

  575.   set_target_properties("${NAME}" PROPERTIES

  576.     POSITION_INDEPENDENT_CODE TRUE

  577.     C_VISIBILITY_PRESET "hidden"

  578.     CXX_VISIBILITY_PRESET "hidden"

  579.     VISIBILITY_INLINES_HIDDEN TRUE)

  580.   if(WIN32)

  581.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  582.   endif()

  583.   if (MINGW)

  584.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  585.   endif()

  586.   if (MSVC)

  587.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  588.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  589.   endif()

  590. endfunction()

  591. 

  592. # dpf__add_plugin_main

  593. # ------------------------------------------------------------------------------

  594. #

  595. # Adds plugin code to the given target.

  596. #

  597. function(dpf__add_plugin_main NAME TARGET)

  598.   target_sources("${NAME}" PRIVATE

  599.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  600.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  601. endfunction()

  602. 

  603. # dpf__add_ui_main

  604. # ------------------------------------------------------------------------------

  605. #

  606. # Adds UI code to the given target (only if the target has UI).

  607. #

  608. function(dpf__add_ui_main NAME TARGET HAS_UI)

  609.   if(HAS_UI)

  610.     target_sources("${NAME}" PRIVATE

  611.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  612.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  613.   endif()

  614. endfunction()

  615. 

  616. # dpf__add_plugin_target_definition

  617. # ------------------------------------------------------------------------------

  618. #

  619. # Adds the plugins target macro definition.

  620. # This selects which entry file is compiled according to the target type.

  621. #

  622. function(dpf__add_plugin_target_definition NAME TARGET)

  623.   string(TOUPPER "${TARGET}" _upperTarget)

  624.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  625. endfunction()

  626. 

  627. # dpf__add_lv2_ttl_generator

  628. # ------------------------------------------------------------------------------

  629. #

  630. # Build the LV2 TTL generator.

  631. #

  632. function(dpf__add_lv2_ttl_generator)

  633.   if(TARGET lv2_ttl_generator)

  634.     return()

  635.   endif()

  636.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  637.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  638.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  639.   endif()

  640. endfunction()

  641. 

  642. # dpf__ensure_sources_non_empty

  643. # ------------------------------------------------------------------------------

  644. #

  645. # Ensure the given source list contains at least one file.

  646. # The function appends an empty source file to the list if necessary.

  647. # This is useful when CMake does not permit to add targets without sources.

  648. #

  649. function(dpf__ensure_sources_non_empty VAR)

  650.   if(NOT "" STREQUAL "${${VAR}}")

  651.     return()

  652.   endif()

  653.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  654.   if(NOT EXISTS "${_file}")

  655.     file(WRITE "${_file}" "")

  656.   endif()

  657.   set("${VAR}" "${_file}" PARENT_SCOPE)

  658. endfunction()

  659. 

  660. # dpf__create_dummy_source_list

  661. # ------------------------------------------------------------------------------

  662. #

  663. # Create a dummy source list which is equivalent to compiling nothing.

  664. # This is only for compatibility with older CMake versions, which refuse to add

  665. # targets without any sources.

  666. #

  667. macro(dpf__create_dummy_source_list VAR)

  668.   set("${VAR}")

  669.   if(CMAKE_VERSION VERSION_LESS "3.11")

  670.     dpf__ensure_sources_non_empty("${VAR}")

  671.   endif()

  672. endmacro()

  673. 

  674. # dpf__warn_once

  675. # ------------------------------------------------------------------------------

  676. #

  677. # Prints a warning message once only.

  678. #

  679. function(dpf__warn_once_only TOKEN MESSAGE)

  680.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  681.   if(NOT _warned)

  682.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  683.     message(WARNING "${MESSAGE}")

  684.   endif()

  685. endfunction()