DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2424 Commits
7 Branches
91MB
Tree: 6c06c80c76
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '6c06c80c76'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1465 lines
53KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  125.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  126.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  127.       set(_dgl_library dgl-cairo)

  128.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  129.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  130.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  131.       set(_dgl_library dgl-external)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  133.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  134.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  135.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  136.       set(_dgl_library dgl-opengl)

  137.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  138.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  139.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  140.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  141.       set(_dgl_library dgl-opengl3)

  142.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  143.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  144.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  145.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  146.       set(_dgl_library dgl-vulkan)

  147.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  148.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  149.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  150.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  151.       set(_dgl_library dgl-external)

  152.     else()

  153.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  154.     endif()

  155.   else()

  156.     set(_dpf_plugin_UI_TYPE "")

  157.   endif()

  158. 

  159.   set(_dgl_has_ui OFF)

  160.   if(_dgl_library)

  161.     set(_dgl_has_ui ON)

  162.   endif()

  163. 

  164.   ###

  165.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  166.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  167.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  168. 

  169.   ###

  170.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  171.   target_include_directories("${NAME}" PUBLIC

  172.     "${DPF_ROOT_DIR}/distrho")

  173. 

  174.   if(_dpf_plugin_USE_FILE_BROWSER)

  175.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  176.   endif()

  177. 

  178.   if(_dpf_plugin_USE_WEB_VIEW)

  179.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  180.   endif()

  181. 

  182.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  183.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  184.   endif()

  185. 

  186.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  187.     target_link_libraries("${NAME}" PRIVATE "dl")

  188.   endif()

  189. 

  190.   if(_dgl_library)

  191.     # make sure that all code will see DGL_* definitions

  192.     target_link_libraries("${NAME}" PUBLIC

  193.       "${_dgl_library}-definitions"

  194.       dgl-system-libs-definitions

  195.       dgl-system-libs)

  196.   endif()

  197. 

  198.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  199.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  200. 

  201.   if(_dgl_library)

  202.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  203.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  204.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  205.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  206.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  207.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  208.           OUTPUT_STRIP_TRAILING_WHITESPACE

  209.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  210.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  211.       endif()

  212.     endif()

  213.     # add the files containing C++17 or Objective-C classes

  214.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  215.   else()

  216.     add_library("${NAME}-ui" INTERFACE)

  217.   endif()

  218. 

  219.   ###

  220.   foreach(_target ${_dpf_plugin_TARGETS})

  221.     if(_target STREQUAL "jack")

  222.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  223.     elseif(_target STREQUAL "ladspa")

  224.       dpf__build_ladspa("${NAME}")

  225.     elseif(_target STREQUAL "dssi")

  226.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  227.     elseif(_target STREQUAL "lv2")

  228.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  229.     elseif(_target STREQUAL "vst2")

  230.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  231.     elseif(_target STREQUAL "vst3")

  232.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  233.     elseif(_target STREQUAL "clap")

  234.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  235.     elseif(_target STREQUAL "au")

  236.       if (APPLE)

  237.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  238.       endif()

  239.     elseif(_target STREQUAL "static")

  240.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  241.     else()

  242.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  243.     endif()

  244.   endforeach()

  245. endfunction()

  246. 

  247. # dpf_add_executable(target <args...>)

  248. # ------------------------------------------------------------------------------

  249. #

  250. # Add a simple executable built using the DISTRHO Plugin Framework.

  251. #

  252. # ------------------------------------------------------------------------------

  253. # Arguments:

  254. #

  255. #   `UI_TYPE` <type>

  256. #       the user interface type, can be one of the following:

  257. #          - cairo

  258. #          - external

  259. #          - opengl (default)

  260. #          - opengl3

  261. #          - vulkan

  262. #          - webview

  263. #

  264. #   `NO_SHARED_RESOURCES`

  265. #       do not build DPF shared resources (fonts, etc)

  266. #

  267. #   `USE_FILE_BROWSER`

  268. #       enable file browser dialog APIs

  269. #

  270. #   `USE_WEB_VIEW`

  271. #       enable web browser view APIs

  272. #

  273. function(dpf_add_executable NAME)

  274.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  275.   set(oneValueArgs UI_TYPE)

  276.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  277. 

  278.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  279.     set(_dpf_plugin_UI_TYPE "opengl")

  280.   endif()

  281. 

  282.   set(_dgl_library)

  283.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  284.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  285.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  286.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  287.     set(_dgl_library dgl-cairo)

  288.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  289.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  290.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  291.     set(_dgl_library dgl-external)

  292.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  293.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  294.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  295.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  296.     set(_dgl_library dgl-opengl)

  297.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  298.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  299.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  300.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  301.     set(_dgl_library dgl-opengl3)

  302.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  303.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  304.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  305.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  306.     set(_dgl_library dgl-vulkan)

  307.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  308.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  309.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  310.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  311.     set(_dgl_library dgl-external)

  312.   else()

  313.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  314.   endif()

  315. 

  316.   set(_dgl_has_ui OFF)

  317.   if(_dgl_library)

  318.     set(_dgl_has_ui ON)

  319.   endif()

  320. 

  321.   dpf__create_dummy_source_list(_no_srcs)

  322.   dpf__add_executable("${NAME}" ${_no_srcs})

  323.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  324. 

  325.   if(_dpf_plugin_USE_FILE_BROWSER)

  326.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  327.   endif()

  328. 

  329.   if(_dpf_plugin_USE_WEB_VIEW)

  330.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  331.   endif()

  332. 

  333.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  334.     target_link_libraries("${NAME}" PRIVATE "dl")

  335.   endif()

  336. 

  337.   if(_dgl_library)

  338.     # make sure that all code will see DGL_* definitions

  339.     target_link_libraries("${NAME}" PUBLIC

  340.       "${_dgl_library}"

  341.       "${_dgl_library}-definitions"

  342.       dgl-system-libs-definitions

  343.       dgl-system-libs)

  344.     # extra linkage for linux web view

  345.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  346.       target_link_libraries("${NAME}" PRIVATE "rt")

  347.     endif()

  348.     # add the files containing C++17 or Objective-C classes

  349.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  350.   endif()

  351. endfunction()

  352. 

  353. # ------------------------------------------------------------------------------

  354. # DPF private functions (prefixed with `dpf__`)

  355. # ------------------------------------------------------------------------------

  356. 

  357. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  358. #       to the output directory.

  359. #

  360. 

  361. # dpf__build_jack

  362. # ------------------------------------------------------------------------------

  363. #

  364. # Add build rules for a JACK/Standalone program.

  365. #

  366. function(dpf__build_jack NAME HAS_UI)

  367.   dpf__create_dummy_source_list(_no_srcs)

  368. 

  369.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  370.   dpf__add_plugin_main("${NAME}-jack" "jack")

  371.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  372.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  373.   set_target_properties("${NAME}-jack" PROPERTIES

  374.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  375.     OUTPUT_NAME "${NAME}")

  376. 

  377.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  378.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  379. 

  380.   find_package(PkgConfig)

  381.   pkg_check_modules(SDL2 "sdl2")

  382.   if(SDL2_FOUND)

  383.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  384.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  385.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  386.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  387.   endif()

  388. 

  389.   if(APPLE OR WIN32)

  390.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  391.   else()

  392.     find_package(Threads)

  393.     pkg_check_modules(ALSA "alsa")

  394.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  395.     if(ALSA_FOUND)

  396.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  397.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  398.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  399.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  400.     endif()

  401.     if(PULSEAUDIO_FOUND)

  402.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  403.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  404.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  405.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  406.     endif()

  407.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  408.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  409.     endif()

  410.   endif()

  411. 

  412.   # for RtAudio native fallback

  413.   if(APPLE)

  414.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  415.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  416.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  417.     target_link_libraries("${NAME}-jack" PRIVATE

  418.       "${APPLE_COREAUDIO_FRAMEWORK}"

  419.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  420.       "${APPLE_COREMIDI_FRAMEWORK}")

  421.   elseif(WIN32)

  422.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  423.     if(HAS_UI AND MINGW)

  424.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  425.     endif()

  426.   endif()

  427. endfunction()

  428. 

  429. # dpf__build_ladspa

  430. # ------------------------------------------------------------------------------

  431. #

  432. # Add build rules for a LADSPA plugin.

  433. #

  434. function(dpf__build_ladspa NAME)

  435.   dpf__create_dummy_source_list(_no_srcs)

  436. 

  437.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  438.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  439.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  440.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  441.   set_target_properties("${NAME}-ladspa" PROPERTIES

  442.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  443.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  444.     OUTPUT_NAME "${NAME}-ladspa"

  445.     PREFIX "")

  446. endfunction()

  447. 

  448. # dpf__build_dssi

  449. # ------------------------------------------------------------------------------

  450. #

  451. # Add build rules for a DSSI plugin.

  452. #

  453. function(dpf__build_dssi NAME HAS_UI)

  454.   find_package(PkgConfig)

  455.   pkg_check_modules(LIBLO "liblo")

  456.   if(NOT LIBLO_FOUND)

  457.     dpf__warn_once_only(missing_liblo

  458.       "liblo is not found, skipping the `dssi` plugin targets")

  459.     return()

  460.   endif()

  461. 

  462.   dpf__create_dummy_source_list(_no_srcs)

  463. 

  464.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  465.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  466.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  467.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  468.   set_target_properties("${NAME}-dssi" PROPERTIES

  469.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  470.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  471.     OUTPUT_NAME "${NAME}-dssi"

  472.     PREFIX "")

  473. 

  474.   if(HAS_UI)

  475.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  476.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  477.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  478.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  479.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  480.       OUTPUT_NAME "${NAME}_ui")

  481. 

  482.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  483.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  484.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  485.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  486.   endif()

  487. endfunction()

  488. 

  489. # dpf__build_lv2

  490. # ------------------------------------------------------------------------------

  491. #

  492. # Add build rules for an LV2 plugin.

  493. #

  494. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  495.   dpf__create_dummy_source_list(_no_srcs)

  496. 

  497.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  498.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  499.   if(HAS_UI AND MONOLITHIC)

  500.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  501.   else()

  502.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  503.   endif()

  504.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  505.   set_target_properties("${NAME}-lv2" PROPERTIES

  506.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  507.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  508.     OUTPUT_NAME "${NAME}_dsp"

  509.     PREFIX "")

  510. 

  511.   if(HAS_UI)

  512.     if(MONOLITHIC)

  513.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  514.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  515.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  516.       set_target_properties("${NAME}-lv2" PROPERTIES

  517.         OUTPUT_NAME "${NAME}")

  518.     else()

  519.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  520.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  521.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  522.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  523.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  524.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  525.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  526.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  527.         OUTPUT_NAME "${NAME}_ui"

  528.         PREFIX "")

  529.     endif()

  530.   endif()

  531. 

  532.   dpf__add_lv2_ttl_generator()

  533.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  534. 

  535.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  536. 

  537.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  538.     COMMAND

  539.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  540.     "$<TARGET_FILE:lv2_ttl_generator>"

  541.     "$<TARGET_FILE:${NAME}-lv2>"

  542.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  543.     DEPENDS lv2_ttl_generator)

  544. endfunction()

  545. 

  546. # dpf__build_vst2

  547. # ------------------------------------------------------------------------------

  548. #

  549. # Add build rules for a VST2 plugin.

  550. #

  551. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  552.   dpf__create_dummy_source_list(_no_srcs)

  553. 

  554.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  555.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  556.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  557.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  558.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  559.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  560.   set_target_properties("${NAME}-vst2" PROPERTIES

  561.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  562.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  563.     OUTPUT_NAME "${NAME}-vst2"

  564.     PREFIX "")

  565.   if(APPLE)

  566.     set_target_properties("${NAME}-vst2" PROPERTIES

  567.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  568.       OUTPUT_NAME "${NAME}"

  569.       SUFFIX "")

  570.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  571.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  572.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  573.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  574.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  575.   endif()

  576. endfunction()

  577. 

  578. # dpf__determine_vst3_package_architecture

  579. # ------------------------------------------------------------------------------

  580. #

  581. # Determines the package architecture for a VST3 plugin target.

  582. #

  583. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  584.   # if set by variable, override the detection

  585.   if(DPF_VST3_ARCHITECTURE)

  586.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  587.     return()

  588.   endif()

  589. 

  590.   # not used on Apple, which supports universal binary

  591.   if(APPLE)

  592.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  593.     return()

  594.   endif()

  595. 

  596.   # identify the target processor (special case of MSVC, problematic sometimes)

  597.   if(MSVC)

  598.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  599.   else()

  600.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  601.   endif()

  602. 

  603.   # transform the processor name to a format that VST3 recognizes

  604.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  605.     set(vst3_package_arch "x86_64")

  606.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  607.     if(WIN32)

  608.       set(vst3_package_arch "x86")

  609.     else()

  610.       set(vst3_package_arch "i386")

  611.     endif()

  612.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  613.     set(vst3_package_arch "${vst3_system_arch}")

  614.   else()

  615.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  616.   endif()

  617. 

  618.   # TODO: the detections for Windows arm/arm64 when supported

  619. 

  620.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  621. endfunction()

  622. 

  623. # dpf__build_vst3

  624. # ------------------------------------------------------------------------------

  625. #

  626. # Add build rules for a VST3 plugin.

  627. #

  628. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  629.   dpf__determine_vst3_package_architecture(vst3_arch)

  630. 

  631.   dpf__create_dummy_source_list(_no_srcs)

  632. 

  633.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  634.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  635.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  636.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  637.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  638.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  639.   set_target_properties("${NAME}-vst3" PROPERTIES

  640.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  641.     OUTPUT_NAME "${NAME}"

  642.     PREFIX "")

  643. 

  644.   if(APPLE)

  645.     set_target_properties("${NAME}-vst3" PROPERTIES

  646.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  647.       SUFFIX "")

  648.   elseif(WIN32)

  649.     set_target_properties("${NAME}-vst3" PROPERTIES

  650.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  651.   else()

  652.     set_target_properties("${NAME}-vst3" PROPERTIES

  653.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  654.   endif()

  655. 

  656.   if(APPLE)

  657.     # Uses the same macOS bundle template as VST2

  658.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  659.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  660.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  661.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  662.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  663.   endif()

  664. endfunction()

  665. 

  666. # dpf__build_clap

  667. # ------------------------------------------------------------------------------

  668. #

  669. # Add build rules for a CLAP plugin.

  670. #

  671. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  672.   dpf__create_dummy_source_list(_no_srcs)

  673. 

  674.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  675.   dpf__add_plugin_main("${NAME}-clap" "clap")

  676.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  677.   dpf__set_module_export_list("${NAME}-clap" "clap")

  678.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  679.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  680.   set_target_properties("${NAME}-clap" PROPERTIES

  681.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  682.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  683.     OUTPUT_NAME "${NAME}"

  684.     PREFIX ""

  685.     SUFFIX ".clap")

  686. 

  687.   if(APPLE)

  688.     set_target_properties("${NAME}-clap" PROPERTIES

  689.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  690.       OUTPUT_NAME "${NAME}"

  691.       SUFFIX "")

  692.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  693.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  694.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  695.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  696.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  697.   endif()

  698. endfunction()

  699. 

  700. # dpf__build_au

  701. # ------------------------------------------------------------------------------

  702. #

  703. # Add build rules for an AUv2 plugin.

  704. #

  705. function(dpf__build_au NAME HAS_UI)

  706.   dpf__create_dummy_source_list(_no_srcs)

  707. 

  708.   dpf__add_module("${NAME}-au" ${_no_srcs})

  709.   dpf__add_plugin_main("${NAME}-au" "au")

  710.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  711.   dpf__set_module_export_list("${NAME}-au" "au")

  712.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  713.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  714.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  715.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  716.   target_link_libraries("${NAME}-au" PRIVATE

  717.     "${NAME}-dsp"

  718.     "${NAME}-ui"

  719.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  720.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  721.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  722.   set_target_properties("${NAME}-au" PROPERTIES

  723.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  724.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  725.     OUTPUT_NAME "${NAME}"

  726.     PREFIX ""

  727.     SUFFIX "")

  728. 

  729.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  730.   dpf__add_plugin_main("${NAME}-export" "export")

  731.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  732.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  733. 

  734.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  735. 

  736.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  737.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  738.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  739.     DEPENDS "${NAME}-export")

  740. 

  741.   add_dependencies("${NAME}-au" "${NAME}-export")

  742. 

  743.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  744.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  745. endfunction()

  746. 

  747. # dpf__build_static

  748. # ------------------------------------------------------------------------------

  749. #

  750. # Add build rules for a static library.

  751. #

  752. function(dpf__build_static NAME HAS_UI)

  753.   dpf__create_dummy_source_list(_no_srcs)

  754. 

  755.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  756.   dpf__add_plugin_main("${NAME}-static" "static")

  757.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  758.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  759. 

  760.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  761.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  762.   foreach(src ${dsp_srcs})

  763.     target_sources("${NAME}-static" PRIVATE ${src})

  764.   endforeach()

  765.   foreach(src ${ui_srcs})

  766.     target_sources("${NAME}-static" PRIVATE ${src})

  767.   endforeach()

  768. 

  769.   set_target_properties("${NAME}-static" PROPERTIES

  770.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  771.     OUTPUT_NAME "${NAME}"

  772.     PREFIX "")

  773. endfunction()

  774. 

  775. # dpf__add_dgl_cairo

  776. # ------------------------------------------------------------------------------

  777. #

  778. # Add the Cairo variant of DGL, if not already available.

  779. #

  780. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  781.   if(TARGET dgl-cairo)

  782.     return()

  783.   endif()

  784. 

  785.   find_package(PkgConfig)

  786.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  787. 

  788.   link_directories(${CAIRO_LIBRARY_DIRS})

  789. 

  790.   dpf__add_static_library(dgl-cairo STATIC

  791.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  792.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  793.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  794.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  795.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  796.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  797.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  798.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  799.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  800.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  801.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  802.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  803.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  804.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  805.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  806.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  807.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  808.   if(SHARED_RESOURCES)

  809.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  810.   else()

  811.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  812.   endif()

  813.   if(APPLE)

  814.     target_sources(dgl-cairo PRIVATE

  815.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  816.   else()

  817.     target_sources(dgl-cairo PRIVATE

  818.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  819.   endif()

  820.   target_include_directories(dgl-cairo PUBLIC

  821.     "${DPF_ROOT_DIR}/dgl")

  822.   target_include_directories(dgl-cairo PUBLIC

  823.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  824. 

  825.   if(USE_FILE_BROWSER)

  826.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  827.   endif()

  828. 

  829.   if(USE_WEB_VIEW)

  830.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  831.     if(APPLE)

  832.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  833.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  834.     elseif(WIN32)

  835.       target_sources(dgl-cairo PRIVATE

  836.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  837.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  838.         PROPERTIES

  839.           COMPILE_FLAGS

  840.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  841.     endif()

  842.   endif()

  843. 

  844.   dpf__add_dgl_system_libs()

  845.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  846. 

  847.   add_library(dgl-cairo-definitions INTERFACE)

  848.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  849. 

  850.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  851.   if(MINGW)

  852.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  853.   else()

  854.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  855.   endif()

  856.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  857. endfunction()

  858. 

  859. # dpf__add_dgl_external

  860. # ------------------------------------------------------------------------------

  861. #

  862. # Add the external variant of DGL, if not already available.

  863. #

  864. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  865.   if(TARGET dgl-external)

  866.     return()

  867.   endif()

  868. 

  869.   dpf__add_static_library(dgl-external STATIC

  870.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  871.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  883.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  884.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  885.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  886.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  887. 

  888.   if(APPLE)

  889.     target_sources(dgl-external PRIVATE

  890.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  891.   else()

  892.     target_sources(dgl-external PRIVATE

  893.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  894.   endif()

  895.   target_include_directories(dgl-external PUBLIC

  896.     "${DPF_ROOT_DIR}/dgl")

  897.   target_include_directories(dgl-external PUBLIC

  898.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  899. 

  900.   if(USE_FILE_BROWSER)

  901.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  902.   endif()

  903. 

  904.   if(USE_WEB_VIEW)

  905.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  906.     if(APPLE)

  907.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  908.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  909.     elseif(WIN32)

  910.       target_sources(dgl-external PRIVATE

  911.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  912.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  913.         PROPERTIES

  914.           COMPILE_FLAGS

  915.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  916.     endif()

  917.   endif()

  918. 

  919.   dpf__add_dgl_system_libs()

  920.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  921.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  922. 

  923.   add_library(dgl-external-definitions INTERFACE)

  924.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  925. 

  926.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  927.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  928. endfunction()

  929. 

  930. # dpf__add_dgl_opengl

  931. # ------------------------------------------------------------------------------

  932. #

  933. # Add the OpenGL variant of DGL, if not already available.

  934. #

  935. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  936.   if(TARGET dgl-opengl)

  937.     return()

  938.   endif()

  939. 

  940.   if(NOT OpenGL_GL_PREFERENCE)

  941.     set(OpenGL_GL_PREFERENCE "LEGACY")

  942.   endif()

  943. 

  944.   find_package(OpenGL REQUIRED)

  945. 

  946.   dpf__add_static_library(dgl-opengl STATIC

  947.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  956.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  957.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  958.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  959.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  960.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  961.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  962.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  963.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  964.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  965.   if(SHARED_RESOURCES)

  966.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  967.   else()

  968.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  969.   endif()

  970.   if(APPLE)

  971.     target_sources(dgl-opengl PRIVATE

  972.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  973.   else()

  974.     target_sources(dgl-opengl PRIVATE

  975.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  976.   endif()

  977.   target_include_directories(dgl-opengl PUBLIC

  978.     "${DPF_ROOT_DIR}/dgl")

  979.   target_include_directories(dgl-opengl PUBLIC

  980.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  981. 

  982.   if(APPLE)

  983.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  984.   endif()

  985. 

  986.   if(USE_FILE_BROWSER)

  987.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  988.   endif()

  989. 

  990.   if(USE_WEB_VIEW)

  991.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  992.     if(APPLE)

  993.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  994.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  995.     elseif(WIN32)

  996.       target_sources(dgl-opengl PRIVATE

  997.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  998.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  999.         PROPERTIES

  1000.           COMPILE_FLAGS

  1001.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1002.     endif()

  1003.   endif()

  1004. 

  1005.   dpf__add_dgl_system_libs()

  1006.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1007. 

  1008.   add_library(dgl-opengl-definitions INTERFACE)

  1009.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  1010. 

  1011.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1012.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1013. endfunction()

  1014. 

  1015. # dpf__add_dgl_opengl3

  1016. # ------------------------------------------------------------------------------

  1017. #

  1018. # Add the OpenGL3 variant of DGL, if not already available.

  1019. #

  1020. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1021.   if(TARGET dgl-opengl3)

  1022.     return()

  1023.   endif()

  1024. 

  1025.   if(NOT OpenGL_GL_PREFERENCE)

  1026.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1027.   endif()

  1028. 

  1029.   find_package(OpenGL REQUIRED)

  1030. 

  1031.   dpf__add_static_library(dgl-opengl3 STATIC

  1032.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1033.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1034.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1035.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1036.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1037.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1038.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1039.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1040.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1041.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1042.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1043.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1044.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1045.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1046.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1047.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1048.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1049.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1050.   if(SHARED_RESOURCES)

  1051.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1052.   else()

  1053.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1054.   endif()

  1055.   if(APPLE)

  1056.     target_sources(dgl-opengl3 PRIVATE

  1057.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1058.   else()

  1059.     target_sources(dgl-opengl3 PRIVATE

  1060.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1061.   endif()

  1062.   target_include_directories(dgl-opengl3 PUBLIC

  1063.     "${DPF_ROOT_DIR}/dgl")

  1064.   target_include_directories(dgl-opengl3 PUBLIC

  1065.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1066. 

  1067.   if(APPLE)

  1068.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1069.   endif()

  1070. 

  1071.   if(USE_FILE_BROWSER)

  1072.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1073.   endif()

  1074. 

  1075.   if(USE_WEB_VIEW)

  1076.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1077.     if(APPLE)

  1078.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1079.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1080.     elseif(WIN32)

  1081.       target_sources(dgl-opengl3 PRIVATE

  1082.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1083.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1084.         PROPERTIES

  1085.           COMPILE_FLAGS

  1086.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1087.     endif()

  1088.   endif()

  1089. 

  1090.   dpf__add_dgl_system_libs()

  1091.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1092. 

  1093.   add_library(dgl-opengl3-definitions INTERFACE)

  1094.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  1095. 

  1096.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1097.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1098. endfunction()

  1099. 

  1100. # dpf__add_dgl_vulkan

  1101. # ------------------------------------------------------------------------------

  1102. #

  1103. # Add the Vulkan variant of DGL, if not already available.

  1104. #

  1105. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1106.   if(TARGET dgl-vulkan)

  1107.     return()

  1108.   endif()

  1109. 

  1110.   find_package(Vulkan REQUIRED)

  1111. 

  1112.   dpf__add_static_library(dgl-vulkan STATIC

  1113.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1114.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1115.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1116.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1117.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1118.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1119.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1120.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1121.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1122.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1123.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1124.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1125.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1126.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1127.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1128.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1129.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1130.   if(NO_SHARED_RESOURCES)

  1131.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1132.   else()

  1133.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1134.   endif()

  1135.   if(APPLE)

  1136.     target_sources(dgl-vulkan PRIVATE

  1137.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1138.   else()

  1139.     target_sources(dgl-vulkan PRIVATE

  1140.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1141.   endif()

  1142.   target_include_directories(dgl-vulkan PUBLIC

  1143.     "${DPF_ROOT_DIR}/dgl")

  1144.   target_include_directories(dgl-vulkan PUBLIC

  1145.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1146. 

  1147.   if(APPLE)

  1148.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1149.   endif()

  1150. 

  1151.   if(USE_FILE_BROWSER)

  1152.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1153.   endif()

  1154. 

  1155.   if(USE_WEB_VIEW)

  1156.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1157.     if(APPLE)

  1158.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1159.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1160.     elseif(WIN32)

  1161.       target_sources(dgl-vulkan PRIVATE

  1162.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1163.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1164.         PROPERTIES

  1165.           COMPILE_FLAGS

  1166.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1167.     endif()

  1168.   endif()

  1169. 

  1170.   dpf__add_dgl_system_libs()

  1171.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1172. 

  1173.   add_library(dgl-vulkan-definitions INTERFACE)

  1174.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1175. 

  1176.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1177.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1178. endfunction()

  1179. 

  1180. # dpf__add_plugin_specific_ui_sources

  1181. # ------------------------------------------------------------------------------

  1182. #

  1183. # Compile system specific files

  1184. #

  1185. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1186.   if(APPLE)

  1187.     target_sources("${NAME}" PRIVATE

  1188.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1189.     if(USE_WEB_VIEW)

  1190.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1191.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1192.     endif()

  1193.   elseif(WIN32 AND USE_WEB_VIEW)

  1194.     target_sources("${NAME}" PRIVATE

  1195.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1196.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1197.       PROPERTIES

  1198.         COMPILE_FLAGS

  1199.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1200.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1201.   endif()

  1202. endfunction()

  1203. 

  1204. # dpf__add_dgl_system_libs

  1205. # ------------------------------------------------------------------------------

  1206. #

  1207. # Find system libraries required by DGL and add them as an interface target.

  1208. #

  1209. function(dpf__add_dgl_system_libs)

  1210.   if(TARGET dgl-system-libs)

  1211.     return()

  1212.   endif()

  1213.   add_library(dgl-system-libs INTERFACE)

  1214.   add_library(dgl-system-libs-definitions INTERFACE)

  1215.   if(APPLE)

  1216.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1217.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1218.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1219.   elseif(EMSCRIPTEN)

  1220.   elseif(HAIKU)

  1221.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1222.   elseif(WIN32)

  1223.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1224.   else()

  1225.     find_package(PkgConfig)

  1226.     pkg_check_modules(DBUS "dbus-1")

  1227.     if(DBUS_FOUND)

  1228.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1229.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1230.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1231.     endif()

  1232.     find_package(X11 REQUIRED)

  1233.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1234.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1235.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1236.     if(X11_Xcursor_FOUND)

  1237.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1238.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1239.     endif()

  1240.     if(X11_Xext_FOUND)

  1241.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1242.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1243.     endif()

  1244.     if(X11_Xrandr_FOUND)

  1245.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1246.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1247.     endif()

  1248.     if(X11_XSync_FOUND)

  1249.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1250.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1251.     endif()

  1252.    endif()

  1253. 

  1254.    if(MSVC)

  1255.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1256.      foreach(_gl_header "glext.h")

  1257.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1258.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1259.        endif()

  1260.      endforeach()

  1261.      foreach(_khr_header "khrplatform.h")

  1262.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1263.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1264.        endif()

  1265.      endforeach()

  1266.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1267.    endif()

  1268. 

  1269.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1270. endfunction()

  1271. 

  1272. # dpf__add_executable

  1273. # ------------------------------------------------------------------------------

  1274. #

  1275. # Adds an executable target, and set some default properties on the target.

  1276. #

  1277. function(dpf__add_executable NAME)

  1278.   add_executable("${NAME}" ${ARGN})

  1279.   dpf__set_target_defaults("${NAME}")

  1280.   if(MINGW)

  1281.     target_link_libraries("${NAME}" PRIVATE "-static")

  1282.   endif()

  1283. endfunction()

  1284. 

  1285. # dpf__add_module

  1286. # ------------------------------------------------------------------------------

  1287. #

  1288. # Adds a module target, and set some default properties on the target.

  1289. #

  1290. function(dpf__add_module NAME)

  1291.   add_library("${NAME}" MODULE ${ARGN})

  1292.   dpf__set_target_defaults("${NAME}")

  1293.   if(APPLE)

  1294.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1295.   elseif(MINGW)

  1296.     target_link_libraries("${NAME}" PRIVATE "-static")

  1297.   endif()

  1298. endfunction()

  1299. 

  1300. # dpf__add_static_library

  1301. # ------------------------------------------------------------------------------

  1302. #

  1303. # Adds a static library target, and set some default properties on the target.

  1304. #

  1305. function(dpf__add_static_library NAME)

  1306.   add_library("${NAME}" STATIC ${ARGN})

  1307.   dpf__set_target_defaults("${NAME}")

  1308. endfunction()

  1309. 

  1310. # dpf__set_module_export_list

  1311. # ------------------------------------------------------------------------------

  1312. #

  1313. # Applies a list of exported symbols to the module target.

  1314. #

  1315. function(dpf__set_module_export_list NAME EXPORTS)

  1316.   if(WIN32)

  1317.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1318.   elseif(APPLE)

  1319.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1320.       "-Xlinker" "-exported_symbols_list"

  1321.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1322.   else()

  1323.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1324.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1325.   endif()

  1326. endfunction()

  1327. 

  1328. # dpf__set_target_defaults

  1329. # ------------------------------------------------------------------------------

  1330. #

  1331. # Set default properties which must apply to all DPF-defined targets.

  1332. #

  1333. function(dpf__set_target_defaults NAME)

  1334.   set_target_properties("${NAME}" PROPERTIES

  1335.     POSITION_INDEPENDENT_CODE TRUE

  1336.     C_VISIBILITY_PRESET "hidden"

  1337.     CXX_VISIBILITY_PRESET "hidden"

  1338.     VISIBILITY_INLINES_HIDDEN TRUE)

  1339.   if(WIN32)

  1340.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1341.   endif()

  1342.   if (MINGW)

  1343.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1344.   endif()

  1345.   if (MSVC)

  1346.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1347.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1348.   endif()

  1349.   if (CMAKE_COMPILER_IS_GNUCXX)

  1350.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1351.   endif()

  1352.   if ((NOT APPLE) AND (NOT MSVC))

  1353.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1354.   endif()

  1355. endfunction()

  1356. 

  1357. # dpf__add_plugin_main

  1358. # ------------------------------------------------------------------------------

  1359. #

  1360. # Adds plugin code to the given target.

  1361. #

  1362. function(dpf__add_plugin_main NAME TARGET)

  1363.   target_sources("${NAME}" PRIVATE

  1364.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1365.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1366. endfunction()

  1367. 

  1368. # dpf__add_ui_main

  1369. # ------------------------------------------------------------------------------

  1370. #

  1371. # Adds UI code to the given target (only if the target has UI).

  1372. #

  1373. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1374.   if(HAS_UI)

  1375.     target_sources("${NAME}" PRIVATE

  1376.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1377.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1378.   endif()

  1379. endfunction()

  1380. 

  1381. # dpf__add_plugin_target_definition

  1382. # ------------------------------------------------------------------------------

  1383. #

  1384. # Adds the plugins target macro definition.

  1385. # This selects which entry file is compiled according to the target type.

  1386. #

  1387. function(dpf__add_plugin_target_definition NAME TARGET)

  1388.   string(TOUPPER "${TARGET}" _upperTarget)

  1389.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1390. endfunction()

  1391. 

  1392. # dpf__add_lv2_ttl_generator

  1393. # ------------------------------------------------------------------------------

  1394. #

  1395. # Build the LV2 TTL generator.

  1396. #

  1397. function(dpf__add_lv2_ttl_generator)

  1398.   if(TARGET lv2_ttl_generator)

  1399.     return()

  1400.   endif()

  1401.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1402.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1403.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1404.   endif()

  1405. endfunction()

  1406. 

  1407. # dpf__ensure_sources_non_empty

  1408. # ------------------------------------------------------------------------------

  1409. #

  1410. # Ensure the given source list contains at least one file.

  1411. # The function appends an empty source file to the list if necessary.

  1412. # This is useful when CMake does not permit to add targets without sources.

  1413. #

  1414. function(dpf__ensure_sources_non_empty VAR)

  1415.   if(NOT "" STREQUAL "${${VAR}}")

  1416.     return()

  1417.   endif()

  1418.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1419.   if(NOT EXISTS "${_file}")

  1420.     file(WRITE "${_file}" "")

  1421.   endif()

  1422.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1423. endfunction()

  1424. 

  1425. # dpf__create_dummy_source_list

  1426. # ------------------------------------------------------------------------------

  1427. #

  1428. # Create a dummy source list which is equivalent to compiling nothing.

  1429. # This is only for compatibility with older CMake versions, which refuse to add

  1430. # targets without any sources.

  1431. #

  1432. macro(dpf__create_dummy_source_list VAR)

  1433.   set("${VAR}")

  1434.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1435.     dpf__ensure_sources_non_empty("${VAR}")

  1436.   endif()

  1437. endmacro()

  1438. 

  1439. # dpf__target_link_directories

  1440. # ------------------------------------------------------------------------------

  1441. #

  1442. # Call `target_link_directories` if cmake >= 3.13,

  1443. # otherwise fallback to global `link_directories`.

  1444. #

  1445. macro(dpf__target_link_directories NAME DIRS)

  1446.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1447.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1448.   else()

  1449.     link_directories(${DIRS})

  1450.   endif()

  1451. endmacro()

  1452. 

  1453. # dpf__warn_once

  1454. # ------------------------------------------------------------------------------

  1455. #

  1456. # Prints a warning message once only.

  1457. #

  1458. function(dpf__warn_once_only TOKEN MESSAGE)

  1459.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1460.   if(NOT _warned)

  1461.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1462.     message(WARNING "${MESSAGE}")

  1463.   endif()

  1464. endfunction()