DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2056 Commits
7 Branches
295MB
Tree: 85cd6c40df
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '85cd6c40df'
${ noResults }
DPF/cmake/DPF-plugin.cmake

901 lines
32KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`

  79. #

  80. #   `MONOLITHIC`

  81. #       build LV2 as a single binary for UI and DSP

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `FILES_COMMON` <file1>...<fileN>

  91. #       list of sources which are part of both DSP and UI

  92. #

  93. function(dpf_add_plugin NAME)

  94.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  95.   set(oneValueArgs UI_TYPE)

  96.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  97.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  98. 

  99.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  100.     set(_dpf_plugin_UI_TYPE "opengl")

  101.   endif()

  102. 

  103.   set(_dgl_library)

  104.   if(_dpf_plugin_FILES_UI)

  105.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  106.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  107.       set(_dgl_library dgl-cairo)

  108.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  109.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  110.       set(_dgl_library dgl-opengl)

  111.     else()

  112.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  113.     endif()

  114.   endif()

  115. 

  116.   ###

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  119.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  120. 

  121.   ###

  122.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  123.   target_include_directories("${NAME}" PUBLIC

  124.     "${DPF_ROOT_DIR}/distrho")

  125. 

  126.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  127.     target_link_libraries("${NAME}" PRIVATE "dl")

  128.   endif()

  129. 

  130.   if(_dgl_library)

  131.     # make sure that all code will see DGL_* definitions

  132.     target_link_libraries("${NAME}" PUBLIC

  133.       "${_dgl_library}-definitions"

  134.       dgl-system-libs-definitions)

  135.   endif()

  136. 

  137.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  138.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  139. 

  140.   if(_dgl_library)

  141.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  142.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  143.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  144.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  145.     endif()

  146.     # add the files containing Objective-C classes

  147.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  148.   else()

  149.     add_library("${NAME}-ui" INTERFACE)

  150.   endif()

  151. 

  152.   ###

  153.   foreach(_target ${_dpf_plugin_TARGETS})

  154.     if(_target STREQUAL "jack")

  155.       dpf__build_jack("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "ladspa")

  157.       dpf__build_ladspa("${NAME}")

  158.     elseif(_target STREQUAL "dssi")

  159.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  160.     elseif(_target STREQUAL "lv2")

  161.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  162.     elseif(_target STREQUAL "vst2")

  163.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  164.     elseif(_target STREQUAL "vst3")

  165.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  166.     elseif(_target STREQUAL "clap")

  167.       dpf__build_clap("${NAME}" "${_dgl_library}")

  168.     else()

  169.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  170.     endif()

  171.   endforeach()

  172. endfunction()

  173. 

  174. # ------------------------------------------------------------------------------

  175. # DPF private functions (prefixed with `dpf__`)

  176. # ------------------------------------------------------------------------------

  177. 

  178. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  179. #       to the output directory.

  180. #

  181. 

  182. # dpf__build_jack

  183. # ------------------------------------------------------------------------------

  184. #

  185. # Add build rules for a JACK/Standalone program.

  186. #

  187. function(dpf__build_jack NAME DGL_LIBRARY)

  188.   dpf__create_dummy_source_list(_no_srcs)

  189. 

  190.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  191.   dpf__add_plugin_main("${NAME}-jack" "jack")

  192.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  193.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  194.   set_target_properties("${NAME}-jack" PROPERTIES

  195.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  196.     OUTPUT_NAME "${NAME}")

  197. 

  198.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  199. 

  200.   find_package(PkgConfig)

  201.   pkg_check_modules(SDL2 "sdl2")

  202.   if(SDL2_FOUND)

  203.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  204.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  205.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  206.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  207.   endif()

  208. 

  209.   if(APPLE OR WIN32)

  210.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  211.   else()

  212.     find_package(Threads)

  213.     pkg_check_modules(ALSA "alsa")

  214.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  215.     if(ALSA_FOUND)

  216.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  217.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  218.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  219.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  220.     endif()

  221.     if(PULSEAUDIO_FOUND)

  222.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  223.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  224.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  225.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  226.     endif()

  227.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  228.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  229.     endif()

  230.   endif()

  231. 

  232.   # for RtAudio native fallback

  233.   if(APPLE)

  234.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  235.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  236.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  237.     target_link_libraries("${NAME}-jack" PRIVATE

  238.       "${APPLE_COREAUDIO_FRAMEWORK}"

  239.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  240.       "${APPLE_COREMIDI_FRAMEWORK}")

  241.   elseif(WIN32)

  242.     target_link_libraries("${NAME}-jack" PRIVATE "dsound" "ole32" "winmm")

  243.   endif()

  244. endfunction()

  245. 

  246. # dpf__build_ladspa

  247. # ------------------------------------------------------------------------------

  248. #

  249. # Add build rules for a LADSPA plugin.

  250. #

  251. function(dpf__build_ladspa NAME)

  252.   dpf__create_dummy_source_list(_no_srcs)

  253. 

  254.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  255.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  256.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  257.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  258.   set_target_properties("${NAME}-ladspa" PROPERTIES

  259.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  260.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  261.     OUTPUT_NAME "${NAME}-ladspa"

  262.     PREFIX "")

  263. endfunction()

  264. 

  265. # dpf__build_dssi

  266. # ------------------------------------------------------------------------------

  267. #

  268. # Add build rules for a DSSI plugin.

  269. #

  270. function(dpf__build_dssi NAME DGL_LIBRARY)

  271.   find_package(PkgConfig)

  272.   pkg_check_modules(LIBLO "liblo")

  273.   if(NOT LIBLO_FOUND)

  274.     dpf__warn_once_only(missing_liblo

  275.       "liblo is not found, skipping the `dssi` plugin targets")

  276.     return()

  277.   endif()

  278. 

  279.   dpf__create_dummy_source_list(_no_srcs)

  280. 

  281.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  282.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  283.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  284.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  285.   set_target_properties("${NAME}-dssi" PROPERTIES

  286.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  287.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  288.     OUTPUT_NAME "${NAME}-dssi"

  289.     PREFIX "")

  290. 

  291.   if(DGL_LIBRARY)

  292.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  293.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  294.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  295.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  296.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  297.       OUTPUT_NAME "${NAME}_ui")

  298. 

  299.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  300.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  301.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  302.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  303.   endif()

  304. endfunction()

  305. 

  306. # dpf__build_lv2

  307. # ------------------------------------------------------------------------------

  308. #

  309. # Add build rules for an LV2 plugin.

  310. #

  311. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  312.   dpf__create_dummy_source_list(_no_srcs)

  313. 

  314.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  315.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  316.   if(DGL_LIBRARY AND MONOLITHIC)

  317.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  318.   else()

  319.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  320.   endif()

  321.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  322.   set_target_properties("${NAME}-lv2" PROPERTIES

  323.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  324.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  325.     OUTPUT_NAME "${NAME}_dsp"

  326.     PREFIX "")

  327. 

  328.   if(DGL_LIBRARY)

  329.     if(MONOLITHIC)

  330.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  331.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  332.       set_target_properties("${NAME}-lv2" PROPERTIES

  333.         OUTPUT_NAME "${NAME}")

  334.     else()

  335.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  336.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  337.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  338.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  339.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  340.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  341.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  342.         OUTPUT_NAME "${NAME}_ui"

  343.         PREFIX "")

  344.     endif()

  345.   endif()

  346. 

  347.   dpf__add_lv2_ttl_generator()

  348.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  349. 

  350.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  351.     COMMAND

  352.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  353.     "$<TARGET_FILE:lv2_ttl_generator>"

  354.     "$<TARGET_FILE:${NAME}-lv2>"

  355.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  356.     DEPENDS lv2_ttl_generator)

  357. endfunction()

  358. 

  359. # dpf__build_vst2

  360. # ------------------------------------------------------------------------------

  361. #

  362. # Add build rules for a VST2 plugin.

  363. #

  364. function(dpf__build_vst2 NAME DGL_LIBRARY)

  365.   dpf__create_dummy_source_list(_no_srcs)

  366. 

  367.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  368.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  369.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  370.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  371.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  372.   set_target_properties("${NAME}-vst2" PROPERTIES

  373.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  374.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  375.     OUTPUT_NAME "${NAME}-vst2"

  376.     PREFIX "")

  377.   if(APPLE)

  378.     set_target_properties("${NAME}-vst2" PROPERTIES

  379.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  380.       OUTPUT_NAME "${NAME}"

  381.       SUFFIX "")

  382.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  383.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  384.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  385.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  386.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  387.   endif()

  388. endfunction()

  389. 

  390. # dpf__determine_vst3_package_architecture

  391. # ------------------------------------------------------------------------------

  392. #

  393. # Determines the package architecture for a VST3 plugin target.

  394. #

  395. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  396.   # if set by variable, override the detection

  397.   if(DPF_VST3_ARCHITECTURE)

  398.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  399.     return()

  400.   endif()

  401. 

  402.   # not used on Apple, which supports universal binary

  403.   if(APPLE)

  404.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  405.     return()

  406.   endif()

  407. 

  408.   # identify the target processor (special case of MSVC, problematic sometimes)

  409.   if(MSVC)

  410.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  411.   else()

  412.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  413.   endif()

  414. 

  415.   # transform the processor name to a format that VST3 recognizes

  416.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  417.     set(vst3_package_arch "x86_64")

  418.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  419.     if(WIN32)

  420.       set(vst3_package_arch "x86")

  421.     else()

  422.       set(vst3_package_arch "i386")

  423.     endif()

  424.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  425.     set(vst3_package_arch "${vst3_system_arch}")

  426.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  427.     set(vst3_package_arch "aarch64")

  428.   else()

  429.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  430.   endif()

  431. 

  432.   # TODO: the detections for Windows arm/arm64 when supported

  433. 

  434.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  435. endfunction()

  436. 

  437. # dpf__build_vst3

  438. # ------------------------------------------------------------------------------

  439. #

  440. # Add build rules for a VST3 plugin.

  441. #

  442. function(dpf__build_vst3 NAME DGL_LIBRARY)

  443.   dpf__determine_vst3_package_architecture(vst3_arch)

  444. 

  445.   dpf__create_dummy_source_list(_no_srcs)

  446. 

  447.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  448.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  449.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  450.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  451.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  452.   set_target_properties("${NAME}-vst3" PROPERTIES

  453.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  454.     OUTPUT_NAME "${NAME}"

  455.     PREFIX "")

  456. 

  457.   if(APPLE)

  458.     set_target_properties("${NAME}-vst3" PROPERTIES

  459.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  460.       SUFFIX "")

  461.   elseif(WIN32)

  462.     set_target_properties("${NAME}-vst3" PROPERTIES

  463.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  464.   else()

  465.     set_target_properties("${NAME}-vst3" PROPERTIES

  466.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  467.   endif()

  468. 

  469.   if(APPLE)

  470.     # Uses the same macOS bundle template as VST2

  471.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  472.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  473.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  474.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  475.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  476.   endif()

  477. endfunction()

  478. 

  479. # dpf__build_clap

  480. # ------------------------------------------------------------------------------

  481. #

  482. # Add build rules for a VST2 plugin.

  483. #

  484. function(dpf__build_clap NAME DGL_LIBRARY)

  485.   dpf__create_dummy_source_list(_no_srcs)

  486. 

  487.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  488.   dpf__add_plugin_main("${NAME}-clap" "clap")

  489.   dpf__add_ui_main("${NAME}-clap" "clap" "${DGL_LIBRARY}")

  490.   dpf__set_module_export_list("${NAME}-clap" "clap")

  491.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  492.   set_target_properties("${NAME}-clap" PROPERTIES

  493.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  494.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  495.     OUTPUT_NAME "${NAME}"

  496.     PREFIX ""

  497.     SUFFIX ".clap")

  498. 

  499.   if(APPLE)

  500.     set_target_properties("${NAME}-clap" PROPERTIES

  501.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  502.       OUTPUT_NAME "${NAME}"

  503.       SUFFIX "")

  504.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  505.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  506.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  507.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  508.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  509.   endif()

  510. endfunction()

  511. 

  512. # dpf__add_dgl_cairo

  513. # ------------------------------------------------------------------------------

  514. #

  515. # Add the Cairo variant of DGL, if not already available.

  516. #

  517. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  518.   if(TARGET dgl-cairo)

  519.     return()

  520.   endif()

  521. 

  522.   find_package(PkgConfig)

  523.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  524. 

  525.   link_directories(${CAIRO_LIBRARY_DIRS})

  526. 

  527.   dpf__add_static_library(dgl-cairo STATIC

  528.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  530.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  531.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  532.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  533.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  534.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  535.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  536.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  537.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  538.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  539.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  540.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  541.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  542.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  543.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  544.   if(NO_SHARED_RESOURCES)

  545.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  546.   else()

  547.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  548.   endif()

  549.   if(NOT APPLE)

  550.     target_sources(dgl-cairo PRIVATE

  551.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  552.   else()

  553.     target_sources(dgl-cairo PRIVATE

  554.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  555.   endif()

  556.   target_include_directories(dgl-cairo PUBLIC

  557.     "${DPF_ROOT_DIR}/dgl")

  558.   target_include_directories(dgl-cairo PUBLIC

  559.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  560. 

  561.   dpf__add_dgl_system_libs()

  562.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  563. 

  564.   add_library(dgl-cairo-definitions INTERFACE)

  565.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  566. 

  567.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  568.   if(MINGW)

  569.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  570.   else()

  571.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  572.   endif()

  573.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  574. endfunction()

  575. 

  576. # dpf__add_dgl_opengl

  577. # ------------------------------------------------------------------------------

  578. #

  579. # Add the OpenGL variant of DGL, if not already available.

  580. #

  581. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  582.   if(TARGET dgl-opengl)

  583.     return()

  584.   endif()

  585. 

  586.   if(NOT OpenGL_GL_PREFERENCE)

  587.     set(OpenGL_GL_PREFERENCE "LEGACY")

  588.   endif()

  589. 

  590.   find_package(OpenGL REQUIRED)

  591. 

  592.   dpf__add_static_library(dgl-opengl STATIC

  593.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  594.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  595.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  596.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  597.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  598.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  599.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  600.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  601.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  602.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  603.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  604.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  605.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  606.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  607.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  608.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  609.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  610.   if(NO_SHARED_RESOURCES)

  611.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  612.   else()

  613.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  614.   endif()

  615.   if(NOT APPLE)

  616.     target_sources(dgl-opengl PRIVATE

  617.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  618.   else()

  619.     target_sources(dgl-opengl PRIVATE

  620.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  621.   endif()

  622.   target_include_directories(dgl-opengl PUBLIC

  623.     "${DPF_ROOT_DIR}/dgl")

  624.   target_include_directories(dgl-opengl PUBLIC

  625.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  626. 

  627.   if(APPLE)

  628.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  629.   endif()

  630. 

  631.   dpf__add_dgl_system_libs()

  632.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  633. 

  634.   add_library(dgl-opengl-definitions INTERFACE)

  635.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  636. 

  637.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  638.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  639. endfunction()

  640. 

  641. # dpf__add_plugin_specific_ui_sources

  642. # ------------------------------------------------------------------------------

  643. #

  644. # Compile system specific files, for now it is just Objective-C code

  645. #

  646. function(dpf__add_plugin_specific_ui_sources NAME)

  647.   if(APPLE)

  648.     target_sources("${NAME}" PRIVATE

  649.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  650.   endif()

  651. endfunction()

  652. 

  653. # dpf__add_dgl_system_libs

  654. # ------------------------------------------------------------------------------

  655. #

  656. # Find system libraries required by DGL and add them as an interface target.

  657. #

  658. function(dpf__add_dgl_system_libs)

  659.   if(TARGET dgl-system-libs)

  660.     return()

  661.   endif()

  662.   add_library(dgl-system-libs INTERFACE)

  663.   add_library(dgl-system-libs-definitions INTERFACE)

  664.   if(HAIKU)

  665.     target_link_libraries(dgl-system-libs INTERFACE "be")

  666.   elseif(WIN32)

  667.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  668.   elseif(APPLE)

  669.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  670.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  671.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  672.   else()

  673.     find_package(X11 REQUIRED)

  674.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  675.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  676.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  677.     if(X11_Xcursor_FOUND)

  678.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  679.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  680.     endif()

  681.     if(X11_Xext_FOUND)

  682.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  683.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  684.     endif()

  685.     if(X11_Xrandr_FOUND)

  686.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  687.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  688.     endif()

  689.     if(X11_XSync_FOUND)

  690.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  691.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  692.     endif()

  693.    endif()

  694. 

  695.    if(MSVC)

  696.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  697.      foreach(_gl_header "glext.h")

  698.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  699.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  700.        endif()

  701.      endforeach()

  702.      foreach(_khr_header "khrplatform.h")

  703.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  704.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  705.        endif()

  706.      endforeach()

  707.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  708.    endif()

  709. 

  710.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  711. endfunction()

  712. 

  713. # dpf__add_executable

  714. # ------------------------------------------------------------------------------

  715. #

  716. # Adds an executable target, and set some default properties on the target.

  717. #

  718. function(dpf__add_executable NAME)

  719.   add_executable("${NAME}" ${ARGN})

  720.   dpf__set_target_defaults("${NAME}")

  721.   if(MINGW)

  722.     target_link_libraries("${NAME}" PRIVATE "-static")

  723.   endif()

  724. endfunction()

  725. 

  726. # dpf__add_module

  727. # ------------------------------------------------------------------------------

  728. #

  729. # Adds a module target, and set some default properties on the target.

  730. #

  731. function(dpf__add_module NAME)

  732.   add_library("${NAME}" MODULE ${ARGN})

  733.   dpf__set_target_defaults("${NAME}")

  734.   if(MINGW)

  735.     target_link_libraries("${NAME}" PRIVATE "-static")

  736.   endif()

  737. endfunction()

  738. 

  739. # dpf__add_static_library

  740. # ------------------------------------------------------------------------------

  741. #

  742. # Adds a static library target, and set some default properties on the target.

  743. #

  744. function(dpf__add_static_library NAME)

  745.   add_library("${NAME}" STATIC ${ARGN})

  746.   dpf__set_target_defaults("${NAME}")

  747. endfunction()

  748. 

  749. # dpf__set_module_export_list

  750. # ------------------------------------------------------------------------------

  751. #

  752. # Applies a list of exported symbols to the module target.

  753. #

  754. function(dpf__set_module_export_list NAME EXPORTS)

  755.   if(WIN32)

  756.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  757.   elseif(APPLE)

  758.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  759.       "-Xlinker" "-exported_symbols_list"

  760.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  761.   else()

  762.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  763.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  764.   endif()

  765. endfunction()

  766. 

  767. # dpf__set_target_defaults

  768. # ------------------------------------------------------------------------------

  769. #

  770. # Set default properties which must apply to all DPF-defined targets.

  771. #

  772. function(dpf__set_target_defaults NAME)

  773.   set_target_properties("${NAME}" PROPERTIES

  774.     POSITION_INDEPENDENT_CODE TRUE

  775.     C_VISIBILITY_PRESET "hidden"

  776.     CXX_VISIBILITY_PRESET "hidden"

  777.     VISIBILITY_INLINES_HIDDEN TRUE)

  778.   if(WIN32)

  779.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  780.   endif()

  781.   if (MINGW)

  782.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  783.   endif()

  784.   if (MSVC)

  785.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  786.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  787.   endif()

  788.   if (CMAKE_COMPILER_IS_GNUCXX)

  789.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  790.   endif()

  791. endfunction()

  792. 

  793. # dpf__add_plugin_main

  794. # ------------------------------------------------------------------------------

  795. #

  796. # Adds plugin code to the given target.

  797. #

  798. function(dpf__add_plugin_main NAME TARGET)

  799.   target_sources("${NAME}" PRIVATE

  800.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  801.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  802. endfunction()

  803. 

  804. # dpf__add_ui_main

  805. # ------------------------------------------------------------------------------

  806. #

  807. # Adds UI code to the given target (only if the target has UI).

  808. #

  809. function(dpf__add_ui_main NAME TARGET HAS_UI)

  810.   if(HAS_UI)

  811.     target_sources("${NAME}" PRIVATE

  812.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  813.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  814.   endif()

  815. endfunction()

  816. 

  817. # dpf__add_plugin_target_definition

  818. # ------------------------------------------------------------------------------

  819. #

  820. # Adds the plugins target macro definition.

  821. # This selects which entry file is compiled according to the target type.

  822. #

  823. function(dpf__add_plugin_target_definition NAME TARGET)

  824.   string(TOUPPER "${TARGET}" _upperTarget)

  825.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  826. endfunction()

  827. 

  828. # dpf__add_lv2_ttl_generator

  829. # ------------------------------------------------------------------------------

  830. #

  831. # Build the LV2 TTL generator.

  832. #

  833. function(dpf__add_lv2_ttl_generator)

  834.   if(TARGET lv2_ttl_generator)

  835.     return()

  836.   endif()

  837.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  838.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  839.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  840.   endif()

  841. endfunction()

  842. 

  843. # dpf__ensure_sources_non_empty

  844. # ------------------------------------------------------------------------------

  845. #

  846. # Ensure the given source list contains at least one file.

  847. # The function appends an empty source file to the list if necessary.

  848. # This is useful when CMake does not permit to add targets without sources.

  849. #

  850. function(dpf__ensure_sources_non_empty VAR)

  851.   if(NOT "" STREQUAL "${${VAR}}")

  852.     return()

  853.   endif()

  854.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  855.   if(NOT EXISTS "${_file}")

  856.     file(WRITE "${_file}" "")

  857.   endif()

  858.   set("${VAR}" "${_file}" PARENT_SCOPE)

  859. endfunction()

  860. 

  861. # dpf__create_dummy_source_list

  862. # ------------------------------------------------------------------------------

  863. #

  864. # Create a dummy source list which is equivalent to compiling nothing.

  865. # This is only for compatibility with older CMake versions, which refuse to add

  866. # targets without any sources.

  867. #

  868. macro(dpf__create_dummy_source_list VAR)

  869.   set("${VAR}")

  870.   if(CMAKE_VERSION VERSION_LESS "3.11")

  871.     dpf__ensure_sources_non_empty("${VAR}")

  872.   endif()

  873. endmacro()

  874. 

  875. # dpf__target_link_directories

  876. # ------------------------------------------------------------------------------

  877. #

  878. # Call `target_link_directories` if cmake >= 3.13,

  879. # otherwise fallback to global `link_directories`.

  880. #

  881. macro(dpf__target_link_directories NAME DIRS)

  882.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  883.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  884.   else()

  885.     link_directories(${DIRS})

  886.   endif()

  887. endmacro()

  888. 

  889. # dpf__warn_once

  890. # ------------------------------------------------------------------------------

  891. #

  892. # Prints a warning message once only.

  893. #

  894. function(dpf__warn_once_only TOKEN MESSAGE)

  895.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  896.   if(NOT _warned)

  897.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  898.     message(WARNING "${MESSAGE}")

  899.   endif()

  900. endfunction()