DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2034 Commits
6 Branches
56MB
Tree: 93cf1535a4
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '93cf1535a4'
${ noResults }
DPF/cmake/DPF-plugin.cmake

895 lines
32KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`

  79. #

  80. #   `MONOLITHIC`

  81. #       build LV2 as a single binary for UI and DSP

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `FILES_COMMON` <file1>...<fileN>

  91. #       list of sources which are part of both DSP and UI

  92. #

  93. function(dpf_add_plugin NAME)

  94.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  95.   set(oneValueArgs UI_TYPE)

  96.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  97.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  98. 

  99.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  100.     set(_dpf_plugin_UI_TYPE "opengl")

  101.   endif()

  102. 

  103.   set(_dgl_library)

  104.   if(_dpf_plugin_FILES_UI)

  105.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  106.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  107.       set(_dgl_library dgl-cairo)

  108.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  109.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  110.       set(_dgl_library dgl-opengl)

  111.     else()

  112.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  113.     endif()

  114.   endif()

  115. 

  116.   ###

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  119.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  120. 

  121.   ###

  122.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  123.   target_include_directories("${NAME}" PUBLIC

  124.     "${DPF_ROOT_DIR}/distrho")

  125. 

  126.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  127.     target_link_libraries("${NAME}" PRIVATE "dl")

  128.   endif()

  129. 

  130.   if(_dgl_library)

  131.     # make sure that all code will see DGL_* definitions

  132.     target_link_libraries("${NAME}" PUBLIC

  133.       "${_dgl_library}-definitions"

  134.       dgl-system-libs-definitions)

  135.   endif()

  136. 

  137.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  138.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  139. 

  140.   if(_dgl_library)

  141.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  142.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  143.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  144.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  145.     endif()

  146.     # add the files containing Objective-C classes

  147.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  148.   else()

  149.     add_library("${NAME}-ui" INTERFACE)

  150.   endif()

  151. 

  152.   ###

  153.   foreach(_target ${_dpf_plugin_TARGETS})

  154.     if(_target STREQUAL "jack")

  155.       dpf__build_jack("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "ladspa")

  157.       dpf__build_ladspa("${NAME}")

  158.     elseif(_target STREQUAL "dssi")

  159.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  160.     elseif(_target STREQUAL "lv2")

  161.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  162.     elseif(_target STREQUAL "vst2")

  163.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  164.     elseif(_target STREQUAL "vst3")

  165.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  166.     elseif(_target STREQUAL "clap")

  167.       dpf__build_clap("${NAME}" "${_dgl_library}")

  168.     else()

  169.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  170.     endif()

  171.   endforeach()

  172. endfunction()

  173. 

  174. # ------------------------------------------------------------------------------

  175. # DPF private functions (prefixed with `dpf__`)

  176. # ------------------------------------------------------------------------------

  177. 

  178. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  179. #       to the output directory.

  180. #

  181. 

  182. # dpf__build_jack

  183. # ------------------------------------------------------------------------------

  184. #

  185. # Add build rules for a JACK/Standalone program.

  186. #

  187. function(dpf__build_jack NAME DGL_LIBRARY)

  188.   dpf__create_dummy_source_list(_no_srcs)

  189. 

  190.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  191.   dpf__add_plugin_main("${NAME}-jack" "jack")

  192.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  193.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  194.   set_target_properties("${NAME}-jack" PROPERTIES

  195.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  196.     OUTPUT_NAME "${NAME}")

  197. 

  198.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  199. 

  200.   find_package(PkgConfig)

  201.   pkg_check_modules(SDL2 "sdl2")

  202.   if(SDL2_FOUND)

  203.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  204.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  205.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  206.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  207.   endif()

  208. 

  209.   if(APPLE OR WIN32)

  210.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  211.   else()

  212.     find_package(Threads)

  213.     pkg_check_modules(ALSA "alsa")

  214.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  215.     if(ALSA_FOUND)

  216.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  217.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  218.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  219.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  220.     endif()

  221.     if(PULSEAUDIO_FOUND)

  222.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  223.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  224.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  225.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  226.     endif()

  227.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  228.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  229.     endif()

  230.   endif()

  231. 

  232.   # for RtAudio native fallback

  233.   if(APPLE)

  234.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  235.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  236.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  237.     target_link_libraries("${NAME}-jack" PRIVATE

  238.       "${APPLE_COREAUDIO_FRAMEWORK}"

  239.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  240.       "${APPLE_COREMIDI_FRAMEWORK}")

  241.   endif()

  242. endfunction()

  243. 

  244. # dpf__build_ladspa

  245. # ------------------------------------------------------------------------------

  246. #

  247. # Add build rules for a LADSPA plugin.

  248. #

  249. function(dpf__build_ladspa NAME)

  250.   dpf__create_dummy_source_list(_no_srcs)

  251. 

  252.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  253.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  254.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  255.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  256.   set_target_properties("${NAME}-ladspa" PROPERTIES

  257.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  258.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  259.     OUTPUT_NAME "${NAME}-ladspa"

  260.     PREFIX "")

  261. endfunction()

  262. 

  263. # dpf__build_dssi

  264. # ------------------------------------------------------------------------------

  265. #

  266. # Add build rules for a DSSI plugin.

  267. #

  268. function(dpf__build_dssi NAME DGL_LIBRARY)

  269.   find_package(PkgConfig)

  270.   pkg_check_modules(LIBLO "liblo")

  271.   if(NOT LIBLO_FOUND)

  272.     dpf__warn_once_only(missing_liblo

  273.       "liblo is not found, skipping the `dssi` plugin targets")

  274.     return()

  275.   endif()

  276. 

  277.   dpf__create_dummy_source_list(_no_srcs)

  278. 

  279.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  280.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  281.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  282.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  283.   set_target_properties("${NAME}-dssi" PROPERTIES

  284.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  285.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  286.     OUTPUT_NAME "${NAME}-dssi"

  287.     PREFIX "")

  288. 

  289.   if(DGL_LIBRARY)

  290.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  291.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  292.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  293.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  294.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  295.       OUTPUT_NAME "${NAME}_ui")

  296. 

  297.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  298.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  299.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  300.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  301.   endif()

  302. endfunction()

  303. 

  304. # dpf__build_lv2

  305. # ------------------------------------------------------------------------------

  306. #

  307. # Add build rules for an LV2 plugin.

  308. #

  309. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  310.   dpf__create_dummy_source_list(_no_srcs)

  311. 

  312.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  313.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  314.   if(DGL_LIBRARY AND MONOLITHIC)

  315.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  316.   else()

  317.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  318.   endif()

  319.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  320.   set_target_properties("${NAME}-lv2" PROPERTIES

  321.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  322.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  323.     OUTPUT_NAME "${NAME}_dsp"

  324.     PREFIX "")

  325. 

  326.   if(DGL_LIBRARY)

  327.     if(MONOLITHIC)

  328.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  329.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  330.       set_target_properties("${NAME}-lv2" PROPERTIES

  331.         OUTPUT_NAME "${NAME}")

  332.     else()

  333.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  334.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  335.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  336.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  337.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  338.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  339.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  340.         OUTPUT_NAME "${NAME}_ui"

  341.         PREFIX "")

  342.     endif()

  343.   endif()

  344. 

  345.   dpf__add_lv2_ttl_generator()

  346.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  347. 

  348.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  349.     COMMAND

  350.     "$<TARGET_FILE:lv2_ttl_generator>"

  351.     "$<TARGET_FILE:${NAME}-lv2>"

  352.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  353.     DEPENDS lv2_ttl_generator)

  354. endfunction()

  355. 

  356. # dpf__build_vst2

  357. # ------------------------------------------------------------------------------

  358. #

  359. # Add build rules for a VST2 plugin.

  360. #

  361. function(dpf__build_vst2 NAME DGL_LIBRARY)

  362.   dpf__create_dummy_source_list(_no_srcs)

  363. 

  364.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  365.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  366.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  367.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  368.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  369.   set_target_properties("${NAME}-vst2" PROPERTIES

  370.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  371.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  372.     OUTPUT_NAME "${NAME}-vst2"

  373.     PREFIX "")

  374.   if(APPLE)

  375.     set_target_properties("${NAME}-vst2" PROPERTIES

  376.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  377.       OUTPUT_NAME "${NAME}"

  378.       SUFFIX "")

  379.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  380.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  381.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  382.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  383.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  384.   endif()

  385. endfunction()

  386. 

  387. # dpf__determine_vst3_package_architecture

  388. # ------------------------------------------------------------------------------

  389. #

  390. # Determines the package architecture for a VST3 plugin target.

  391. #

  392. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  393.   # if set by variable, override the detection

  394.   if(DPF_VST3_ARCHITECTURE)

  395.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  396.     return()

  397.   endif()

  398. 

  399.   # not used on Apple, which supports universal binary

  400.   if(APPLE)

  401.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  402.     return()

  403.   endif()

  404. 

  405.   # identify the target processor (special case of MSVC, problematic sometimes)

  406.   if(MSVC)

  407.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  408.   else()

  409.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  410.   endif()

  411. 

  412.   # transform the processor name to a format that VST3 recognizes

  413.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  414.     set(vst3_package_arch "x86_64")

  415.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  416.     if(WIN32)

  417.       set(vst3_package_arch "x86")

  418.     else()

  419.       set(vst3_package_arch "i386")

  420.     endif()

  421.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  422.     set(vst3_package_arch "${vst3_system_arch}")

  423.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  424.     set(vst3_package_arch "aarch64")

  425.   else()

  426.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  427.   endif()

  428. 

  429.   # TODO: the detections for Windows arm/arm64 when supported

  430. 

  431.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  432. endfunction()

  433. 

  434. # dpf__build_vst3

  435. # ------------------------------------------------------------------------------

  436. #

  437. # Add build rules for a VST3 plugin.

  438. #

  439. function(dpf__build_vst3 NAME DGL_LIBRARY)

  440.   dpf__determine_vst3_package_architecture(vst3_arch)

  441. 

  442.   dpf__create_dummy_source_list(_no_srcs)

  443. 

  444.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  445.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  446.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  447.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  448.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  449.   set_target_properties("${NAME}-vst3" PROPERTIES

  450.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  451.     OUTPUT_NAME "${NAME}"

  452.     PREFIX "")

  453. 

  454.   if(APPLE)

  455.     set_target_properties("${NAME}-vst3" PROPERTIES

  456.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  457.       SUFFIX "")

  458.   elseif(WIN32)

  459.     set_target_properties("${NAME}-vst3" PROPERTIES

  460.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  461.   else()

  462.     set_target_properties("${NAME}-vst3" PROPERTIES

  463.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  464.   endif()

  465. 

  466.   if(APPLE)

  467.     # Uses the same macOS bundle template as VST2

  468.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  469.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  470.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  471.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  472.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  473.   endif()

  474. endfunction()

  475. 

  476. # dpf__build_clap

  477. # ------------------------------------------------------------------------------

  478. #

  479. # Add build rules for a VST2 plugin.

  480. #

  481. function(dpf__build_clap NAME DGL_LIBRARY)

  482.   dpf__create_dummy_source_list(_no_srcs)

  483. 

  484.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  485.   dpf__add_plugin_main("${NAME}-clap" "clap")

  486.   dpf__add_ui_main("${NAME}-clap" "clap" "${DGL_LIBRARY}")

  487.   dpf__set_module_export_list("${NAME}-clap" "clap")

  488.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  489.   set_target_properties("${NAME}-clap" PROPERTIES

  490.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  491.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  492.     OUTPUT_NAME "${NAME}"

  493.     PREFIX ""

  494.     SUFFIX ".clap")

  495. 

  496.   if(APPLE)

  497.     set_target_properties("${NAME}-clap" PROPERTIES

  498.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  499.       OUTPUT_NAME "${NAME}"

  500.       SUFFIX "")

  501.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  502.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  503.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  504.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  505.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  506.   endif()

  507. endfunction()

  508. 

  509. # dpf__add_dgl_cairo

  510. # ------------------------------------------------------------------------------

  511. #

  512. # Add the Cairo variant of DGL, if not already available.

  513. #

  514. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  515.   if(TARGET dgl-cairo)

  516.     return()

  517.   endif()

  518. 

  519.   find_package(PkgConfig)

  520.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  521. 

  522.   link_directories(${CAIRO_LIBRARY_DIRS})

  523. 

  524.   dpf__add_static_library(dgl-cairo STATIC

  525.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  526.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  528.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  530.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  531.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  532.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  533.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  534.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  535.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  536.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  537.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  538.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  539.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  540.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  541.   if(NO_SHARED_RESOURCES)

  542.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  543.   else()

  544.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  545.   endif()

  546.   if(NOT APPLE)

  547.     target_sources(dgl-cairo PRIVATE

  548.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  549.   else()

  550.     target_sources(dgl-cairo PRIVATE

  551.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  552.   endif()

  553.   target_include_directories(dgl-cairo PUBLIC

  554.     "${DPF_ROOT_DIR}/dgl")

  555.   target_include_directories(dgl-cairo PUBLIC

  556.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  557. 

  558.   dpf__add_dgl_system_libs()

  559.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  560. 

  561.   add_library(dgl-cairo-definitions INTERFACE)

  562.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  563. 

  564.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  565.   if(MINGW)

  566.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  567.   else()

  568.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  569.   endif()

  570.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  571. endfunction()

  572. 

  573. # dpf__add_dgl_opengl

  574. # ------------------------------------------------------------------------------

  575. #

  576. # Add the OpenGL variant of DGL, if not already available.

  577. #

  578. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  579.   if(TARGET dgl-opengl)

  580.     return()

  581.   endif()

  582. 

  583.   if(NOT OpenGL_GL_PREFERENCE)

  584.     set(OpenGL_GL_PREFERENCE "LEGACY")

  585.   endif()

  586. 

  587.   find_package(OpenGL REQUIRED)

  588. 

  589.   dpf__add_static_library(dgl-opengl STATIC

  590.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  591.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  592.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  593.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  594.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  595.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  596.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  597.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  598.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  599.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  600.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  601.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  602.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  603.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  604.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  605.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  606.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  607.   if(NO_SHARED_RESOURCES)

  608.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  609.   else()

  610.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  611.   endif()

  612.   if(NOT APPLE)

  613.     target_sources(dgl-opengl PRIVATE

  614.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  615.   else()

  616.     target_sources(dgl-opengl PRIVATE

  617.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  618.   endif()

  619.   target_include_directories(dgl-opengl PUBLIC

  620.     "${DPF_ROOT_DIR}/dgl")

  621.   target_include_directories(dgl-opengl PUBLIC

  622.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  623. 

  624.   if(APPLE)

  625.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  626.   endif()

  627. 

  628.   dpf__add_dgl_system_libs()

  629.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  630. 

  631.   add_library(dgl-opengl-definitions INTERFACE)

  632.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  633. 

  634.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  635.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  636. endfunction()

  637. 

  638. # dpf__add_plugin_specific_ui_sources

  639. # ------------------------------------------------------------------------------

  640. #

  641. # Compile system specific files, for now it is just Objective-C code

  642. #

  643. function(dpf__add_plugin_specific_ui_sources NAME)

  644.   if(APPLE)

  645.     target_sources("${NAME}" PRIVATE

  646.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  647.   endif()

  648. endfunction()

  649. 

  650. # dpf__add_dgl_system_libs

  651. # ------------------------------------------------------------------------------

  652. #

  653. # Find system libraries required by DGL and add them as an interface target.

  654. #

  655. function(dpf__add_dgl_system_libs)

  656.   if(TARGET dgl-system-libs)

  657.     return()

  658.   endif()

  659.   add_library(dgl-system-libs INTERFACE)

  660.   add_library(dgl-system-libs-definitions INTERFACE)

  661.   if(HAIKU)

  662.     target_link_libraries(dgl-system-libs INTERFACE "be")

  663.   elseif(WIN32)

  664.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  665.   elseif(APPLE)

  666.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  667.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  668.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  669.   else()

  670.     find_package(X11 REQUIRED)

  671.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  672.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  673.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  674.     if(X11_Xcursor_FOUND)

  675.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  676.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  677.     endif()

  678.     if(X11_Xext_FOUND)

  679.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  680.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  681.     endif()

  682.     if(X11_Xrandr_FOUND)

  683.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  684.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  685.     endif()

  686.     if(X11_XSync_FOUND)

  687.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  688.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  689.     endif()

  690.    endif()

  691. 

  692.    if(MSVC)

  693.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  694.      foreach(_gl_header "glext.h")

  695.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  696.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  697.        endif()

  698.      endforeach()

  699.      foreach(_khr_header "khrplatform.h")

  700.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  701.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  702.        endif()

  703.      endforeach()

  704.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  705.    endif()

  706. 

  707.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  708. endfunction()

  709. 

  710. # dpf__add_executable

  711. # ------------------------------------------------------------------------------

  712. #

  713. # Adds an executable target, and set some default properties on the target.

  714. #

  715. function(dpf__add_executable NAME)

  716.   add_executable("${NAME}" ${ARGN})

  717.   dpf__set_target_defaults("${NAME}")

  718.   if(MINGW)

  719.     target_link_libraries("${NAME}" PRIVATE "-static")

  720.   endif()

  721. endfunction()

  722. 

  723. # dpf__add_module

  724. # ------------------------------------------------------------------------------

  725. #

  726. # Adds a module target, and set some default properties on the target.

  727. #

  728. function(dpf__add_module NAME)

  729.   add_library("${NAME}" MODULE ${ARGN})

  730.   dpf__set_target_defaults("${NAME}")

  731.   if(MINGW)

  732.     target_link_libraries("${NAME}" PRIVATE "-static")

  733.   endif()

  734. endfunction()

  735. 

  736. # dpf__add_static_library

  737. # ------------------------------------------------------------------------------

  738. #

  739. # Adds a static library target, and set some default properties on the target.

  740. #

  741. function(dpf__add_static_library NAME)

  742.   add_library("${NAME}" STATIC ${ARGN})

  743.   dpf__set_target_defaults("${NAME}")

  744. endfunction()

  745. 

  746. # dpf__set_module_export_list

  747. # ------------------------------------------------------------------------------

  748. #

  749. # Applies a list of exported symbols to the module target.

  750. #

  751. function(dpf__set_module_export_list NAME EXPORTS)

  752.   if(WIN32)

  753.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  754.   elseif(APPLE)

  755.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  756.       "-Xlinker" "-exported_symbols_list"

  757.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  758.   else()

  759.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  760.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  761.   endif()

  762. endfunction()

  763. 

  764. # dpf__set_target_defaults

  765. # ------------------------------------------------------------------------------

  766. #

  767. # Set default properties which must apply to all DPF-defined targets.

  768. #

  769. function(dpf__set_target_defaults NAME)

  770.   set_target_properties("${NAME}" PROPERTIES

  771.     POSITION_INDEPENDENT_CODE TRUE

  772.     C_VISIBILITY_PRESET "hidden"

  773.     CXX_VISIBILITY_PRESET "hidden"

  774.     VISIBILITY_INLINES_HIDDEN TRUE)

  775.   if(WIN32)

  776.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  777.   endif()

  778.   if (MINGW)

  779.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  780.   endif()

  781.   if (MSVC)

  782.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  783.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  784.   endif()

  785. endfunction()

  786. 

  787. # dpf__add_plugin_main

  788. # ------------------------------------------------------------------------------

  789. #

  790. # Adds plugin code to the given target.

  791. #

  792. function(dpf__add_plugin_main NAME TARGET)

  793.   target_sources("${NAME}" PRIVATE

  794.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  795.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  796. endfunction()

  797. 

  798. # dpf__add_ui_main

  799. # ------------------------------------------------------------------------------

  800. #

  801. # Adds UI code to the given target (only if the target has UI).

  802. #

  803. function(dpf__add_ui_main NAME TARGET HAS_UI)

  804.   if(HAS_UI)

  805.     target_sources("${NAME}" PRIVATE

  806.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  807.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  808.   endif()

  809. endfunction()

  810. 

  811. # dpf__add_plugin_target_definition

  812. # ------------------------------------------------------------------------------

  813. #

  814. # Adds the plugins target macro definition.

  815. # This selects which entry file is compiled according to the target type.

  816. #

  817. function(dpf__add_plugin_target_definition NAME TARGET)

  818.   string(TOUPPER "${TARGET}" _upperTarget)

  819.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  820. endfunction()

  821. 

  822. # dpf__add_lv2_ttl_generator

  823. # ------------------------------------------------------------------------------

  824. #

  825. # Build the LV2 TTL generator.

  826. #

  827. function(dpf__add_lv2_ttl_generator)

  828.   if(TARGET lv2_ttl_generator)

  829.     return()

  830.   endif()

  831.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  832.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  833.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  834.   endif()

  835. endfunction()

  836. 

  837. # dpf__ensure_sources_non_empty

  838. # ------------------------------------------------------------------------------

  839. #

  840. # Ensure the given source list contains at least one file.

  841. # The function appends an empty source file to the list if necessary.

  842. # This is useful when CMake does not permit to add targets without sources.

  843. #

  844. function(dpf__ensure_sources_non_empty VAR)

  845.   if(NOT "" STREQUAL "${${VAR}}")

  846.     return()

  847.   endif()

  848.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  849.   if(NOT EXISTS "${_file}")

  850.     file(WRITE "${_file}" "")

  851.   endif()

  852.   set("${VAR}" "${_file}" PARENT_SCOPE)

  853. endfunction()

  854. 

  855. # dpf__create_dummy_source_list

  856. # ------------------------------------------------------------------------------

  857. #

  858. # Create a dummy source list which is equivalent to compiling nothing.

  859. # This is only for compatibility with older CMake versions, which refuse to add

  860. # targets without any sources.

  861. #

  862. macro(dpf__create_dummy_source_list VAR)

  863.   set("${VAR}")

  864.   if(CMAKE_VERSION VERSION_LESS "3.11")

  865.     dpf__ensure_sources_non_empty("${VAR}")

  866.   endif()

  867. endmacro()

  868. 

  869. # dpf__target_link_directories

  870. # ------------------------------------------------------------------------------

  871. #

  872. # Call `target_link_directories` if cmake >= 3.13,

  873. # otherwise fallback to global `link_directories`.

  874. #

  875. macro(dpf__target_link_directories NAME DIRS)

  876.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  877.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  878.   else()

  879.     link_directories(${DIRS})

  880.   endif()

  881. endmacro()

  882. 

  883. # dpf__warn_once

  884. # ------------------------------------------------------------------------------

  885. #

  886. # Prints a warning message once only.

  887. #

  888. function(dpf__warn_once_only TOKEN MESSAGE)

  889.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  890.   if(NOT _warned)

  891.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  892.     message(WARNING "${MESSAGE}")

  893.   endif()

  894. endfunction()