DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2499 Commits
6 Branches
58MB
Tree: 690bfd2c47
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '690bfd2c47'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1753 lines
62KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `FORCE_NATIVE_AUDIO_FALLBACK`

  108. #       force the JACK/Standalone format to use native audio fallback instead of JACK

  109. #

  110. #   `SKIP_NATIVE_AUDIO_FALLBACK`

  111. #       force the JACK/Standalone format to always use JACK, skipping native audio fallback

  112. #

  113. #   `USE_FILE_BROWSER`

  114. #       enable file browser dialog APIs

  115. #

  116. #   `USE_WEB_VIEW`

  117. #       enable web browser view APIs

  118. #

  119. function(dpf_add_plugin NAME)

  120.   set(options MONOLITHIC NO_SHARED_RESOURCES FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER USE_WEB_VIEW)

  121.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  122.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  123.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  124. 

  125.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  126.     set(_dpf_plugin_UI_TYPE "opengl")

  127.   endif()

  128. 

  129.   set(_dgl_library)

  130.   if(_dpf_plugin_FILES_UI)

  131.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  132.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  133.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  134.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  135.       set(_dgl_library dgl-cairo)

  136.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  137.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  138.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  139.       set(_dgl_library dgl-external)

  140.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  141.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  142.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  143.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  144.       set(_dgl_library dgl-gles2)

  145.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  146.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  147.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  148.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  149.       set(_dgl_library dgl-gles3)

  150.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  151.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  152.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  153.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  154.       set(_dgl_library dgl-opengl)

  155.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  156.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  157.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  158.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  159.       set(_dgl_library dgl-opengl3)

  160.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  161.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  162.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  163.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  164.       set(_dgl_library dgl-vulkan)

  165.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  166.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  167.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  168.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  169.       set(_dgl_library dgl-external)

  170.     else()

  171.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  172.     endif()

  173.   else()

  174.     set(_dpf_plugin_UI_TYPE "")

  175.   endif()

  176. 

  177.   set(_dgl_has_ui OFF)

  178.   if(_dgl_library)

  179.     set(_dgl_has_ui ON)

  180.   endif()

  181. 

  182.   ###

  183.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  184.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  185.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  186. 

  187.   ###

  188.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  189.   target_include_directories("${NAME}" PUBLIC

  190.     "${DPF_ROOT_DIR}/distrho")

  191. 

  192.   if(_dpf_plugin_USE_FILE_BROWSER)

  193.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  194.   endif()

  195. 

  196.   if(_dpf_plugin_USE_WEB_VIEW)

  197.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  198.   endif()

  199. 

  200.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  201.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  202.   endif()

  203. 

  204.   find_package(Threads)

  205.   target_link_libraries("${NAME}" PUBLIC "${CMAKE_THREAD_LIBS_INIT}")

  206. 

  207.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  208.     target_link_libraries("${NAME}" PRIVATE "dl")

  209.   endif()

  210. 

  211.   if(_dgl_library)

  212.     # make sure that all code will see DGL_* definitions

  213.     target_link_libraries("${NAME}" PUBLIC

  214.       "${_dgl_library}-definitions"

  215.       dgl-system-libs-definitions

  216.       dgl-system-libs)

  217.   endif()

  218. 

  219.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  220.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  221. 

  222.   if(_dgl_library)

  223.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  224.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  225.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  226.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  227.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  228.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  229.           OUTPUT_STRIP_TRAILING_WHITESPACE

  230.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  231.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  232.       endif()

  233.     endif()

  234.     # add the files containing C++17 or Objective-C classes

  235.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  236.   else()

  237.     add_library("${NAME}-ui" INTERFACE)

  238.   endif()

  239. 

  240.   ###

  241.   foreach(_target ${_dpf_plugin_TARGETS})

  242.     if(_target STREQUAL "jack")

  243.       dpf__build_jack("${NAME}"

  244.                       "${_dgl_has_ui}"

  245.                       "${_dpf_plugin_FORCE_NATIVE_AUDIO_FALLBACK}"

  246.                       "${_dpf_plugin_SKIP_NATIVE_AUDIO_FALLBACK}"

  247.                       "${_dpf_plugin_USE_FILE_BROWSER}")

  248.     elseif(_target STREQUAL "ladspa")

  249.       dpf__build_ladspa("${NAME}")

  250.     elseif(_target STREQUAL "dssi")

  251.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  252.     elseif(_target STREQUAL "lv2")

  253.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  254.     elseif(_target STREQUAL "vst2")

  255.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  256.     elseif(_target STREQUAL "vst3")

  257.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  258.     elseif(_target STREQUAL "clap")

  259.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  260.     elseif(_target STREQUAL "au")

  261.       if (APPLE)

  262.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  263.       endif()

  264.     elseif(_target STREQUAL "static")

  265.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  266.     else()

  267.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  268.     endif()

  269.   endforeach()

  270. endfunction()

  271. 

  272. # dpf_add_executable(target <args...>)

  273. # ------------------------------------------------------------------------------

  274. #

  275. # Add a simple executable built using the DISTRHO Plugin Framework.

  276. #

  277. # ------------------------------------------------------------------------------

  278. # Arguments:

  279. #

  280. #   `UI_TYPE` <type>

  281. #       the user interface type, can be one of the following:

  282. #          - cairo

  283. #          - external

  284. #          - gles2

  285. #          - gles3

  286. #          - opengl (default)

  287. #          - opengl3

  288. #          - vulkan

  289. #          - webview

  290. #

  291. #   `NO_SHARED_RESOURCES`

  292. #       do not build DPF shared resources (fonts, etc)

  293. #

  294. #   `USE_FILE_BROWSER`

  295. #       enable file browser dialog APIs

  296. #

  297. #   `USE_WEB_VIEW`

  298. #       enable web browser view APIs

  299. #

  300. function(dpf_add_executable NAME)

  301.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  302.   set(oneValueArgs UI_TYPE)

  303.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  304. 

  305.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  306.     set(_dpf_plugin_UI_TYPE "opengl")

  307.   endif()

  308. 

  309.   set(_dgl_library)

  310.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  311.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  312.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  313.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  314.     set(_dgl_library dgl-cairo)

  315.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  316.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  317.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  318.     set(_dgl_library dgl-external)

  319.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  320.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  321.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  322.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  323.     set(_dgl_library dgl-gles2)

  324.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  325.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  326.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  327.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  328.     set(_dgl_library dgl-gles3)

  329.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  330.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  331.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  332.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  333.     set(_dgl_library dgl-opengl)

  334.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  335.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  336.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  337.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  338.     set(_dgl_library dgl-opengl3)

  339.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  340.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  341.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  342.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  343.     set(_dgl_library dgl-vulkan)

  344.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  345.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  346.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  347.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  348.     set(_dgl_library dgl-external)

  349.   else()

  350.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  351.   endif()

  352. 

  353.   set(_dgl_has_ui OFF)

  354.   if(_dgl_library)

  355.     set(_dgl_has_ui ON)

  356.   endif()

  357. 

  358.   dpf__create_dummy_source_list(_no_srcs)

  359.   dpf__add_executable("${NAME}" ${_no_srcs})

  360.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  361.   set_target_properties("${NAME}" PROPERTIES

  362.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  363.     OUTPUT_NAME "${NAME}")

  364. 

  365.   if(EMSCRIPTEN)

  366.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  367.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  368.     target_link_options("${NAME}"

  369.       PRIVATE

  370.         -sEXPORTED_RUNTIME_METHODS=dynCall)

  371.   endif()

  372. 

  373.   if(_dpf_plugin_USE_FILE_BROWSER)

  374.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  375.     if(EMSCRIPTEN)

  376.       target_link_options("${NAME}" PRIVATE -sEXPORTED_RUNTIME_METHODS=FS,cwrap)

  377.     endif()

  378.   endif()

  379. 

  380.   if(_dpf_plugin_USE_WEB_VIEW)

  381.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  382.   endif()

  383. 

  384.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  385.     target_link_libraries("${NAME}" PRIVATE "dl")

  386.   endif()

  387. 

  388.   if(_dgl_library)

  389.     # make sure that all code will see DGL_* definitions

  390.     target_link_libraries("${NAME}" PUBLIC

  391.       "${_dgl_library}"

  392.       "${_dgl_library}-definitions"

  393.       dgl-system-libs-definitions

  394.       dgl-system-libs)

  395.     # extra linkage for linux web view

  396.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  397.       target_link_libraries("${NAME}" PRIVATE "rt")

  398.     endif()

  399.     # add the files containing C++17 or Objective-C classes

  400.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  401.   endif()

  402. endfunction()

  403. 

  404. # ------------------------------------------------------------------------------

  405. # DPF private functions (prefixed with `dpf__`)

  406. # ------------------------------------------------------------------------------

  407. 

  408. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  409. #       to the output directory.

  410. #

  411. 

  412. # dpf__build_jack

  413. # ------------------------------------------------------------------------------

  414. #

  415. # Add build rules for a JACK/Standalone program.

  416. #

  417. function(dpf__build_jack NAME HAS_UI FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER)

  418.   dpf__create_dummy_source_list(_no_srcs)

  419. 

  420.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  421.   dpf__add_plugin_main("${NAME}-jack" "jack")

  422.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  423.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  424.   set_target_properties("${NAME}-jack" PROPERTIES

  425.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  426.     OUTPUT_NAME "${NAME}")

  427. 

  428.   if(EMSCRIPTEN)

  429.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  430.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  431.     target_link_options("${NAME}-jack"

  432.       PRIVATE

  433.         -sEXPORTED_RUNTIME_METHODS=dynCall

  434.         $<$<BOOL:${USE_FILE_BROWSER}>:-sEXPORTED_RUNTIME_METHODS=FS,cwrap>)

  435.   endif()

  436. 

  437.   if(NOT FORCE_NATIVE_AUDIO_FALLBACK)

  438.     target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  439.     target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  440.   endif()

  441. 

  442.   if(SKIP_NATIVE_AUDIO_FALLBACK)

  443.     return()

  444.   endif()

  445. 

  446.   find_package(PkgConfig QUIET)

  447.   if(PKG_CONFIG_FOUND)

  448.     pkg_check_modules(SDL2 "sdl2")

  449.   else()

  450.     set(SDL2_FOUND FALSE)

  451.   endif()

  452.   if(SDL2_FOUND)

  453.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  454.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  455.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  456.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  457.   endif()

  458. 

  459.   if(APPLE OR WIN32)

  460.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  461.   elseif(EMSCRIPTEN)

  462.   else()

  463.     pkg_check_modules(ALSA "alsa")

  464.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  465.     if(ALSA_FOUND)

  466.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  467.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  468.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES})

  469.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  470.     endif()

  471.     if(PULSEAUDIO_FOUND)

  472.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  473.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  474.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES})

  475.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  476.     endif()

  477.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  478.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  479.     endif()

  480.   endif()

  481. 

  482.   # for RtAudio native fallback

  483.   if(APPLE)

  484.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  485.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  486.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  487.     target_link_libraries("${NAME}-jack" PRIVATE

  488.       "${APPLE_COREAUDIO_FRAMEWORK}"

  489.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  490.       "${APPLE_COREMIDI_FRAMEWORK}")

  491.   elseif(WIN32)

  492.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  493.     if(HAS_UI AND MINGW)

  494.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  495.     endif()

  496.   endif()

  497. endfunction()

  498. 

  499. # dpf__build_ladspa

  500. # ------------------------------------------------------------------------------

  501. #

  502. # Add build rules for a LADSPA plugin.

  503. #

  504. function(dpf__build_ladspa NAME)

  505.   dpf__create_dummy_source_list(_no_srcs)

  506. 

  507.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  508.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  509.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  510.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  511.   set_target_properties("${NAME}-ladspa" PROPERTIES

  512.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  513.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  514.     OUTPUT_NAME "${NAME}-ladspa"

  515.     PREFIX "")

  516. endfunction()

  517. 

  518. # dpf__build_dssi

  519. # ------------------------------------------------------------------------------

  520. #

  521. # Add build rules for a DSSI plugin.

  522. #

  523. function(dpf__build_dssi NAME HAS_UI)

  524.   find_package(PkgConfig QUIET)

  525.   if(PKG_CONFIG_FOUND)

  526.     pkg_check_modules(LIBLO "liblo")

  527.   else()

  528.     set(LIBLO_FOUND FALSE)

  529.   endif()

  530.   if(NOT LIBLO_FOUND)

  531.     dpf__warn_once_only(missing_liblo

  532.       "liblo is not found, skipping the `dssi` plugin targets")

  533.     return()

  534.   endif()

  535. 

  536.   dpf__create_dummy_source_list(_no_srcs)

  537. 

  538.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  539.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  540.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  541.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  542.   set_target_properties("${NAME}-dssi" PROPERTIES

  543.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  544.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  545.     OUTPUT_NAME "${NAME}-dssi"

  546.     PREFIX "")

  547. 

  548.   if(HAS_UI)

  549.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  550.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  551.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  552.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  553.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  554.       OUTPUT_NAME "${NAME}_ui")

  555. 

  556.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  557.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  558.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  559.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  560.   endif()

  561. endfunction()

  562. 

  563. # dpf__build_lv2

  564. # ------------------------------------------------------------------------------

  565. #

  566. # Add build rules for an LV2 plugin.

  567. #

  568. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  569.   dpf__create_dummy_source_list(_no_srcs)

  570. 

  571.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  572.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  573.   if(HAS_UI AND MONOLITHIC)

  574.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  575.   else()

  576.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  577.   endif()

  578.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  579.   set_target_properties("${NAME}-lv2" PROPERTIES

  580.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  581.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  582.     OUTPUT_NAME "${NAME}_dsp"

  583.     PREFIX "")

  584. 

  585.   if(HAS_UI)

  586.     if(MONOLITHIC)

  587.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  588.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  589.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  590.       set_target_properties("${NAME}-lv2" PROPERTIES

  591.         OUTPUT_NAME "${NAME}")

  592.     else()

  593.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  594.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  595.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  596.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  597.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  598.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  599.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  600.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  601.         OUTPUT_NAME "${NAME}_ui"

  602.         PREFIX "")

  603.     endif()

  604.   endif()

  605. 

  606.   dpf__add_lv2_ttl_generator()

  607.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  608. 

  609.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  610. 

  611.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  612.     COMMAND

  613.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  614.     "$<TARGET_FILE:lv2_ttl_generator>"

  615.     "$<TARGET_FILE:${NAME}-lv2>"

  616.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  617. endfunction()

  618. 

  619. # dpf__build_vst2

  620. # ------------------------------------------------------------------------------

  621. #

  622. # Add build rules for a VST2 plugin.

  623. #

  624. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  625.   dpf__create_dummy_source_list(_no_srcs)

  626. 

  627.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  628.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  629.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  630.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  631.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  632.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  633.   set_target_properties("${NAME}-vst2" PROPERTIES

  634.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  635.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  636.     OUTPUT_NAME "${NAME}-vst2"

  637.     PREFIX "")

  638.   if(APPLE)

  639.     set_target_properties("${NAME}-vst2" PROPERTIES

  640.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  641.       OUTPUT_NAME "${NAME}"

  642.       SUFFIX "")

  643.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  644.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  645.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  646.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  647.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  648.   endif()

  649. endfunction()

  650. 

  651. # dpf__determine_vst3_package_architecture

  652. # ------------------------------------------------------------------------------

  653. #

  654. # Determines the package architecture for a VST3 plugin target.

  655. #

  656. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  657.   # if set by variable, override the detection

  658.   if(DPF_VST3_ARCHITECTURE)

  659.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  660.     return()

  661.   endif()

  662. 

  663.   # not used on Apple, which supports universal binary

  664.   if(APPLE)

  665.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  666.     return()

  667.   endif()

  668. 

  669.   # identify the target processor (special case of MSVC, problematic sometimes)

  670.   if(MSVC)

  671.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  672.   else()

  673.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  674.   endif()

  675. 

  676.   # transform the processor name to a format that VST3 recognizes

  677.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  678.     set(vst3_package_arch "x86_64")

  679.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  680.     if(WIN32)

  681.       set(vst3_package_arch "x86")

  682.     else()

  683.       set(vst3_package_arch "i386")

  684.     endif()

  685.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  686.     set(vst3_package_arch "${vst3_system_arch}")

  687.   else()

  688.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  689.   endif()

  690. 

  691.   # TODO: the detections for Windows arm/arm64 when supported

  692. 

  693.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  694. endfunction()

  695. 

  696. # dpf__build_vst3

  697. # ------------------------------------------------------------------------------

  698. #

  699. # Add build rules for a VST3 plugin.

  700. #

  701. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  702.   dpf__determine_vst3_package_architecture(vst3_arch)

  703. 

  704.   dpf__create_dummy_source_list(_no_srcs)

  705. 

  706.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  707.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  708.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  709.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  710.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  711.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  712.   set_target_properties("${NAME}-vst3" PROPERTIES

  713.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  714.     OUTPUT_NAME "${NAME}"

  715.     PREFIX "")

  716. 

  717.   if(APPLE)

  718.     set_target_properties("${NAME}-vst3" PROPERTIES

  719.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  720.       SUFFIX "")

  721.   elseif(WIN32)

  722.     set_target_properties("${NAME}-vst3" PROPERTIES

  723.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  724.   else()

  725.     set_target_properties("${NAME}-vst3" PROPERTIES

  726.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  727.   endif()

  728. 

  729.   if(APPLE)

  730.     # Uses the same macOS bundle template as VST2

  731.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  732.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  733.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  734.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  735.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  736.   endif()

  737. endfunction()

  738. 

  739. # dpf__build_clap

  740. # ------------------------------------------------------------------------------

  741. #

  742. # Add build rules for a CLAP plugin.

  743. #

  744. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  745.   dpf__create_dummy_source_list(_no_srcs)

  746. 

  747.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  748.   dpf__add_plugin_main("${NAME}-clap" "clap")

  749.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  750.   dpf__set_module_export_list("${NAME}-clap" "clap")

  751.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  752.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  753.   set_target_properties("${NAME}-clap" PROPERTIES

  754.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  755.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  756.     OUTPUT_NAME "${NAME}"

  757.     PREFIX ""

  758.     SUFFIX ".clap")

  759. 

  760.   if(APPLE)

  761.     set_target_properties("${NAME}-clap" PROPERTIES

  762.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  763.       OUTPUT_NAME "${NAME}"

  764.       SUFFIX "")

  765.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  766.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  767.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  768.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  769.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  770.   endif()

  771. endfunction()

  772. 

  773. # dpf__build_au

  774. # ------------------------------------------------------------------------------

  775. #

  776. # Add build rules for an AUv2 plugin.

  777. #

  778. function(dpf__build_au NAME HAS_UI)

  779.   dpf__create_dummy_source_list(_no_srcs)

  780. 

  781.   dpf__add_module("${NAME}-au" ${_no_srcs})

  782.   dpf__add_plugin_main("${NAME}-au" "au")

  783.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  784.   dpf__set_module_export_list("${NAME}-au" "au")

  785.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  786.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  787.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  788.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  789.   target_link_libraries("${NAME}-au" PRIVATE

  790.     "${NAME}-dsp"

  791.     "${NAME}-ui"

  792.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  793.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  794.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  795.   set_target_properties("${NAME}-au" PROPERTIES

  796.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  797.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  798.     OUTPUT_NAME "${NAME}"

  799.     PREFIX ""

  800.     SUFFIX "")

  801. 

  802.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  803.   dpf__add_plugin_main("${NAME}-export" "export")

  804.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  805.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  806. 

  807.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  808. 

  809.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  810.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  811.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  812. 

  813.   add_dependencies("${NAME}-au" "${NAME}-export")

  814. 

  815.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  816.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  817. endfunction()

  818. 

  819. # dpf__build_static

  820. # ------------------------------------------------------------------------------

  821. #

  822. # Add build rules for a static library.

  823. #

  824. function(dpf__build_static NAME HAS_UI)

  825.   dpf__create_dummy_source_list(_no_srcs)

  826. 

  827.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  828.   dpf__add_plugin_main("${NAME}-static" "static")

  829.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  830.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  831. 

  832.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  833.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  834.   foreach(src ${dsp_srcs})

  835.     target_sources("${NAME}-static" PRIVATE ${src})

  836.   endforeach()

  837.   foreach(src ${ui_srcs})

  838.     target_sources("${NAME}-static" PRIVATE ${src})

  839.   endforeach()

  840. 

  841.   set_target_properties("${NAME}-static" PROPERTIES

  842.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  843.     OUTPUT_NAME "${NAME}"

  844.     PREFIX "")

  845. endfunction()

  846. 

  847. # dpf__add_dgl_cairo

  848. # ------------------------------------------------------------------------------

  849. #

  850. # Add the Cairo variant of DGL, if not already available.

  851. #

  852. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  853.   if(TARGET dgl-cairo)

  854.     return()

  855.   endif()

  856. 

  857.   find_package(PkgConfig REQUIRED)

  858.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  859. 

  860.   link_directories(${CAIRO_LIBRARY_DIRS})

  861. 

  862.   dpf__add_static_library(dgl-cairo STATIC

  863.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  864.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  865.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  866.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  867.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  868.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  869.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  870.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  871.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  880.   if(SHARED_RESOURCES)

  881.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  882.   else()

  883.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  884.   endif()

  885.   if(APPLE)

  886.     target_sources(dgl-cairo PRIVATE

  887.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  888.   else()

  889.     target_sources(dgl-cairo PRIVATE

  890.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  891.   endif()

  892.   target_include_directories(dgl-cairo PUBLIC

  893.     "${DPF_ROOT_DIR}/dgl")

  894.   target_include_directories(dgl-cairo PUBLIC

  895.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  896. 

  897.   if(USE_FILE_BROWSER)

  898.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  899.   endif()

  900. 

  901.   if(USE_WEB_VIEW)

  902.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  903.     if(APPLE)

  904.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  905.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  906.     elseif(WIN32)

  907.       target_sources(dgl-cairo PRIVATE

  908.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  909.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  910.         PROPERTIES

  911.           COMPILE_FLAGS

  912.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  913.     endif()

  914.   endif()

  915. 

  916.   dpf__add_dgl_system_libs()

  917.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  918. 

  919.   add_library(dgl-cairo-definitions INTERFACE)

  920.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  921. 

  922.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  923.   if(MINGW)

  924.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  925.   else()

  926.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  927.   endif()

  928.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  929. endfunction()

  930. 

  931. # dpf__add_dgl_external

  932. # ------------------------------------------------------------------------------

  933. #

  934. # Add the external variant of DGL, if not already available.

  935. #

  936. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  937.   if(TARGET dgl-external)

  938.     return()

  939.   endif()

  940. 

  941.   dpf__add_static_library(dgl-external STATIC

  942.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  944.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  945.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  946.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  956.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  957.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  958.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  959. 

  960.   if(APPLE)

  961.     target_sources(dgl-external PRIVATE

  962.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  963.   else()

  964.     target_sources(dgl-external PRIVATE

  965.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  966.   endif()

  967.   target_include_directories(dgl-external PUBLIC

  968.     "${DPF_ROOT_DIR}/dgl")

  969.   target_include_directories(dgl-external PUBLIC

  970.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  971. 

  972.   if(USE_FILE_BROWSER)

  973.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  974.   endif()

  975. 

  976.   if(USE_WEB_VIEW)

  977.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  978.     if(APPLE)

  979.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  980.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  981.     elseif(WIN32)

  982.       target_sources(dgl-external PRIVATE

  983.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  984.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  985.         PROPERTIES

  986.           COMPILE_FLAGS

  987.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  988.     endif()

  989.   endif()

  990. 

  991.   dpf__add_dgl_system_libs()

  992.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  993.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  994. 

  995.   add_library(dgl-external-definitions INTERFACE)

  996.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  997. 

  998.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  999.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  1000. endfunction()

  1001. 

  1002. # dpf__add_dgl_gles2

  1003. # ------------------------------------------------------------------------------

  1004. #

  1005. # Add the GLESv2 variant of DGL, if not already available.

  1006. #

  1007. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1008.   if(TARGET dgl-gles2)

  1009.     return()

  1010.   endif()

  1011. 

  1012.   if(NOT OpenGL_GL_PREFERENCE)

  1013.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1014.   endif()

  1015. 

  1016.   find_package(OpenGL REQUIRED)

  1017. 

  1018.   dpf__add_static_library(dgl-gles2 STATIC

  1019.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1020.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1021.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1022.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1023.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1024.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1025.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1026.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1027.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1028.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1029.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1030.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1031.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1032.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1033.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1034.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1035.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1036.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1037.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1038.   if(SHARED_RESOURCES)

  1039.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1040.   else()

  1041.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1042.   endif()

  1043.   if(APPLE)

  1044.     target_sources(dgl-gles2 PRIVATE

  1045.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1046.   else()

  1047.     target_sources(dgl-gles2 PRIVATE

  1048.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1049.   endif()

  1050.   target_include_directories(dgl-gles2 PUBLIC

  1051.     "${DPF_ROOT_DIR}/dgl")

  1052.   target_include_directories(dgl-gles2 PUBLIC

  1053.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1054. 

  1055.   if(APPLE)

  1056.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1057.   endif()

  1058. 

  1059.   if(USE_FILE_BROWSER)

  1060.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1061.   endif()

  1062. 

  1063.   if(USE_WEB_VIEW)

  1064.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1065.     if(APPLE)

  1066.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1067.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1068.     elseif(WIN32)

  1069.       target_sources(dgl-gles2 PRIVATE

  1070.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1071.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1072.         PROPERTIES

  1073.           COMPILE_FLAGS

  1074.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1075.     endif()

  1076.   endif()

  1077. 

  1078.   dpf__add_dgl_system_libs()

  1079.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1080.   target_link_options(dgl-gles2

  1081.     INTERFACE

  1082.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1083.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1084.   )

  1085. 

  1086.   add_library(dgl-gles2-definitions INTERFACE)

  1087.   target_compile_definitions(dgl-gles2-definitions

  1088.     INTERFACE

  1089.       DGL_USE_OPENGL3

  1090.       DGL_USE_GLES

  1091.       DGL_USE_GLES2

  1092.       DGL_OPENGL

  1093.       HAVE_OPENGL

  1094.       HAVE_DGL

  1095.   )

  1096. 

  1097.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1098.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1099. endfunction()

  1100. 

  1101. # dpf__add_dgl_gles3

  1102. # ------------------------------------------------------------------------------

  1103. #

  1104. # Add the GLESv3 variant of DGL, if not already available.

  1105. #

  1106. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1107.   if(TARGET dgl-gles3)

  1108.     return()

  1109.   endif()

  1110. 

  1111.   if(NOT OpenGL_GL_PREFERENCE)

  1112.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1113.   endif()

  1114. 

  1115.   find_package(OpenGL REQUIRED)

  1116. 

  1117.   dpf__add_static_library(dgl-gles3 STATIC

  1118.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1119.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1120.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1121.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1122.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1123.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1124.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1125.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1126.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1127.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1128.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1129.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1130.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1131.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1132.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1133.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1134.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1135.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1136.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1137.   if(SHARED_RESOURCES)

  1138.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1139.   else()

  1140.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1141.   endif()

  1142.   if(APPLE)

  1143.     target_sources(dgl-gles3 PRIVATE

  1144.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1145.   else()

  1146.     target_sources(dgl-gles3 PRIVATE

  1147.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1148.   endif()

  1149.   target_include_directories(dgl-gles3 PUBLIC

  1150.     "${DPF_ROOT_DIR}/dgl")

  1151.   target_include_directories(dgl-gles3 PUBLIC

  1152.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1153. 

  1154.   if(APPLE)

  1155.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1156.   endif()

  1157. 

  1158.   if(USE_FILE_BROWSER)

  1159.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1160.   endif()

  1161. 

  1162.   if(USE_WEB_VIEW)

  1163.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1164.     if(APPLE)

  1165.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1166.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1167.     elseif(WIN32)

  1168.       target_sources(dgl-gles3 PRIVATE

  1169.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1170.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1171.         PROPERTIES

  1172.           COMPILE_FLAGS

  1173.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1174.     endif()

  1175.   endif()

  1176. 

  1177.   dpf__add_dgl_system_libs()

  1178.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1179.   target_link_options(dgl-gles3

  1180.     INTERFACE

  1181.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=3>

  1182.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=3>

  1183.   )

  1184. 

  1185.   add_library(dgl-gles3-definitions INTERFACE)

  1186.   target_compile_definitions(dgl-gles3-definitions

  1187.     INTERFACE

  1188.       DGL_USE_OPENGL3

  1189.       DGL_USE_GLES

  1190.       DGL_USE_GLES3

  1191.       DGL_OPENGL

  1192.       HAVE_OPENGL

  1193.       HAVE_DGL

  1194.   )

  1195. 

  1196.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1197.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1198. endfunction()

  1199. 

  1200. # dpf__add_dgl_opengl

  1201. # ------------------------------------------------------------------------------

  1202. #

  1203. # Add the OpenGL variant of DGL, if not already available.

  1204. #

  1205. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1206.   if(TARGET dgl-opengl)

  1207.     return()

  1208.   endif()

  1209. 

  1210.   if(NOT OpenGL_GL_PREFERENCE)

  1211.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1212.   endif()

  1213. 

  1214.   find_package(OpenGL REQUIRED)

  1215. 

  1216.   dpf__add_static_library(dgl-opengl STATIC

  1217.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1218.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1219.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1220.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1221.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1222.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1223.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1224.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1225.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1226.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1227.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1228.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1229.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1230.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1231.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1232.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1233.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1234.     "${DPF_ROOT_DIR}/dgl/src/OpenGL2.cpp"

  1235.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1236.   if(SHARED_RESOURCES)

  1237.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1238.   else()

  1239.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1240.   endif()

  1241.   if(APPLE)

  1242.     target_sources(dgl-opengl PRIVATE

  1243.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1244.   else()

  1245.     target_sources(dgl-opengl PRIVATE

  1246.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1247.   endif()

  1248.   target_include_directories(dgl-opengl PUBLIC

  1249.     "${DPF_ROOT_DIR}/dgl")

  1250.   target_include_directories(dgl-opengl PUBLIC

  1251.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1252. 

  1253.   if(APPLE)

  1254.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1255.   endif()

  1256. 

  1257.   if(USE_FILE_BROWSER)

  1258.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1259.   endif()

  1260. 

  1261.   if(USE_WEB_VIEW)

  1262.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1263.     if(APPLE)

  1264.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1265.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1266.     elseif(WIN32)

  1267.       target_sources(dgl-opengl PRIVATE

  1268.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1269.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1270.         PROPERTIES

  1271.           COMPILE_FLAGS

  1272.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1273.     endif()

  1274.   endif()

  1275. 

  1276.   dpf__add_dgl_system_libs()

  1277.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1278.   target_link_options(dgl-opengl

  1279.     INTERFACE

  1280.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1281.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1282.   )

  1283. 

  1284.   add_library(dgl-opengl-definitions INTERFACE)

  1285.   target_compile_definitions(dgl-opengl-definitions

  1286.     INTERFACE

  1287.       DGL_OPENGL

  1288.       HAVE_OPENGL

  1289.       HAVE_DGL

  1290.   )

  1291. 

  1292.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1293.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1294. endfunction()

  1295. 

  1296. # dpf__add_dgl_opengl3

  1297. # ------------------------------------------------------------------------------

  1298. #

  1299. # Add the OpenGL3 variant of DGL, if not already available.

  1300. #

  1301. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1302.   if(TARGET dgl-opengl3)

  1303.     return()

  1304.   endif()

  1305. 

  1306.   if(NOT OpenGL_GL_PREFERENCE)

  1307.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1308.   endif()

  1309. 

  1310.   find_package(OpenGL REQUIRED)

  1311. 

  1312.   dpf__add_static_library(dgl-opengl3 STATIC

  1313.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1314.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1315.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1316.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1317.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1318.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1319.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1320.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1321.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1322.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1323.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1324.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1325.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1326.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1327.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1328.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1329.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1330.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1331.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1332.   if(SHARED_RESOURCES)

  1333.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1334.   else()

  1335.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1336.   endif()

  1337.   if(APPLE)

  1338.     target_sources(dgl-opengl3 PRIVATE

  1339.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1340.   else()

  1341.     target_sources(dgl-opengl3 PRIVATE

  1342.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1343.   endif()

  1344.   target_include_directories(dgl-opengl3 PUBLIC

  1345.     "${DPF_ROOT_DIR}/dgl")

  1346.   target_include_directories(dgl-opengl3 PUBLIC

  1347.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1348. 

  1349.   if(APPLE)

  1350.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1351.   endif()

  1352. 

  1353.   if(USE_FILE_BROWSER)

  1354.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1355.   endif()

  1356. 

  1357.   if(USE_WEB_VIEW)

  1358.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1359.     if(APPLE)

  1360.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1361.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1362.     elseif(WIN32)

  1363.       target_sources(dgl-opengl3 PRIVATE

  1364.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1365.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1366.         PROPERTIES

  1367.           COMPILE_FLAGS

  1368.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1369.     endif()

  1370.   endif()

  1371. 

  1372.   dpf__add_dgl_system_libs()

  1373.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1374. 

  1375.   add_library(dgl-opengl3-definitions INTERFACE)

  1376.   target_compile_definitions(dgl-opengl3-definitions

  1377.     INTERFACE

  1378.       DGL_USE_OPENGL3

  1379.       DGL_OPENGL

  1380.       HAVE_OPENGL

  1381.       HAVE_DGL

  1382.   )

  1383. 

  1384.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1385.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1386. endfunction()

  1387. 

  1388. # dpf__add_dgl_vulkan

  1389. # ------------------------------------------------------------------------------

  1390. #

  1391. # Add the Vulkan variant of DGL, if not already available.

  1392. #

  1393. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1394.   if(TARGET dgl-vulkan)

  1395.     return()

  1396.   endif()

  1397. 

  1398.   find_package(Vulkan REQUIRED)

  1399. 

  1400.   dpf__add_static_library(dgl-vulkan STATIC

  1401.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1402.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1403.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1404.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1405.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1406.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1407.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1408.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1409.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1410.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1411.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1412.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1413.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1414.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1415.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1416.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1417.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1418.   if(NO_SHARED_RESOURCES)

  1419.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1420.   else()

  1421.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1422.   endif()

  1423.   if(APPLE)

  1424.     target_sources(dgl-vulkan PRIVATE

  1425.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1426.   else()

  1427.     target_sources(dgl-vulkan PRIVATE

  1428.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1429.   endif()

  1430.   target_include_directories(dgl-vulkan PUBLIC

  1431.     "${DPF_ROOT_DIR}/dgl")

  1432.   target_include_directories(dgl-vulkan PUBLIC

  1433.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1434. 

  1435.   if(APPLE)

  1436.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1437.   endif()

  1438. 

  1439.   if(USE_FILE_BROWSER)

  1440.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1441.   endif()

  1442. 

  1443.   if(USE_WEB_VIEW)

  1444.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1445.     if(APPLE)

  1446.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1447.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1448.     elseif(WIN32)

  1449.       target_sources(dgl-vulkan PRIVATE

  1450.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1451.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1452.         PROPERTIES

  1453.           COMPILE_FLAGS

  1454.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1455.     endif()

  1456.   endif()

  1457. 

  1458.   dpf__add_dgl_system_libs()

  1459.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1460. 

  1461.   add_library(dgl-vulkan-definitions INTERFACE)

  1462.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1463. 

  1464.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1465.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1466. endfunction()

  1467. 

  1468. # dpf__add_plugin_specific_ui_sources

  1469. # ------------------------------------------------------------------------------

  1470. #

  1471. # Compile system specific files

  1472. #

  1473. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1474.   if(APPLE)

  1475.     target_sources("${NAME}" PRIVATE

  1476.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1477.     if(USE_WEB_VIEW)

  1478.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1479.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1480.     endif()

  1481.   elseif(WIN32 AND USE_WEB_VIEW)

  1482.     target_sources("${NAME}" PRIVATE

  1483.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1484.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1485.       PROPERTIES

  1486.         COMPILE_FLAGS

  1487.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1488.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1489.   endif()

  1490. endfunction()

  1491. 

  1492. # dpf__add_dgl_system_libs

  1493. # ------------------------------------------------------------------------------

  1494. #

  1495. # Find system libraries required by DGL and add them as an interface target.

  1496. #

  1497. function(dpf__add_dgl_system_libs)

  1498.   if(TARGET dgl-system-libs)

  1499.     return()

  1500.   endif()

  1501.   add_library(dgl-system-libs INTERFACE)

  1502.   add_library(dgl-system-libs-definitions INTERFACE)

  1503.   if(APPLE)

  1504.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1505.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1506.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1507.   elseif(EMSCRIPTEN)

  1508.   elseif(HAIKU)

  1509.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1510.   elseif(WIN32)

  1511.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1512.   else()

  1513.     find_package(PkgConfig REQUIRED)

  1514.     pkg_check_modules(DBUS "dbus-1")

  1515.     if(DBUS_FOUND)

  1516.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1517.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1518.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1519.     endif()

  1520.     find_package(X11 REQUIRED)

  1521.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1522.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1523.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1524.     if(X11_Xcursor_FOUND)

  1525.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1526.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1527.     endif()

  1528.     if(X11_Xext_FOUND)

  1529.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1530.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1531.     endif()

  1532.     if(X11_Xrandr_FOUND)

  1533.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1534.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1535.     endif()

  1536.     if(X11_XSync_FOUND)

  1537.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1538.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1539.     endif()

  1540.    endif()

  1541. 

  1542.    if(MSVC)

  1543.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1544.      foreach(_gl_header "glext.h")

  1545.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1546.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1547.        endif()

  1548.      endforeach()

  1549.      foreach(_khr_header "khrplatform.h")

  1550.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1551.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1552.        endif()

  1553.      endforeach()

  1554.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1555.    endif()

  1556. 

  1557.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1558. endfunction()

  1559. 

  1560. # dpf__add_executable

  1561. # ------------------------------------------------------------------------------

  1562. #

  1563. # Adds an executable target, and set some default properties on the target.

  1564. #

  1565. function(dpf__add_executable NAME)

  1566.   add_executable("${NAME}" ${ARGN})

  1567.   dpf__set_target_defaults("${NAME}")

  1568.   if(MINGW)

  1569.     target_link_libraries("${NAME}" PRIVATE "-static")

  1570.   endif()

  1571. endfunction()

  1572. 

  1573. # dpf__add_module

  1574. # ------------------------------------------------------------------------------

  1575. #

  1576. # Adds a module target, and set some default properties on the target.

  1577. #

  1578. function(dpf__add_module NAME)

  1579.   add_library("${NAME}" MODULE ${ARGN})

  1580.   dpf__set_target_defaults("${NAME}")

  1581.   if(APPLE)

  1582.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1583.   elseif(MINGW)

  1584.     target_link_libraries("${NAME}" PRIVATE "-static")

  1585.   endif()

  1586. endfunction()

  1587. 

  1588. # dpf__add_static_library

  1589. # ------------------------------------------------------------------------------

  1590. #

  1591. # Adds a static library target, and set some default properties on the target.

  1592. #

  1593. function(dpf__add_static_library NAME)

  1594.   add_library("${NAME}" STATIC ${ARGN})

  1595.   dpf__set_target_defaults("${NAME}")

  1596. endfunction()

  1597. 

  1598. # dpf__set_module_export_list

  1599. # ------------------------------------------------------------------------------

  1600. #

  1601. # Applies a list of exported symbols to the module target.

  1602. #

  1603. function(dpf__set_module_export_list NAME EXPORTS)

  1604.   if(WIN32)

  1605.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1606.   elseif(APPLE)

  1607.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1608.       "-Xlinker" "-exported_symbols_list"

  1609.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1610.   else()

  1611.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1612.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1613.   endif()

  1614. endfunction()

  1615. 

  1616. # dpf__set_target_defaults

  1617. # ------------------------------------------------------------------------------

  1618. #

  1619. # Set default properties which must apply to all DPF-defined targets.

  1620. #

  1621. function(dpf__set_target_defaults NAME)

  1622.   set_target_properties("${NAME}" PROPERTIES

  1623.     POSITION_INDEPENDENT_CODE TRUE

  1624.     C_VISIBILITY_PRESET "hidden"

  1625.     CXX_VISIBILITY_PRESET "hidden"

  1626.     VISIBILITY_INLINES_HIDDEN TRUE)

  1627.   if(WIN32)

  1628.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1629.   endif()

  1630.   if (MINGW)

  1631.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1632.   endif()

  1633.   if (MSVC)

  1634.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1635.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1636.   endif()

  1637.   if (CMAKE_COMPILER_IS_GNUCXX)

  1638.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1639.   endif()

  1640.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1641.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1642.   endif()

  1643. endfunction()

  1644. 

  1645. # dpf__add_plugin_main

  1646. # ------------------------------------------------------------------------------

  1647. #

  1648. # Adds plugin code to the given target.

  1649. #

  1650. function(dpf__add_plugin_main NAME TARGET)

  1651.   target_sources("${NAME}" PRIVATE

  1652.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1653.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1654. endfunction()

  1655. 

  1656. # dpf__add_ui_main

  1657. # ------------------------------------------------------------------------------

  1658. #

  1659. # Adds UI code to the given target (only if the target has UI).

  1660. #

  1661. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1662.   if(HAS_UI)

  1663.     target_sources("${NAME}" PRIVATE

  1664.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1665.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1666.   endif()

  1667. endfunction()

  1668. 

  1669. # dpf__add_plugin_target_definition

  1670. # ------------------------------------------------------------------------------

  1671. #

  1672. # Adds the plugins target macro definition.

  1673. # This selects which entry file is compiled according to the target type.

  1674. #

  1675. function(dpf__add_plugin_target_definition NAME TARGET)

  1676.   string(TOUPPER "${TARGET}" _upperTarget)

  1677.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1678. endfunction()

  1679. 

  1680. # dpf__add_lv2_ttl_generator

  1681. # ------------------------------------------------------------------------------

  1682. #

  1683. # Build the LV2 TTL generator.

  1684. #

  1685. function(dpf__add_lv2_ttl_generator)

  1686.   if(TARGET lv2_ttl_generator)

  1687.     return()

  1688.   endif()

  1689.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1690.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1691.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1692.   endif()

  1693. endfunction()

  1694. 

  1695. # dpf__ensure_sources_non_empty

  1696. # ------------------------------------------------------------------------------

  1697. #

  1698. # Ensure the given source list contains at least one file.

  1699. # The function appends an empty source file to the list if necessary.

  1700. # This is useful when CMake does not permit to add targets without sources.

  1701. #

  1702. function(dpf__ensure_sources_non_empty VAR)

  1703.   if(NOT "" STREQUAL "${${VAR}}")

  1704.     return()

  1705.   endif()

  1706.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1707.   if(NOT EXISTS "${_file}")

  1708.     file(WRITE "${_file}" "")

  1709.   endif()

  1710.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1711. endfunction()

  1712. 

  1713. # dpf__create_dummy_source_list

  1714. # ------------------------------------------------------------------------------

  1715. #

  1716. # Create a dummy source list which is equivalent to compiling nothing.

  1717. # This is only for compatibility with older CMake versions, which refuse to add

  1718. # targets without any sources.

  1719. #

  1720. macro(dpf__create_dummy_source_list VAR)

  1721.   set("${VAR}")

  1722.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1723.     dpf__ensure_sources_non_empty("${VAR}")

  1724.   endif()

  1725. endmacro()

  1726. 

  1727. # dpf__target_link_directories

  1728. # ------------------------------------------------------------------------------

  1729. #

  1730. # Call `target_link_directories` if cmake >= 3.13,

  1731. # otherwise fallback to global `link_directories`.

  1732. #

  1733. macro(dpf__target_link_directories NAME DIRS)

  1734.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1735.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1736.   else()

  1737.     link_directories(${DIRS})

  1738.   endif()

  1739. endmacro()

  1740. 

  1741. # dpf__warn_once

  1742. # ------------------------------------------------------------------------------

  1743. #

  1744. # Prints a warning message once only.

  1745. #

  1746. function(dpf__warn_once_only TOKEN MESSAGE)

  1747.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1748.   if(NOT _warned)

  1749.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1750.     message(WARNING "${MESSAGE}")

  1751.   endif()

  1752. endfunction()