DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1055 Commits
7 Branches
91MB
Tree: 9421c3d39a
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '9421c3d39a'
${ noResults }
DPF/cmake/DPF-plugin.cmake

575 lines
19KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC "${_dgl_library}-definitions")

  128.   endif()

  129. 

  130.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  131.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  132. 

  133.   if(_dgl_library)

  134.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  135.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  136.   else()

  137.     add_library("${NAME}-ui" INTERFACE)

  138.   endif()

  139. 

  140.   ###

  141.   foreach(_target ${_dpf_plugin_TARGETS})

  142.     if(_target STREQUAL "jack")

  143.       dpf__build_jack("${NAME}" "${_dgl_library}")

  144.     elseif(_target STREQUAL "ladspa")

  145.       dpf__build_ladspa("${NAME}")

  146.     elseif(_target STREQUAL "dssi")

  147.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "lv2")

  149.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  150.     elseif(_target STREQUAL "vst2")

  151.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  152.     else()

  153.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  154.     endif()

  155.   endforeach()

  156. endfunction()

  157. 

  158. # ------------------------------------------------------------------------------

  159. # DPF private functions (prefixed with `dpf__`)

  160. # ------------------------------------------------------------------------------

  161. 

  162. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  163. #       to the output directory.

  164. #

  165. 

  166. # dpf__build_jack

  167. # ------------------------------------------------------------------------------

  168. #

  169. # Add build rules for a JACK program.

  170. #

  171. function(dpf__build_jack NAME DGL_LIBRARY)

  172.   find_package(PkgConfig)

  173.   pkg_check_modules(JACK "jack")

  174.   if(NOT JACK_FOUND)

  175.     dpf__warn_once_only(missing_jack

  176.       "JACK is not found, skipping the `jack` plugin targets")

  177.     return()

  178.   endif()

  179. 

  180.   link_directories(${JACK_LIBRARY_DIRS})

  181. 

  182.   dpf__create_dummy_source_list(_no_srcs)

  183. 

  184.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  185.   dpf__add_plugin_main("${NAME}-jack" "jack")

  186.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  187.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  188.   set_target_properties("${NAME}-jack" PROPERTIES

  189.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  190.     OUTPUT_NAME "${NAME}")

  191. 

  192.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  193.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  194. endfunction()

  195. 

  196. # dpf__build_ladspa

  197. # ------------------------------------------------------------------------------

  198. #

  199. # Add build rules for a DSSI plugin.

  200. #

  201. function(dpf__build_ladspa NAME)

  202.   dpf__create_dummy_source_list(_no_srcs)

  203. 

  204.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  205.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  206.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  207.   set_target_properties("${NAME}-ladspa" PROPERTIES

  208.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  209.     OUTPUT_NAME "${NAME}-ladspa"

  210.     PREFIX "")

  211. endfunction()

  212. 

  213. # dpf__build_dssi

  214. # ------------------------------------------------------------------------------

  215. #

  216. # Add build rules for a DSSI plugin.

  217. #

  218. function(dpf__build_dssi NAME DGL_LIBRARY)

  219.   find_package(PkgConfig)

  220.   pkg_check_modules(LIBLO "liblo")

  221.   if(NOT LIBLO_FOUND)

  222.     dpf__warn_once_only(missing_liblo

  223.       "liblo is not found, skipping the `dssi` plugin targets")

  224.     return()

  225.   endif()

  226. 

  227.   link_directories(${LIBLO_LIBRARY_DIRS})

  228. 

  229.   dpf__create_dummy_source_list(_no_srcs)

  230. 

  231.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  232.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  233.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  234.   set_target_properties("${NAME}-dssi" PROPERTIES

  235.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  236.     OUTPUT_NAME "${NAME}-dssi"

  237.     PREFIX "")

  238. 

  239.   if(DGL_LIBRARY)

  240.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  241.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  242.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  243.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  244.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  245.       OUTPUT_NAME "${NAME}_ui")

  246. 

  247.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  248.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  249.   endif()

  250. endfunction()

  251. 

  252. # dpf__build_lv2

  253. # ------------------------------------------------------------------------------

  254. #

  255. # Add build rules for a LV2 plugin.

  256. #

  257. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  258.   dpf__create_dummy_source_list(_no_srcs)

  259. 

  260.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  261.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  262.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  263.   set_target_properties("${NAME}-lv2" PROPERTIES

  264.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  265.     OUTPUT_NAME "${NAME}_dsp"

  266.     PREFIX "")

  267. 

  268.   if(DGL_LIBRARY)

  269.     if(MONOLITHIC)

  270.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  271.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  272.       set_target_properties("${NAME}-lv2" PROPERTIES

  273.         OUTPUT_NAME "${NAME}")

  274.     else()

  275.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  276.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  277.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  278.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  279.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  280.         OUTPUT_NAME "${NAME}_ui"

  281.         PREFIX "")

  282.     endif()

  283.   endif()

  284. 

  285.   dpf__add_lv2_ttl_generator()

  286.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  287. 

  288.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  289.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  290.     "$<TARGET_FILE:lv2_ttl_generator>"

  291.     "$<TARGET_FILE:${NAME}-lv2>"

  292.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  293. endfunction()

  294. 

  295. # dpf__build_vst2

  296. # ------------------------------------------------------------------------------

  297. #

  298. # Add build rules for a VST2 plugin.

  299. #

  300. function(dpf__build_vst2 NAME DGL_LIBRARY)

  301.   dpf__create_dummy_source_list(_no_srcs)

  302. 

  303.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  304.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  305.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  306.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  307.   set_target_properties("${NAME}-vst2" PROPERTIES

  308.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  309.     OUTPUT_NAME "${NAME}-vst2"

  310.     PREFIX "")

  311. endfunction()

  312. 

  313. # dpf__add_dgl_cairo

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add the Cairo variant of DGL, if not already available.

  317. #

  318. function(dpf__add_dgl_cairo)

  319.   if(TARGET dgl-cairo)

  320.     return()

  321.   endif()

  322. 

  323.   find_package(PkgConfig)

  324.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  325. 

  326.   link_directories(${CAIRO_LIBRARY_DIRS})

  327. 

  328.   dpf__add_static_library(dgl-cairo STATIC

  329.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  330.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  331.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  333.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  337.   if(NOT APPLE)

  338.     target_sources(dgl-cairo PRIVATE

  339.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  340.   else()

  341.     target_sources(dgl-cairo PRIVATE

  342.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  343.   endif()

  344.   target_include_directories(dgl-cairo PUBLIC

  345.     "${DPF_ROOT_DIR}/dgl")

  346. 

  347.   dpf__add_dgl_system_libs()

  348.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  349. 

  350.   add_library(dgl-cairo-definitions INTERFACE)

  351.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  352. 

  353.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  354.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  355. endfunction()

  356. 

  357. # dpf__add_dgl_opengl

  358. # ------------------------------------------------------------------------------

  359. #

  360. # Add the OpenGL variant of DGL, if not already available.

  361. #

  362. function(dpf__add_dgl_opengl)

  363.   if(TARGET dgl-opengl)

  364.     return()

  365.   endif()

  366. 

  367.   if(NOT OpenGL_GL_PREFERENCE)

  368.     set(OpenGL_GL_PREFERENCE "LEGACY")

  369.   endif()

  370. 

  371.   find_package(OpenGL REQUIRED)

  372. 

  373.   dpf__add_static_library(dgl-opengl STATIC

  374.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  375.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  376.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  377.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  378.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  379.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  380.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  381.     "${DPF_ROOT_DIR}/dgl/src/Image.cpp"

  382.     "${DPF_ROOT_DIR}/dgl/src/ImageWidgets.cpp"

  383.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp"

  384.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  385.   if(NOT APPLE)

  386.     target_sources(dgl-opengl PRIVATE

  387.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  388.   else()

  389.     target_sources(dgl-opengl PRIVATE

  390.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  391.   endif()

  392.   target_include_directories(dgl-opengl PUBLIC

  393.     "${DPF_ROOT_DIR}/dgl")

  394. 

  395.   dpf__add_dgl_system_libs()

  396.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  397. 

  398.   add_library(dgl-opengl-definitions INTERFACE)

  399.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  400. 

  401.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  402.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  403. endfunction()

  404. 

  405. # dpf__add_dgl_system_libs

  406. # ------------------------------------------------------------------------------

  407. #

  408. # Find system libraries required by DGL and add them as an interface target.

  409. #

  410. function(dpf__add_dgl_system_libs)

  411.   if(TARGET dgl-system-libs)

  412.     return()

  413.   endif()

  414.   add_library(dgl-system-libs INTERFACE)

  415.   if(HAIKU)

  416.     target_link_libraries(dgl-system-libs INTERFACE "be")

  417.   elseif(WIN32)

  418.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  419.   elseif(APPLE)

  420.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  421.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}")

  422.   else()

  423.     find_package(X11 REQUIRED)

  424.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  425.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  426.   endif()

  427. endfunction()

  428. 

  429. # dpf__add_executable

  430. # ------------------------------------------------------------------------------

  431. #

  432. # Adds an executable target, and set some default properties on the target.

  433. #

  434. function(dpf__add_executable NAME)

  435.   add_executable("${NAME}" ${ARGN})

  436.   set_target_properties("${NAME}" PROPERTIES

  437.     POSITION_INDEPENDENT_CODE TRUE

  438.     C_VISIBILITY_PRESET "hidden"

  439.     CXX_VISIBILITY_PRESET "hidden"

  440.     VISIBILITY_INLINES_HIDDEN TRUE)

  441. endfunction()

  442. 

  443. # dpf__add_module

  444. # ------------------------------------------------------------------------------

  445. #

  446. # Adds a module target, and set some default properties on the target.

  447. #

  448. function(dpf__add_module NAME)

  449.   add_library("${NAME}" MODULE ${ARGN})

  450.   set_target_properties("${NAME}" PROPERTIES

  451.     POSITION_INDEPENDENT_CODE TRUE

  452.     C_VISIBILITY_PRESET "hidden"

  453.     CXX_VISIBILITY_PRESET "hidden"

  454.     VISIBILITY_INLINES_HIDDEN TRUE)

  455.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  456.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  457.   endif()

  458. endfunction()

  459. 

  460. # dpf__add_static_library

  461. # ------------------------------------------------------------------------------

  462. #

  463. # Adds a static library target, and set some default properties on the target.

  464. #

  465. function(dpf__add_static_library NAME)

  466.   add_library("${NAME}" STATIC ${ARGN})

  467.   set_target_properties("${NAME}" PROPERTIES

  468.     POSITION_INDEPENDENT_CODE TRUE

  469.     C_VISIBILITY_PRESET "hidden"

  470.     CXX_VISIBILITY_PRESET "hidden"

  471.     VISIBILITY_INLINES_HIDDEN TRUE)

  472. endfunction()

  473. 

  474. # dpf__add_plugin_main

  475. # ------------------------------------------------------------------------------

  476. #

  477. # Adds plugin code to the given target.

  478. #

  479. function(dpf__add_plugin_main NAME TARGET)

  480.   target_sources("${NAME}" PRIVATE

  481.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  482.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  483. endfunction()

  484. 

  485. # dpf__add_ui_main

  486. # ------------------------------------------------------------------------------

  487. #

  488. # Adds UI code to the given target (only if the target has UI).

  489. #

  490. function(dpf__add_ui_main NAME TARGET HAS_UI)

  491.   if(HAS_UI)

  492.     target_sources("${NAME}" PRIVATE

  493.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  494.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  495.   endif()

  496. endfunction()

  497. 

  498. # dpf__add_plugin_target_definition

  499. # ------------------------------------------------------------------------------

  500. #

  501. # Adds the plugins target macro definition.

  502. # This selects which entry file is compiled according to the target type.

  503. #

  504. function(dpf__add_plugin_target_definition NAME TARGET)

  505.   string(TOUPPER "${TARGET}" _upperTarget)

  506. 

  507.   # resolve the alias into the proper name

  508.   # the name "vst2" is new, "vst" is legacy

  509.   if(_upperTarget STREQUAL "VST2")

  510.     set(_upperTarget "VST")

  511.   endif()

  512. 

  513.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  514. endfunction()

  515. 

  516. # dpf__add_lv2_ttl_generator

  517. # ------------------------------------------------------------------------------

  518. #

  519. # Build the LV2 TTL generator.

  520. #

  521. function(dpf__add_lv2_ttl_generator)

  522.   if(TARGET lv2_ttl_generator)

  523.     return()

  524.   endif()

  525.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  526.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  527.     target_link_libraries(lv2_ttl_generator "dl")

  528.   endif()

  529. endfunction()

  530. 

  531. # dpf__ensure_sources_non_empty

  532. # ------------------------------------------------------------------------------

  533. #

  534. # Ensure the given source list contains at least one file.

  535. # The function appends an empty source file to the list if necessary.

  536. # This is useful when CMake does not permit to add targets without sources.

  537. #

  538. function(dpf__ensure_sources_non_empty VAR)

  539.   if(NOT "" STREQUAL "${${VAR}}")

  540.     return()

  541.   endif()

  542.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  543.   if(NOT EXISTS "${_file}")

  544.     file(WRITE "${_file}" "")

  545.   endif()

  546.   set("${VAR}" "${_file}" PARENT_SCOPE)

  547. endfunction()

  548. 

  549. # dpf__create_dummy_source_list

  550. # ------------------------------------------------------------------------------

  551. #

  552. # Create a dummy source list which is equivalent to compiling nothing.

  553. # This is only for compatibility with older CMake versions, which refuse to add

  554. # targets without any sources.

  555. #

  556. macro(dpf__create_dummy_source_list VAR)

  557.   set("${VAR}")

  558.   if(CMAKE_VERSION VERSION_LESS "3.11")

  559.     dpf__ensure_sources_non_empty("${VAR}")

  560.   endif()

  561. endmacro()

  562. 

  563. # dpf__warn_once

  564. # ------------------------------------------------------------------------------

  565. #

  566. # Prints a warning message once only.

  567. #

  568. function(dpf__warn_once_only TOKEN MESSAGE)

  569.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  570.   if(NOT _warned)

  571.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  572.     message(WARNING "${MESSAGE}")

  573.   endif()

  574. endfunction()