DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2515 Commits
6 Branches
50MB
Tree: 5d2c29f493
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '5d2c29f493'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1764 lines
63KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `FORCE_NATIVE_AUDIO_FALLBACK`

  108. #       force the JACK/Standalone format to use native audio fallback instead of JACK

  109. #

  110. #   `SKIP_NATIVE_AUDIO_FALLBACK`

  111. #       force the JACK/Standalone format to always use JACK, skipping native audio fallback

  112. #

  113. #   `USE_FILE_BROWSER`

  114. #       enable file browser dialog APIs

  115. #

  116. #   `USE_WEB_VIEW`

  117. #       enable web browser view APIs

  118. #

  119. function(dpf_add_plugin NAME)

  120.   set(options MONOLITHIC NO_SHARED_RESOURCES FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER USE_WEB_VIEW)

  121.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  122.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  123.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  124. 

  125.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  126.     set(_dpf_plugin_UI_TYPE "opengl")

  127.   endif()

  128. 

  129.   set(_dgl_library)

  130.   if(_dpf_plugin_FILES_UI)

  131.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  132.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  133.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  134.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  135.       set(_dgl_library dgl-cairo)

  136.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  137.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  138.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  139.       set(_dgl_library dgl-external)

  140.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  141.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  142.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  143.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  144.       set(_dgl_library dgl-gles2)

  145.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  146.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  147.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  148.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  149.       set(_dgl_library dgl-gles3)

  150.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  151.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  152.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  153.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  154.       set(_dgl_library dgl-opengl)

  155.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  156.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  157.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  158.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  159.       set(_dgl_library dgl-opengl3)

  160.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  161.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  162.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  163.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  164.       set(_dgl_library dgl-vulkan)

  165.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  166.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  167.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  168.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  169.       set(_dgl_library dgl-external)

  170.     else()

  171.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  172.     endif()

  173.   else()

  174.     set(_dpf_plugin_UI_TYPE "")

  175.   endif()

  176. 

  177.   set(_dgl_has_ui OFF)

  178.   if(_dgl_library)

  179.     set(_dgl_has_ui ON)

  180.   endif()

  181. 

  182.   ###

  183.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  184.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  185.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  186. 

  187.   ###

  188.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  189.   target_include_directories("${NAME}" PUBLIC

  190.     "${DPF_ROOT_DIR}/distrho")

  191. 

  192.   if(_dpf_plugin_USE_FILE_BROWSER)

  193.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  194.   endif()

  195. 

  196.   if(_dpf_plugin_USE_WEB_VIEW)

  197.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  198.   endif()

  199. 

  200.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  201.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  202.   endif()

  203. 

  204.   find_package(Threads)

  205.   target_link_libraries("${NAME}" PUBLIC "${CMAKE_THREAD_LIBS_INIT}")

  206. 

  207.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  208.     target_link_libraries("${NAME}" PRIVATE "dl")

  209.   endif()

  210. 

  211.   if(_dgl_library)

  212.     # make sure that all code will see DGL_* definitions

  213.     target_link_libraries("${NAME}" PUBLIC

  214.       "${_dgl_library}-definitions"

  215.       dgl-system-libs-definitions

  216.       dgl-system-libs)

  217.   endif()

  218. 

  219.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  220.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  221. 

  222.   if(_dgl_library)

  223.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  224.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  225.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  226.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  227.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  228.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  229.           OUTPUT_STRIP_TRAILING_WHITESPACE

  230.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  231.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  232.       endif()

  233.     endif()

  234.     # add the files containing C++17 or Objective-C classes

  235.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  236.   else()

  237.     add_library("${NAME}-ui" INTERFACE)

  238.   endif()

  239. 

  240.   ###

  241.   foreach(_target ${_dpf_plugin_TARGETS})

  242.     if(_target STREQUAL "jack")

  243.       dpf__build_jack("${NAME}"

  244.                       "${_dgl_has_ui}"

  245.                       "${_dpf_plugin_FORCE_NATIVE_AUDIO_FALLBACK}"

  246.                       "${_dpf_plugin_SKIP_NATIVE_AUDIO_FALLBACK}"

  247.                       "${_dpf_plugin_USE_FILE_BROWSER}")

  248.     elseif(_target STREQUAL "ladspa")

  249.       dpf__build_ladspa("${NAME}")

  250.     elseif(_target STREQUAL "dssi")

  251.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  252.     elseif(_target STREQUAL "lv2")

  253.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  254.     elseif(_target STREQUAL "vst2")

  255.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  256.     elseif(_target STREQUAL "vst3")

  257.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  258.     elseif(_target STREQUAL "clap")

  259.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  260.     elseif(_target STREQUAL "au")

  261.       if (APPLE)

  262.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  263.       endif()

  264.     elseif(_target STREQUAL "static")

  265.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  266.     else()

  267.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  268.     endif()

  269.   endforeach()

  270. endfunction()

  271. 

  272. # dpf_add_executable(target <args...>)

  273. # ------------------------------------------------------------------------------

  274. #

  275. # Add a simple executable built using the DISTRHO Plugin Framework.

  276. #

  277. # ------------------------------------------------------------------------------

  278. # Arguments:

  279. #

  280. #   `UI_TYPE` <type>

  281. #       the user interface type, can be one of the following:

  282. #          - cairo

  283. #          - external

  284. #          - gles2

  285. #          - gles3

  286. #          - opengl (default)

  287. #          - opengl3

  288. #          - vulkan

  289. #          - webview

  290. #

  291. #   `NO_SHARED_RESOURCES`

  292. #       do not build DPF shared resources (fonts, etc)

  293. #

  294. #   `USE_FILE_BROWSER`

  295. #       enable file browser dialog APIs

  296. #

  297. #   `USE_WEB_VIEW`

  298. #       enable web browser view APIs

  299. #

  300. function(dpf_add_executable NAME)

  301.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  302.   set(oneValueArgs UI_TYPE)

  303.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  304. 

  305.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  306.     set(_dpf_plugin_UI_TYPE "opengl")

  307.   endif()

  308. 

  309.   set(_dgl_library)

  310.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  311.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  312.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  313.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  314.     set(_dgl_library dgl-cairo)

  315.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  316.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  317.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  318.     set(_dgl_library dgl-external)

  319.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  320.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  321.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  322.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  323.     set(_dgl_library dgl-gles2)

  324.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  325.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  326.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  327.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  328.     set(_dgl_library dgl-gles3)

  329.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  330.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  331.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  332.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  333.     set(_dgl_library dgl-opengl)

  334.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  335.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  336.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  337.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  338.     set(_dgl_library dgl-opengl3)

  339.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  340.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  341.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  342.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  343.     set(_dgl_library dgl-vulkan)

  344.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  345.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  346.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  347.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  348.     set(_dgl_library dgl-external)

  349.   else()

  350.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  351.   endif()

  352. 

  353.   set(_dgl_has_ui OFF)

  354.   if(_dgl_library)

  355.     set(_dgl_has_ui ON)

  356.   endif()

  357. 

  358.   dpf__create_dummy_source_list(_no_srcs)

  359.   dpf__add_executable("${NAME}" ${_no_srcs})

  360.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  361.   set_target_properties("${NAME}" PROPERTIES

  362.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  363.     OUTPUT_NAME "${NAME}")

  364. 

  365.   if(EMSCRIPTEN)

  366.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  367.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  368.     target_link_options("${NAME}"

  369.       PRIVATE

  370.         -sEXPORTED_RUNTIME_METHODS=dynCall)

  371.   endif()

  372. 

  373.   if(_dpf_plugin_USE_FILE_BROWSER)

  374.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  375.     if(EMSCRIPTEN)

  376.       target_link_options("${NAME}" PRIVATE -sEXPORTED_RUNTIME_METHODS=FS,cwrap)

  377.     endif()

  378.   endif()

  379. 

  380.   if(_dpf_plugin_USE_WEB_VIEW)

  381.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  382.   endif()

  383. 

  384.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  385.     target_link_libraries("${NAME}" PRIVATE "dl")

  386.   endif()

  387. 

  388.   if(_dgl_library)

  389.     # make sure that all code will see DGL_* definitions

  390.     target_link_libraries("${NAME}" PUBLIC

  391.       "${_dgl_library}"

  392.       "${_dgl_library}-definitions"

  393.       dgl-system-libs-definitions

  394.       dgl-system-libs)

  395.     # extra linkage for linux web view

  396.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  397.       target_link_libraries("${NAME}" PRIVATE "rt")

  398.     endif()

  399.     # add the files containing C++17 or Objective-C classes

  400.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  401.   endif()

  402. endfunction()

  403. 

  404. # ------------------------------------------------------------------------------

  405. # DPF private functions (prefixed with `dpf__`)

  406. # ------------------------------------------------------------------------------

  407. 

  408. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  409. #       to the output directory.

  410. #

  411. 

  412. # dpf__build_jack

  413. # ------------------------------------------------------------------------------

  414. #

  415. # Add build rules for a JACK/Standalone program.

  416. #

  417. function(dpf__build_jack NAME HAS_UI FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER)

  418.   dpf__create_dummy_source_list(_no_srcs)

  419. 

  420.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  421.   dpf__add_plugin_main("${NAME}-jack" "jack")

  422.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  423.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  424.   set_target_properties("${NAME}-jack" PROPERTIES

  425.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  426.     OUTPUT_NAME "${NAME}")

  427. 

  428.   if(EMSCRIPTEN)

  429.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  430.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  431.     target_link_options("${NAME}-jack"

  432.       PRIVATE

  433.         -sEXPORTED_RUNTIME_METHODS=dynCall

  434.         $<$<BOOL:${USE_FILE_BROWSER}>:-sEXPORTED_RUNTIME_METHODS=FS,cwrap>)

  435.   endif()

  436. 

  437.   if(NOT FORCE_NATIVE_AUDIO_FALLBACK)

  438.     target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  439.     target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  440.   endif()

  441. 

  442.   if(SKIP_NATIVE_AUDIO_FALLBACK)

  443.     return()

  444.   endif()

  445. 

  446.   find_package(PkgConfig QUIET)

  447.   if(PKG_CONFIG_FOUND)

  448.     pkg_check_modules(SDL2 "sdl2")

  449.   else()

  450.     set(SDL2_FOUND FALSE)

  451.   endif()

  452.   if(SDL2_FOUND)

  453.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  454.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  455.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  456.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  457.   endif()

  458. 

  459.   if(APPLE OR WIN32)

  460.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  461.   elseif(EMSCRIPTEN)

  462.   else()

  463.     pkg_check_modules(ALSA "alsa")

  464.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  465.     if(ALSA_FOUND)

  466.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  467.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  468.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES})

  469.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  470.     endif()

  471.     if(PULSEAUDIO_FOUND)

  472.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  473.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  474.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES})

  475.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  476.     endif()

  477.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  478.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  479.     endif()

  480.   endif()

  481. 

  482.   # for RtAudio native fallback

  483.   if(APPLE)

  484.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  485.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  486.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  487.     target_link_libraries("${NAME}-jack" PRIVATE

  488.       "${APPLE_COREAUDIO_FRAMEWORK}"

  489.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  490.       "${APPLE_COREMIDI_FRAMEWORK}")

  491.   elseif(WIN32)

  492.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  493.     if(HAS_UI AND MINGW)

  494.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  495.     endif()

  496.   endif()

  497. endfunction()

  498. 

  499. # dpf__build_ladspa

  500. # ------------------------------------------------------------------------------

  501. #

  502. # Add build rules for a LADSPA plugin.

  503. #

  504. function(dpf__build_ladspa NAME)

  505.   dpf__create_dummy_source_list(_no_srcs)

  506. 

  507.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  508.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  509.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  510.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  511.   set_target_properties("${NAME}-ladspa" PROPERTIES

  512.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  513.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  514.     OUTPUT_NAME "${NAME}-ladspa"

  515.     PREFIX "")

  516. endfunction()

  517. 

  518. # dpf__build_dssi

  519. # ------------------------------------------------------------------------------

  520. #

  521. # Add build rules for a DSSI plugin.

  522. #

  523. function(dpf__build_dssi NAME HAS_UI)

  524.   find_package(PkgConfig QUIET)

  525.   if(PKG_CONFIG_FOUND)

  526.     pkg_check_modules(LIBLO "liblo")

  527.   else()

  528.     set(LIBLO_FOUND FALSE)

  529.   endif()

  530.   if(NOT LIBLO_FOUND)

  531.     dpf__warn_once_only(missing_liblo

  532.       "liblo is not found, skipping the `dssi` plugin targets")

  533.     return()

  534.   endif()

  535. 

  536.   dpf__create_dummy_source_list(_no_srcs)

  537. 

  538.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  539.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  540.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  541.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  542.   set_target_properties("${NAME}-dssi" PROPERTIES

  543.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  544.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  545.     OUTPUT_NAME "${NAME}-dssi"

  546.     PREFIX "")

  547. 

  548.   if(HAS_UI)

  549.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  550.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  551.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  552.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  553.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  554.       OUTPUT_NAME "${NAME}_ui")

  555. 

  556.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  557.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  558.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  559.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  560.   endif()

  561. endfunction()

  562. 

  563. # dpf__build_lv2

  564. # ------------------------------------------------------------------------------

  565. #

  566. # Add build rules for an LV2 plugin.

  567. #

  568. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  569.   dpf__create_dummy_source_list(_no_srcs)

  570. 

  571.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  572.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  573.   if(HAS_UI AND MONOLITHIC)

  574.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  575.   else()

  576.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  577.   endif()

  578.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  579.   set_target_properties("${NAME}-lv2" PROPERTIES

  580.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  581.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  582.     OUTPUT_NAME "${NAME}_dsp"

  583.     PREFIX "")

  584. 

  585.   # helper property for custom outside handling

  586.   set_target_properties("${NAME}" PROPERTIES

  587.     LV2_BUNDLE "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  588. 

  589.   if(HAS_UI)

  590.     if(MONOLITHIC)

  591.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  592.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  593.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  594.       set_target_properties("${NAME}-lv2" PROPERTIES

  595.         OUTPUT_NAME "${NAME}")

  596.     else()

  597.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  598.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  599.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  600.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  601.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  602.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  603.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  604.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  605.         OUTPUT_NAME "${NAME}_ui"

  606.         PREFIX "")

  607.     endif()

  608.   endif()

  609. 

  610.   dpf__add_lv2_ttl_generator()

  611.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  612. 

  613.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  614. 

  615.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  616.     COMMAND

  617.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  618.     "$<TARGET_FILE:lv2_ttl_generator>"

  619.     "$<TARGET_FILE:${NAME}-lv2>"

  620.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  621. endfunction()

  622. 

  623. # dpf__build_vst2

  624. # ------------------------------------------------------------------------------

  625. #

  626. # Add build rules for a VST2 plugin.

  627. #

  628. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  629.   dpf__create_dummy_source_list(_no_srcs)

  630. 

  631.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  632.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  633.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  634.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  635.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  636.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  637.   set_target_properties("${NAME}-vst2" PROPERTIES

  638.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  639.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  640.     OUTPUT_NAME "${NAME}-vst2"

  641.     PREFIX "")

  642.   if(APPLE)

  643.     set_target_properties("${NAME}-vst2" PROPERTIES

  644.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  645.       OUTPUT_NAME "${NAME}"

  646.       SUFFIX "")

  647.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  648.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  649.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  650.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  651.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  652.   endif()

  653. endfunction()

  654. 

  655. # dpf__determine_vst3_package_architecture

  656. # ------------------------------------------------------------------------------

  657. #

  658. # Determines the package architecture for a VST3 plugin target.

  659. #

  660. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  661.   # if set by variable, override the detection

  662.   if(DPF_VST3_ARCHITECTURE)

  663.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  664.     return()

  665.   endif()

  666. 

  667.   # not used on Apple, which supports universal binary

  668.   if(APPLE)

  669.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  670.     return()

  671.   endif()

  672. 

  673.   # identify the target processor (special case of MSVC, problematic sometimes)

  674.   if(MSVC)

  675.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  676.   else()

  677.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  678.   endif()

  679. 

  680.   # transform the processor name to a format that VST3 recognizes

  681.   # see https://steinbergmedia.github.io/vst3_dev_portal/pages/Technical+Documentation/Locations+Format/Plugin+Format.html

  682.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  683.     set(vst3_package_arch "x86_64")

  684.   elseif(vst3_system_arch MATCHES "^(ARM)$")

  685.     set(vst3_package_arch "arm")

  686.   elseif(vst3_system_arch MATCHES "^(ARM64)$")

  687.     set(vst3_package_arch "arm64")

  688.   elseif(vst3_system_arch MATCHES "^(ARM64EC)$")

  689.     set(vst3_package_arch "arm64x")

  690.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  691.     if(WIN32)

  692.       set(vst3_package_arch "x86")

  693.     else()

  694.       set(vst3_package_arch "i386")

  695.     endif()

  696.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  697.     set(vst3_package_arch "${vst3_system_arch}")

  698.   else()

  699.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  700.   endif()

  701. 

  702.   # TODO: the detections for Windows arm/arm64 when supported

  703. 

  704.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  705. endfunction()

  706. 

  707. # dpf__build_vst3

  708. # ------------------------------------------------------------------------------

  709. #

  710. # Add build rules for a VST3 plugin.

  711. #

  712. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  713.   dpf__determine_vst3_package_architecture(vst3_arch)

  714. 

  715.   dpf__create_dummy_source_list(_no_srcs)

  716. 

  717.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  718.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  719.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  720.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  721.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  722.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  723.   set_target_properties("${NAME}-vst3" PROPERTIES

  724.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  725.     OUTPUT_NAME "${NAME}"

  726.     PREFIX "")

  727. 

  728.   if(APPLE)

  729.     set_target_properties("${NAME}-vst3" PROPERTIES

  730.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  731.       SUFFIX "")

  732.   elseif(WIN32)

  733.     set_target_properties("${NAME}-vst3" PROPERTIES

  734.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  735.   else()

  736.     set_target_properties("${NAME}-vst3" PROPERTIES

  737.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  738.   endif()

  739. 

  740.   if(APPLE)

  741.     # Uses the same macOS bundle template as VST2

  742.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  743.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  744.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  745.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  746.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  747.   endif()

  748. endfunction()

  749. 

  750. # dpf__build_clap

  751. # ------------------------------------------------------------------------------

  752. #

  753. # Add build rules for a CLAP plugin.

  754. #

  755. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  756.   dpf__create_dummy_source_list(_no_srcs)

  757. 

  758.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  759.   dpf__add_plugin_main("${NAME}-clap" "clap")

  760.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  761.   dpf__set_module_export_list("${NAME}-clap" "clap")

  762.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  763.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  764.   set_target_properties("${NAME}-clap" PROPERTIES

  765.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  766.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  767.     OUTPUT_NAME "${NAME}"

  768.     PREFIX ""

  769.     SUFFIX ".clap")

  770. 

  771.   if(APPLE)

  772.     set_target_properties("${NAME}-clap" PROPERTIES

  773.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  774.       OUTPUT_NAME "${NAME}"

  775.       SUFFIX "")

  776.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  777.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  778.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  779.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  780.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  781.   endif()

  782. endfunction()

  783. 

  784. # dpf__build_au

  785. # ------------------------------------------------------------------------------

  786. #

  787. # Add build rules for an AUv2 plugin.

  788. #

  789. function(dpf__build_au NAME HAS_UI)

  790.   dpf__create_dummy_source_list(_no_srcs)

  791. 

  792.   dpf__add_module("${NAME}-au" ${_no_srcs})

  793.   dpf__add_plugin_main("${NAME}-au" "au")

  794.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  795.   dpf__set_module_export_list("${NAME}-au" "au")

  796.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  797.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  798.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  799.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  800.   target_link_libraries("${NAME}-au" PRIVATE

  801.     "${NAME}-dsp"

  802.     "${NAME}-ui"

  803.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  804.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  805.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  806.   set_target_properties("${NAME}-au" PROPERTIES

  807.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  808.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  809.     OUTPUT_NAME "${NAME}"

  810.     PREFIX ""

  811.     SUFFIX "")

  812. 

  813.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  814.   dpf__add_plugin_main("${NAME}-export" "export")

  815.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  816.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  817. 

  818.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  819. 

  820.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  821.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  822.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  823. 

  824.   add_dependencies("${NAME}-au" "${NAME}-export")

  825. 

  826.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  827.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  828. endfunction()

  829. 

  830. # dpf__build_static

  831. # ------------------------------------------------------------------------------

  832. #

  833. # Add build rules for a static library.

  834. #

  835. function(dpf__build_static NAME HAS_UI)

  836.   dpf__create_dummy_source_list(_no_srcs)

  837. 

  838.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  839.   dpf__add_plugin_main("${NAME}-static" "static")

  840.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  841.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  842. 

  843.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  844.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  845.   foreach(src ${dsp_srcs})

  846.     target_sources("${NAME}-static" PRIVATE ${src})

  847.   endforeach()

  848.   foreach(src ${ui_srcs})

  849.     target_sources("${NAME}-static" PRIVATE ${src})

  850.   endforeach()

  851. 

  852.   set_target_properties("${NAME}-static" PROPERTIES

  853.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  854.     OUTPUT_NAME "${NAME}"

  855.     PREFIX "")

  856. endfunction()

  857. 

  858. # dpf__add_dgl_cairo

  859. # ------------------------------------------------------------------------------

  860. #

  861. # Add the Cairo variant of DGL, if not already available.

  862. #

  863. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  864.   if(TARGET dgl-cairo)

  865.     return()

  866.   endif()

  867. 

  868.   find_package(PkgConfig REQUIRED)

  869.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  870. 

  871.   link_directories(${CAIRO_LIBRARY_DIRS})

  872. 

  873.   dpf__add_static_library(dgl-cairo STATIC

  874.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  883.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  884.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  885.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  886.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  887.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  888.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  889.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  890.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  891.   if(SHARED_RESOURCES)

  892.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  893.   else()

  894.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  895.   endif()

  896.   if(APPLE)

  897.     target_sources(dgl-cairo PRIVATE

  898.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  899.   else()

  900.     target_sources(dgl-cairo PRIVATE

  901.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  902.   endif()

  903.   target_include_directories(dgl-cairo PUBLIC

  904.     "${DPF_ROOT_DIR}/dgl")

  905.   target_include_directories(dgl-cairo PUBLIC

  906.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  907. 

  908.   if(USE_FILE_BROWSER)

  909.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  910.   endif()

  911. 

  912.   if(USE_WEB_VIEW)

  913.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  914.     if(APPLE)

  915.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  916.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  917.     elseif(WIN32)

  918.       target_sources(dgl-cairo PRIVATE

  919.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  920.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  921.         PROPERTIES

  922.           COMPILE_FLAGS

  923.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  924.     endif()

  925.   endif()

  926. 

  927.   dpf__add_dgl_system_libs()

  928.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  929. 

  930.   add_library(dgl-cairo-definitions INTERFACE)

  931.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  932. 

  933.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  934.   if(MINGW)

  935.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  936.   else()

  937.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  938.   endif()

  939.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  940. endfunction()

  941. 

  942. # dpf__add_dgl_external

  943. # ------------------------------------------------------------------------------

  944. #

  945. # Add the external variant of DGL, if not already available.

  946. #

  947. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  948.   if(TARGET dgl-external)

  949.     return()

  950.   endif()

  951. 

  952.   dpf__add_static_library(dgl-external STATIC

  953.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  956.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  957.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  958.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  959.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  960.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  961.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  962.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  963.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  964.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  965.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  966.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  967.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  968.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  969.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  970. 

  971.   if(APPLE)

  972.     target_sources(dgl-external PRIVATE

  973.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  974.   else()

  975.     target_sources(dgl-external PRIVATE

  976.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  977.   endif()

  978.   target_include_directories(dgl-external PUBLIC

  979.     "${DPF_ROOT_DIR}/dgl")

  980.   target_include_directories(dgl-external PUBLIC

  981.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  982. 

  983.   if(USE_FILE_BROWSER)

  984.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  985.   endif()

  986. 

  987.   if(USE_WEB_VIEW)

  988.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  989.     if(APPLE)

  990.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  991.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  992.     elseif(WIN32)

  993.       target_sources(dgl-external PRIVATE

  994.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  995.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  996.         PROPERTIES

  997.           COMPILE_FLAGS

  998.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  999.     endif()

  1000.   endif()

  1001. 

  1002.   dpf__add_dgl_system_libs()

  1003.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  1004.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  1005. 

  1006.   add_library(dgl-external-definitions INTERFACE)

  1007.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  1008. 

  1009.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  1010.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  1011. endfunction()

  1012. 

  1013. # dpf__add_dgl_gles2

  1014. # ------------------------------------------------------------------------------

  1015. #

  1016. # Add the GLESv2 variant of DGL, if not already available.

  1017. #

  1018. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1019.   if(TARGET dgl-gles2)

  1020.     return()

  1021.   endif()

  1022. 

  1023.   if(NOT OpenGL_GL_PREFERENCE)

  1024.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1025.   endif()

  1026. 

  1027.   find_package(OpenGL REQUIRED)

  1028. 

  1029.   dpf__add_static_library(dgl-gles2 STATIC

  1030.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1031.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1032.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1033.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1034.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1035.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1036.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1037.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1038.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1039.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1040.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1041.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1042.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1043.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1044.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1045.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1046.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1047.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1048.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1049.   if(SHARED_RESOURCES)

  1050.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1051.   else()

  1052.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1053.   endif()

  1054.   if(APPLE)

  1055.     target_sources(dgl-gles2 PRIVATE

  1056.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1057.   else()

  1058.     target_sources(dgl-gles2 PRIVATE

  1059.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1060.   endif()

  1061.   target_include_directories(dgl-gles2 PUBLIC

  1062.     "${DPF_ROOT_DIR}/dgl")

  1063.   target_include_directories(dgl-gles2 PUBLIC

  1064.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1065. 

  1066.   if(APPLE)

  1067.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1068.   endif()

  1069. 

  1070.   if(USE_FILE_BROWSER)

  1071.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1072.   endif()

  1073. 

  1074.   if(USE_WEB_VIEW)

  1075.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1076.     if(APPLE)

  1077.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1078.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1079.     elseif(WIN32)

  1080.       target_sources(dgl-gles2 PRIVATE

  1081.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1082.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1083.         PROPERTIES

  1084.           COMPILE_FLAGS

  1085.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1086.     endif()

  1087.   endif()

  1088. 

  1089.   dpf__add_dgl_system_libs()

  1090.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1091.   target_link_options(dgl-gles2

  1092.     INTERFACE

  1093.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1094.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1095.   )

  1096. 

  1097.   add_library(dgl-gles2-definitions INTERFACE)

  1098.   target_compile_definitions(dgl-gles2-definitions

  1099.     INTERFACE

  1100.       DGL_USE_OPENGL3

  1101.       DGL_USE_GLES

  1102.       DGL_USE_GLES2

  1103.       DGL_OPENGL

  1104.       HAVE_OPENGL

  1105.       HAVE_DGL

  1106.   )

  1107. 

  1108.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1109.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1110. endfunction()

  1111. 

  1112. # dpf__add_dgl_gles3

  1113. # ------------------------------------------------------------------------------

  1114. #

  1115. # Add the GLESv3 variant of DGL, if not already available.

  1116. #

  1117. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1118.   if(TARGET dgl-gles3)

  1119.     return()

  1120.   endif()

  1121. 

  1122.   if(NOT OpenGL_GL_PREFERENCE)

  1123.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1124.   endif()

  1125. 

  1126.   find_package(OpenGL REQUIRED)

  1127. 

  1128.   dpf__add_static_library(dgl-gles3 STATIC

  1129.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1130.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1131.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1132.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1133.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1134.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1135.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1136.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1137.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1138.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1139.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1140.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1141.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1142.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1143.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1144.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1145.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1146.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1147.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1148.   if(SHARED_RESOURCES)

  1149.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1150.   else()

  1151.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1152.   endif()

  1153.   if(APPLE)

  1154.     target_sources(dgl-gles3 PRIVATE

  1155.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1156.   else()

  1157.     target_sources(dgl-gles3 PRIVATE

  1158.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1159.   endif()

  1160.   target_include_directories(dgl-gles3 PUBLIC

  1161.     "${DPF_ROOT_DIR}/dgl")

  1162.   target_include_directories(dgl-gles3 PUBLIC

  1163.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1164. 

  1165.   if(APPLE)

  1166.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1167.   endif()

  1168. 

  1169.   if(USE_FILE_BROWSER)

  1170.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1171.   endif()

  1172. 

  1173.   if(USE_WEB_VIEW)

  1174.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1175.     if(APPLE)

  1176.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1177.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1178.     elseif(WIN32)

  1179.       target_sources(dgl-gles3 PRIVATE

  1180.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1181.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1182.         PROPERTIES

  1183.           COMPILE_FLAGS

  1184.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1185.     endif()

  1186.   endif()

  1187. 

  1188.   dpf__add_dgl_system_libs()

  1189.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1190.   target_link_options(dgl-gles3

  1191.     INTERFACE

  1192.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=3>

  1193.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=3>

  1194.   )

  1195. 

  1196.   add_library(dgl-gles3-definitions INTERFACE)

  1197.   target_compile_definitions(dgl-gles3-definitions

  1198.     INTERFACE

  1199.       DGL_USE_OPENGL3

  1200.       DGL_USE_GLES

  1201.       DGL_USE_GLES3

  1202.       DGL_OPENGL

  1203.       HAVE_OPENGL

  1204.       HAVE_DGL

  1205.   )

  1206. 

  1207.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1208.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1209. endfunction()

  1210. 

  1211. # dpf__add_dgl_opengl

  1212. # ------------------------------------------------------------------------------

  1213. #

  1214. # Add the OpenGL variant of DGL, if not already available.

  1215. #

  1216. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1217.   if(TARGET dgl-opengl)

  1218.     return()

  1219.   endif()

  1220. 

  1221.   if(NOT OpenGL_GL_PREFERENCE)

  1222.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1223.   endif()

  1224. 

  1225.   find_package(OpenGL REQUIRED)

  1226. 

  1227.   dpf__add_static_library(dgl-opengl STATIC

  1228.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1229.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1230.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1231.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1232.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1233.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1234.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1235.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1236.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1237.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1238.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1239.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1240.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1241.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1242.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1243.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1244.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1245.     "${DPF_ROOT_DIR}/dgl/src/OpenGL2.cpp"

  1246.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1247.   if(SHARED_RESOURCES)

  1248.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1249.   else()

  1250.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1251.   endif()

  1252.   if(APPLE)

  1253.     target_sources(dgl-opengl PRIVATE

  1254.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1255.   else()

  1256.     target_sources(dgl-opengl PRIVATE

  1257.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1258.   endif()

  1259.   target_include_directories(dgl-opengl PUBLIC

  1260.     "${DPF_ROOT_DIR}/dgl")

  1261.   target_include_directories(dgl-opengl PUBLIC

  1262.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1263. 

  1264.   if(APPLE)

  1265.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1266.   endif()

  1267. 

  1268.   if(USE_FILE_BROWSER)

  1269.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1270.   endif()

  1271. 

  1272.   if(USE_WEB_VIEW)

  1273.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1274.     if(APPLE)

  1275.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1276.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1277.     elseif(WIN32)

  1278.       target_sources(dgl-opengl PRIVATE

  1279.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1280.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1281.         PROPERTIES

  1282.           COMPILE_FLAGS

  1283.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1284.     endif()

  1285.   endif()

  1286. 

  1287.   dpf__add_dgl_system_libs()

  1288.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1289.   target_link_options(dgl-opengl

  1290.     INTERFACE

  1291.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1292.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1293.   )

  1294. 

  1295.   add_library(dgl-opengl-definitions INTERFACE)

  1296.   target_compile_definitions(dgl-opengl-definitions

  1297.     INTERFACE

  1298.       DGL_OPENGL

  1299.       HAVE_OPENGL

  1300.       HAVE_DGL

  1301.   )

  1302. 

  1303.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1304.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1305. endfunction()

  1306. 

  1307. # dpf__add_dgl_opengl3

  1308. # ------------------------------------------------------------------------------

  1309. #

  1310. # Add the OpenGL3 variant of DGL, if not already available.

  1311. #

  1312. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1313.   if(TARGET dgl-opengl3)

  1314.     return()

  1315.   endif()

  1316. 

  1317.   if(NOT OpenGL_GL_PREFERENCE)

  1318.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1319.   endif()

  1320. 

  1321.   find_package(OpenGL REQUIRED)

  1322. 

  1323.   dpf__add_static_library(dgl-opengl3 STATIC

  1324.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1325.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1326.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1327.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1328.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1329.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1330.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1331.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1332.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1333.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1334.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1335.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1336.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1337.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1338.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1339.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1340.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1341.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1342.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1343.   if(SHARED_RESOURCES)

  1344.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1345.   else()

  1346.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1347.   endif()

  1348.   if(APPLE)

  1349.     target_sources(dgl-opengl3 PRIVATE

  1350.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1351.   else()

  1352.     target_sources(dgl-opengl3 PRIVATE

  1353.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1354.   endif()

  1355.   target_include_directories(dgl-opengl3 PUBLIC

  1356.     "${DPF_ROOT_DIR}/dgl")

  1357.   target_include_directories(dgl-opengl3 PUBLIC

  1358.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1359. 

  1360.   if(APPLE)

  1361.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1362.   endif()

  1363. 

  1364.   if(USE_FILE_BROWSER)

  1365.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1366.   endif()

  1367. 

  1368.   if(USE_WEB_VIEW)

  1369.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1370.     if(APPLE)

  1371.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1372.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1373.     elseif(WIN32)

  1374.       target_sources(dgl-opengl3 PRIVATE

  1375.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1376.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1377.         PROPERTIES

  1378.           COMPILE_FLAGS

  1379.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1380.     endif()

  1381.   endif()

  1382. 

  1383.   dpf__add_dgl_system_libs()

  1384.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1385. 

  1386.   add_library(dgl-opengl3-definitions INTERFACE)

  1387.   target_compile_definitions(dgl-opengl3-definitions

  1388.     INTERFACE

  1389.       DGL_USE_OPENGL3

  1390.       DGL_OPENGL

  1391.       HAVE_OPENGL

  1392.       HAVE_DGL

  1393.   )

  1394. 

  1395.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1396.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1397. endfunction()

  1398. 

  1399. # dpf__add_dgl_vulkan

  1400. # ------------------------------------------------------------------------------

  1401. #

  1402. # Add the Vulkan variant of DGL, if not already available.

  1403. #

  1404. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1405.   if(TARGET dgl-vulkan)

  1406.     return()

  1407.   endif()

  1408. 

  1409.   find_package(Vulkan REQUIRED)

  1410. 

  1411.   dpf__add_static_library(dgl-vulkan STATIC

  1412.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1413.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1414.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1415.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1416.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1417.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1418.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1419.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1420.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1421.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1422.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1423.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1424.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1425.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1426.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1427.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1428.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1429.   if(NO_SHARED_RESOURCES)

  1430.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1431.   else()

  1432.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1433.   endif()

  1434.   if(APPLE)

  1435.     target_sources(dgl-vulkan PRIVATE

  1436.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1437.   else()

  1438.     target_sources(dgl-vulkan PRIVATE

  1439.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1440.   endif()

  1441.   target_include_directories(dgl-vulkan PUBLIC

  1442.     "${DPF_ROOT_DIR}/dgl")

  1443.   target_include_directories(dgl-vulkan PUBLIC

  1444.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1445. 

  1446.   if(APPLE)

  1447.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1448.   endif()

  1449. 

  1450.   if(USE_FILE_BROWSER)

  1451.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1452.   endif()

  1453. 

  1454.   if(USE_WEB_VIEW)

  1455.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1456.     if(APPLE)

  1457.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1458.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1459.     elseif(WIN32)

  1460.       target_sources(dgl-vulkan PRIVATE

  1461.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1462.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1463.         PROPERTIES

  1464.           COMPILE_FLAGS

  1465.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1466.     endif()

  1467.   endif()

  1468. 

  1469.   dpf__add_dgl_system_libs()

  1470.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1471. 

  1472.   add_library(dgl-vulkan-definitions INTERFACE)

  1473.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1474. 

  1475.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1476.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1477. endfunction()

  1478. 

  1479. # dpf__add_plugin_specific_ui_sources

  1480. # ------------------------------------------------------------------------------

  1481. #

  1482. # Compile system specific files

  1483. #

  1484. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1485.   if(APPLE)

  1486.     target_sources("${NAME}" PRIVATE

  1487.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1488.     if(USE_WEB_VIEW)

  1489.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1490.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1491.     endif()

  1492.   elseif(WIN32 AND USE_WEB_VIEW)

  1493.     target_sources("${NAME}" PRIVATE

  1494.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1495.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1496.       PROPERTIES

  1497.         COMPILE_FLAGS

  1498.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1499.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1500.   endif()

  1501. endfunction()

  1502. 

  1503. # dpf__add_dgl_system_libs

  1504. # ------------------------------------------------------------------------------

  1505. #

  1506. # Find system libraries required by DGL and add them as an interface target.

  1507. #

  1508. function(dpf__add_dgl_system_libs)

  1509.   if(TARGET dgl-system-libs)

  1510.     return()

  1511.   endif()

  1512.   add_library(dgl-system-libs INTERFACE)

  1513.   add_library(dgl-system-libs-definitions INTERFACE)

  1514.   if(APPLE)

  1515.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1516.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1517.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1518.   elseif(EMSCRIPTEN)

  1519.   elseif(HAIKU)

  1520.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1521.   elseif(WIN32)

  1522.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1523.   else()

  1524.     find_package(PkgConfig REQUIRED)

  1525.     pkg_check_modules(DBUS "dbus-1")

  1526.     if(DBUS_FOUND)

  1527.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1528.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1529.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1530.     endif()

  1531.     find_package(X11 REQUIRED)

  1532.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1533.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1534.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1535.     if(X11_Xcursor_FOUND)

  1536.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1537.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1538.     endif()

  1539.     if(X11_Xext_FOUND)

  1540.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1541.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1542.     endif()

  1543.     if(X11_Xrandr_FOUND)

  1544.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1545.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1546.     endif()

  1547.     if(X11_XSync_FOUND)

  1548.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1549.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1550.     endif()

  1551.    endif()

  1552. 

  1553.    if(MSVC)

  1554.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1555.      foreach(_gl_header "glext.h")

  1556.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1557.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1558.        endif()

  1559.      endforeach()

  1560.      foreach(_khr_header "khrplatform.h")

  1561.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1562.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1563.        endif()

  1564.      endforeach()

  1565.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1566.    endif()

  1567. 

  1568.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1569. endfunction()

  1570. 

  1571. # dpf__add_executable

  1572. # ------------------------------------------------------------------------------

  1573. #

  1574. # Adds an executable target, and set some default properties on the target.

  1575. #

  1576. function(dpf__add_executable NAME)

  1577.   add_executable("${NAME}" ${ARGN})

  1578.   dpf__set_target_defaults("${NAME}")

  1579.   if(MINGW)

  1580.     target_link_libraries("${NAME}" PRIVATE "-static")

  1581.   endif()

  1582. endfunction()

  1583. 

  1584. # dpf__add_module

  1585. # ------------------------------------------------------------------------------

  1586. #

  1587. # Adds a module target, and set some default properties on the target.

  1588. #

  1589. function(dpf__add_module NAME)

  1590.   add_library("${NAME}" MODULE ${ARGN})

  1591.   dpf__set_target_defaults("${NAME}")

  1592.   if(APPLE)

  1593.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1594.   elseif(MINGW)

  1595.     target_link_libraries("${NAME}" PRIVATE "-static")

  1596.   endif()

  1597. endfunction()

  1598. 

  1599. # dpf__add_static_library

  1600. # ------------------------------------------------------------------------------

  1601. #

  1602. # Adds a static library target, and set some default properties on the target.

  1603. #

  1604. function(dpf__add_static_library NAME)

  1605.   add_library("${NAME}" STATIC ${ARGN})

  1606.   dpf__set_target_defaults("${NAME}")

  1607. endfunction()

  1608. 

  1609. # dpf__set_module_export_list

  1610. # ------------------------------------------------------------------------------

  1611. #

  1612. # Applies a list of exported symbols to the module target.

  1613. #

  1614. function(dpf__set_module_export_list NAME EXPORTS)

  1615.   if(WIN32)

  1616.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1617.   elseif(APPLE)

  1618.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1619.       "-Xlinker" "-exported_symbols_list"

  1620.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1621.   else()

  1622.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1623.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1624.   endif()

  1625. endfunction()

  1626. 

  1627. # dpf__set_target_defaults

  1628. # ------------------------------------------------------------------------------

  1629. #

  1630. # Set default properties which must apply to all DPF-defined targets.

  1631. #

  1632. function(dpf__set_target_defaults NAME)

  1633.   set_target_properties("${NAME}" PROPERTIES

  1634.     POSITION_INDEPENDENT_CODE TRUE

  1635.     C_VISIBILITY_PRESET "hidden"

  1636.     CXX_VISIBILITY_PRESET "hidden"

  1637.     VISIBILITY_INLINES_HIDDEN TRUE)

  1638.   if(WIN32)

  1639.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1640.   endif()

  1641.   if (MINGW)

  1642.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1643.   endif()

  1644.   if (MSVC)

  1645.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1646.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1647.   endif()

  1648.   if (CMAKE_COMPILER_IS_GNUCXX)

  1649.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1650.   endif()

  1651.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1652.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1653.   endif()

  1654. endfunction()

  1655. 

  1656. # dpf__add_plugin_main

  1657. # ------------------------------------------------------------------------------

  1658. #

  1659. # Adds plugin code to the given target.

  1660. #

  1661. function(dpf__add_plugin_main NAME TARGET)

  1662.   target_sources("${NAME}" PRIVATE

  1663.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1664.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1665. endfunction()

  1666. 

  1667. # dpf__add_ui_main

  1668. # ------------------------------------------------------------------------------

  1669. #

  1670. # Adds UI code to the given target (only if the target has UI).

  1671. #

  1672. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1673.   if(HAS_UI)

  1674.     target_sources("${NAME}" PRIVATE

  1675.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1676.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1677.   endif()

  1678. endfunction()

  1679. 

  1680. # dpf__add_plugin_target_definition

  1681. # ------------------------------------------------------------------------------

  1682. #

  1683. # Adds the plugins target macro definition.

  1684. # This selects which entry file is compiled according to the target type.

  1685. #

  1686. function(dpf__add_plugin_target_definition NAME TARGET)

  1687.   string(TOUPPER "${TARGET}" _upperTarget)

  1688.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1689. endfunction()

  1690. 

  1691. # dpf__add_lv2_ttl_generator

  1692. # ------------------------------------------------------------------------------

  1693. #

  1694. # Build the LV2 TTL generator.

  1695. #

  1696. function(dpf__add_lv2_ttl_generator)

  1697.   if(TARGET lv2_ttl_generator)

  1698.     return()

  1699.   endif()

  1700.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1701.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1702.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1703.   endif()

  1704. endfunction()

  1705. 

  1706. # dpf__ensure_sources_non_empty

  1707. # ------------------------------------------------------------------------------

  1708. #

  1709. # Ensure the given source list contains at least one file.

  1710. # The function appends an empty source file to the list if necessary.

  1711. # This is useful when CMake does not permit to add targets without sources.

  1712. #

  1713. function(dpf__ensure_sources_non_empty VAR)

  1714.   if(NOT "" STREQUAL "${${VAR}}")

  1715.     return()

  1716.   endif()

  1717.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1718.   if(NOT EXISTS "${_file}")

  1719.     file(WRITE "${_file}" "")

  1720.   endif()

  1721.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1722. endfunction()

  1723. 

  1724. # dpf__create_dummy_source_list

  1725. # ------------------------------------------------------------------------------

  1726. #

  1727. # Create a dummy source list which is equivalent to compiling nothing.

  1728. # This is only for compatibility with older CMake versions, which refuse to add

  1729. # targets without any sources.

  1730. #

  1731. macro(dpf__create_dummy_source_list VAR)

  1732.   set("${VAR}")

  1733.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1734.     dpf__ensure_sources_non_empty("${VAR}")

  1735.   endif()

  1736. endmacro()

  1737. 

  1738. # dpf__target_link_directories

  1739. # ------------------------------------------------------------------------------

  1740. #

  1741. # Call `target_link_directories` if cmake >= 3.13,

  1742. # otherwise fallback to global `link_directories`.

  1743. #

  1744. macro(dpf__target_link_directories NAME DIRS)

  1745.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1746.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1747.   else()

  1748.     link_directories(${DIRS})

  1749.   endif()

  1750. endmacro()

  1751. 

  1752. # dpf__warn_once

  1753. # ------------------------------------------------------------------------------

  1754. #

  1755. # Prints a warning message once only.

  1756. #

  1757. function(dpf__warn_once_only TOKEN MESSAGE)

  1758.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1759.   if(NOT _warned)

  1760.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1761.     message(WARNING "${MESSAGE}")

  1762.   endif()

  1763. endfunction()