DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2105 Commits
7 Branches
68MB
Tree: 8d6748c502
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '8d6748c502'
${ noResults }
DPF/cmake/DPF-plugin.cmake

930 lines
33KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`, `external`

  79. #

  80. #   `FILES_COMMON` <file1>...<fileN>

  81. #       list of sources which are part of both DSP and UI

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `MODGUI_CLASS_NAME`

  91. #       class name to use for modgui builds

  92. #

  93. #   `MONOLITHIC`

  94. #       build LV2 as a single binary for UI and DSP

  95. #

  96. #   `NO_SHARED_RESOURCES`

  97. #       do not build DPF shared resources (fonts, etc)

  98. #

  99. function(dpf_add_plugin NAME)

  100.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  101.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  102.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  103.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  104. 

  105.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  106.     set(_dpf_plugin_UI_TYPE "opengl")

  107.   endif()

  108. 

  109.   set(_dgl_library)

  110.   set(_dgl_external OFF)

  111.   if(_dpf_plugin_FILES_UI)

  112.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  113.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  114.       set(_dgl_library dgl-cairo)

  115.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  116.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  117.       set(_dgl_library dgl-opengl)

  118.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  119.       set(_dgl_external ON)

  120.     else()

  121.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  122.     endif()

  123.   endif()

  124. 

  125.   set(_dgl_has_ui OFF)

  126.   if(_dgl_library OR _dgl_external)

  127.     set(_dgl_has_ui ON)

  128.   endif()

  129. 

  130.   ###

  131.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  132.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  133.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  134. 

  135.   ###

  136.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  137.   target_include_directories("${NAME}" PUBLIC

  138.     "${DPF_ROOT_DIR}/distrho")

  139. 

  140.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  141.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  142.   endif()

  143. 

  144.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  145.     target_link_libraries("${NAME}" PRIVATE "dl")

  146.   endif()

  147. 

  148.   if(_dgl_library AND NOT _dgl_external)

  149.     # make sure that all code will see DGL_* definitions

  150.     target_link_libraries("${NAME}" PUBLIC

  151.       "${_dgl_library}-definitions"

  152.       dgl-system-libs-definitions)

  153.   elseif(_dgl_external)

  154.     target_link_libraries("${NAME}" PUBLIC

  155.       dgl-system-libs-definitions)

  156.   endif()

  157. 

  158.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  159.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  160. 

  161.   if(_dgl_library AND NOT _dgl_external)

  162.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  163.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  164.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  165.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  166.     endif()

  167.     # add the files containing Objective-C classes

  168.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  169.   elseif(_dgl_external)

  170.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  171.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}")

  172.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  173.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  174.     endif()

  175.     # add the files containing Objective-C classes

  176.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  177.   else()

  178.     add_library("${NAME}-ui" INTERFACE)

  179.   endif()

  180. 

  181.   ###

  182.   foreach(_target ${_dpf_plugin_TARGETS})

  183.     if(_target STREQUAL "jack")

  184.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  185.     elseif(_target STREQUAL "ladspa")

  186.       dpf__build_ladspa("${NAME}")

  187.     elseif(_target STREQUAL "dssi")

  188.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  189.     elseif(_target STREQUAL "lv2")

  190.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  191.     elseif(_target STREQUAL "vst2")

  192.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  193.     elseif(_target STREQUAL "vst3")

  194.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  195.     elseif(_target STREQUAL "clap")

  196.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  197.     else()

  198.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  199.     endif()

  200.   endforeach()

  201. endfunction()

  202. 

  203. # ------------------------------------------------------------------------------

  204. # DPF private functions (prefixed with `dpf__`)

  205. # ------------------------------------------------------------------------------

  206. 

  207. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  208. #       to the output directory.

  209. #

  210. 

  211. # dpf__build_jack

  212. # ------------------------------------------------------------------------------

  213. #

  214. # Add build rules for a JACK/Standalone program.

  215. #

  216. function(dpf__build_jack NAME HAS_UI)

  217.   dpf__create_dummy_source_list(_no_srcs)

  218. 

  219.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  220.   dpf__add_plugin_main("${NAME}-jack" "jack")

  221.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  222.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  223.   set_target_properties("${NAME}-jack" PROPERTIES

  224.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  225.     OUTPUT_NAME "${NAME}")

  226. 

  227.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  228. 

  229.   find_package(PkgConfig)

  230.   pkg_check_modules(SDL2 "sdl2")

  231.   if(SDL2_FOUND)

  232.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  233.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  234.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  235.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  236.   endif()

  237. 

  238.   if(APPLE OR WIN32)

  239.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  240.   else()

  241.     find_package(Threads)

  242.     pkg_check_modules(ALSA "alsa")

  243.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  244.     if(ALSA_FOUND)

  245.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  246.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  247.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  248.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  249.     endif()

  250.     if(PULSEAUDIO_FOUND)

  251.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  252.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  253.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  254.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  255.     endif()

  256.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  257.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  258.     endif()

  259.   endif()

  260. 

  261.   # for RtAudio native fallback

  262.   if(APPLE)

  263.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  264.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  265.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  266.     target_link_libraries("${NAME}-jack" PRIVATE

  267.       "${APPLE_COREAUDIO_FRAMEWORK}"

  268.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  269.       "${APPLE_COREMIDI_FRAMEWORK}")

  270.   elseif(WIN32)

  271.     target_link_libraries("${NAME}-jack" PRIVATE "dsound" "ole32" "winmm")

  272.   endif()

  273. endfunction()

  274. 

  275. # dpf__build_ladspa

  276. # ------------------------------------------------------------------------------

  277. #

  278. # Add build rules for a LADSPA plugin.

  279. #

  280. function(dpf__build_ladspa NAME)

  281.   dpf__create_dummy_source_list(_no_srcs)

  282. 

  283.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  284.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  285.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  286.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  287.   set_target_properties("${NAME}-ladspa" PROPERTIES

  288.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  289.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  290.     OUTPUT_NAME "${NAME}-ladspa"

  291.     PREFIX "")

  292. endfunction()

  293. 

  294. # dpf__build_dssi

  295. # ------------------------------------------------------------------------------

  296. #

  297. # Add build rules for a DSSI plugin.

  298. #

  299. function(dpf__build_dssi NAME HAS_UI)

  300.   find_package(PkgConfig)

  301.   pkg_check_modules(LIBLO "liblo")

  302.   if(NOT LIBLO_FOUND)

  303.     dpf__warn_once_only(missing_liblo

  304.       "liblo is not found, skipping the `dssi` plugin targets")

  305.     return()

  306.   endif()

  307. 

  308.   dpf__create_dummy_source_list(_no_srcs)

  309. 

  310.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  311.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  312.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  313.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  314.   set_target_properties("${NAME}-dssi" PROPERTIES

  315.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  316.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  317.     OUTPUT_NAME "${NAME}-dssi"

  318.     PREFIX "")

  319. 

  320.   if(HAS_UI)

  321.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  322.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  323.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  324.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  325.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  326.       OUTPUT_NAME "${NAME}_ui")

  327. 

  328.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  329.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  330.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  331.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  332.   endif()

  333. endfunction()

  334. 

  335. # dpf__build_lv2

  336. # ------------------------------------------------------------------------------

  337. #

  338. # Add build rules for an LV2 plugin.

  339. #

  340. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  341.   dpf__create_dummy_source_list(_no_srcs)

  342. 

  343.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  344.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  345.   if(HAS_UI AND MONOLITHIC)

  346.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  347.   else()

  348.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  349.   endif()

  350.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  351.   set_target_properties("${NAME}-lv2" PROPERTIES

  352.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  353.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  354.     OUTPUT_NAME "${NAME}_dsp"

  355.     PREFIX "")

  356. 

  357.   if(HAS_UI)

  358.     if(MONOLITHIC)

  359.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  360.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  361.       set_target_properties("${NAME}-lv2" PROPERTIES

  362.         OUTPUT_NAME "${NAME}")

  363.     else()

  364.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  365.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  366.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  367.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  368.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  369.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  370.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  371.         OUTPUT_NAME "${NAME}_ui"

  372.         PREFIX "")

  373.     endif()

  374.   endif()

  375. 

  376.   dpf__add_lv2_ttl_generator()

  377.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  378. 

  379.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  380.     COMMAND

  381.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  382.     "$<TARGET_FILE:lv2_ttl_generator>"

  383.     "$<TARGET_FILE:${NAME}-lv2>"

  384.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  385.     DEPENDS lv2_ttl_generator)

  386. endfunction()

  387. 

  388. # dpf__build_vst2

  389. # ------------------------------------------------------------------------------

  390. #

  391. # Add build rules for a VST2 plugin.

  392. #

  393. function(dpf__build_vst2 NAME HAS_UI)

  394.   dpf__create_dummy_source_list(_no_srcs)

  395. 

  396.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  397.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  398.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  399.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  400.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  401.   set_target_properties("${NAME}-vst2" PROPERTIES

  402.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  403.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  404.     OUTPUT_NAME "${NAME}-vst2"

  405.     PREFIX "")

  406.   if(APPLE)

  407.     set_target_properties("${NAME}-vst2" PROPERTIES

  408.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  409.       OUTPUT_NAME "${NAME}"

  410.       SUFFIX "")

  411.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  412.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  413.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  414.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  415.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  416.   endif()

  417. endfunction()

  418. 

  419. # dpf__determine_vst3_package_architecture

  420. # ------------------------------------------------------------------------------

  421. #

  422. # Determines the package architecture for a VST3 plugin target.

  423. #

  424. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  425.   # if set by variable, override the detection

  426.   if(DPF_VST3_ARCHITECTURE)

  427.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  428.     return()

  429.   endif()

  430. 

  431.   # not used on Apple, which supports universal binary

  432.   if(APPLE)

  433.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  434.     return()

  435.   endif()

  436. 

  437.   # identify the target processor (special case of MSVC, problematic sometimes)

  438.   if(MSVC)

  439.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  440.   else()

  441.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  442.   endif()

  443. 

  444.   # transform the processor name to a format that VST3 recognizes

  445.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  446.     set(vst3_package_arch "x86_64")

  447.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  448.     if(WIN32)

  449.       set(vst3_package_arch "x86")

  450.     else()

  451.       set(vst3_package_arch "i386")

  452.     endif()

  453.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  454.     set(vst3_package_arch "${vst3_system_arch}")

  455.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  456.     set(vst3_package_arch "aarch64")

  457.   else()

  458.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  459.   endif()

  460. 

  461.   # TODO: the detections for Windows arm/arm64 when supported

  462. 

  463.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  464. endfunction()

  465. 

  466. # dpf__build_vst3

  467. # ------------------------------------------------------------------------------

  468. #

  469. # Add build rules for a VST3 plugin.

  470. #

  471. function(dpf__build_vst3 NAME HAS_UI)

  472.   dpf__determine_vst3_package_architecture(vst3_arch)

  473. 

  474.   dpf__create_dummy_source_list(_no_srcs)

  475. 

  476.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  477.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  478.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  479.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  480.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  481.   set_target_properties("${NAME}-vst3" PROPERTIES

  482.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  483.     OUTPUT_NAME "${NAME}"

  484.     PREFIX "")

  485. 

  486.   if(APPLE)

  487.     set_target_properties("${NAME}-vst3" PROPERTIES

  488.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  489.       SUFFIX "")

  490.   elseif(WIN32)

  491.     set_target_properties("${NAME}-vst3" PROPERTIES

  492.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  493.   else()

  494.     set_target_properties("${NAME}-vst3" PROPERTIES

  495.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  496.   endif()

  497. 

  498.   if(APPLE)

  499.     # Uses the same macOS bundle template as VST2

  500.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  501.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  502.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  503.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  504.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  505.   endif()

  506. endfunction()

  507. 

  508. # dpf__build_clap

  509. # ------------------------------------------------------------------------------

  510. #

  511. # Add build rules for a VST2 plugin.

  512. #

  513. function(dpf__build_clap NAME HAS_UI)

  514.   dpf__create_dummy_source_list(_no_srcs)

  515. 

  516.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  517.   dpf__add_plugin_main("${NAME}-clap" "clap")

  518.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  519.   dpf__set_module_export_list("${NAME}-clap" "clap")

  520.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  521.   set_target_properties("${NAME}-clap" PROPERTIES

  522.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  523.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  524.     OUTPUT_NAME "${NAME}"

  525.     PREFIX ""

  526.     SUFFIX ".clap")

  527. 

  528.   if(APPLE)

  529.     set_target_properties("${NAME}-clap" PROPERTIES

  530.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  531.       OUTPUT_NAME "${NAME}"

  532.       SUFFIX "")

  533.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  534.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  535.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  536.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  537.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  538.   endif()

  539. endfunction()

  540. 

  541. # dpf__add_dgl_cairo

  542. # ------------------------------------------------------------------------------

  543. #

  544. # Add the Cairo variant of DGL, if not already available.

  545. #

  546. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  547.   if(TARGET dgl-cairo)

  548.     return()

  549.   endif()

  550. 

  551.   find_package(PkgConfig)

  552.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  553. 

  554.   link_directories(${CAIRO_LIBRARY_DIRS})

  555. 

  556.   dpf__add_static_library(dgl-cairo STATIC

  557.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  558.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  559.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  560.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  561.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  562.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  563.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  564.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  565.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  566.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  567.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  568.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  569.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  570.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  571.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  572.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  573.   if(NO_SHARED_RESOURCES)

  574.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  575.   else()

  576.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  577.   endif()

  578.   if(NOT APPLE)

  579.     target_sources(dgl-cairo PRIVATE

  580.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  581.   else()

  582.     target_sources(dgl-cairo PRIVATE

  583.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  584.   endif()

  585.   target_include_directories(dgl-cairo PUBLIC

  586.     "${DPF_ROOT_DIR}/dgl")

  587.   target_include_directories(dgl-cairo PUBLIC

  588.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  589. 

  590.   dpf__add_dgl_system_libs()

  591.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  592. 

  593.   add_library(dgl-cairo-definitions INTERFACE)

  594.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  595. 

  596.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  597.   if(MINGW)

  598.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  599.   else()

  600.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  601.   endif()

  602.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  603. endfunction()

  604. 

  605. # dpf__add_dgl_opengl

  606. # ------------------------------------------------------------------------------

  607. #

  608. # Add the OpenGL variant of DGL, if not already available.

  609. #

  610. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  611.   if(TARGET dgl-opengl)

  612.     return()

  613.   endif()

  614. 

  615.   if(NOT OpenGL_GL_PREFERENCE)

  616.     set(OpenGL_GL_PREFERENCE "LEGACY")

  617.   endif()

  618. 

  619.   find_package(OpenGL REQUIRED)

  620. 

  621.   dpf__add_static_library(dgl-opengl STATIC

  622.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  623.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  624.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  625.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  626.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  627.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  628.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  629.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  630.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  631.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  632.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  633.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  634.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  635.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  636.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  637.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  638.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  639.   if(NO_SHARED_RESOURCES)

  640.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  641.   else()

  642.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  643.   endif()

  644.   if(NOT APPLE)

  645.     target_sources(dgl-opengl PRIVATE

  646.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  647.   else()

  648.     target_sources(dgl-opengl PRIVATE

  649.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  650.   endif()

  651.   target_include_directories(dgl-opengl PUBLIC

  652.     "${DPF_ROOT_DIR}/dgl")

  653.   target_include_directories(dgl-opengl PUBLIC

  654.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  655. 

  656.   if(APPLE)

  657.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  658.   endif()

  659. 

  660.   dpf__add_dgl_system_libs()

  661.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  662. 

  663.   add_library(dgl-opengl-definitions INTERFACE)

  664.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  665. 

  666.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  667.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  668. endfunction()

  669. 

  670. # dpf__add_plugin_specific_ui_sources

  671. # ------------------------------------------------------------------------------

  672. #

  673. # Compile system specific files, for now it is just Objective-C code

  674. #

  675. function(dpf__add_plugin_specific_ui_sources NAME)

  676.   if(APPLE)

  677.     target_sources("${NAME}" PRIVATE

  678.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  679.   endif()

  680. endfunction()

  681. 

  682. # dpf__add_dgl_system_libs

  683. # ------------------------------------------------------------------------------

  684. #

  685. # Find system libraries required by DGL and add them as an interface target.

  686. #

  687. function(dpf__add_dgl_system_libs)

  688.   if(TARGET dgl-system-libs)

  689.     return()

  690.   endif()

  691.   add_library(dgl-system-libs INTERFACE)

  692.   add_library(dgl-system-libs-definitions INTERFACE)

  693.   if(HAIKU)

  694.     target_link_libraries(dgl-system-libs INTERFACE "be")

  695.   elseif(WIN32)

  696.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  697.   elseif(APPLE)

  698.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  699.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  700.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  701.   else()

  702.     find_package(X11 REQUIRED)

  703.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  704.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  705.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  706.     if(X11_Xcursor_FOUND)

  707.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  708.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  709.     endif()

  710.     if(X11_Xext_FOUND)

  711.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  712.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  713.     endif()

  714.     if(X11_Xrandr_FOUND)

  715.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  716.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  717.     endif()

  718.     if(X11_XSync_FOUND)

  719.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  720.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  721.     endif()

  722.    endif()

  723. 

  724.    if(MSVC)

  725.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  726.      foreach(_gl_header "glext.h")

  727.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  728.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  729.        endif()

  730.      endforeach()

  731.      foreach(_khr_header "khrplatform.h")

  732.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  733.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  734.        endif()

  735.      endforeach()

  736.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  737.    endif()

  738. 

  739.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  740. endfunction()

  741. 

  742. # dpf__add_executable

  743. # ------------------------------------------------------------------------------

  744. #

  745. # Adds an executable target, and set some default properties on the target.

  746. #

  747. function(dpf__add_executable NAME)

  748.   add_executable("${NAME}" ${ARGN})

  749.   dpf__set_target_defaults("${NAME}")

  750.   if(MINGW)

  751.     target_link_libraries("${NAME}" PRIVATE "-static")

  752.   endif()

  753. endfunction()

  754. 

  755. # dpf__add_module

  756. # ------------------------------------------------------------------------------

  757. #

  758. # Adds a module target, and set some default properties on the target.

  759. #

  760. function(dpf__add_module NAME)

  761.   add_library("${NAME}" MODULE ${ARGN})

  762.   dpf__set_target_defaults("${NAME}")

  763.   if(MINGW)

  764.     target_link_libraries("${NAME}" PRIVATE "-static")

  765.   endif()

  766. endfunction()

  767. 

  768. # dpf__add_static_library

  769. # ------------------------------------------------------------------------------

  770. #

  771. # Adds a static library target, and set some default properties on the target.

  772. #

  773. function(dpf__add_static_library NAME)

  774.   add_library("${NAME}" STATIC ${ARGN})

  775.   dpf__set_target_defaults("${NAME}")

  776. endfunction()

  777. 

  778. # dpf__set_module_export_list

  779. # ------------------------------------------------------------------------------

  780. #

  781. # Applies a list of exported symbols to the module target.

  782. #

  783. function(dpf__set_module_export_list NAME EXPORTS)

  784.   if(WIN32)

  785.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  786.   elseif(APPLE)

  787.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  788.       "-Xlinker" "-exported_symbols_list"

  789.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  790.   else()

  791.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  792.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  793.   endif()

  794. endfunction()

  795. 

  796. # dpf__set_target_defaults

  797. # ------------------------------------------------------------------------------

  798. #

  799. # Set default properties which must apply to all DPF-defined targets.

  800. #

  801. function(dpf__set_target_defaults NAME)

  802.   set_target_properties("${NAME}" PROPERTIES

  803.     POSITION_INDEPENDENT_CODE TRUE

  804.     C_VISIBILITY_PRESET "hidden"

  805.     CXX_VISIBILITY_PRESET "hidden"

  806.     VISIBILITY_INLINES_HIDDEN TRUE)

  807.   if(WIN32)

  808.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  809.   endif()

  810.   if (MINGW)

  811.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  812.   endif()

  813.   if (MSVC)

  814.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  815.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  816.   endif()

  817.   if (CMAKE_COMPILER_IS_GNUCXX)

  818.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  819.   endif()

  820. endfunction()

  821. 

  822. # dpf__add_plugin_main

  823. # ------------------------------------------------------------------------------

  824. #

  825. # Adds plugin code to the given target.

  826. #

  827. function(dpf__add_plugin_main NAME TARGET)

  828.   target_sources("${NAME}" PRIVATE

  829.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  830.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  831. endfunction()

  832. 

  833. # dpf__add_ui_main

  834. # ------------------------------------------------------------------------------

  835. #

  836. # Adds UI code to the given target (only if the target has UI).

  837. #

  838. function(dpf__add_ui_main NAME TARGET HAS_UI)

  839.   if(HAS_UI)

  840.     target_sources("${NAME}" PRIVATE

  841.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  842.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  843.   endif()

  844. endfunction()

  845. 

  846. # dpf__add_plugin_target_definition

  847. # ------------------------------------------------------------------------------

  848. #

  849. # Adds the plugins target macro definition.

  850. # This selects which entry file is compiled according to the target type.

  851. #

  852. function(dpf__add_plugin_target_definition NAME TARGET)

  853.   string(TOUPPER "${TARGET}" _upperTarget)

  854.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  855. endfunction()

  856. 

  857. # dpf__add_lv2_ttl_generator

  858. # ------------------------------------------------------------------------------

  859. #

  860. # Build the LV2 TTL generator.

  861. #

  862. function(dpf__add_lv2_ttl_generator)

  863.   if(TARGET lv2_ttl_generator)

  864.     return()

  865.   endif()

  866.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  867.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  868.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  869.   endif()

  870. endfunction()

  871. 

  872. # dpf__ensure_sources_non_empty

  873. # ------------------------------------------------------------------------------

  874. #

  875. # Ensure the given source list contains at least one file.

  876. # The function appends an empty source file to the list if necessary.

  877. # This is useful when CMake does not permit to add targets without sources.

  878. #

  879. function(dpf__ensure_sources_non_empty VAR)

  880.   if(NOT "" STREQUAL "${${VAR}}")

  881.     return()

  882.   endif()

  883.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  884.   if(NOT EXISTS "${_file}")

  885.     file(WRITE "${_file}" "")

  886.   endif()

  887.   set("${VAR}" "${_file}" PARENT_SCOPE)

  888. endfunction()

  889. 

  890. # dpf__create_dummy_source_list

  891. # ------------------------------------------------------------------------------

  892. #

  893. # Create a dummy source list which is equivalent to compiling nothing.

  894. # This is only for compatibility with older CMake versions, which refuse to add

  895. # targets without any sources.

  896. #

  897. macro(dpf__create_dummy_source_list VAR)

  898.   set("${VAR}")

  899.   if(CMAKE_VERSION VERSION_LESS "3.11")

  900.     dpf__ensure_sources_non_empty("${VAR}")

  901.   endif()

  902. endmacro()

  903. 

  904. # dpf__target_link_directories

  905. # ------------------------------------------------------------------------------

  906. #

  907. # Call `target_link_directories` if cmake >= 3.13,

  908. # otherwise fallback to global `link_directories`.

  909. #

  910. macro(dpf__target_link_directories NAME DIRS)

  911.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  912.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  913.   else()

  914.     link_directories(${DIRS})

  915.   endif()

  916. endmacro()

  917. 

  918. # dpf__warn_once

  919. # ------------------------------------------------------------------------------

  920. #

  921. # Prints a warning message once only.

  922. #

  923. function(dpf__warn_once_only TOKEN MESSAGE)

  924.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  925.   if(NOT _warned)

  926.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  927.     message(WARNING "${MESSAGE}")

  928.   endif()

  929. endfunction()