DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1079 Commits
7 Branches
302MB
Tree: 8cc6eb8f2f
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '8cc6eb8f2f'
${ noResults }
DPF/cmake/DPF-plugin.cmake

665 lines
23KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   find_package(PkgConfig)

  177.   pkg_check_modules(JACK "jack")

  178.   if(NOT JACK_FOUND)

  179.     dpf__warn_once_only(missing_jack

  180.       "JACK is not found, skipping the `jack` plugin targets")

  181.     return()

  182.   endif()

  183. 

  184.   link_directories(${JACK_LIBRARY_DIRS})

  185. 

  186.   dpf__create_dummy_source_list(_no_srcs)

  187. 

  188.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  189.   dpf__add_plugin_main("${NAME}-jack" "jack")

  190.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  191.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  192.   set_target_properties("${NAME}-jack" PROPERTIES

  193.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  194.     OUTPUT_NAME "${NAME}")

  195. 

  196.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  197.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  198. endfunction()

  199. 

  200. # dpf__build_ladspa

  201. # ------------------------------------------------------------------------------

  202. #

  203. # Add build rules for a DSSI plugin.

  204. #

  205. function(dpf__build_ladspa NAME)

  206.   dpf__create_dummy_source_list(_no_srcs)

  207. 

  208.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  209.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  210.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  211.   set_target_properties("${NAME}-ladspa" PROPERTIES

  212.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  213.     OUTPUT_NAME "${NAME}-ladspa"

  214.     PREFIX "")

  215. endfunction()

  216. 

  217. # dpf__build_dssi

  218. # ------------------------------------------------------------------------------

  219. #

  220. # Add build rules for a DSSI plugin.

  221. #

  222. function(dpf__build_dssi NAME DGL_LIBRARY)

  223.   find_package(PkgConfig)

  224.   pkg_check_modules(LIBLO "liblo")

  225.   if(NOT LIBLO_FOUND)

  226.     dpf__warn_once_only(missing_liblo

  227.       "liblo is not found, skipping the `dssi` plugin targets")

  228.     return()

  229.   endif()

  230. 

  231.   link_directories(${LIBLO_LIBRARY_DIRS})

  232. 

  233.   dpf__create_dummy_source_list(_no_srcs)

  234. 

  235.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  236.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  237.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  238.   set_target_properties("${NAME}-dssi" PROPERTIES

  239.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  240.     OUTPUT_NAME "${NAME}-dssi"

  241.     PREFIX "")

  242. 

  243.   if(DGL_LIBRARY)

  244.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  245.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  246.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  247.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  248.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  249.       OUTPUT_NAME "${NAME}_ui")

  250. 

  251.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  252.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  253.   endif()

  254. endfunction()

  255. 

  256. # dpf__build_lv2

  257. # ------------------------------------------------------------------------------

  258. #

  259. # Add build rules for a LV2 plugin.

  260. #

  261. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  262.   dpf__create_dummy_source_list(_no_srcs)

  263. 

  264.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  265.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  266.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  267.   set_target_properties("${NAME}-lv2" PROPERTIES

  268.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  269.     OUTPUT_NAME "${NAME}_dsp"

  270.     PREFIX "")

  271. 

  272.   if(DGL_LIBRARY)

  273.     if(MONOLITHIC)

  274.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  275.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  276.       set_target_properties("${NAME}-lv2" PROPERTIES

  277.         OUTPUT_NAME "${NAME}")

  278.     else()

  279.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  280.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  281.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  282.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  283.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  284.         OUTPUT_NAME "${NAME}_ui"

  285.         PREFIX "")

  286.     endif()

  287.   endif()

  288. 

  289.   dpf__add_lv2_ttl_generator()

  290.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  291. 

  292.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  293.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  294.     "$<TARGET_FILE:lv2_ttl_generator>"

  295.     "$<TARGET_FILE:${NAME}-lv2>"

  296.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  297.     DEPENDS lv2_ttl_generator)

  298. endfunction()

  299. 

  300. # dpf__build_vst2

  301. # ------------------------------------------------------------------------------

  302. #

  303. # Add build rules for a VST2 plugin.

  304. #

  305. function(dpf__build_vst2 NAME DGL_LIBRARY)

  306.   dpf__create_dummy_source_list(_no_srcs)

  307. 

  308.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  309.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  310.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  311.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  312.   set_target_properties("${NAME}-vst2" PROPERTIES

  313.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  314.     OUTPUT_NAME "${NAME}-vst2"

  315.     PREFIX "")

  316. endfunction()

  317. 

  318. # dpf__add_dgl_cairo

  319. # ------------------------------------------------------------------------------

  320. #

  321. # Add the Cairo variant of DGL, if not already available.

  322. #

  323. function(dpf__add_dgl_cairo)

  324.   if(TARGET dgl-cairo)

  325.     return()

  326.   endif()

  327. 

  328.   find_package(PkgConfig)

  329.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  330. 

  331.   link_directories(${CAIRO_LIBRARY_DIRS})

  332. 

  333.   dpf__add_static_library(dgl-cairo STATIC

  334.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  343.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  344.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  345.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  346.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  347.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  348.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  349.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  350.   if(NOT APPLE)

  351.     target_sources(dgl-cairo PRIVATE

  352.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  353.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  354.     #target_sources(dgl-opengl PRIVATE

  355.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  356.   endif()

  357.   target_include_directories(dgl-cairo PUBLIC

  358.     "${DPF_ROOT_DIR}/dgl")

  359.   target_include_directories(dgl-cairo PUBLIC

  360.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  361. 

  362.   dpf__add_dgl_system_libs()

  363.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  364. 

  365.   add_library(dgl-cairo-definitions INTERFACE)

  366.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  367. 

  368.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  369.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  370. endfunction()

  371. 

  372. # dpf__add_dgl_opengl

  373. # ------------------------------------------------------------------------------

  374. #

  375. # Add the OpenGL variant of DGL, if not already available.

  376. #

  377. function(dpf__add_dgl_opengl)

  378.   if(TARGET dgl-opengl)

  379.     return()

  380.   endif()

  381. 

  382.   if(NOT OpenGL_GL_PREFERENCE)

  383.     set(OpenGL_GL_PREFERENCE "LEGACY")

  384.   endif()

  385. 

  386.   find_package(OpenGL REQUIRED)

  387. 

  388.   dpf__add_static_library(dgl-opengl STATIC

  389.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  390.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  391.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  392.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  393.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  394.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  405.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  406.   if(NOT APPLE)

  407.     target_sources(dgl-opengl PRIVATE

  408.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  409.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  410.     #target_sources(dgl-opengl PRIVATE

  411.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  412.   endif()

  413.   target_include_directories(dgl-opengl PUBLIC

  414.     "${DPF_ROOT_DIR}/dgl")

  415.   target_include_directories(dgl-opengl PUBLIC

  416.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  417. 

  418.   if(APPLE)

  419.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  420.   endif()

  421. 

  422.   dpf__add_dgl_system_libs()

  423.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  424. 

  425.   add_library(dgl-opengl-definitions INTERFACE)

  426.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  427. 

  428.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  429.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  430. endfunction()

  431. 

  432. # dpf__add_plugin_specific_ui_sources

  433. # ------------------------------------------------------------------------------

  434. #

  435. # Compile plugin-specific UI sources into the target designated by the given

  436. # name. There are some special considerations here:

  437. # - On most platforms, sources can be compiled only once, as part of DGL;

  438. # - On macOS, for any sources which define Objective-C interfaces, these must

  439. #   be recompiled for each plugin under a unique namespace. In this case, the

  440. #   name must be a plugin-specific identifier, and it will be used for computing

  441. #   the unique ID along with the project version.

  442. function(dpf__add_plugin_specific_ui_sources NAME)

  443.   if(APPLE)

  444.     target_sources("${NAME}" PRIVATE

  445.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  446.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  447.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  448.   endif()

  449. endfunction()

  450. 

  451. # dpf__add_dgl_system_libs

  452. # ------------------------------------------------------------------------------

  453. #

  454. # Find system libraries required by DGL and add them as an interface target.

  455. #

  456. function(dpf__add_dgl_system_libs)

  457.   if(TARGET dgl-system-libs)

  458.     return()

  459.   endif()

  460.   add_library(dgl-system-libs INTERFACE)

  461.   add_library(dgl-system-libs-definitions INTERFACE)

  462.   if(HAIKU)

  463.     target_link_libraries(dgl-system-libs INTERFACE "be")

  464.   elseif(WIN32)

  465.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  466.   elseif(APPLE)

  467.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  468.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  469.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  470.   else()

  471.     find_package(X11 REQUIRED)

  472.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  473.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  474.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  475.     if(X11_Xext_FOUND)

  476.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  477.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  478.     endif()

  479.     if(X11_XSync_FOUND)

  480.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  481.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  482.     endif()

  483.     if(X11_Xrandr_FOUND)

  484.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  485.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  486.     endif()

  487.     #if(X11_Xcursor_FOUND)

  488.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  489.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  490.     #endif()

  491.    endif()

  492. 

  493.    if(MSVC)

  494.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  495.      foreach(_gl_header "glext.h")

  496.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  497.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  498.        endif()

  499.      endforeach()

  500.      foreach(_khr_header "khrplatform.h")

  501.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  502.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  503.        endif()

  504.      endforeach()

  505.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  506.    endif()

  507. 

  508.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  509. endfunction()

  510. 

  511. # dpf__add_executable

  512. # ------------------------------------------------------------------------------

  513. #

  514. # Adds an executable target, and set some default properties on the target.

  515. #

  516. function(dpf__add_executable NAME)

  517.   add_executable("${NAME}" ${ARGN})

  518.   dpf__set_target_defaults("${NAME}")

  519. endfunction()

  520. 

  521. # dpf__add_module

  522. # ------------------------------------------------------------------------------

  523. #

  524. # Adds a module target, and set some default properties on the target.

  525. #

  526. function(dpf__add_module NAME)

  527.   add_library("${NAME}" MODULE ${ARGN})

  528.   dpf__set_target_defaults("${NAME}")

  529. endfunction()

  530. 

  531. # dpf__add_static_library

  532. # ------------------------------------------------------------------------------

  533. #

  534. # Adds a static library target, and set some default properties on the target.

  535. #

  536. function(dpf__add_static_library NAME)

  537.   add_library("${NAME}" STATIC ${ARGN})

  538.   dpf__set_target_defaults("${NAME}")

  539. endfunction()

  540. 

  541. # dpf__set_target_defaults

  542. # ------------------------------------------------------------------------------

  543. #

  544. # Set default properties which must apply to all DPF-defined targets.

  545. #

  546. function(dpf__set_target_defaults NAME)

  547.   set_target_properties("${NAME}" PROPERTIES

  548.     POSITION_INDEPENDENT_CODE TRUE

  549.     C_VISIBILITY_PRESET "hidden"

  550.     CXX_VISIBILITY_PRESET "hidden"

  551.     VISIBILITY_INLINES_HIDDEN TRUE)

  552.   if(WIN32)

  553.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  554.   endif()

  555.   if (MINGW)

  556.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  557.   endif()

  558.   if (MSVC)

  559.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  560.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  561.   endif()

  562. endfunction()

  563. 

  564. # dpf__add_plugin_main

  565. # ------------------------------------------------------------------------------

  566. #

  567. # Adds plugin code to the given target.

  568. #

  569. function(dpf__add_plugin_main NAME TARGET)

  570.   target_sources("${NAME}" PRIVATE

  571.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  572.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  573. endfunction()

  574. 

  575. # dpf__add_ui_main

  576. # ------------------------------------------------------------------------------

  577. #

  578. # Adds UI code to the given target (only if the target has UI).

  579. #

  580. function(dpf__add_ui_main NAME TARGET HAS_UI)

  581.   if(HAS_UI)

  582.     target_sources("${NAME}" PRIVATE

  583.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  584.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  585.   endif()

  586. endfunction()

  587. 

  588. # dpf__add_plugin_target_definition

  589. # ------------------------------------------------------------------------------

  590. #

  591. # Adds the plugins target macro definition.

  592. # This selects which entry file is compiled according to the target type.

  593. #

  594. function(dpf__add_plugin_target_definition NAME TARGET)

  595.   string(TOUPPER "${TARGET}" _upperTarget)

  596. 

  597.   # resolve the alias into the proper name

  598.   # the name "vst2" is new, "vst" is legacy

  599.   if(_upperTarget STREQUAL "VST2")

  600.     set(_upperTarget "VST")

  601.   endif()

  602. 

  603.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  604. endfunction()

  605. 

  606. # dpf__add_lv2_ttl_generator

  607. # ------------------------------------------------------------------------------

  608. #

  609. # Build the LV2 TTL generator.

  610. #

  611. function(dpf__add_lv2_ttl_generator)

  612.   if(TARGET lv2_ttl_generator)

  613.     return()

  614.   endif()

  615.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  616.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  617.     target_link_libraries(lv2_ttl_generator "dl")

  618.   endif()

  619. endfunction()

  620. 

  621. # dpf__ensure_sources_non_empty

  622. # ------------------------------------------------------------------------------

  623. #

  624. # Ensure the given source list contains at least one file.

  625. # The function appends an empty source file to the list if necessary.

  626. # This is useful when CMake does not permit to add targets without sources.

  627. #

  628. function(dpf__ensure_sources_non_empty VAR)

  629.   if(NOT "" STREQUAL "${${VAR}}")

  630.     return()

  631.   endif()

  632.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  633.   if(NOT EXISTS "${_file}")

  634.     file(WRITE "${_file}" "")

  635.   endif()

  636.   set("${VAR}" "${_file}" PARENT_SCOPE)

  637. endfunction()

  638. 

  639. # dpf__create_dummy_source_list

  640. # ------------------------------------------------------------------------------

  641. #

  642. # Create a dummy source list which is equivalent to compiling nothing.

  643. # This is only for compatibility with older CMake versions, which refuse to add

  644. # targets without any sources.

  645. #

  646. macro(dpf__create_dummy_source_list VAR)

  647.   set("${VAR}")

  648.   if(CMAKE_VERSION VERSION_LESS "3.11")

  649.     dpf__ensure_sources_non_empty("${VAR}")

  650.   endif()

  651. endmacro()

  652. 

  653. # dpf__warn_once

  654. # ------------------------------------------------------------------------------

  655. #

  656. # Prints a warning message once only.

  657. #

  658. function(dpf__warn_once_only TOKEN MESSAGE)

  659.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  660.   if(NOT _warned)

  661.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  662.     message(WARNING "${MESSAGE}")

  663.   endif()

  664. endfunction()