DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2374 Commits
7 Branches
91MB
Tree: 8ee7f96f4e
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '8ee7f96f4e'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1281 lines
46KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  125.       set(_dgl_library dgl-cairo)

  126.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  127.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  128.       set(_dgl_library dgl-external)

  129.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  130.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  131.       set(_dgl_library dgl-opengl)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  133.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  134.       set(_dgl_library dgl-opengl3)

  135.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  136.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  137.       set(_dgl_library dgl-vulkan)

  138.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  139.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  140.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  141.       set(_dgl_library dgl-external)

  142.     else()

  143.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  144.     endif()

  145.   else()

  146.     set(_dpf_plugin_UI_TYPE "")

  147.   endif()

  148. 

  149.   set(_dgl_has_ui OFF)

  150.   if(_dgl_library)

  151.     set(_dgl_has_ui ON)

  152.   endif()

  153. 

  154.   ###

  155.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  156.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  157.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  158. 

  159.   ###

  160.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  161.   target_include_directories("${NAME}" PUBLIC

  162.     "${DPF_ROOT_DIR}/distrho")

  163. 

  164.   if(_dpf_plugin_USE_FILE_BROWSER)

  165.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  166.   endif()

  167. 

  168.   if(_dpf_plugin_USE_WEB_VIEW)

  169.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  170.   endif()

  171. 

  172.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  173.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  174.   endif()

  175. 

  176.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  177.     target_link_libraries("${NAME}" PRIVATE "dl")

  178.   endif()

  179. 

  180.   if(_dgl_library)

  181.     # make sure that all code will see DGL_* definitions

  182.     target_link_libraries("${NAME}" PUBLIC

  183.       "${_dgl_library}-definitions"

  184.       dgl-system-libs-definitions

  185.       dgl-system-libs)

  186.   endif()

  187. 

  188.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  189.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  190. 

  191.   if(_dgl_library)

  192.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  193.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  194.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  195.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  196.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  197.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  198.           OUTPUT_STRIP_TRAILING_WHITESPACE

  199.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  200.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  201.       endif()

  202.     endif()

  203.     # add the files containing C++17 or Objective-C classes

  204.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  205.   else()

  206.     add_library("${NAME}-ui" INTERFACE)

  207.   endif()

  208. 

  209.   ###

  210.   foreach(_target ${_dpf_plugin_TARGETS})

  211.     if(_target STREQUAL "jack")

  212.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  213.     elseif(_target STREQUAL "ladspa")

  214.       dpf__build_ladspa("${NAME}")

  215.     elseif(_target STREQUAL "dssi")

  216.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  217.     elseif(_target STREQUAL "lv2")

  218.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  219.     elseif(_target STREQUAL "vst2")

  220.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  221.     elseif(_target STREQUAL "vst3")

  222.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  223.     elseif(_target STREQUAL "clap")

  224.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  225.     elseif(_target STREQUAL "au")

  226.       if (APPLE)

  227.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  228.       endif()

  229.     elseif(_target STREQUAL "static")

  230.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  231.     else()

  232.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  233.     endif()

  234.   endforeach()

  235. endfunction()

  236. 

  237. # ------------------------------------------------------------------------------

  238. # DPF private functions (prefixed with `dpf__`)

  239. # ------------------------------------------------------------------------------

  240. 

  241. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  242. #       to the output directory.

  243. #

  244. 

  245. # dpf__build_jack

  246. # ------------------------------------------------------------------------------

  247. #

  248. # Add build rules for a JACK/Standalone program.

  249. #

  250. function(dpf__build_jack NAME HAS_UI)

  251.   dpf__create_dummy_source_list(_no_srcs)

  252. 

  253.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  254.   dpf__add_plugin_main("${NAME}-jack" "jack")

  255.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  256.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  257.   set_target_properties("${NAME}-jack" PROPERTIES

  258.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  259.     OUTPUT_NAME "${NAME}")

  260. 

  261.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  262.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  263. 

  264.   find_package(PkgConfig)

  265.   pkg_check_modules(SDL2 "sdl2")

  266.   if(SDL2_FOUND)

  267.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  268.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  269.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  270.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  271.   endif()

  272. 

  273.   if(APPLE OR WIN32)

  274.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  275.   else()

  276.     find_package(Threads)

  277.     pkg_check_modules(ALSA "alsa")

  278.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  279.     if(ALSA_FOUND)

  280.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  281.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  282.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  283.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  284.     endif()

  285.     if(PULSEAUDIO_FOUND)

  286.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  287.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  288.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  289.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  290.     endif()

  291.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  292.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  293.     endif()

  294.   endif()

  295. 

  296.   # for RtAudio native fallback

  297.   if(APPLE)

  298.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  299.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  300.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  301.     target_link_libraries("${NAME}-jack" PRIVATE

  302.       "${APPLE_COREAUDIO_FRAMEWORK}"

  303.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  304.       "${APPLE_COREMIDI_FRAMEWORK}")

  305.   elseif(WIN32)

  306.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  307.     if(HAS_UI AND MINGW)

  308.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  309.     endif()

  310.   endif()

  311. endfunction()

  312. 

  313. # dpf__build_ladspa

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add build rules for a LADSPA plugin.

  317. #

  318. function(dpf__build_ladspa NAME)

  319.   dpf__create_dummy_source_list(_no_srcs)

  320. 

  321.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  322.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  323.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  324.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  325.   set_target_properties("${NAME}-ladspa" PROPERTIES

  326.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  327.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  328.     OUTPUT_NAME "${NAME}-ladspa"

  329.     PREFIX "")

  330. endfunction()

  331. 

  332. # dpf__build_dssi

  333. # ------------------------------------------------------------------------------

  334. #

  335. # Add build rules for a DSSI plugin.

  336. #

  337. function(dpf__build_dssi NAME HAS_UI)

  338.   find_package(PkgConfig)

  339.   pkg_check_modules(LIBLO "liblo")

  340.   if(NOT LIBLO_FOUND)

  341.     dpf__warn_once_only(missing_liblo

  342.       "liblo is not found, skipping the `dssi` plugin targets")

  343.     return()

  344.   endif()

  345. 

  346.   dpf__create_dummy_source_list(_no_srcs)

  347. 

  348.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  349.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  350.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  351.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  352.   set_target_properties("${NAME}-dssi" PROPERTIES

  353.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  354.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  355.     OUTPUT_NAME "${NAME}-dssi"

  356.     PREFIX "")

  357. 

  358.   if(HAS_UI)

  359.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  360.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  361.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  362.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  363.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  364.       OUTPUT_NAME "${NAME}_ui")

  365. 

  366.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  367.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  368.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  369.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  370.   endif()

  371. endfunction()

  372. 

  373. # dpf__build_lv2

  374. # ------------------------------------------------------------------------------

  375. #

  376. # Add build rules for an LV2 plugin.

  377. #

  378. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  379.   dpf__create_dummy_source_list(_no_srcs)

  380. 

  381.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  382.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  383.   if(HAS_UI AND MONOLITHIC)

  384.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  385.   else()

  386.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  387.   endif()

  388.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  389.   set_target_properties("${NAME}-lv2" PROPERTIES

  390.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  391.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  392.     OUTPUT_NAME "${NAME}_dsp"

  393.     PREFIX "")

  394. 

  395.   if(HAS_UI)

  396.     if(MONOLITHIC)

  397.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  398.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  399.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  400.       set_target_properties("${NAME}-lv2" PROPERTIES

  401.         OUTPUT_NAME "${NAME}")

  402.     else()

  403.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  404.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  405.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  406.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  407.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  408.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  409.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  410.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  411.         OUTPUT_NAME "${NAME}_ui"

  412.         PREFIX "")

  413.     endif()

  414.   endif()

  415. 

  416.   dpf__add_lv2_ttl_generator()

  417.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  418. 

  419.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  420. 

  421.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  422.     COMMAND

  423.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  424.     "$<TARGET_FILE:lv2_ttl_generator>"

  425.     "$<TARGET_FILE:${NAME}-lv2>"

  426.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  427.     DEPENDS lv2_ttl_generator)

  428. endfunction()

  429. 

  430. # dpf__build_vst2

  431. # ------------------------------------------------------------------------------

  432. #

  433. # Add build rules for a VST2 plugin.

  434. #

  435. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  436.   dpf__create_dummy_source_list(_no_srcs)

  437. 

  438.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  439.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  440.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  441.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  442.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  443.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  444.   set_target_properties("${NAME}-vst2" PROPERTIES

  445.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  446.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  447.     OUTPUT_NAME "${NAME}-vst2"

  448.     PREFIX "")

  449.   if(APPLE)

  450.     set_target_properties("${NAME}-vst2" PROPERTIES

  451.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  452.       OUTPUT_NAME "${NAME}"

  453.       SUFFIX "")

  454.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  455.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  456.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  457.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  458.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  459.   endif()

  460. endfunction()

  461. 

  462. # dpf__determine_vst3_package_architecture

  463. # ------------------------------------------------------------------------------

  464. #

  465. # Determines the package architecture for a VST3 plugin target.

  466. #

  467. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  468.   # if set by variable, override the detection

  469.   if(DPF_VST3_ARCHITECTURE)

  470.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  471.     return()

  472.   endif()

  473. 

  474.   # not used on Apple, which supports universal binary

  475.   if(APPLE)

  476.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  477.     return()

  478.   endif()

  479. 

  480.   # identify the target processor (special case of MSVC, problematic sometimes)

  481.   if(MSVC)

  482.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  483.   else()

  484.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  485.   endif()

  486. 

  487.   # transform the processor name to a format that VST3 recognizes

  488.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  489.     set(vst3_package_arch "x86_64")

  490.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  491.     if(WIN32)

  492.       set(vst3_package_arch "x86")

  493.     else()

  494.       set(vst3_package_arch "i386")

  495.     endif()

  496.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*|ppc(64)?(le)?)$")

  497.     set(vst3_package_arch "${vst3_system_arch}")

  498.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  499.     set(vst3_package_arch "aarch64")

  500.   elseif(vst3_system_arch MATCHES "^(loongarch64)$")

  501.     set(vst3_package_arch "loongarch64")

  502.   else()

  503.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  504.   endif()

  505. 

  506.   # TODO: the detections for Windows arm/arm64 when supported

  507. 

  508.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  509. endfunction()

  510. 

  511. # dpf__build_vst3

  512. # ------------------------------------------------------------------------------

  513. #

  514. # Add build rules for a VST3 plugin.

  515. #

  516. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  517.   dpf__determine_vst3_package_architecture(vst3_arch)

  518. 

  519.   dpf__create_dummy_source_list(_no_srcs)

  520. 

  521.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  522.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  523.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  524.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  525.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  526.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  527.   set_target_properties("${NAME}-vst3" PROPERTIES

  528.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  529.     OUTPUT_NAME "${NAME}"

  530.     PREFIX "")

  531. 

  532.   if(APPLE)

  533.     set_target_properties("${NAME}-vst3" PROPERTIES

  534.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  535.       SUFFIX "")

  536.   elseif(WIN32)

  537.     set_target_properties("${NAME}-vst3" PROPERTIES

  538.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  539.   else()

  540.     set_target_properties("${NAME}-vst3" PROPERTIES

  541.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  542.   endif()

  543. 

  544.   if(APPLE)

  545.     # Uses the same macOS bundle template as VST2

  546.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  547.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  548.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  549.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  550.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  551.   endif()

  552. endfunction()

  553. 

  554. # dpf__build_clap

  555. # ------------------------------------------------------------------------------

  556. #

  557. # Add build rules for a CLAP plugin.

  558. #

  559. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  560.   dpf__create_dummy_source_list(_no_srcs)

  561. 

  562.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  563.   dpf__add_plugin_main("${NAME}-clap" "clap")

  564.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  565.   dpf__set_module_export_list("${NAME}-clap" "clap")

  566.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  567.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  568.   set_target_properties("${NAME}-clap" PROPERTIES

  569.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  570.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  571.     OUTPUT_NAME "${NAME}"

  572.     PREFIX ""

  573.     SUFFIX ".clap")

  574. 

  575.   if(APPLE)

  576.     set_target_properties("${NAME}-clap" PROPERTIES

  577.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  578.       OUTPUT_NAME "${NAME}"

  579.       SUFFIX "")

  580.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  581.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  582.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  583.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  584.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  585.   endif()

  586. endfunction()

  587. 

  588. # dpf__build_au

  589. # ------------------------------------------------------------------------------

  590. #

  591. # Add build rules for an AUv2 plugin.

  592. #

  593. function(dpf__build_au NAME HAS_UI)

  594.   dpf__create_dummy_source_list(_no_srcs)

  595. 

  596.   dpf__add_module("${NAME}-au" ${_no_srcs})

  597.   dpf__add_plugin_main("${NAME}-au" "au")

  598.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  599.   dpf__set_module_export_list("${NAME}-au" "au")

  600.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  601.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  602.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  603.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  604.   target_link_libraries("${NAME}-au" PRIVATE

  605.     "${NAME}-dsp"

  606.     "${NAME}-ui"

  607.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  608.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  609.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  610.   set_target_properties("${NAME}-au" PROPERTIES

  611.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  612.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  613.     OUTPUT_NAME "${NAME}"

  614.     PREFIX ""

  615.     SUFFIX "")

  616. 

  617.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  618.   dpf__add_plugin_main("${NAME}-export" "export")

  619.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  620.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  621. 

  622.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  623. 

  624.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  625.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  626.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  627.     DEPENDS "${NAME}-export")

  628. 

  629.   add_dependencies("${NAME}-au" "${NAME}-export")

  630. 

  631.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  632.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  633. endfunction()

  634. 

  635. # dpf__build_static

  636. # ------------------------------------------------------------------------------

  637. #

  638. # Add build rules for a static library.

  639. #

  640. function(dpf__build_static NAME HAS_UI)

  641.   dpf__create_dummy_source_list(_no_srcs)

  642. 

  643.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  644.   dpf__add_plugin_main("${NAME}-static" "static")

  645.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  646.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  647. 

  648.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  649.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  650.   foreach(src ${dsp_srcs})

  651.     target_sources("${NAME}-static" PRIVATE ${src})

  652.   endforeach()

  653.   foreach(src ${ui_srcs})

  654.     target_sources("${NAME}-static" PRIVATE ${src})

  655.   endforeach()

  656. 

  657.   set_target_properties("${NAME}-static" PROPERTIES

  658.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  659.     OUTPUT_NAME "${NAME}"

  660.     PREFIX "")

  661. endfunction()

  662. 

  663. # dpf__add_dgl_cairo

  664. # ------------------------------------------------------------------------------

  665. #

  666. # Add the Cairo variant of DGL, if not already available.

  667. #

  668. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER)

  669.   if(TARGET dgl-cairo)

  670.     return()

  671.   endif()

  672. 

  673.   find_package(PkgConfig)

  674.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  675. 

  676.   link_directories(${CAIRO_LIBRARY_DIRS})

  677. 

  678.   dpf__add_static_library(dgl-cairo STATIC

  679.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  680.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  681.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  682.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  683.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  684.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  685.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  686.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  687.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  688.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  689.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  690.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  691.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  692.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  693.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  694.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  695.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  696.   if(SHARED_RESOURCES)

  697.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  698.   else()

  699.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  700.   endif()

  701.   if(APPLE)

  702.     target_sources(dgl-cairo PRIVATE

  703.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  704.   else()

  705.     target_sources(dgl-cairo PRIVATE

  706.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  707.   endif()

  708.   target_include_directories(dgl-cairo PUBLIC

  709.     "${DPF_ROOT_DIR}/dgl")

  710.   target_include_directories(dgl-cairo PUBLIC

  711.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  712. 

  713.   if(USE_FILE_BROWSER)

  714.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  715.   endif()

  716. 

  717.   dpf__add_dgl_system_libs()

  718.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  719. 

  720.   add_library(dgl-cairo-definitions INTERFACE)

  721.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  722. 

  723.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  724.   if(MINGW)

  725.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  726.   else()

  727.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  728.   endif()

  729.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  730. endfunction()

  731. 

  732. # dpf__add_dgl_external

  733. # ------------------------------------------------------------------------------

  734. #

  735. # Add the external variant of DGL, if not already available.

  736. #

  737. function(dpf__add_dgl_external USE_FILE_BROWSER)

  738.   if(TARGET dgl-external)

  739.     return()

  740.   endif()

  741. 

  742.   dpf__add_static_library(dgl-external STATIC

  743.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  744.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  745.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  746.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  747.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  748.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  749.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  750.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  751.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  752.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  753.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  754.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  755.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  756.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  757.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  758.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  759.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  760. 

  761.   if(APPLE)

  762.     target_sources(dgl-external PRIVATE

  763.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  764.   else()

  765.     target_sources(dgl-external PRIVATE

  766.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  767.   endif()

  768.   target_include_directories(dgl-external PUBLIC

  769.     "${DPF_ROOT_DIR}/dgl")

  770.   target_include_directories(dgl-external PUBLIC

  771.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  772. 

  773.   if(USE_FILE_BROWSER)

  774.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  775.   endif()

  776. 

  777.   dpf__add_dgl_system_libs()

  778.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  779.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  780. 

  781.   add_library(dgl-external-definitions INTERFACE)

  782.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  783. 

  784.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  785.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  786. endfunction()

  787. 

  788. # dpf__add_dgl_opengl

  789. # ------------------------------------------------------------------------------

  790. #

  791. # Add the OpenGL variant of DGL, if not already available.

  792. #

  793. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER)

  794.   if(TARGET dgl-opengl)

  795.     return()

  796.   endif()

  797. 

  798.   if(NOT OpenGL_GL_PREFERENCE)

  799.     set(OpenGL_GL_PREFERENCE "LEGACY")

  800.   endif()

  801. 

  802.   find_package(OpenGL REQUIRED)

  803. 

  804.   dpf__add_static_library(dgl-opengl STATIC

  805.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  806.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  807.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  808.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  809.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  810.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  811.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  812.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  813.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  814.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  815.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  816.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  817.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  818.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  819.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  820.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  821.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  822.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  823.   if(SHARED_RESOURCES)

  824.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  825.   else()

  826.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  827.   endif()

  828.   if(APPLE)

  829.     target_sources(dgl-opengl PRIVATE

  830.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  831.   else()

  832.     target_sources(dgl-opengl PRIVATE

  833.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  834.   endif()

  835.   target_include_directories(dgl-opengl PUBLIC

  836.     "${DPF_ROOT_DIR}/dgl")

  837.   target_include_directories(dgl-opengl PUBLIC

  838.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  839. 

  840.   if(APPLE)

  841.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  842.   endif()

  843. 

  844.   if(USE_FILE_BROWSER)

  845.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  846.   endif()

  847. 

  848.   dpf__add_dgl_system_libs()

  849.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  850. 

  851.   add_library(dgl-opengl-definitions INTERFACE)

  852.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  853. 

  854.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  855.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  856. endfunction()

  857. 

  858. # dpf__add_dgl_opengl3

  859. # ------------------------------------------------------------------------------

  860. #

  861. # Add the OpenGL3 variant of DGL, if not already available.

  862. #

  863. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER)

  864.   if(TARGET dgl-opengl3)

  865.     return()

  866.   endif()

  867. 

  868.   if(NOT OpenGL_GL_PREFERENCE)

  869.     set(OpenGL_GL_PREFERENCE "LEGACY")

  870.   endif()

  871. 

  872.   find_package(OpenGL REQUIRED)

  873. 

  874.   dpf__add_static_library(dgl-opengl3 STATIC

  875.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  883.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  884.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  885.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  886.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  887.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  888.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  889.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  890.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  891.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  892.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  893.   if(SHARED_RESOURCES)

  894.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  895.   else()

  896.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  897.   endif()

  898.   if(APPLE)

  899.     target_sources(dgl-opengl3 PRIVATE

  900.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  901.   else()

  902.     target_sources(dgl-opengl3 PRIVATE

  903.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  904.   endif()

  905.   target_include_directories(dgl-opengl3 PUBLIC

  906.     "${DPF_ROOT_DIR}/dgl")

  907.   target_include_directories(dgl-opengl3 PUBLIC

  908.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  909. 

  910.   if(APPLE)

  911.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  912.   endif()

  913. 

  914.   if(USE_FILE_BROWSER)

  915.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  916.   endif()

  917. 

  918.   dpf__add_dgl_system_libs()

  919.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  920. 

  921.   add_library(dgl-opengl3-definitions INTERFACE)

  922.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  923. 

  924.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  925.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  926. endfunction()

  927. 

  928. # dpf__add_dgl_vulkan

  929. # ------------------------------------------------------------------------------

  930. #

  931. # Add the Vulkan variant of DGL, if not already available.

  932. #

  933. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER)

  934.   if(TARGET dgl-vulkan)

  935.     return()

  936.   endif()

  937. 

  938.   find_package(Vulkan REQUIRED)

  939. 

  940.   dpf__add_static_library(dgl-vulkan STATIC

  941.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  944.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  945.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  946.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  956.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  957.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  958.   if(NO_SHARED_RESOURCES)

  959.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  960.   else()

  961.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  962.   endif()

  963.   if(APPLE)

  964.     target_sources(dgl-vulkan PRIVATE

  965.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  966.   else()

  967.     target_sources(dgl-vulkan PRIVATE

  968.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  969.   endif()

  970.   target_include_directories(dgl-vulkan PUBLIC

  971.     "${DPF_ROOT_DIR}/dgl")

  972.   target_include_directories(dgl-vulkan PUBLIC

  973.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  974. 

  975.   if(APPLE)

  976.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  977.   endif()

  978. 

  979.   if(USE_FILE_BROWSER)

  980.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  981.   endif()

  982. 

  983.   dpf__add_dgl_system_libs()

  984.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  985. 

  986.   add_library(dgl-vulkan-definitions INTERFACE)

  987.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  988. 

  989.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  990.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  991. endfunction()

  992. 

  993. # dpf__add_plugin_specific_ui_sources

  994. # ------------------------------------------------------------------------------

  995. #

  996. # Compile system specific files

  997. #

  998. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  999.   if(APPLE)

  1000.     target_sources("${NAME}" PRIVATE

  1001.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1002.     if(USE_WEB_VIEW)

  1003.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1004.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1005.     endif()

  1006.   elseif(WIN32 AND USE_WEB_VIEW)

  1007.     target_sources("${NAME}" PRIVATE

  1008.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1009.     if (MSVC)

  1010.       set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1011.         PROPERTIES COMPILE_FLAGS /std:c++17)

  1012.     else()

  1013.       set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1014.         PROPERTIES COMPILE_FLAGS -std=gnu++17)

  1015.     endif()

  1016.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1017.   endif()

  1018. endfunction()

  1019. 

  1020. # dpf__add_dgl_system_libs

  1021. # ------------------------------------------------------------------------------

  1022. #

  1023. # Find system libraries required by DGL and add them as an interface target.

  1024. #

  1025. function(dpf__add_dgl_system_libs)

  1026.   if(TARGET dgl-system-libs)

  1027.     return()

  1028.   endif()

  1029.   add_library(dgl-system-libs INTERFACE)

  1030.   add_library(dgl-system-libs-definitions INTERFACE)

  1031.   if(APPLE)

  1032.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1033.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1034.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1035.   elseif(EMSCRIPTEN)

  1036.   elseif(HAIKU)

  1037.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1038.   elseif(WIN32)

  1039.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1040.   else()

  1041.     find_package(PkgConfig)

  1042.     pkg_check_modules(DBUS "dbus-1")

  1043.     if(DBUS_FOUND)

  1044.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1045.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1046.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1047.     endif()

  1048.     find_package(X11 REQUIRED)

  1049.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1050.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1051.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1052.     if(X11_Xcursor_FOUND)

  1053.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1054.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1055.     endif()

  1056.     if(X11_Xext_FOUND)

  1057.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1058.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1059.     endif()

  1060.     if(X11_Xrandr_FOUND)

  1061.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1062.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1063.     endif()

  1064.     if(X11_XSync_FOUND)

  1065.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1066.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1067.     endif()

  1068.    endif()

  1069. 

  1070.    if(MSVC)

  1071.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1072.      foreach(_gl_header "glext.h")

  1073.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1074.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1075.        endif()

  1076.      endforeach()

  1077.      foreach(_khr_header "khrplatform.h")

  1078.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1079.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1080.        endif()

  1081.      endforeach()

  1082.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1083.    endif()

  1084. 

  1085.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1086. endfunction()

  1087. 

  1088. # dpf__add_executable

  1089. # ------------------------------------------------------------------------------

  1090. #

  1091. # Adds an executable target, and set some default properties on the target.

  1092. #

  1093. function(dpf__add_executable NAME)

  1094.   add_executable("${NAME}" ${ARGN})

  1095.   dpf__set_target_defaults("${NAME}")

  1096.   if(MINGW)

  1097.     target_link_libraries("${NAME}" PRIVATE "-static")

  1098.   endif()

  1099. endfunction()

  1100. 

  1101. # dpf__add_module

  1102. # ------------------------------------------------------------------------------

  1103. #

  1104. # Adds a module target, and set some default properties on the target.

  1105. #

  1106. function(dpf__add_module NAME)

  1107.   add_library("${NAME}" MODULE ${ARGN})

  1108.   dpf__set_target_defaults("${NAME}")

  1109.   if(APPLE)

  1110.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1111.   elseif(MINGW)

  1112.     target_link_libraries("${NAME}" PRIVATE "-static")

  1113.   endif()

  1114. endfunction()

  1115. 

  1116. # dpf__add_static_library

  1117. # ------------------------------------------------------------------------------

  1118. #

  1119. # Adds a static library target, and set some default properties on the target.

  1120. #

  1121. function(dpf__add_static_library NAME)

  1122.   add_library("${NAME}" STATIC ${ARGN})

  1123.   dpf__set_target_defaults("${NAME}")

  1124. endfunction()

  1125. 

  1126. # dpf__set_module_export_list

  1127. # ------------------------------------------------------------------------------

  1128. #

  1129. # Applies a list of exported symbols to the module target.

  1130. #

  1131. function(dpf__set_module_export_list NAME EXPORTS)

  1132.   if(WIN32)

  1133.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1134.   elseif(APPLE)

  1135.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1136.       "-Xlinker" "-exported_symbols_list"

  1137.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1138.   else()

  1139.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1140.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1141.   endif()

  1142. endfunction()

  1143. 

  1144. # dpf__set_target_defaults

  1145. # ------------------------------------------------------------------------------

  1146. #

  1147. # Set default properties which must apply to all DPF-defined targets.

  1148. #

  1149. function(dpf__set_target_defaults NAME)

  1150.   set_target_properties("${NAME}" PROPERTIES

  1151.     POSITION_INDEPENDENT_CODE TRUE

  1152.     C_VISIBILITY_PRESET "hidden"

  1153.     CXX_VISIBILITY_PRESET "hidden"

  1154.     VISIBILITY_INLINES_HIDDEN TRUE)

  1155.   if(WIN32)

  1156.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1157.   endif()

  1158.   if (MINGW)

  1159.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1160.   endif()

  1161.   if (MSVC)

  1162.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1163.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1164.   endif()

  1165.   if (CMAKE_COMPILER_IS_GNUCXX)

  1166.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1167.   endif()

  1168.   if ((NOT APPLE) AND (NOT MSVC))

  1169.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1170.   endif()

  1171. endfunction()

  1172. 

  1173. # dpf__add_plugin_main

  1174. # ------------------------------------------------------------------------------

  1175. #

  1176. # Adds plugin code to the given target.

  1177. #

  1178. function(dpf__add_plugin_main NAME TARGET)

  1179.   target_sources("${NAME}" PRIVATE

  1180.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1181.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1182. endfunction()

  1183. 

  1184. # dpf__add_ui_main

  1185. # ------------------------------------------------------------------------------

  1186. #

  1187. # Adds UI code to the given target (only if the target has UI).

  1188. #

  1189. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1190.   if(HAS_UI)

  1191.     target_sources("${NAME}" PRIVATE

  1192.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1193.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1194.   endif()

  1195. endfunction()

  1196. 

  1197. # dpf__add_plugin_target_definition

  1198. # ------------------------------------------------------------------------------

  1199. #

  1200. # Adds the plugins target macro definition.

  1201. # This selects which entry file is compiled according to the target type.

  1202. #

  1203. function(dpf__add_plugin_target_definition NAME TARGET)

  1204.   string(TOUPPER "${TARGET}" _upperTarget)

  1205.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1206. endfunction()

  1207. 

  1208. # dpf__add_lv2_ttl_generator

  1209. # ------------------------------------------------------------------------------

  1210. #

  1211. # Build the LV2 TTL generator.

  1212. #

  1213. function(dpf__add_lv2_ttl_generator)

  1214.   if(TARGET lv2_ttl_generator)

  1215.     return()

  1216.   endif()

  1217.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1218.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1219.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1220.   endif()

  1221. endfunction()

  1222. 

  1223. # dpf__ensure_sources_non_empty

  1224. # ------------------------------------------------------------------------------

  1225. #

  1226. # Ensure the given source list contains at least one file.

  1227. # The function appends an empty source file to the list if necessary.

  1228. # This is useful when CMake does not permit to add targets without sources.

  1229. #

  1230. function(dpf__ensure_sources_non_empty VAR)

  1231.   if(NOT "" STREQUAL "${${VAR}}")

  1232.     return()

  1233.   endif()

  1234.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1235.   if(NOT EXISTS "${_file}")

  1236.     file(WRITE "${_file}" "")

  1237.   endif()

  1238.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1239. endfunction()

  1240. 

  1241. # dpf__create_dummy_source_list

  1242. # ------------------------------------------------------------------------------

  1243. #

  1244. # Create a dummy source list which is equivalent to compiling nothing.

  1245. # This is only for compatibility with older CMake versions, which refuse to add

  1246. # targets without any sources.

  1247. #

  1248. macro(dpf__create_dummy_source_list VAR)

  1249.   set("${VAR}")

  1250.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1251.     dpf__ensure_sources_non_empty("${VAR}")

  1252.   endif()

  1253. endmacro()

  1254. 

  1255. # dpf__target_link_directories

  1256. # ------------------------------------------------------------------------------

  1257. #

  1258. # Call `target_link_directories` if cmake >= 3.13,

  1259. # otherwise fallback to global `link_directories`.

  1260. #

  1261. macro(dpf__target_link_directories NAME DIRS)

  1262.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1263.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1264.   else()

  1265.     link_directories(${DIRS})

  1266.   endif()

  1267. endmacro()

  1268. 

  1269. # dpf__warn_once

  1270. # ------------------------------------------------------------------------------

  1271. #

  1272. # Prints a warning message once only.

  1273. #

  1274. function(dpf__warn_once_only TOKEN MESSAGE)

  1275.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1276.   if(NOT _warned)

  1277.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1278.     message(WARNING "${MESSAGE}")

  1279.   endif()

  1280. endfunction()