DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
888 Commits
7 Branches
91MB
Tree: 90c22db67a
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '90c22db67a'
${ noResults }
DPF/cmake/DPF-plugin.cmake

565 lines
18KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC "${_dgl_library}-definitions")

  128.   endif()

  129. 

  130.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  131.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  132. 

  133.   if(_dgl_library)

  134.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  135.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  136.   else()

  137.     add_library("${NAME}-ui" INTERFACE)

  138.   endif()

  139. 

  140.   ###

  141.   foreach(_target ${_dpf_plugin_TARGETS})

  142.     if(_target STREQUAL "jack")

  143.       dpf__build_jack("${NAME}" "${_dgl_library}")

  144.     elseif(_target STREQUAL "ladspa")

  145.       dpf__build_ladspa("${NAME}")

  146.     elseif(_target STREQUAL "dssi")

  147.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "lv2")

  149.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  150.     elseif(_target STREQUAL "vst")

  151.       dpf__build_vst("${NAME}" "${_dgl_library}")

  152.     else()

  153.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  154.     endif()

  155.   endforeach()

  156. endfunction()

  157. 

  158. # ------------------------------------------------------------------------------

  159. # DPF private functions (prefixed with `dpf__`)

  160. # ------------------------------------------------------------------------------

  161. 

  162. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  163. #       to the output directory.

  164. #

  165. 

  166. # dpf__build_jack

  167. # ------------------------------------------------------------------------------

  168. #

  169. # Add build rules for a JACK program.

  170. #

  171. function(dpf__build_jack NAME DGL_LIBRARY)

  172.   find_package(PkgConfig)

  173.   pkg_check_modules(JACK "jack")

  174.   if(NOT JACK_FOUND)

  175.     dpf__warn_once_only(missing_jack

  176.       "JACK is not found, skipping the `jack` plugin targets")

  177.     return()

  178.   endif()

  179. 

  180.   dpf__create_dummy_source_list(_no_srcs)

  181. 

  182.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  183.   dpf__add_plugin_main("${NAME}-jack" "jack")

  184.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  185.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  186.   set_target_properties("${NAME}-jack" PROPERTIES

  187.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  188.     OUTPUT_NAME "${NAME}")

  189. 

  190.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  191.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  192.   link_directories(${JACK_LIBRARY_DIRS})

  193. endfunction()

  194. 

  195. # dpf__build_ladspa

  196. # ------------------------------------------------------------------------------

  197. #

  198. # Add build rules for a DSSI plugin.

  199. #

  200. function(dpf__build_ladspa NAME)

  201.   dpf__create_dummy_source_list(_no_srcs)

  202. 

  203.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  204.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  205.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  206.   set_target_properties("${NAME}-ladspa" PROPERTIES

  207.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  208.     OUTPUT_NAME "${NAME}-ladspa"

  209.     PREFIX "")

  210. endfunction()

  211. 

  212. # dpf__build_dssi

  213. # ------------------------------------------------------------------------------

  214. #

  215. # Add build rules for a DSSI plugin.

  216. #

  217. function(dpf__build_dssi NAME DGL_LIBRARY)

  218.   find_package(PkgConfig)

  219.   pkg_check_modules(LIBLO "liblo")

  220.   if(NOT LIBLO_FOUND)

  221.     dpf__warn_once_only(missing_liblo

  222.       "liblo is not found, skipping the `dssi` plugin targets")

  223.     return()

  224.   endif()

  225. 

  226.   dpf__create_dummy_source_list(_no_srcs)

  227. 

  228.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  229.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  230.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  231.   set_target_properties("${NAME}-dssi" PROPERTIES

  232.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  233.     OUTPUT_NAME "${NAME}-dssi"

  234.     PREFIX "")

  235. 

  236.   if(DGL_LIBRARY)

  237.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  238.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  239.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  240.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  241.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  242.       OUTPUT_NAME "${NAME}_ui")

  243. 

  244.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  245.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  246.     link_directories(${LIBLO_LIBRARY_DIRS})

  247.   endif()

  248. endfunction()

  249. 

  250. # dpf__build_lv2

  251. # ------------------------------------------------------------------------------

  252. #

  253. # Add build rules for a LV2 plugin.

  254. #

  255. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  256.   dpf__create_dummy_source_list(_no_srcs)

  257. 

  258.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  259.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  260.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  261.   set_target_properties("${NAME}-lv2" PROPERTIES

  262.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  263.     OUTPUT_NAME "${NAME}_dsp"

  264.     PREFIX "")

  265. 

  266.   if(DGL_LIBRARY)

  267.     if(MONOLITHIC)

  268.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  269.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  270.       set_target_properties("${NAME}-lv2" PROPERTIES

  271.         OUTPUT_NAME "${NAME}")

  272.     else()

  273.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  274.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  275.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  276.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  277.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  278.         OUTPUT_NAME "${NAME}_ui"

  279.         PREFIX "")

  280.     endif()

  281.   endif()

  282. 

  283.   dpf__add_lv2_ttl_generator()

  284.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  285. 

  286.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  287.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  288.     "$<TARGET_FILE:lv2_ttl_generator>"

  289.     "$<TARGET_FILE:${NAME}-lv2>"

  290.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  291. endfunction()

  292. 

  293. # dpf__build_vst

  294. # ------------------------------------------------------------------------------

  295. #

  296. # Add build rules for a VST plugin.

  297. #

  298. function(dpf__build_vst NAME DGL_LIBRARY)

  299.   dpf__create_dummy_source_list(_no_srcs)

  300. 

  301.   dpf__add_module("${NAME}-vst" ${_no_srcs})

  302.   dpf__add_plugin_main("${NAME}-vst" "vst")

  303.   dpf__add_ui_main("${NAME}-vst" "vst" "${DGL_LIBRARY}")

  304.   target_link_libraries("${NAME}-vst" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  305.   set_target_properties("${NAME}-vst" PROPERTIES

  306.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  307.     OUTPUT_NAME "${NAME}-vst"

  308.     PREFIX "")

  309. endfunction()

  310. 

  311. # dpf__add_dgl_cairo

  312. # ------------------------------------------------------------------------------

  313. #

  314. # Add the Cairo variant of DGL, if not already available.

  315. #

  316. function(dpf__add_dgl_cairo)

  317.   if(TARGET dgl-cairo)

  318.     return()

  319.   endif()

  320. 

  321.   find_package(PkgConfig)

  322.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  323. 

  324.   dpf__add_static_library(dgl-cairo STATIC

  325.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  326.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  327.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  328.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  329.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  330.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  331.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  333.   if(NOT APPLE)

  334.     target_sources(dgl-cairo PRIVATE

  335.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  336.   else()

  337.     target_sources(dgl-cairo PRIVATE

  338.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  339.   endif()

  340.   target_include_directories(dgl-cairo PUBLIC

  341.     "${DPF_ROOT_DIR}/dgl")

  342. 

  343.   dpf__add_dgl_system_libs()

  344.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  345. 

  346.   add_library(dgl-cairo-definitions INTERFACE)

  347.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  348. 

  349.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  350.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  351.   link_directories(${CAIRO_LIBRARY_DIRS})

  352. endfunction()

  353. 

  354. # dpf__add_dgl_opengl

  355. # ------------------------------------------------------------------------------

  356. #

  357. # Add the OpenGL variant of DGL, if not already available.

  358. #

  359. function(dpf__add_dgl_opengl)

  360.   if(TARGET dgl-opengl)

  361.     return()

  362.   endif()

  363. 

  364.   if(NOT OpenGL_GL_PREFERENCE)

  365.     set(OpenGL_GL_PREFERENCE "LEGACY")

  366.   endif()

  367. 

  368.   find_package(OpenGL REQUIRED)

  369. 

  370.   dpf__add_static_library(dgl-opengl STATIC

  371.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  372.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  373.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  374.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  375.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  376.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  377.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  378.     "${DPF_ROOT_DIR}/dgl/src/Image.cpp"

  379.     "${DPF_ROOT_DIR}/dgl/src/ImageWidgets.cpp"

  380.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp"

  381.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  382.   if(NOT APPLE)

  383.     target_sources(dgl-opengl PRIVATE

  384.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  385.   else()

  386.     target_sources(dgl-opengl PRIVATE

  387.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  388.   endif()

  389.   target_include_directories(dgl-opengl PUBLIC

  390.     "${DPF_ROOT_DIR}/dgl")

  391. 

  392.   dpf__add_dgl_system_libs()

  393.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  394. 

  395.   add_library(dgl-opengl-definitions INTERFACE)

  396.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  397. 

  398.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  399.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  400. endfunction()

  401. 

  402. # dpf__add_dgl_system_libs

  403. # ------------------------------------------------------------------------------

  404. #

  405. # Find system libraries required by DGL and add them as an interface target.

  406. #

  407. function(dpf__add_dgl_system_libs)

  408.   if(TARGET dgl-system-libs)

  409.     return()

  410.   endif()

  411.   add_library(dgl-system-libs INTERFACE)

  412.   if(HAIKU)

  413.     target_link_libraries(dgl-system-libs INTERFACE "be")

  414.   elseif(WIN32)

  415.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  416.   elseif(APPLE)

  417.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  418.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}")

  419.   else()

  420.     find_package(X11 REQUIRED)

  421.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  422.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  423.   endif()

  424. endfunction()

  425. 

  426. # dpf__add_executable

  427. # ------------------------------------------------------------------------------

  428. #

  429. # Adds an executable target, and set some default properties on the target.

  430. #

  431. function(dpf__add_executable NAME)

  432.   add_executable("${NAME}" ${ARGN})

  433.   set_target_properties("${NAME}" PROPERTIES

  434.     POSITION_INDEPENDENT_CODE TRUE

  435.     C_VISIBILITY_PRESET "hidden"

  436.     CXX_VISIBILITY_PRESET "hidden"

  437.     VISIBILITY_INLINES_HIDDEN TRUE)

  438. endfunction()

  439. 

  440. # dpf__add_module

  441. # ------------------------------------------------------------------------------

  442. #

  443. # Adds a module target, and set some default properties on the target.

  444. #

  445. function(dpf__add_module NAME)

  446.   add_library("${NAME}" MODULE ${ARGN})

  447.   set_target_properties("${NAME}" PROPERTIES

  448.     POSITION_INDEPENDENT_CODE TRUE

  449.     C_VISIBILITY_PRESET "hidden"

  450.     CXX_VISIBILITY_PRESET "hidden"

  451.     VISIBILITY_INLINES_HIDDEN TRUE)

  452.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  453.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  454.   endif()

  455. endfunction()

  456. 

  457. # dpf__add_static_library

  458. # ------------------------------------------------------------------------------

  459. #

  460. # Adds a static library target, and set some default properties on the target.

  461. #

  462. function(dpf__add_static_library NAME)

  463.   add_library("${NAME}" STATIC ${ARGN})

  464.   set_target_properties("${NAME}" PROPERTIES

  465.     POSITION_INDEPENDENT_CODE TRUE

  466.     C_VISIBILITY_PRESET "hidden"

  467.     CXX_VISIBILITY_PRESET "hidden"

  468.     VISIBILITY_INLINES_HIDDEN TRUE)

  469. endfunction()

  470. 

  471. # dpf__add_plugin_main

  472. # ------------------------------------------------------------------------------

  473. #

  474. # Adds plugin code to the given target.

  475. #

  476. function(dpf__add_plugin_main NAME TARGET)

  477.   target_sources("${NAME}" PRIVATE

  478.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  479.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  480. endfunction()

  481. 

  482. # dpf__add_ui_main

  483. # ------------------------------------------------------------------------------

  484. #

  485. # Adds UI code to the given target (only if the target has UI).

  486. #

  487. function(dpf__add_ui_main NAME TARGET HAS_UI)

  488.   if(HAS_UI)

  489.     target_sources("${NAME}" PRIVATE

  490.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  491.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  492.   endif()

  493. endfunction()

  494. 

  495. # dpf__add_plugin_target_definition

  496. # ------------------------------------------------------------------------------

  497. #

  498. # Adds the plugins target macro definition.

  499. # This selects which entry file is compiled according to the target type.

  500. #

  501. function(dpf__add_plugin_target_definition NAME TARGET)

  502.   string(TOUPPER "${TARGET}" _upperTarget)

  503.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  504. endfunction()

  505. 

  506. # dpf__add_lv2_ttl_generator

  507. # ------------------------------------------------------------------------------

  508. #

  509. # Build the LV2 TTL generator.

  510. #

  511. function(dpf__add_lv2_ttl_generator)

  512.   if(TARGET lv2_ttl_generator)

  513.     return()

  514.   endif()

  515.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  516.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  517.     target_link_libraries(lv2_ttl_generator "dl")

  518.   endif()

  519. endfunction()

  520. 

  521. # dpf__ensure_sources_non_empty

  522. # ------------------------------------------------------------------------------

  523. #

  524. # Ensure the given source list contains at least one file.

  525. # The function appends an empty source file to the list if necessary.

  526. # This is useful when CMake does not permit to add targets without sources.

  527. #

  528. function(dpf__ensure_sources_non_empty VAR)

  529.   if(NOT "" STREQUAL "${${VAR}}")

  530.     return()

  531.   endif()

  532.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  533.   if(NOT EXISTS "${_file}")

  534.     file(WRITE "${_file}" "")

  535.   endif()

  536.   set("${VAR}" "${_file}" PARENT_SCOPE)

  537. endfunction()

  538. 

  539. # dpf__create_dummy_source_list

  540. # ------------------------------------------------------------------------------

  541. #

  542. # Create a dummy source list which is equivalent to compiling nothing.

  543. # This is only for compatibility with older CMake versions, which refuse to add

  544. # targets without any sources.

  545. #

  546. macro(dpf__create_dummy_source_list VAR)

  547.   set("${VAR}")

  548.   if(CMAKE_VERSION VERSION_LESS "3.11")

  549.     dpf__ensure_sources_non_empty("${VAR}")

  550.   endif()

  551. endmacro()

  552. 

  553. # dpf__warn_once

  554. # ------------------------------------------------------------------------------

  555. #

  556. # Prints a warning message once only.

  557. #

  558. function(dpf__warn_once_only TOKEN MESSAGE)

  559.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  560.   if(NOT _warned)

  561.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  562.     message(WARNING "${MESSAGE}")

  563.   endif()

  564. endfunction()