DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2420 Commits
7 Branches
91MB
Tree: 5cd8730506
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '5cd8730506'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1344 lines
48KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  125.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  126.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  127.       set(_dgl_library dgl-cairo)

  128.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  129.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  130.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  131.       set(_dgl_library dgl-external)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  133.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  134.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  135.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  136.       set(_dgl_library dgl-opengl)

  137.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  138.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  139.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  140.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  141.       set(_dgl_library dgl-opengl3)

  142.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  143.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  144.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  145.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  146.       set(_dgl_library dgl-vulkan)

  147.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  148.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  149.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  150.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  151.       set(_dgl_library dgl-external)

  152.     else()

  153.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  154.     endif()

  155.   else()

  156.     set(_dpf_plugin_UI_TYPE "")

  157.   endif()

  158. 

  159.   set(_dgl_has_ui OFF)

  160.   if(_dgl_library)

  161.     set(_dgl_has_ui ON)

  162.   endif()

  163. 

  164.   ###

  165.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  166.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  167.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  168. 

  169.   ###

  170.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  171.   target_include_directories("${NAME}" PUBLIC

  172.     "${DPF_ROOT_DIR}/distrho")

  173. 

  174.   if(_dpf_plugin_USE_FILE_BROWSER)

  175.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  176.   endif()

  177. 

  178.   if(_dpf_plugin_USE_WEB_VIEW)

  179.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  180.   endif()

  181. 

  182.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  183.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  184.   endif()

  185. 

  186.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  187.     target_link_libraries("${NAME}" PRIVATE "dl")

  188.   endif()

  189. 

  190.   if(_dgl_library)

  191.     # make sure that all code will see DGL_* definitions

  192.     target_link_libraries("${NAME}" PUBLIC

  193.       "${_dgl_library}-definitions"

  194.       dgl-system-libs-definitions

  195.       dgl-system-libs)

  196.   endif()

  197. 

  198.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  199.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  200. 

  201.   if(_dgl_library)

  202.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  203.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  204.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  205.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  206.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  207.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  208.           OUTPUT_STRIP_TRAILING_WHITESPACE

  209.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  210.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  211.       endif()

  212.     endif()

  213.     # add the files containing C++17 or Objective-C classes

  214.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  215.   else()

  216.     add_library("${NAME}-ui" INTERFACE)

  217.   endif()

  218. 

  219.   ###

  220.   foreach(_target ${_dpf_plugin_TARGETS})

  221.     if(_target STREQUAL "jack")

  222.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  223.     elseif(_target STREQUAL "ladspa")

  224.       dpf__build_ladspa("${NAME}")

  225.     elseif(_target STREQUAL "dssi")

  226.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  227.     elseif(_target STREQUAL "lv2")

  228.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  229.     elseif(_target STREQUAL "vst2")

  230.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  231.     elseif(_target STREQUAL "vst3")

  232.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  233.     elseif(_target STREQUAL "clap")

  234.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  235.     elseif(_target STREQUAL "au")

  236.       if (APPLE)

  237.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  238.       endif()

  239.     elseif(_target STREQUAL "static")

  240.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  241.     else()

  242.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  243.     endif()

  244.   endforeach()

  245. endfunction()

  246. 

  247. # ------------------------------------------------------------------------------

  248. # DPF private functions (prefixed with `dpf__`)

  249. # ------------------------------------------------------------------------------

  250. 

  251. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  252. #       to the output directory.

  253. #

  254. 

  255. # dpf__build_jack

  256. # ------------------------------------------------------------------------------

  257. #

  258. # Add build rules for a JACK/Standalone program.

  259. #

  260. function(dpf__build_jack NAME HAS_UI)

  261.   dpf__create_dummy_source_list(_no_srcs)

  262. 

  263.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  264.   dpf__add_plugin_main("${NAME}-jack" "jack")

  265.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  266.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  267.   set_target_properties("${NAME}-jack" PROPERTIES

  268.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  269.     OUTPUT_NAME "${NAME}")

  270. 

  271.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  272.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  273. 

  274.   find_package(PkgConfig)

  275.   pkg_check_modules(SDL2 "sdl2")

  276.   if(SDL2_FOUND)

  277.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  278.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  279.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  280.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  281.   endif()

  282. 

  283.   if(APPLE OR WIN32)

  284.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  285.   else()

  286.     find_package(Threads)

  287.     pkg_check_modules(ALSA "alsa")

  288.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  289.     if(ALSA_FOUND)

  290.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  291.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  292.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  293.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  294.     endif()

  295.     if(PULSEAUDIO_FOUND)

  296.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  297.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  298.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  299.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  300.     endif()

  301.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  302.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  303.     endif()

  304.   endif()

  305. 

  306.   # for RtAudio native fallback

  307.   if(APPLE)

  308.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  309.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  310.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  311.     target_link_libraries("${NAME}-jack" PRIVATE

  312.       "${APPLE_COREAUDIO_FRAMEWORK}"

  313.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  314.       "${APPLE_COREMIDI_FRAMEWORK}")

  315.   elseif(WIN32)

  316.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  317.     if(HAS_UI AND MINGW)

  318.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  319.     endif()

  320.   endif()

  321. endfunction()

  322. 

  323. # dpf__build_ladspa

  324. # ------------------------------------------------------------------------------

  325. #

  326. # Add build rules for a LADSPA plugin.

  327. #

  328. function(dpf__build_ladspa NAME)

  329.   dpf__create_dummy_source_list(_no_srcs)

  330. 

  331.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  332.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  333.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  334.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  335.   set_target_properties("${NAME}-ladspa" PROPERTIES

  336.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  337.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  338.     OUTPUT_NAME "${NAME}-ladspa"

  339.     PREFIX "")

  340. endfunction()

  341. 

  342. # dpf__build_dssi

  343. # ------------------------------------------------------------------------------

  344. #

  345. # Add build rules for a DSSI plugin.

  346. #

  347. function(dpf__build_dssi NAME HAS_UI)

  348.   find_package(PkgConfig)

  349.   pkg_check_modules(LIBLO "liblo")

  350.   if(NOT LIBLO_FOUND)

  351.     dpf__warn_once_only(missing_liblo

  352.       "liblo is not found, skipping the `dssi` plugin targets")

  353.     return()

  354.   endif()

  355. 

  356.   dpf__create_dummy_source_list(_no_srcs)

  357. 

  358.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  359.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  360.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  361.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  362.   set_target_properties("${NAME}-dssi" PROPERTIES

  363.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  364.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  365.     OUTPUT_NAME "${NAME}-dssi"

  366.     PREFIX "")

  367. 

  368.   if(HAS_UI)

  369.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  370.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  371.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  372.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  373.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  374.       OUTPUT_NAME "${NAME}_ui")

  375. 

  376.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  377.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  378.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  379.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  380.   endif()

  381. endfunction()

  382. 

  383. # dpf__build_lv2

  384. # ------------------------------------------------------------------------------

  385. #

  386. # Add build rules for an LV2 plugin.

  387. #

  388. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  389.   dpf__create_dummy_source_list(_no_srcs)

  390. 

  391.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  392.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  393.   if(HAS_UI AND MONOLITHIC)

  394.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  395.   else()

  396.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  397.   endif()

  398.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  399.   set_target_properties("${NAME}-lv2" PROPERTIES

  400.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  401.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  402.     OUTPUT_NAME "${NAME}_dsp"

  403.     PREFIX "")

  404. 

  405.   if(HAS_UI)

  406.     if(MONOLITHIC)

  407.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  408.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  409.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  410.       set_target_properties("${NAME}-lv2" PROPERTIES

  411.         OUTPUT_NAME "${NAME}")

  412.     else()

  413.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  414.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  415.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  416.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  417.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  418.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  419.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  420.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  421.         OUTPUT_NAME "${NAME}_ui"

  422.         PREFIX "")

  423.     endif()

  424.   endif()

  425. 

  426.   dpf__add_lv2_ttl_generator()

  427.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  428. 

  429.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  430. 

  431.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  432.     COMMAND

  433.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  434.     "$<TARGET_FILE:lv2_ttl_generator>"

  435.     "$<TARGET_FILE:${NAME}-lv2>"

  436.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  437.     DEPENDS lv2_ttl_generator)

  438. endfunction()

  439. 

  440. # dpf__build_vst2

  441. # ------------------------------------------------------------------------------

  442. #

  443. # Add build rules for a VST2 plugin.

  444. #

  445. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  446.   dpf__create_dummy_source_list(_no_srcs)

  447. 

  448.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  449.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  450.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  451.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  452.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  453.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  454.   set_target_properties("${NAME}-vst2" PROPERTIES

  455.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  456.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  457.     OUTPUT_NAME "${NAME}-vst2"

  458.     PREFIX "")

  459.   if(APPLE)

  460.     set_target_properties("${NAME}-vst2" PROPERTIES

  461.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  462.       OUTPUT_NAME "${NAME}"

  463.       SUFFIX "")

  464.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  465.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  466.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  467.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  468.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  469.   endif()

  470. endfunction()

  471. 

  472. # dpf__determine_vst3_package_architecture

  473. # ------------------------------------------------------------------------------

  474. #

  475. # Determines the package architecture for a VST3 plugin target.

  476. #

  477. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  478.   # if set by variable, override the detection

  479.   if(DPF_VST3_ARCHITECTURE)

  480.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  481.     return()

  482.   endif()

  483. 

  484.   # not used on Apple, which supports universal binary

  485.   if(APPLE)

  486.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  487.     return()

  488.   endif()

  489. 

  490.   # identify the target processor (special case of MSVC, problematic sometimes)

  491.   if(MSVC)

  492.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  493.   else()

  494.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  495.   endif()

  496. 

  497.   # transform the processor name to a format that VST3 recognizes

  498.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  499.     set(vst3_package_arch "x86_64")

  500.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  501.     if(WIN32)

  502.       set(vst3_package_arch "x86")

  503.     else()

  504.       set(vst3_package_arch "i386")

  505.     endif()

  506.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  507.     set(vst3_package_arch "${vst3_system_arch}")

  508.   else()

  509.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  510.   endif()

  511. 

  512.   # TODO: the detections for Windows arm/arm64 when supported

  513. 

  514.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  515. endfunction()

  516. 

  517. # dpf__build_vst3

  518. # ------------------------------------------------------------------------------

  519. #

  520. # Add build rules for a VST3 plugin.

  521. #

  522. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  523.   dpf__determine_vst3_package_architecture(vst3_arch)

  524. 

  525.   dpf__create_dummy_source_list(_no_srcs)

  526. 

  527.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  528.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  529.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  530.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  531.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  532.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  533.   set_target_properties("${NAME}-vst3" PROPERTIES

  534.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  535.     OUTPUT_NAME "${NAME}"

  536.     PREFIX "")

  537. 

  538.   if(APPLE)

  539.     set_target_properties("${NAME}-vst3" PROPERTIES

  540.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  541.       SUFFIX "")

  542.   elseif(WIN32)

  543.     set_target_properties("${NAME}-vst3" PROPERTIES

  544.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  545.   else()

  546.     set_target_properties("${NAME}-vst3" PROPERTIES

  547.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  548.   endif()

  549. 

  550.   if(APPLE)

  551.     # Uses the same macOS bundle template as VST2

  552.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  553.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  554.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  555.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  556.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  557.   endif()

  558. endfunction()

  559. 

  560. # dpf__build_clap

  561. # ------------------------------------------------------------------------------

  562. #

  563. # Add build rules for a CLAP plugin.

  564. #

  565. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  566.   dpf__create_dummy_source_list(_no_srcs)

  567. 

  568.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  569.   dpf__add_plugin_main("${NAME}-clap" "clap")

  570.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  571.   dpf__set_module_export_list("${NAME}-clap" "clap")

  572.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  573.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  574.   set_target_properties("${NAME}-clap" PROPERTIES

  575.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  576.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  577.     OUTPUT_NAME "${NAME}"

  578.     PREFIX ""

  579.     SUFFIX ".clap")

  580. 

  581.   if(APPLE)

  582.     set_target_properties("${NAME}-clap" PROPERTIES

  583.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  584.       OUTPUT_NAME "${NAME}"

  585.       SUFFIX "")

  586.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  587.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  588.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  589.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  590.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  591.   endif()

  592. endfunction()

  593. 

  594. # dpf__build_au

  595. # ------------------------------------------------------------------------------

  596. #

  597. # Add build rules for an AUv2 plugin.

  598. #

  599. function(dpf__build_au NAME HAS_UI)

  600.   dpf__create_dummy_source_list(_no_srcs)

  601. 

  602.   dpf__add_module("${NAME}-au" ${_no_srcs})

  603.   dpf__add_plugin_main("${NAME}-au" "au")

  604.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  605.   dpf__set_module_export_list("${NAME}-au" "au")

  606.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  607.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  608.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  609.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  610.   target_link_libraries("${NAME}-au" PRIVATE

  611.     "${NAME}-dsp"

  612.     "${NAME}-ui"

  613.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  614.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  615.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  616.   set_target_properties("${NAME}-au" PROPERTIES

  617.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  618.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  619.     OUTPUT_NAME "${NAME}"

  620.     PREFIX ""

  621.     SUFFIX "")

  622. 

  623.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  624.   dpf__add_plugin_main("${NAME}-export" "export")

  625.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  626.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  627. 

  628.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  629. 

  630.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  631.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  632.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  633.     DEPENDS "${NAME}-export")

  634. 

  635.   add_dependencies("${NAME}-au" "${NAME}-export")

  636. 

  637.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  638.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  639. endfunction()

  640. 

  641. # dpf__build_static

  642. # ------------------------------------------------------------------------------

  643. #

  644. # Add build rules for a static library.

  645. #

  646. function(dpf__build_static NAME HAS_UI)

  647.   dpf__create_dummy_source_list(_no_srcs)

  648. 

  649.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  650.   dpf__add_plugin_main("${NAME}-static" "static")

  651.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  652.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  653. 

  654.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  655.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  656.   foreach(src ${dsp_srcs})

  657.     target_sources("${NAME}-static" PRIVATE ${src})

  658.   endforeach()

  659.   foreach(src ${ui_srcs})

  660.     target_sources("${NAME}-static" PRIVATE ${src})

  661.   endforeach()

  662. 

  663.   set_target_properties("${NAME}-static" PROPERTIES

  664.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  665.     OUTPUT_NAME "${NAME}"

  666.     PREFIX "")

  667. endfunction()

  668. 

  669. # dpf__add_dgl_cairo

  670. # ------------------------------------------------------------------------------

  671. #

  672. # Add the Cairo variant of DGL, if not already available.

  673. #

  674. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  675.   if(TARGET dgl-cairo)

  676.     return()

  677.   endif()

  678. 

  679.   find_package(PkgConfig)

  680.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  681. 

  682.   link_directories(${CAIRO_LIBRARY_DIRS})

  683. 

  684.   dpf__add_static_library(dgl-cairo STATIC

  685.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  686.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  687.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  688.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  689.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  690.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  691.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  692.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  693.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  694.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  695.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  696.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  697.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  698.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  699.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  700.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  701.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  702.   if(SHARED_RESOURCES)

  703.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  704.   else()

  705.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  706.   endif()

  707.   if(APPLE)

  708.     target_sources(dgl-cairo PRIVATE

  709.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  710.   else()

  711.     target_sources(dgl-cairo PRIVATE

  712.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  713.   endif()

  714.   target_include_directories(dgl-cairo PUBLIC

  715.     "${DPF_ROOT_DIR}/dgl")

  716.   target_include_directories(dgl-cairo PUBLIC

  717.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  718. 

  719.   if(USE_FILE_BROWSER)

  720.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  721.   endif()

  722. 

  723.   if(USE_WEB_VIEW)

  724.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  725.     if(WIN32)

  726.       target_sources(dgl-cairo PRIVATE

  727.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  728.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  729.         PROPERTIES

  730.           COMPILE_FLAGS

  731.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  732.     endif()

  733.   endif()

  734. 

  735.   dpf__add_dgl_system_libs()

  736.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  737. 

  738.   add_library(dgl-cairo-definitions INTERFACE)

  739.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  740. 

  741.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  742.   if(MINGW)

  743.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  744.   else()

  745.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  746.   endif()

  747.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  748. endfunction()

  749. 

  750. # dpf__add_dgl_external

  751. # ------------------------------------------------------------------------------

  752. #

  753. # Add the external variant of DGL, if not already available.

  754. #

  755. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  756.   if(TARGET dgl-external)

  757.     return()

  758.   endif()

  759. 

  760.   dpf__add_static_library(dgl-external STATIC

  761.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  762.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  763.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  764.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  765.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  766.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  767.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  768.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  769.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  770.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  771.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  772.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  773.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  774.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  775.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  776.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  777.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  778. 

  779.   if(APPLE)

  780.     target_sources(dgl-external PRIVATE

  781.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  782.   else()

  783.     target_sources(dgl-external PRIVATE

  784.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  785.   endif()

  786.   target_include_directories(dgl-external PUBLIC

  787.     "${DPF_ROOT_DIR}/dgl")

  788.   target_include_directories(dgl-external PUBLIC

  789.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  790. 

  791.   if(USE_FILE_BROWSER)

  792.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  793.   endif()

  794. 

  795.   if(USE_WEB_VIEW)

  796.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  797.     if(WIN32)

  798.       target_sources(dgl-external PRIVATE

  799.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  800.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  801.         PROPERTIES

  802.           COMPILE_FLAGS

  803.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  804.     endif()

  805.   endif()

  806. 

  807.   dpf__add_dgl_system_libs()

  808.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  809.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  810. 

  811.   add_library(dgl-external-definitions INTERFACE)

  812.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  813. 

  814.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  815.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  816. endfunction()

  817. 

  818. # dpf__add_dgl_opengl

  819. # ------------------------------------------------------------------------------

  820. #

  821. # Add the OpenGL variant of DGL, if not already available.

  822. #

  823. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  824.   if(TARGET dgl-opengl)

  825.     return()

  826.   endif()

  827. 

  828.   if(NOT OpenGL_GL_PREFERENCE)

  829.     set(OpenGL_GL_PREFERENCE "LEGACY")

  830.   endif()

  831. 

  832.   find_package(OpenGL REQUIRED)

  833. 

  834.   dpf__add_static_library(dgl-opengl STATIC

  835.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  836.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  837.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  838.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  839.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  840.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  841.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  842.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  843.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  844.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  845.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  846.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  847.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  848.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  849.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  850.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  851.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  852.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  853.   if(SHARED_RESOURCES)

  854.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  855.   else()

  856.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  857.   endif()

  858.   if(APPLE)

  859.     target_sources(dgl-opengl PRIVATE

  860.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  861.   else()

  862.     target_sources(dgl-opengl PRIVATE

  863.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  864.   endif()

  865.   target_include_directories(dgl-opengl PUBLIC

  866.     "${DPF_ROOT_DIR}/dgl")

  867.   target_include_directories(dgl-opengl PUBLIC

  868.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  869. 

  870.   if(APPLE)

  871.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  872.   endif()

  873. 

  874.   if(USE_FILE_BROWSER)

  875.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  876.   endif()

  877. 

  878.   if(USE_WEB_VIEW)

  879.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  880.     if(WIN32)

  881.       target_sources(dgl-opengl PRIVATE

  882.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  883.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  884.         PROPERTIES

  885.           COMPILE_FLAGS

  886.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  887.     endif()

  888.   endif()

  889. 

  890.   dpf__add_dgl_system_libs()

  891.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  892. 

  893.   add_library(dgl-opengl-definitions INTERFACE)

  894.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  895. 

  896.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  897.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  898. endfunction()

  899. 

  900. # dpf__add_dgl_opengl3

  901. # ------------------------------------------------------------------------------

  902. #

  903. # Add the OpenGL3 variant of DGL, if not already available.

  904. #

  905. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  906.   if(TARGET dgl-opengl3)

  907.     return()

  908.   endif()

  909. 

  910.   if(NOT OpenGL_GL_PREFERENCE)

  911.     set(OpenGL_GL_PREFERENCE "LEGACY")

  912.   endif()

  913. 

  914.   find_package(OpenGL REQUIRED)

  915. 

  916.   dpf__add_static_library(dgl-opengl3 STATIC

  917.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  918.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  919.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  920.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  921.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  922.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  923.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  924.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  925.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  926.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  927.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  928.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  929.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  930.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  931.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  932.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  933.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  934.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  935.   if(SHARED_RESOURCES)

  936.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  937.   else()

  938.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  939.   endif()

  940.   if(APPLE)

  941.     target_sources(dgl-opengl3 PRIVATE

  942.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  943.   else()

  944.     target_sources(dgl-opengl3 PRIVATE

  945.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  946.   endif()

  947.   target_include_directories(dgl-opengl3 PUBLIC

  948.     "${DPF_ROOT_DIR}/dgl")

  949.   target_include_directories(dgl-opengl3 PUBLIC

  950.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  951. 

  952.   if(APPLE)

  953.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  954.   endif()

  955. 

  956.   if(USE_FILE_BROWSER)

  957.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  958.   endif()

  959. 

  960.   if(USE_WEB_VIEW)

  961.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  962.     if(WIN32)

  963.       target_sources(dgl-opengl3 PRIVATE

  964.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  965.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  966.         PROPERTIES

  967.           COMPILE_FLAGS

  968.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  969.     endif()

  970.   endif()

  971. 

  972.   dpf__add_dgl_system_libs()

  973.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  974. 

  975.   add_library(dgl-opengl3-definitions INTERFACE)

  976.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  977. 

  978.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  979.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  980. endfunction()

  981. 

  982. # dpf__add_dgl_vulkan

  983. # ------------------------------------------------------------------------------

  984. #

  985. # Add the Vulkan variant of DGL, if not already available.

  986. #

  987. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  988.   if(TARGET dgl-vulkan)

  989.     return()

  990.   endif()

  991. 

  992.   find_package(Vulkan REQUIRED)

  993. 

  994.   dpf__add_static_library(dgl-vulkan STATIC

  995.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  996.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  997.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  998.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  999.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1000.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1001.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1002.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1003.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1004.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1005.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1006.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1007.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1008.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1009.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1010.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1011.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1012.   if(NO_SHARED_RESOURCES)

  1013.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1014.   else()

  1015.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1016.   endif()

  1017.   if(APPLE)

  1018.     target_sources(dgl-vulkan PRIVATE

  1019.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1020.   else()

  1021.     target_sources(dgl-vulkan PRIVATE

  1022.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1023.   endif()

  1024.   target_include_directories(dgl-vulkan PUBLIC

  1025.     "${DPF_ROOT_DIR}/dgl")

  1026.   target_include_directories(dgl-vulkan PUBLIC

  1027.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1028. 

  1029.   if(APPLE)

  1030.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1031.   endif()

  1032. 

  1033.   if(USE_FILE_BROWSER)

  1034.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1035.   endif()

  1036. 

  1037.   if(USE_WEB_VIEW)

  1038.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1039.     if(WIN32)

  1040.       target_sources(dgl-vulkan PRIVATE

  1041.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1042.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1043.         PROPERTIES

  1044.           COMPILE_FLAGS

  1045.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1046.     endif()

  1047.   endif()

  1048. 

  1049.   dpf__add_dgl_system_libs()

  1050.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1051. 

  1052.   add_library(dgl-vulkan-definitions INTERFACE)

  1053.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1054. 

  1055.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1056.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1057. endfunction()

  1058. 

  1059. # dpf__add_plugin_specific_ui_sources

  1060. # ------------------------------------------------------------------------------

  1061. #

  1062. # Compile system specific files

  1063. #

  1064. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1065.   if(APPLE)

  1066.     target_sources("${NAME}" PRIVATE

  1067.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1068.     if(USE_WEB_VIEW)

  1069.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1070.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1071.     endif()

  1072.   elseif(WIN32 AND USE_WEB_VIEW)

  1073.     target_sources("${NAME}" PRIVATE

  1074.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1075.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1076.       PROPERTIES

  1077.         COMPILE_FLAGS

  1078.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1079.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1080.   endif()

  1081. endfunction()

  1082. 

  1083. # dpf__add_dgl_system_libs

  1084. # ------------------------------------------------------------------------------

  1085. #

  1086. # Find system libraries required by DGL and add them as an interface target.

  1087. #

  1088. function(dpf__add_dgl_system_libs)

  1089.   if(TARGET dgl-system-libs)

  1090.     return()

  1091.   endif()

  1092.   add_library(dgl-system-libs INTERFACE)

  1093.   add_library(dgl-system-libs-definitions INTERFACE)

  1094.   if(APPLE)

  1095.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1096.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1097.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1098.   elseif(EMSCRIPTEN)

  1099.   elseif(HAIKU)

  1100.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1101.   elseif(WIN32)

  1102.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1103.   else()

  1104.     find_package(PkgConfig)

  1105.     pkg_check_modules(DBUS "dbus-1")

  1106.     if(DBUS_FOUND)

  1107.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1108.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1109.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1110.     endif()

  1111.     find_package(X11 REQUIRED)

  1112.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1113.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1114.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1115.     if(X11_Xcursor_FOUND)

  1116.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1117.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1118.     endif()

  1119.     if(X11_Xext_FOUND)

  1120.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1121.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1122.     endif()

  1123.     if(X11_Xrandr_FOUND)

  1124.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1125.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1126.     endif()

  1127.     if(X11_XSync_FOUND)

  1128.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1129.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1130.     endif()

  1131.    endif()

  1132. 

  1133.    if(MSVC)

  1134.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1135.      foreach(_gl_header "glext.h")

  1136.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1137.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1138.        endif()

  1139.      endforeach()

  1140.      foreach(_khr_header "khrplatform.h")

  1141.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1142.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1143.        endif()

  1144.      endforeach()

  1145.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1146.    endif()

  1147. 

  1148.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1149. endfunction()

  1150. 

  1151. # dpf__add_executable

  1152. # ------------------------------------------------------------------------------

  1153. #

  1154. # Adds an executable target, and set some default properties on the target.

  1155. #

  1156. function(dpf__add_executable NAME)

  1157.   add_executable("${NAME}" ${ARGN})

  1158.   dpf__set_target_defaults("${NAME}")

  1159.   if(MINGW)

  1160.     target_link_libraries("${NAME}" PRIVATE "-static")

  1161.   endif()

  1162. endfunction()

  1163. 

  1164. # dpf__add_module

  1165. # ------------------------------------------------------------------------------

  1166. #

  1167. # Adds a module target, and set some default properties on the target.

  1168. #

  1169. function(dpf__add_module NAME)

  1170.   add_library("${NAME}" MODULE ${ARGN})

  1171.   dpf__set_target_defaults("${NAME}")

  1172.   if(APPLE)

  1173.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1174.   elseif(MINGW)

  1175.     target_link_libraries("${NAME}" PRIVATE "-static")

  1176.   endif()

  1177. endfunction()

  1178. 

  1179. # dpf__add_static_library

  1180. # ------------------------------------------------------------------------------

  1181. #

  1182. # Adds a static library target, and set some default properties on the target.

  1183. #

  1184. function(dpf__add_static_library NAME)

  1185.   add_library("${NAME}" STATIC ${ARGN})

  1186.   dpf__set_target_defaults("${NAME}")

  1187. endfunction()

  1188. 

  1189. # dpf__set_module_export_list

  1190. # ------------------------------------------------------------------------------

  1191. #

  1192. # Applies a list of exported symbols to the module target.

  1193. #

  1194. function(dpf__set_module_export_list NAME EXPORTS)

  1195.   if(WIN32)

  1196.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1197.   elseif(APPLE)

  1198.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1199.       "-Xlinker" "-exported_symbols_list"

  1200.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1201.   else()

  1202.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1203.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1204.   endif()

  1205. endfunction()

  1206. 

  1207. # dpf__set_target_defaults

  1208. # ------------------------------------------------------------------------------

  1209. #

  1210. # Set default properties which must apply to all DPF-defined targets.

  1211. #

  1212. function(dpf__set_target_defaults NAME)

  1213.   set_target_properties("${NAME}" PROPERTIES

  1214.     POSITION_INDEPENDENT_CODE TRUE

  1215.     C_VISIBILITY_PRESET "hidden"

  1216.     CXX_VISIBILITY_PRESET "hidden"

  1217.     VISIBILITY_INLINES_HIDDEN TRUE)

  1218.   if(WIN32)

  1219.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1220.   endif()

  1221.   if (MINGW)

  1222.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1223.   endif()

  1224.   if (MSVC)

  1225.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1226.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1227.   endif()

  1228.   if (CMAKE_COMPILER_IS_GNUCXX)

  1229.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1230.   endif()

  1231.   if ((NOT APPLE) AND (NOT MSVC))

  1232.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1233.   endif()

  1234. endfunction()

  1235. 

  1236. # dpf__add_plugin_main

  1237. # ------------------------------------------------------------------------------

  1238. #

  1239. # Adds plugin code to the given target.

  1240. #

  1241. function(dpf__add_plugin_main NAME TARGET)

  1242.   target_sources("${NAME}" PRIVATE

  1243.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1244.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1245. endfunction()

  1246. 

  1247. # dpf__add_ui_main

  1248. # ------------------------------------------------------------------------------

  1249. #

  1250. # Adds UI code to the given target (only if the target has UI).

  1251. #

  1252. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1253.   if(HAS_UI)

  1254.     target_sources("${NAME}" PRIVATE

  1255.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1256.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1257.   endif()

  1258. endfunction()

  1259. 

  1260. # dpf__add_plugin_target_definition

  1261. # ------------------------------------------------------------------------------

  1262. #

  1263. # Adds the plugins target macro definition.

  1264. # This selects which entry file is compiled according to the target type.

  1265. #

  1266. function(dpf__add_plugin_target_definition NAME TARGET)

  1267.   string(TOUPPER "${TARGET}" _upperTarget)

  1268.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1269. endfunction()

  1270. 

  1271. # dpf__add_lv2_ttl_generator

  1272. # ------------------------------------------------------------------------------

  1273. #

  1274. # Build the LV2 TTL generator.

  1275. #

  1276. function(dpf__add_lv2_ttl_generator)

  1277.   if(TARGET lv2_ttl_generator)

  1278.     return()

  1279.   endif()

  1280.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1281.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1282.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1283.   endif()

  1284. endfunction()

  1285. 

  1286. # dpf__ensure_sources_non_empty

  1287. # ------------------------------------------------------------------------------

  1288. #

  1289. # Ensure the given source list contains at least one file.

  1290. # The function appends an empty source file to the list if necessary.

  1291. # This is useful when CMake does not permit to add targets without sources.

  1292. #

  1293. function(dpf__ensure_sources_non_empty VAR)

  1294.   if(NOT "" STREQUAL "${${VAR}}")

  1295.     return()

  1296.   endif()

  1297.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1298.   if(NOT EXISTS "${_file}")

  1299.     file(WRITE "${_file}" "")

  1300.   endif()

  1301.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1302. endfunction()

  1303. 

  1304. # dpf__create_dummy_source_list

  1305. # ------------------------------------------------------------------------------

  1306. #

  1307. # Create a dummy source list which is equivalent to compiling nothing.

  1308. # This is only for compatibility with older CMake versions, which refuse to add

  1309. # targets without any sources.

  1310. #

  1311. macro(dpf__create_dummy_source_list VAR)

  1312.   set("${VAR}")

  1313.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1314.     dpf__ensure_sources_non_empty("${VAR}")

  1315.   endif()

  1316. endmacro()

  1317. 

  1318. # dpf__target_link_directories

  1319. # ------------------------------------------------------------------------------

  1320. #

  1321. # Call `target_link_directories` if cmake >= 3.13,

  1322. # otherwise fallback to global `link_directories`.

  1323. #

  1324. macro(dpf__target_link_directories NAME DIRS)

  1325.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1326.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1327.   else()

  1328.     link_directories(${DIRS})

  1329.   endif()

  1330. endmacro()

  1331. 

  1332. # dpf__warn_once

  1333. # ------------------------------------------------------------------------------

  1334. #

  1335. # Prints a warning message once only.

  1336. #

  1337. function(dpf__warn_once_only TOKEN MESSAGE)

  1338.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1339.   if(NOT _warned)

  1340.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1341.     message(WARNING "${MESSAGE}")

  1342.   endif()

  1343. endfunction()