DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2108 Commits
7 Branches
295MB
Tree: 8a545127cd
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '8a545127cd'
${ noResults }
DPF/cmake/DPF-plugin.cmake

927 lines
33KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`, `external`

  79. #

  80. #   `FILES_COMMON` <file1>...<fileN>

  81. #       list of sources which are part of both DSP and UI

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `MODGUI_CLASS_NAME`

  91. #       class name to use for modgui builds

  92. #

  93. #   `MONOLITHIC`

  94. #       build LV2 as a single binary for UI and DSP

  95. #

  96. #   `NO_SHARED_RESOURCES`

  97. #       do not build DPF shared resources (fonts, etc)

  98. #

  99. function(dpf_add_plugin NAME)

  100.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  101.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  102.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  103.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  104. 

  105.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  106.     set(_dpf_plugin_UI_TYPE "opengl")

  107.   endif()

  108. 

  109.   set(_dgl_library)

  110.   set(_dgl_external OFF)

  111.   if(_dpf_plugin_FILES_UI)

  112.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  113.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  114.       set(_dgl_library dgl-cairo)

  115.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  116.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  117.       set(_dgl_library dgl-opengl)

  118.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  119.       set(_dgl_external ON)

  120.     else()

  121.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  122.     endif()

  123.   endif()

  124. 

  125.   set(_dgl_has_ui OFF)

  126.   if(_dgl_library OR _dgl_external)

  127.     set(_dgl_has_ui ON)

  128.   endif()

  129. 

  130.   ###

  131.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  132.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  133.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  134. 

  135.   ###

  136.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  137.   target_include_directories("${NAME}" PUBLIC

  138.     "${DPF_ROOT_DIR}/distrho")

  139. 

  140.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  141.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  142.   endif()

  143. 

  144.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  145.     target_link_libraries("${NAME}" PRIVATE "dl")

  146.   endif()

  147. 

  148.   if(_dgl_library AND NOT _dgl_external)

  149.     # make sure that all code will see DGL_* definitions

  150.     target_link_libraries("${NAME}" PUBLIC

  151.       "${_dgl_library}-definitions"

  152.       dgl-system-libs-definitions)

  153.   endif()

  154. 

  155.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  156.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  157. 

  158.   if(_dgl_library AND NOT _dgl_external)

  159.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  160.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  161.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  162.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  163.     endif()

  164.     # add the files containing Objective-C classes

  165.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  166.   elseif(_dgl_external)

  167.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  168.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}")

  169.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  170.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  171.     endif()

  172.     # add the files containing Objective-C classes

  173.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  174.   else()

  175.     add_library("${NAME}-ui" INTERFACE)

  176.   endif()

  177. 

  178.   ###

  179.   foreach(_target ${_dpf_plugin_TARGETS})

  180.     if(_target STREQUAL "jack")

  181.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  182.     elseif(_target STREQUAL "ladspa")

  183.       dpf__build_ladspa("${NAME}")

  184.     elseif(_target STREQUAL "dssi")

  185.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  186.     elseif(_target STREQUAL "lv2")

  187.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  188.     elseif(_target STREQUAL "vst2")

  189.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  190.     elseif(_target STREQUAL "vst3")

  191.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  192.     elseif(_target STREQUAL "clap")

  193.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  194.     else()

  195.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  196.     endif()

  197.   endforeach()

  198. endfunction()

  199. 

  200. # ------------------------------------------------------------------------------

  201. # DPF private functions (prefixed with `dpf__`)

  202. # ------------------------------------------------------------------------------

  203. 

  204. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  205. #       to the output directory.

  206. #

  207. 

  208. # dpf__build_jack

  209. # ------------------------------------------------------------------------------

  210. #

  211. # Add build rules for a JACK/Standalone program.

  212. #

  213. function(dpf__build_jack NAME HAS_UI)

  214.   dpf__create_dummy_source_list(_no_srcs)

  215. 

  216.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  217.   dpf__add_plugin_main("${NAME}-jack" "jack")

  218.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  219.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  220.   set_target_properties("${NAME}-jack" PROPERTIES

  221.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  222.     OUTPUT_NAME "${NAME}")

  223. 

  224.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  225. 

  226.   find_package(PkgConfig)

  227.   pkg_check_modules(SDL2 "sdl2")

  228.   if(SDL2_FOUND)

  229.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  230.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  231.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  232.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  233.   endif()

  234. 

  235.   if(APPLE OR WIN32)

  236.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  237.   else()

  238.     find_package(Threads)

  239.     pkg_check_modules(ALSA "alsa")

  240.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  241.     if(ALSA_FOUND)

  242.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  243.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  244.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  245.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  246.     endif()

  247.     if(PULSEAUDIO_FOUND)

  248.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  249.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  250.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  251.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  252.     endif()

  253.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  254.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  255.     endif()

  256.   endif()

  257. 

  258.   # for RtAudio native fallback

  259.   if(APPLE)

  260.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  261.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  262.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  263.     target_link_libraries("${NAME}-jack" PRIVATE

  264.       "${APPLE_COREAUDIO_FRAMEWORK}"

  265.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  266.       "${APPLE_COREMIDI_FRAMEWORK}")

  267.   elseif(WIN32)

  268.     target_link_libraries("${NAME}-jack" PRIVATE "dsound" "ole32" "winmm")

  269.   endif()

  270. endfunction()

  271. 

  272. # dpf__build_ladspa

  273. # ------------------------------------------------------------------------------

  274. #

  275. # Add build rules for a LADSPA plugin.

  276. #

  277. function(dpf__build_ladspa NAME)

  278.   dpf__create_dummy_source_list(_no_srcs)

  279. 

  280.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  281.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  282.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  283.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  284.   set_target_properties("${NAME}-ladspa" PROPERTIES

  285.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  286.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  287.     OUTPUT_NAME "${NAME}-ladspa"

  288.     PREFIX "")

  289. endfunction()

  290. 

  291. # dpf__build_dssi

  292. # ------------------------------------------------------------------------------

  293. #

  294. # Add build rules for a DSSI plugin.

  295. #

  296. function(dpf__build_dssi NAME HAS_UI)

  297.   find_package(PkgConfig)

  298.   pkg_check_modules(LIBLO "liblo")

  299.   if(NOT LIBLO_FOUND)

  300.     dpf__warn_once_only(missing_liblo

  301.       "liblo is not found, skipping the `dssi` plugin targets")

  302.     return()

  303.   endif()

  304. 

  305.   dpf__create_dummy_source_list(_no_srcs)

  306. 

  307.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  308.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  309.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  310.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  311.   set_target_properties("${NAME}-dssi" PROPERTIES

  312.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  313.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  314.     OUTPUT_NAME "${NAME}-dssi"

  315.     PREFIX "")

  316. 

  317.   if(HAS_UI)

  318.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  319.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  320.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  321.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  322.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  323.       OUTPUT_NAME "${NAME}_ui")

  324. 

  325.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  326.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  327.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  328.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  329.   endif()

  330. endfunction()

  331. 

  332. # dpf__build_lv2

  333. # ------------------------------------------------------------------------------

  334. #

  335. # Add build rules for an LV2 plugin.

  336. #

  337. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  338.   dpf__create_dummy_source_list(_no_srcs)

  339. 

  340.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  341.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  342.   if(HAS_UI AND MONOLITHIC)

  343.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  344.   else()

  345.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  346.   endif()

  347.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  348.   set_target_properties("${NAME}-lv2" PROPERTIES

  349.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  350.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  351.     OUTPUT_NAME "${NAME}_dsp"

  352.     PREFIX "")

  353. 

  354.   if(HAS_UI)

  355.     if(MONOLITHIC)

  356.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  357.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  358.       set_target_properties("${NAME}-lv2" PROPERTIES

  359.         OUTPUT_NAME "${NAME}")

  360.     else()

  361.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  362.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  363.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  364.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  365.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  366.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  367.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  368.         OUTPUT_NAME "${NAME}_ui"

  369.         PREFIX "")

  370.     endif()

  371.   endif()

  372. 

  373.   dpf__add_lv2_ttl_generator()

  374.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  375. 

  376.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  377.     COMMAND

  378.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  379.     "$<TARGET_FILE:lv2_ttl_generator>"

  380.     "$<TARGET_FILE:${NAME}-lv2>"

  381.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  382.     DEPENDS lv2_ttl_generator)

  383. endfunction()

  384. 

  385. # dpf__build_vst2

  386. # ------------------------------------------------------------------------------

  387. #

  388. # Add build rules for a VST2 plugin.

  389. #

  390. function(dpf__build_vst2 NAME HAS_UI)

  391.   dpf__create_dummy_source_list(_no_srcs)

  392. 

  393.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  394.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  395.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  396.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  397.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  398.   set_target_properties("${NAME}-vst2" PROPERTIES

  399.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  400.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  401.     OUTPUT_NAME "${NAME}-vst2"

  402.     PREFIX "")

  403.   if(APPLE)

  404.     set_target_properties("${NAME}-vst2" PROPERTIES

  405.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  406.       OUTPUT_NAME "${NAME}"

  407.       SUFFIX "")

  408.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  409.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  410.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  411.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  412.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  413.   endif()

  414. endfunction()

  415. 

  416. # dpf__determine_vst3_package_architecture

  417. # ------------------------------------------------------------------------------

  418. #

  419. # Determines the package architecture for a VST3 plugin target.

  420. #

  421. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  422.   # if set by variable, override the detection

  423.   if(DPF_VST3_ARCHITECTURE)

  424.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  425.     return()

  426.   endif()

  427. 

  428.   # not used on Apple, which supports universal binary

  429.   if(APPLE)

  430.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  431.     return()

  432.   endif()

  433. 

  434.   # identify the target processor (special case of MSVC, problematic sometimes)

  435.   if(MSVC)

  436.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  437.   else()

  438.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  439.   endif()

  440. 

  441.   # transform the processor name to a format that VST3 recognizes

  442.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  443.     set(vst3_package_arch "x86_64")

  444.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  445.     if(WIN32)

  446.       set(vst3_package_arch "x86")

  447.     else()

  448.       set(vst3_package_arch "i386")

  449.     endif()

  450.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  451.     set(vst3_package_arch "${vst3_system_arch}")

  452.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  453.     set(vst3_package_arch "aarch64")

  454.   else()

  455.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  456.   endif()

  457. 

  458.   # TODO: the detections for Windows arm/arm64 when supported

  459. 

  460.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  461. endfunction()

  462. 

  463. # dpf__build_vst3

  464. # ------------------------------------------------------------------------------

  465. #

  466. # Add build rules for a VST3 plugin.

  467. #

  468. function(dpf__build_vst3 NAME HAS_UI)

  469.   dpf__determine_vst3_package_architecture(vst3_arch)

  470. 

  471.   dpf__create_dummy_source_list(_no_srcs)

  472. 

  473.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  474.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  475.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  476.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  477.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  478.   set_target_properties("${NAME}-vst3" PROPERTIES

  479.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  480.     OUTPUT_NAME "${NAME}"

  481.     PREFIX "")

  482. 

  483.   if(APPLE)

  484.     set_target_properties("${NAME}-vst3" PROPERTIES

  485.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  486.       SUFFIX "")

  487.   elseif(WIN32)

  488.     set_target_properties("${NAME}-vst3" PROPERTIES

  489.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  490.   else()

  491.     set_target_properties("${NAME}-vst3" PROPERTIES

  492.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  493.   endif()

  494. 

  495.   if(APPLE)

  496.     # Uses the same macOS bundle template as VST2

  497.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  498.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  499.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  500.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  501.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  502.   endif()

  503. endfunction()

  504. 

  505. # dpf__build_clap

  506. # ------------------------------------------------------------------------------

  507. #

  508. # Add build rules for a VST2 plugin.

  509. #

  510. function(dpf__build_clap NAME HAS_UI)

  511.   dpf__create_dummy_source_list(_no_srcs)

  512. 

  513.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  514.   dpf__add_plugin_main("${NAME}-clap" "clap")

  515.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  516.   dpf__set_module_export_list("${NAME}-clap" "clap")

  517.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  518.   set_target_properties("${NAME}-clap" PROPERTIES

  519.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  520.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  521.     OUTPUT_NAME "${NAME}"

  522.     PREFIX ""

  523.     SUFFIX ".clap")

  524. 

  525.   if(APPLE)

  526.     set_target_properties("${NAME}-clap" PROPERTIES

  527.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  528.       OUTPUT_NAME "${NAME}"

  529.       SUFFIX "")

  530.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  531.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  532.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  533.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  534.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  535.   endif()

  536. endfunction()

  537. 

  538. # dpf__add_dgl_cairo

  539. # ------------------------------------------------------------------------------

  540. #

  541. # Add the Cairo variant of DGL, if not already available.

  542. #

  543. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  544.   if(TARGET dgl-cairo)

  545.     return()

  546.   endif()

  547. 

  548.   find_package(PkgConfig)

  549.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  550. 

  551.   link_directories(${CAIRO_LIBRARY_DIRS})

  552. 

  553.   dpf__add_static_library(dgl-cairo STATIC

  554.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  555.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  556.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  557.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  558.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  559.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  560.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  561.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  562.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  563.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  564.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  565.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  566.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  567.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  568.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  569.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  570.   if(NO_SHARED_RESOURCES)

  571.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  572.   else()

  573.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  574.   endif()

  575.   if(NOT APPLE)

  576.     target_sources(dgl-cairo PRIVATE

  577.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  578.   else()

  579.     target_sources(dgl-cairo PRIVATE

  580.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  581.   endif()

  582.   target_include_directories(dgl-cairo PUBLIC

  583.     "${DPF_ROOT_DIR}/dgl")

  584.   target_include_directories(dgl-cairo PUBLIC

  585.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  586. 

  587.   dpf__add_dgl_system_libs()

  588.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  589. 

  590.   add_library(dgl-cairo-definitions INTERFACE)

  591.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  592. 

  593.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  594.   if(MINGW)

  595.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  596.   else()

  597.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  598.   endif()

  599.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  600. endfunction()

  601. 

  602. # dpf__add_dgl_opengl

  603. # ------------------------------------------------------------------------------

  604. #

  605. # Add the OpenGL variant of DGL, if not already available.

  606. #

  607. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  608.   if(TARGET dgl-opengl)

  609.     return()

  610.   endif()

  611. 

  612.   if(NOT OpenGL_GL_PREFERENCE)

  613.     set(OpenGL_GL_PREFERENCE "LEGACY")

  614.   endif()

  615. 

  616.   find_package(OpenGL REQUIRED)

  617. 

  618.   dpf__add_static_library(dgl-opengl STATIC

  619.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  620.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  621.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  622.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  623.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  624.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  625.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  626.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  627.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  628.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  629.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  630.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  631.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  632.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  633.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  634.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  635.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  636.   if(NO_SHARED_RESOURCES)

  637.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  638.   else()

  639.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  640.   endif()

  641.   if(NOT APPLE)

  642.     target_sources(dgl-opengl PRIVATE

  643.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  644.   else()

  645.     target_sources(dgl-opengl PRIVATE

  646.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  647.   endif()

  648.   target_include_directories(dgl-opengl PUBLIC

  649.     "${DPF_ROOT_DIR}/dgl")

  650.   target_include_directories(dgl-opengl PUBLIC

  651.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  652. 

  653.   if(APPLE)

  654.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  655.   endif()

  656. 

  657.   dpf__add_dgl_system_libs()

  658.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  659. 

  660.   add_library(dgl-opengl-definitions INTERFACE)

  661.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  662. 

  663.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  664.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  665. endfunction()

  666. 

  667. # dpf__add_plugin_specific_ui_sources

  668. # ------------------------------------------------------------------------------

  669. #

  670. # Compile system specific files, for now it is just Objective-C code

  671. #

  672. function(dpf__add_plugin_specific_ui_sources NAME)

  673.   if(APPLE)

  674.     target_sources("${NAME}" PRIVATE

  675.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  676.   endif()

  677. endfunction()

  678. 

  679. # dpf__add_dgl_system_libs

  680. # ------------------------------------------------------------------------------

  681. #

  682. # Find system libraries required by DGL and add them as an interface target.

  683. #

  684. function(dpf__add_dgl_system_libs)

  685.   if(TARGET dgl-system-libs)

  686.     return()

  687.   endif()

  688.   add_library(dgl-system-libs INTERFACE)

  689.   add_library(dgl-system-libs-definitions INTERFACE)

  690.   if(HAIKU)

  691.     target_link_libraries(dgl-system-libs INTERFACE "be")

  692.   elseif(WIN32)

  693.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  694.   elseif(APPLE)

  695.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  696.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  697.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  698.   else()

  699.     find_package(X11 REQUIRED)

  700.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  701.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  702.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  703.     if(X11_Xcursor_FOUND)

  704.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  705.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  706.     endif()

  707.     if(X11_Xext_FOUND)

  708.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  709.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  710.     endif()

  711.     if(X11_Xrandr_FOUND)

  712.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  713.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  714.     endif()

  715.     if(X11_XSync_FOUND)

  716.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  717.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  718.     endif()

  719.    endif()

  720. 

  721.    if(MSVC)

  722.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  723.      foreach(_gl_header "glext.h")

  724.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  725.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  726.        endif()

  727.      endforeach()

  728.      foreach(_khr_header "khrplatform.h")

  729.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  730.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  731.        endif()

  732.      endforeach()

  733.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  734.    endif()

  735. 

  736.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  737. endfunction()

  738. 

  739. # dpf__add_executable

  740. # ------------------------------------------------------------------------------

  741. #

  742. # Adds an executable target, and set some default properties on the target.

  743. #

  744. function(dpf__add_executable NAME)

  745.   add_executable("${NAME}" ${ARGN})

  746.   dpf__set_target_defaults("${NAME}")

  747.   if(MINGW)

  748.     target_link_libraries("${NAME}" PRIVATE "-static")

  749.   endif()

  750. endfunction()

  751. 

  752. # dpf__add_module

  753. # ------------------------------------------------------------------------------

  754. #

  755. # Adds a module target, and set some default properties on the target.

  756. #

  757. function(dpf__add_module NAME)

  758.   add_library("${NAME}" MODULE ${ARGN})

  759.   dpf__set_target_defaults("${NAME}")

  760.   if(MINGW)

  761.     target_link_libraries("${NAME}" PRIVATE "-static")

  762.   endif()

  763. endfunction()

  764. 

  765. # dpf__add_static_library

  766. # ------------------------------------------------------------------------------

  767. #

  768. # Adds a static library target, and set some default properties on the target.

  769. #

  770. function(dpf__add_static_library NAME)

  771.   add_library("${NAME}" STATIC ${ARGN})

  772.   dpf__set_target_defaults("${NAME}")

  773. endfunction()

  774. 

  775. # dpf__set_module_export_list

  776. # ------------------------------------------------------------------------------

  777. #

  778. # Applies a list of exported symbols to the module target.

  779. #

  780. function(dpf__set_module_export_list NAME EXPORTS)

  781.   if(WIN32)

  782.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  783.   elseif(APPLE)

  784.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  785.       "-Xlinker" "-exported_symbols_list"

  786.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  787.   else()

  788.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  789.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  790.   endif()

  791. endfunction()

  792. 

  793. # dpf__set_target_defaults

  794. # ------------------------------------------------------------------------------

  795. #

  796. # Set default properties which must apply to all DPF-defined targets.

  797. #

  798. function(dpf__set_target_defaults NAME)

  799.   set_target_properties("${NAME}" PROPERTIES

  800.     POSITION_INDEPENDENT_CODE TRUE

  801.     C_VISIBILITY_PRESET "hidden"

  802.     CXX_VISIBILITY_PRESET "hidden"

  803.     VISIBILITY_INLINES_HIDDEN TRUE)

  804.   if(WIN32)

  805.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  806.   endif()

  807.   if (MINGW)

  808.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  809.   endif()

  810.   if (MSVC)

  811.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  812.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  813.   endif()

  814.   if (CMAKE_COMPILER_IS_GNUCXX)

  815.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  816.   endif()

  817. endfunction()

  818. 

  819. # dpf__add_plugin_main

  820. # ------------------------------------------------------------------------------

  821. #

  822. # Adds plugin code to the given target.

  823. #

  824. function(dpf__add_plugin_main NAME TARGET)

  825.   target_sources("${NAME}" PRIVATE

  826.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  827.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  828. endfunction()

  829. 

  830. # dpf__add_ui_main

  831. # ------------------------------------------------------------------------------

  832. #

  833. # Adds UI code to the given target (only if the target has UI).

  834. #

  835. function(dpf__add_ui_main NAME TARGET HAS_UI)

  836.   if(HAS_UI)

  837.     target_sources("${NAME}" PRIVATE

  838.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  839.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  840.   endif()

  841. endfunction()

  842. 

  843. # dpf__add_plugin_target_definition

  844. # ------------------------------------------------------------------------------

  845. #

  846. # Adds the plugins target macro definition.

  847. # This selects which entry file is compiled according to the target type.

  848. #

  849. function(dpf__add_plugin_target_definition NAME TARGET)

  850.   string(TOUPPER "${TARGET}" _upperTarget)

  851.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  852. endfunction()

  853. 

  854. # dpf__add_lv2_ttl_generator

  855. # ------------------------------------------------------------------------------

  856. #

  857. # Build the LV2 TTL generator.

  858. #

  859. function(dpf__add_lv2_ttl_generator)

  860.   if(TARGET lv2_ttl_generator)

  861.     return()

  862.   endif()

  863.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  864.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  865.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  866.   endif()

  867. endfunction()

  868. 

  869. # dpf__ensure_sources_non_empty

  870. # ------------------------------------------------------------------------------

  871. #

  872. # Ensure the given source list contains at least one file.

  873. # The function appends an empty source file to the list if necessary.

  874. # This is useful when CMake does not permit to add targets without sources.

  875. #

  876. function(dpf__ensure_sources_non_empty VAR)

  877.   if(NOT "" STREQUAL "${${VAR}}")

  878.     return()

  879.   endif()

  880.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  881.   if(NOT EXISTS "${_file}")

  882.     file(WRITE "${_file}" "")

  883.   endif()

  884.   set("${VAR}" "${_file}" PARENT_SCOPE)

  885. endfunction()

  886. 

  887. # dpf__create_dummy_source_list

  888. # ------------------------------------------------------------------------------

  889. #

  890. # Create a dummy source list which is equivalent to compiling nothing.

  891. # This is only for compatibility with older CMake versions, which refuse to add

  892. # targets without any sources.

  893. #

  894. macro(dpf__create_dummy_source_list VAR)

  895.   set("${VAR}")

  896.   if(CMAKE_VERSION VERSION_LESS "3.11")

  897.     dpf__ensure_sources_non_empty("${VAR}")

  898.   endif()

  899. endmacro()

  900. 

  901. # dpf__target_link_directories

  902. # ------------------------------------------------------------------------------

  903. #

  904. # Call `target_link_directories` if cmake >= 3.13,

  905. # otherwise fallback to global `link_directories`.

  906. #

  907. macro(dpf__target_link_directories NAME DIRS)

  908.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  909.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  910.   else()

  911.     link_directories(${DIRS})

  912.   endif()

  913. endmacro()

  914. 

  915. # dpf__warn_once

  916. # ------------------------------------------------------------------------------

  917. #

  918. # Prints a warning message once only.

  919. #

  920. function(dpf__warn_once_only TOKEN MESSAGE)

  921.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  922.   if(NOT _warned)

  923.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  924.     message(WARNING "${MESSAGE}")

  925.   endif()

  926. endfunction()