DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1241 Commits
7 Branches
54MB
Tree: 6125f48a68
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '6125f48a68'
${ noResults }
DPF/cmake/DPF-plugin.cmake

670 lines
23KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   dpf__create_dummy_source_list(_no_srcs)

  177. 

  178.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  179.   dpf__add_plugin_main("${NAME}-jack" "jack")

  180.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  181.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  182.   set_target_properties("${NAME}-jack" PROPERTIES

  183.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  184.     OUTPUT_NAME "${NAME}")

  185. 

  186.   # Note: libjack will be linked at runtime

  187.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  188.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  189.   endif()

  190. 

  191.   # for RtAudio native fallback

  192.   if(APPLE)

  193.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  194.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  195.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  196.   endif()

  197. endfunction()

  198. 

  199. # dpf__build_ladspa

  200. # ------------------------------------------------------------------------------

  201. #

  202. # Add build rules for a DSSI plugin.

  203. #

  204. function(dpf__build_ladspa NAME)

  205.   dpf__create_dummy_source_list(_no_srcs)

  206. 

  207.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  208.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  209.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  210.   set_target_properties("${NAME}-ladspa" PROPERTIES

  211.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  212.     OUTPUT_NAME "${NAME}-ladspa"

  213.     PREFIX "")

  214. endfunction()

  215. 

  216. # dpf__build_dssi

  217. # ------------------------------------------------------------------------------

  218. #

  219. # Add build rules for a DSSI plugin.

  220. #

  221. function(dpf__build_dssi NAME DGL_LIBRARY)

  222.   find_package(PkgConfig)

  223.   pkg_check_modules(LIBLO "liblo")

  224.   if(NOT LIBLO_FOUND)

  225.     dpf__warn_once_only(missing_liblo

  226.       "liblo is not found, skipping the `dssi` plugin targets")

  227.     return()

  228.   endif()

  229. 

  230.   link_directories(${LIBLO_LIBRARY_DIRS})

  231. 

  232.   dpf__create_dummy_source_list(_no_srcs)

  233. 

  234.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  235.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  236.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  237.   set_target_properties("${NAME}-dssi" PROPERTIES

  238.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  239.     OUTPUT_NAME "${NAME}-dssi"

  240.     PREFIX "")

  241. 

  242.   if(DGL_LIBRARY)

  243.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  244.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  245.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  246.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  247.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  248.       OUTPUT_NAME "${NAME}_ui")

  249. 

  250.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  251.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  252.   endif()

  253. endfunction()

  254. 

  255. # dpf__build_lv2

  256. # ------------------------------------------------------------------------------

  257. #

  258. # Add build rules for a LV2 plugin.

  259. #

  260. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  261.   dpf__create_dummy_source_list(_no_srcs)

  262. 

  263.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  264.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  265.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  266.   set_target_properties("${NAME}-lv2" PROPERTIES

  267.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  268.     OUTPUT_NAME "${NAME}_dsp"

  269.     PREFIX "")

  270. 

  271.   if(DGL_LIBRARY)

  272.     if(MONOLITHIC)

  273.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  274.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  275.       set_target_properties("${NAME}-lv2" PROPERTIES

  276.         OUTPUT_NAME "${NAME}")

  277.     else()

  278.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  279.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  280.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  281.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  282.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  283.         OUTPUT_NAME "${NAME}_ui"

  284.         PREFIX "")

  285.     endif()

  286.   endif()

  287. 

  288.   dpf__add_lv2_ttl_generator()

  289.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  290. 

  291.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  292.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  293.     "$<TARGET_FILE:lv2_ttl_generator>"

  294.     "$<TARGET_FILE:${NAME}-lv2>"

  295.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  296.     DEPENDS lv2_ttl_generator)

  297. endfunction()

  298. 

  299. # dpf__build_vst2

  300. # ------------------------------------------------------------------------------

  301. #

  302. # Add build rules for a VST2 plugin.

  303. #

  304. function(dpf__build_vst2 NAME DGL_LIBRARY)

  305.   dpf__create_dummy_source_list(_no_srcs)

  306. 

  307.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  308.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  309.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  310.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  311.   set_target_properties("${NAME}-vst2" PROPERTIES

  312.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  313.     OUTPUT_NAME "${NAME}-vst2"

  314.     PREFIX "")

  315. endfunction()

  316. 

  317. # dpf__add_dgl_cairo

  318. # ------------------------------------------------------------------------------

  319. #

  320. # Add the Cairo variant of DGL, if not already available.

  321. #

  322. function(dpf__add_dgl_cairo)

  323.   if(TARGET dgl-cairo)

  324.     return()

  325.   endif()

  326. 

  327.   find_package(PkgConfig)

  328.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  329. 

  330.   link_directories(${CAIRO_LIBRARY_DIRS})

  331. 

  332.   dpf__add_static_library(dgl-cairo STATIC

  333.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  343.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  344.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  345.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  346.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  347.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  348.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  349.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  350.   if(NOT APPLE)

  351.     target_sources(dgl-cairo PRIVATE

  352.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  353.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  354.     #target_sources(dgl-opengl PRIVATE

  355.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  356.   endif()

  357.   target_include_directories(dgl-cairo PUBLIC

  358.     "${DPF_ROOT_DIR}/dgl")

  359.   target_include_directories(dgl-cairo PUBLIC

  360.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  361. 

  362.   dpf__add_dgl_system_libs()

  363.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  364. 

  365.   add_library(dgl-cairo-definitions INTERFACE)

  366.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  367. 

  368.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  369.   if(MINGW)

  370.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  371.   else()

  372.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  373.   endif()

  374.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  375. endfunction()

  376. 

  377. # dpf__add_dgl_opengl

  378. # ------------------------------------------------------------------------------

  379. #

  380. # Add the OpenGL variant of DGL, if not already available.

  381. #

  382. function(dpf__add_dgl_opengl)

  383.   if(TARGET dgl-opengl)

  384.     return()

  385.   endif()

  386. 

  387.   if(NOT OpenGL_GL_PREFERENCE)

  388.     set(OpenGL_GL_PREFERENCE "LEGACY")

  389.   endif()

  390. 

  391.   find_package(OpenGL REQUIRED)

  392. 

  393.   dpf__add_static_library(dgl-opengl STATIC

  394.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  403.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  404.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  405.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  406.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  407.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  408.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  409.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  410.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  411.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  412.   if(NOT APPLE)

  413.     target_sources(dgl-opengl PRIVATE

  414.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  415.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  416.     #target_sources(dgl-opengl PRIVATE

  417.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  418.   endif()

  419.   target_include_directories(dgl-opengl PUBLIC

  420.     "${DPF_ROOT_DIR}/dgl")

  421.   target_include_directories(dgl-opengl PUBLIC

  422.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  423. 

  424.   if(APPLE)

  425.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  426.   endif()

  427. 

  428.   dpf__add_dgl_system_libs()

  429.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  430. 

  431.   add_library(dgl-opengl-definitions INTERFACE)

  432.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  433. 

  434.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  435.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  436. endfunction()

  437. 

  438. # dpf__add_plugin_specific_ui_sources

  439. # ------------------------------------------------------------------------------

  440. #

  441. # Compile plugin-specific UI sources into the target designated by the given

  442. # name. There are some special considerations here:

  443. # - On most platforms, sources can be compiled only once, as part of DGL;

  444. # - On macOS, for any sources which define Objective-C interfaces, these must

  445. #   be recompiled for each plugin under a unique namespace. In this case, the

  446. #   name must be a plugin-specific identifier, and it will be used for computing

  447. #   the unique ID along with the project version.

  448. function(dpf__add_plugin_specific_ui_sources NAME)

  449.   if(APPLE)

  450.     target_sources("${NAME}" PRIVATE

  451.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  452.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  453.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  454.   endif()

  455. endfunction()

  456. 

  457. # dpf__add_dgl_system_libs

  458. # ------------------------------------------------------------------------------

  459. #

  460. # Find system libraries required by DGL and add them as an interface target.

  461. #

  462. function(dpf__add_dgl_system_libs)

  463.   if(TARGET dgl-system-libs)

  464.     return()

  465.   endif()

  466.   add_library(dgl-system-libs INTERFACE)

  467.   add_library(dgl-system-libs-definitions INTERFACE)

  468.   if(HAIKU)

  469.     target_link_libraries(dgl-system-libs INTERFACE "be")

  470.   elseif(WIN32)

  471.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  472.   elseif(APPLE)

  473.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  474.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  475.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  476.   else()

  477.     find_package(X11 REQUIRED)

  478.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  479.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  480.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  481.     if(X11_Xext_FOUND)

  482.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  483.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  484.     endif()

  485.     if(X11_XSync_FOUND)

  486.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  487.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  488.     endif()

  489.     if(X11_Xrandr_FOUND)

  490.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  491.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  492.     endif()

  493.     #if(X11_Xcursor_FOUND)

  494.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  495.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  496.     #endif()

  497.    endif()

  498. 

  499.    if(MSVC)

  500.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  501.      foreach(_gl_header "glext.h")

  502.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  503.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  504.        endif()

  505.      endforeach()

  506.      foreach(_khr_header "khrplatform.h")

  507.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  508.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  509.        endif()

  510.      endforeach()

  511.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  512.    endif()

  513. 

  514.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  515. endfunction()

  516. 

  517. # dpf__add_executable

  518. # ------------------------------------------------------------------------------

  519. #

  520. # Adds an executable target, and set some default properties on the target.

  521. #

  522. function(dpf__add_executable NAME)

  523.   add_executable("${NAME}" ${ARGN})

  524.   dpf__set_target_defaults("${NAME}")

  525.   if(MINGW)

  526.     target_link_libraries("${NAME}" PRIVATE "-static")

  527.   endif()

  528. endfunction()

  529. 

  530. # dpf__add_module

  531. # ------------------------------------------------------------------------------

  532. #

  533. # Adds a module target, and set some default properties on the target.

  534. #

  535. function(dpf__add_module NAME)

  536.   add_library("${NAME}" MODULE ${ARGN})

  537.   dpf__set_target_defaults("${NAME}")

  538.   if(MINGW)

  539.     target_link_libraries("${NAME}" PRIVATE "-static")

  540.   endif()

  541. endfunction()

  542. 

  543. # dpf__add_static_library

  544. # ------------------------------------------------------------------------------

  545. #

  546. # Adds a static library target, and set some default properties on the target.

  547. #

  548. function(dpf__add_static_library NAME)

  549.   add_library("${NAME}" STATIC ${ARGN})

  550.   dpf__set_target_defaults("${NAME}")

  551. endfunction()

  552. 

  553. # dpf__set_target_defaults

  554. # ------------------------------------------------------------------------------

  555. #

  556. # Set default properties which must apply to all DPF-defined targets.

  557. #

  558. function(dpf__set_target_defaults NAME)

  559.   set_target_properties("${NAME}" PROPERTIES

  560.     POSITION_INDEPENDENT_CODE TRUE

  561.     C_VISIBILITY_PRESET "hidden"

  562.     CXX_VISIBILITY_PRESET "hidden"

  563.     VISIBILITY_INLINES_HIDDEN TRUE)

  564.   if(WIN32)

  565.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  566.   endif()

  567.   if (MINGW)

  568.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  569.   endif()

  570.   if (MSVC)

  571.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  572.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  573.   endif()

  574. endfunction()

  575. 

  576. # dpf__add_plugin_main

  577. # ------------------------------------------------------------------------------

  578. #

  579. # Adds plugin code to the given target.

  580. #

  581. function(dpf__add_plugin_main NAME TARGET)

  582.   target_sources("${NAME}" PRIVATE

  583.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  584.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  585. endfunction()

  586. 

  587. # dpf__add_ui_main

  588. # ------------------------------------------------------------------------------

  589. #

  590. # Adds UI code to the given target (only if the target has UI).

  591. #

  592. function(dpf__add_ui_main NAME TARGET HAS_UI)

  593.   if(HAS_UI)

  594.     target_sources("${NAME}" PRIVATE

  595.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  596.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  597.   endif()

  598. endfunction()

  599. 

  600. # dpf__add_plugin_target_definition

  601. # ------------------------------------------------------------------------------

  602. #

  603. # Adds the plugins target macro definition.

  604. # This selects which entry file is compiled according to the target type.

  605. #

  606. function(dpf__add_plugin_target_definition NAME TARGET)

  607.   string(TOUPPER "${TARGET}" _upperTarget)

  608.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  609. endfunction()

  610. 

  611. # dpf__add_lv2_ttl_generator

  612. # ------------------------------------------------------------------------------

  613. #

  614. # Build the LV2 TTL generator.

  615. #

  616. function(dpf__add_lv2_ttl_generator)

  617.   if(TARGET lv2_ttl_generator)

  618.     return()

  619.   endif()

  620.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  621.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  622.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  623.   endif()

  624. endfunction()

  625. 

  626. # dpf__ensure_sources_non_empty

  627. # ------------------------------------------------------------------------------

  628. #

  629. # Ensure the given source list contains at least one file.

  630. # The function appends an empty source file to the list if necessary.

  631. # This is useful when CMake does not permit to add targets without sources.

  632. #

  633. function(dpf__ensure_sources_non_empty VAR)

  634.   if(NOT "" STREQUAL "${${VAR}}")

  635.     return()

  636.   endif()

  637.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  638.   if(NOT EXISTS "${_file}")

  639.     file(WRITE "${_file}" "")

  640.   endif()

  641.   set("${VAR}" "${_file}" PARENT_SCOPE)

  642. endfunction()

  643. 

  644. # dpf__create_dummy_source_list

  645. # ------------------------------------------------------------------------------

  646. #

  647. # Create a dummy source list which is equivalent to compiling nothing.

  648. # This is only for compatibility with older CMake versions, which refuse to add

  649. # targets without any sources.

  650. #

  651. macro(dpf__create_dummy_source_list VAR)

  652.   set("${VAR}")

  653.   if(CMAKE_VERSION VERSION_LESS "3.11")

  654.     dpf__ensure_sources_non_empty("${VAR}")

  655.   endif()

  656. endmacro()

  657. 

  658. # dpf__warn_once

  659. # ------------------------------------------------------------------------------

  660. #

  661. # Prints a warning message once only.

  662. #

  663. function(dpf__warn_once_only TOKEN MESSAGE)

  664.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  665.   if(NOT _warned)

  666.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  667.     message(WARNING "${MESSAGE}")

  668.   endif()

  669. endfunction()