DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2088 Commits
7 Branches
49MB
Tree: 75abdb30da
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '75abdb30da'
${ noResults }
DPF/cmake/DPF-plugin.cmake

923 lines
32KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`, `external`

  79. #

  80. #   `FILES_COMMON` <file1>...<fileN>

  81. #       list of sources which are part of both DSP and UI

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `MONOLITHIC`

  91. #       build LV2 as a single binary for UI and DSP

  92. #

  93. #   `NO_SHARED_RESOURCES`

  94. #       do not build DPF shared resources (fonts, etc)

  95. #

  96. function(dpf_add_plugin NAME)

  97.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  98.   set(oneValueArgs UI_TYPE)

  99.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  100.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  101. 

  102.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  103.     set(_dpf_plugin_UI_TYPE "opengl")

  104.   endif()

  105. 

  106.   set(_dgl_library)

  107.   set(_dgl_external OFF)

  108.   if(_dpf_plugin_FILES_UI)

  109.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  110.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  111.       set(_dgl_library dgl-cairo)

  112.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  113.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  114.       set(_dgl_library dgl-opengl)

  115.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  116.       set(_dgl_external ON)

  117.     else()

  118.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  119.     endif()

  120.   endif()

  121. 

  122.   set(_dgl_has_ui OFF)

  123.   if(_dgl_library OR _dgl_external)

  124.     set(_dgl_has_ui ON)

  125.   endif()

  126. 

  127.   ###

  128.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  129.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  130.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  131. 

  132.   ###

  133.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  134.   target_include_directories("${NAME}" PUBLIC

  135.     "${DPF_ROOT_DIR}/distrho")

  136. 

  137.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  138.     target_link_libraries("${NAME}" PRIVATE "dl")

  139.   endif()

  140. 

  141.   if(_dgl_library AND NOT _dgl_external)

  142.     # make sure that all code will see DGL_* definitions

  143.     target_link_libraries("${NAME}" PUBLIC

  144.       "${_dgl_library}-definitions"

  145.       dgl-system-libs-definitions)

  146.   elseif(_dgl_external)

  147.     target_link_libraries("${NAME}" PUBLIC

  148.       dgl-system-libs-definitions)

  149.   endif()

  150. 

  151.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  152.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  153. 

  154.   if(_dgl_library AND NOT _dgl_external)

  155.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  156.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  157.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  158.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  159.     endif()

  160.     # add the files containing Objective-C classes

  161.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  162.   elseif(_dgl_external)

  163.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  164.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}")

  165.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  166.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  167.     endif()

  168.     # add the files containing Objective-C classes

  169.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  170.   else()

  171.     add_library("${NAME}-ui" INTERFACE)

  172.   endif()

  173. 

  174.   ###

  175.   foreach(_target ${_dpf_plugin_TARGETS})

  176.     if(_target STREQUAL "jack")

  177.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  178.     elseif(_target STREQUAL "ladspa")

  179.       dpf__build_ladspa("${NAME}")

  180.     elseif(_target STREQUAL "dssi")

  181.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  182.     elseif(_target STREQUAL "lv2")

  183.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  184.     elseif(_target STREQUAL "vst2")

  185.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  186.     elseif(_target STREQUAL "vst3")

  187.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  188.     elseif(_target STREQUAL "clap")

  189.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  190.     else()

  191.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  192.     endif()

  193.   endforeach()

  194. endfunction()

  195. 

  196. # ------------------------------------------------------------------------------

  197. # DPF private functions (prefixed with `dpf__`)

  198. # ------------------------------------------------------------------------------

  199. 

  200. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  201. #       to the output directory.

  202. #

  203. 

  204. # dpf__build_jack

  205. # ------------------------------------------------------------------------------

  206. #

  207. # Add build rules for a JACK/Standalone program.

  208. #

  209. function(dpf__build_jack NAME HAS_UI)

  210.   dpf__create_dummy_source_list(_no_srcs)

  211. 

  212.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  213.   dpf__add_plugin_main("${NAME}-jack" "jack")

  214.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  215.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  216.   set_target_properties("${NAME}-jack" PROPERTIES

  217.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  218.     OUTPUT_NAME "${NAME}")

  219. 

  220.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  221. 

  222.   find_package(PkgConfig)

  223.   pkg_check_modules(SDL2 "sdl2")

  224.   if(SDL2_FOUND)

  225.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  226.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  227.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  228.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  229.   endif()

  230. 

  231.   if(APPLE OR WIN32)

  232.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  233.   else()

  234.     find_package(Threads)

  235.     pkg_check_modules(ALSA "alsa")

  236.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  237.     if(ALSA_FOUND)

  238.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  239.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  240.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  241.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  242.     endif()

  243.     if(PULSEAUDIO_FOUND)

  244.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  245.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  246.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  247.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  248.     endif()

  249.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  250.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  251.     endif()

  252.   endif()

  253. 

  254.   # for RtAudio native fallback

  255.   if(APPLE)

  256.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  257.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  258.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  259.     target_link_libraries("${NAME}-jack" PRIVATE

  260.       "${APPLE_COREAUDIO_FRAMEWORK}"

  261.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  262.       "${APPLE_COREMIDI_FRAMEWORK}")

  263.   elseif(WIN32)

  264.     target_link_libraries("${NAME}-jack" PRIVATE "dsound" "ole32" "winmm")

  265.   endif()

  266. endfunction()

  267. 

  268. # dpf__build_ladspa

  269. # ------------------------------------------------------------------------------

  270. #

  271. # Add build rules for a LADSPA plugin.

  272. #

  273. function(dpf__build_ladspa NAME)

  274.   dpf__create_dummy_source_list(_no_srcs)

  275. 

  276.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  277.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  278.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  279.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  280.   set_target_properties("${NAME}-ladspa" PROPERTIES

  281.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  282.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  283.     OUTPUT_NAME "${NAME}-ladspa"

  284.     PREFIX "")

  285. endfunction()

  286. 

  287. # dpf__build_dssi

  288. # ------------------------------------------------------------------------------

  289. #

  290. # Add build rules for a DSSI plugin.

  291. #

  292. function(dpf__build_dssi NAME HAS_UI)

  293.   find_package(PkgConfig)

  294.   pkg_check_modules(LIBLO "liblo")

  295.   if(NOT LIBLO_FOUND)

  296.     dpf__warn_once_only(missing_liblo

  297.       "liblo is not found, skipping the `dssi` plugin targets")

  298.     return()

  299.   endif()

  300. 

  301.   dpf__create_dummy_source_list(_no_srcs)

  302. 

  303.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  304.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  305.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  306.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  307.   set_target_properties("${NAME}-dssi" PROPERTIES

  308.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  309.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  310.     OUTPUT_NAME "${NAME}-dssi"

  311.     PREFIX "")

  312. 

  313.   if(HAS_UI)

  314.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  315.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  316.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  317.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  318.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  319.       OUTPUT_NAME "${NAME}_ui")

  320. 

  321.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  322.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  323.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  324.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  325.   endif()

  326. endfunction()

  327. 

  328. # dpf__build_lv2

  329. # ------------------------------------------------------------------------------

  330. #

  331. # Add build rules for an LV2 plugin.

  332. #

  333. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  334.   dpf__create_dummy_source_list(_no_srcs)

  335. 

  336.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  337.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  338.   if(HAS_UI AND MONOLITHIC)

  339.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  340.   else()

  341.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  342.   endif()

  343.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  344.   set_target_properties("${NAME}-lv2" PROPERTIES

  345.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  346.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  347.     OUTPUT_NAME "${NAME}_dsp"

  348.     PREFIX "")

  349. 

  350.   if(HAS_UI)

  351.     if(MONOLITHIC)

  352.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  353.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  354.       set_target_properties("${NAME}-lv2" PROPERTIES

  355.         OUTPUT_NAME "${NAME}")

  356.     else()

  357.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  358.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  359.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  360.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  361.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  362.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  363.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  364.         OUTPUT_NAME "${NAME}_ui"

  365.         PREFIX "")

  366.     endif()

  367.   endif()

  368. 

  369.   dpf__add_lv2_ttl_generator()

  370.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  371. 

  372.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  373.     COMMAND

  374.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  375.     "$<TARGET_FILE:lv2_ttl_generator>"

  376.     "$<TARGET_FILE:${NAME}-lv2>"

  377.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  378.     DEPENDS lv2_ttl_generator)

  379. endfunction()

  380. 

  381. # dpf__build_vst2

  382. # ------------------------------------------------------------------------------

  383. #

  384. # Add build rules for a VST2 plugin.

  385. #

  386. function(dpf__build_vst2 NAME HAS_UI)

  387.   dpf__create_dummy_source_list(_no_srcs)

  388. 

  389.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  390.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  391.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  392.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  393.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  394.   set_target_properties("${NAME}-vst2" PROPERTIES

  395.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  396.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  397.     OUTPUT_NAME "${NAME}-vst2"

  398.     PREFIX "")

  399.   if(APPLE)

  400.     set_target_properties("${NAME}-vst2" PROPERTIES

  401.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  402.       OUTPUT_NAME "${NAME}"

  403.       SUFFIX "")

  404.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  405.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  406.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  407.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  408.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  409.   endif()

  410. endfunction()

  411. 

  412. # dpf__determine_vst3_package_architecture

  413. # ------------------------------------------------------------------------------

  414. #

  415. # Determines the package architecture for a VST3 plugin target.

  416. #

  417. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  418.   # if set by variable, override the detection

  419.   if(DPF_VST3_ARCHITECTURE)

  420.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  421.     return()

  422.   endif()

  423. 

  424.   # not used on Apple, which supports universal binary

  425.   if(APPLE)

  426.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  427.     return()

  428.   endif()

  429. 

  430.   # identify the target processor (special case of MSVC, problematic sometimes)

  431.   if(MSVC)

  432.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  433.   else()

  434.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  435.   endif()

  436. 

  437.   # transform the processor name to a format that VST3 recognizes

  438.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  439.     set(vst3_package_arch "x86_64")

  440.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  441.     if(WIN32)

  442.       set(vst3_package_arch "x86")

  443.     else()

  444.       set(vst3_package_arch "i386")

  445.     endif()

  446.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  447.     set(vst3_package_arch "${vst3_system_arch}")

  448.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  449.     set(vst3_package_arch "aarch64")

  450.   else()

  451.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  452.   endif()

  453. 

  454.   # TODO: the detections for Windows arm/arm64 when supported

  455. 

  456.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  457. endfunction()

  458. 

  459. # dpf__build_vst3

  460. # ------------------------------------------------------------------------------

  461. #

  462. # Add build rules for a VST3 plugin.

  463. #

  464. function(dpf__build_vst3 NAME HAS_UI)

  465.   dpf__determine_vst3_package_architecture(vst3_arch)

  466. 

  467.   dpf__create_dummy_source_list(_no_srcs)

  468. 

  469.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  470.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  471.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  472.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  473.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  474.   set_target_properties("${NAME}-vst3" PROPERTIES

  475.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  476.     OUTPUT_NAME "${NAME}"

  477.     PREFIX "")

  478. 

  479.   if(APPLE)

  480.     set_target_properties("${NAME}-vst3" PROPERTIES

  481.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  482.       SUFFIX "")

  483.   elseif(WIN32)

  484.     set_target_properties("${NAME}-vst3" PROPERTIES

  485.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  486.   else()

  487.     set_target_properties("${NAME}-vst3" PROPERTIES

  488.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  489.   endif()

  490. 

  491.   if(APPLE)

  492.     # Uses the same macOS bundle template as VST2

  493.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  494.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  495.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  496.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  497.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  498.   endif()

  499. endfunction()

  500. 

  501. # dpf__build_clap

  502. # ------------------------------------------------------------------------------

  503. #

  504. # Add build rules for a VST2 plugin.

  505. #

  506. function(dpf__build_clap NAME HAS_UI)

  507.   dpf__create_dummy_source_list(_no_srcs)

  508. 

  509.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  510.   dpf__add_plugin_main("${NAME}-clap" "clap")

  511.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  512.   dpf__set_module_export_list("${NAME}-clap" "clap")

  513.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  514.   set_target_properties("${NAME}-clap" PROPERTIES

  515.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  516.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  517.     OUTPUT_NAME "${NAME}"

  518.     PREFIX ""

  519.     SUFFIX ".clap")

  520. 

  521.   if(APPLE)

  522.     set_target_properties("${NAME}-clap" PROPERTIES

  523.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  524.       OUTPUT_NAME "${NAME}"

  525.       SUFFIX "")

  526.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  527.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  528.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  529.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  530.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  531.   endif()

  532. endfunction()

  533. 

  534. # dpf__add_dgl_cairo

  535. # ------------------------------------------------------------------------------

  536. #

  537. # Add the Cairo variant of DGL, if not already available.

  538. #

  539. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  540.   if(TARGET dgl-cairo)

  541.     return()

  542.   endif()

  543. 

  544.   find_package(PkgConfig)

  545.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  546. 

  547.   link_directories(${CAIRO_LIBRARY_DIRS})

  548. 

  549.   dpf__add_static_library(dgl-cairo STATIC

  550.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  551.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  552.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  553.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  554.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  555.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  556.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  557.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  558.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  559.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  560.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  561.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  562.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  563.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  564.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  565.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  566.   if(NO_SHARED_RESOURCES)

  567.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  568.   else()

  569.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  570.   endif()

  571.   if(NOT APPLE)

  572.     target_sources(dgl-cairo PRIVATE

  573.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  574.   else()

  575.     target_sources(dgl-cairo PRIVATE

  576.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  577.   endif()

  578.   target_include_directories(dgl-cairo PUBLIC

  579.     "${DPF_ROOT_DIR}/dgl")

  580.   target_include_directories(dgl-cairo PUBLIC

  581.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  582. 

  583.   dpf__add_dgl_system_libs()

  584.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  585. 

  586.   add_library(dgl-cairo-definitions INTERFACE)

  587.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  588. 

  589.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  590.   if(MINGW)

  591.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  592.   else()

  593.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  594.   endif()

  595.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  596. endfunction()

  597. 

  598. # dpf__add_dgl_opengl

  599. # ------------------------------------------------------------------------------

  600. #

  601. # Add the OpenGL variant of DGL, if not already available.

  602. #

  603. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  604.   if(TARGET dgl-opengl)

  605.     return()

  606.   endif()

  607. 

  608.   if(NOT OpenGL_GL_PREFERENCE)

  609.     set(OpenGL_GL_PREFERENCE "LEGACY")

  610.   endif()

  611. 

  612.   find_package(OpenGL REQUIRED)

  613. 

  614.   dpf__add_static_library(dgl-opengl STATIC

  615.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  616.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  617.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  618.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  619.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  620.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  621.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  622.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  623.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  624.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  625.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  626.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  627.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  628.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  629.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  630.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  631.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  632.   if(NO_SHARED_RESOURCES)

  633.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  634.   else()

  635.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  636.   endif()

  637.   if(NOT APPLE)

  638.     target_sources(dgl-opengl PRIVATE

  639.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  640.   else()

  641.     target_sources(dgl-opengl PRIVATE

  642.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  643.   endif()

  644.   target_include_directories(dgl-opengl PUBLIC

  645.     "${DPF_ROOT_DIR}/dgl")

  646.   target_include_directories(dgl-opengl PUBLIC

  647.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  648. 

  649.   if(APPLE)

  650.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  651.   endif()

  652. 

  653.   dpf__add_dgl_system_libs()

  654.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  655. 

  656.   add_library(dgl-opengl-definitions INTERFACE)

  657.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  658. 

  659.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  660.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  661. endfunction()

  662. 

  663. # dpf__add_plugin_specific_ui_sources

  664. # ------------------------------------------------------------------------------

  665. #

  666. # Compile system specific files, for now it is just Objective-C code

  667. #

  668. function(dpf__add_plugin_specific_ui_sources NAME)

  669.   if(APPLE)

  670.     target_sources("${NAME}" PRIVATE

  671.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  672.   endif()

  673. endfunction()

  674. 

  675. # dpf__add_dgl_system_libs

  676. # ------------------------------------------------------------------------------

  677. #

  678. # Find system libraries required by DGL and add them as an interface target.

  679. #

  680. function(dpf__add_dgl_system_libs)

  681.   if(TARGET dgl-system-libs)

  682.     return()

  683.   endif()

  684.   add_library(dgl-system-libs INTERFACE)

  685.   add_library(dgl-system-libs-definitions INTERFACE)

  686.   if(HAIKU)

  687.     target_link_libraries(dgl-system-libs INTERFACE "be")

  688.   elseif(WIN32)

  689.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  690.   elseif(APPLE)

  691.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  692.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  693.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  694.   else()

  695.     find_package(X11 REQUIRED)

  696.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  697.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  698.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  699.     if(X11_Xcursor_FOUND)

  700.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  701.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  702.     endif()

  703.     if(X11_Xext_FOUND)

  704.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  705.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  706.     endif()

  707.     if(X11_Xrandr_FOUND)

  708.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  709.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  710.     endif()

  711.     if(X11_XSync_FOUND)

  712.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  713.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  714.     endif()

  715.    endif()

  716. 

  717.    if(MSVC)

  718.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  719.      foreach(_gl_header "glext.h")

  720.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  721.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  722.        endif()

  723.      endforeach()

  724.      foreach(_khr_header "khrplatform.h")

  725.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  726.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  727.        endif()

  728.      endforeach()

  729.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  730.    endif()

  731. 

  732.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  733. endfunction()

  734. 

  735. # dpf__add_executable

  736. # ------------------------------------------------------------------------------

  737. #

  738. # Adds an executable target, and set some default properties on the target.

  739. #

  740. function(dpf__add_executable NAME)

  741.   add_executable("${NAME}" ${ARGN})

  742.   dpf__set_target_defaults("${NAME}")

  743.   if(MINGW)

  744.     target_link_libraries("${NAME}" PRIVATE "-static")

  745.   endif()

  746. endfunction()

  747. 

  748. # dpf__add_module

  749. # ------------------------------------------------------------------------------

  750. #

  751. # Adds a module target, and set some default properties on the target.

  752. #

  753. function(dpf__add_module NAME)

  754.   add_library("${NAME}" MODULE ${ARGN})

  755.   dpf__set_target_defaults("${NAME}")

  756.   if(MINGW)

  757.     target_link_libraries("${NAME}" PRIVATE "-static")

  758.   endif()

  759. endfunction()

  760. 

  761. # dpf__add_static_library

  762. # ------------------------------------------------------------------------------

  763. #

  764. # Adds a static library target, and set some default properties on the target.

  765. #

  766. function(dpf__add_static_library NAME)

  767.   add_library("${NAME}" STATIC ${ARGN})

  768.   dpf__set_target_defaults("${NAME}")

  769. endfunction()

  770. 

  771. # dpf__set_module_export_list

  772. # ------------------------------------------------------------------------------

  773. #

  774. # Applies a list of exported symbols to the module target.

  775. #

  776. function(dpf__set_module_export_list NAME EXPORTS)

  777.   if(WIN32)

  778.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  779.   elseif(APPLE)

  780.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  781.       "-Xlinker" "-exported_symbols_list"

  782.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  783.   else()

  784.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  785.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  786.   endif()

  787. endfunction()

  788. 

  789. # dpf__set_target_defaults

  790. # ------------------------------------------------------------------------------

  791. #

  792. # Set default properties which must apply to all DPF-defined targets.

  793. #

  794. function(dpf__set_target_defaults NAME)

  795.   set_target_properties("${NAME}" PROPERTIES

  796.     POSITION_INDEPENDENT_CODE TRUE

  797.     C_VISIBILITY_PRESET "hidden"

  798.     CXX_VISIBILITY_PRESET "hidden"

  799.     VISIBILITY_INLINES_HIDDEN TRUE)

  800.   if(WIN32)

  801.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  802.   endif()

  803.   if (MINGW)

  804.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  805.   endif()

  806.   if (MSVC)

  807.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  808.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  809.   endif()

  810.   if (CMAKE_COMPILER_IS_GNUCXX)

  811.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  812.   endif()

  813. endfunction()

  814. 

  815. # dpf__add_plugin_main

  816. # ------------------------------------------------------------------------------

  817. #

  818. # Adds plugin code to the given target.

  819. #

  820. function(dpf__add_plugin_main NAME TARGET)

  821.   target_sources("${NAME}" PRIVATE

  822.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  823.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  824. endfunction()

  825. 

  826. # dpf__add_ui_main

  827. # ------------------------------------------------------------------------------

  828. #

  829. # Adds UI code to the given target (only if the target has UI).

  830. #

  831. function(dpf__add_ui_main NAME TARGET HAS_UI)

  832.   if(HAS_UI)

  833.     target_sources("${NAME}" PRIVATE

  834.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  835.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  836.   endif()

  837. endfunction()

  838. 

  839. # dpf__add_plugin_target_definition

  840. # ------------------------------------------------------------------------------

  841. #

  842. # Adds the plugins target macro definition.

  843. # This selects which entry file is compiled according to the target type.

  844. #

  845. function(dpf__add_plugin_target_definition NAME TARGET)

  846.   string(TOUPPER "${TARGET}" _upperTarget)

  847.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  848. endfunction()

  849. 

  850. # dpf__add_lv2_ttl_generator

  851. # ------------------------------------------------------------------------------

  852. #

  853. # Build the LV2 TTL generator.

  854. #

  855. function(dpf__add_lv2_ttl_generator)

  856.   if(TARGET lv2_ttl_generator)

  857.     return()

  858.   endif()

  859.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  860.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  861.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  862.   endif()

  863. endfunction()

  864. 

  865. # dpf__ensure_sources_non_empty

  866. # ------------------------------------------------------------------------------

  867. #

  868. # Ensure the given source list contains at least one file.

  869. # The function appends an empty source file to the list if necessary.

  870. # This is useful when CMake does not permit to add targets without sources.

  871. #

  872. function(dpf__ensure_sources_non_empty VAR)

  873.   if(NOT "" STREQUAL "${${VAR}}")

  874.     return()

  875.   endif()

  876.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  877.   if(NOT EXISTS "${_file}")

  878.     file(WRITE "${_file}" "")

  879.   endif()

  880.   set("${VAR}" "${_file}" PARENT_SCOPE)

  881. endfunction()

  882. 

  883. # dpf__create_dummy_source_list

  884. # ------------------------------------------------------------------------------

  885. #

  886. # Create a dummy source list which is equivalent to compiling nothing.

  887. # This is only for compatibility with older CMake versions, which refuse to add

  888. # targets without any sources.

  889. #

  890. macro(dpf__create_dummy_source_list VAR)

  891.   set("${VAR}")

  892.   if(CMAKE_VERSION VERSION_LESS "3.11")

  893.     dpf__ensure_sources_non_empty("${VAR}")

  894.   endif()

  895. endmacro()

  896. 

  897. # dpf__target_link_directories

  898. # ------------------------------------------------------------------------------

  899. #

  900. # Call `target_link_directories` if cmake >= 3.13,

  901. # otherwise fallback to global `link_directories`.

  902. #

  903. macro(dpf__target_link_directories NAME DIRS)

  904.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  905.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  906.   else()

  907.     link_directories(${DIRS})

  908.   endif()

  909. endmacro()

  910. 

  911. # dpf__warn_once

  912. # ------------------------------------------------------------------------------

  913. #

  914. # Prints a warning message once only.

  915. #

  916. function(dpf__warn_once_only TOKEN MESSAGE)

  917.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  918.   if(NOT _warned)

  919.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  920.     message(WARNING "${MESSAGE}")

  921.   endif()

  922. endfunction()