DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2333 Commits
7 Branches
295MB
Tree: 57d0c51866
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '57d0c51866'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1256 lines
45KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - opengl (default)

  82. #          - opengl3

  83. #          - vulkan

  84. #          - webview

  85. #

  86. #   `FILES_COMMON` <file1>...<fileN>

  87. #       list of sources which are part of both DSP and UI

  88. #

  89. #   `FILES_DSP` <file1>...<fileN>

  90. #       list of sources which are part of the DSP

  91. #

  92. #   `FILES_UI` <file1>...<fileN>

  93. #       list of sources which are part of the UI

  94. #       empty indicates the plugin does not have UI

  95. #

  96. #   `MODGUI_CLASS_NAME`

  97. #       class name to use for modgui builds

  98. #

  99. #   `MONOLITHIC`

  100. #       build LV2 as a single binary for UI and DSP

  101. #

  102. #   `NO_SHARED_RESOURCES`

  103. #       do not build DPF shared resources (fonts, etc)

  104. #

  105. #   `USE_FILE_BROWSER`

  106. #       enable file browser dialog APIs

  107. #

  108. #   `USE_WEB_VIEW`

  109. #       enable web browser view APIs

  110. #

  111. function(dpf_add_plugin NAME)

  112.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  113.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  114.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  115.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  116. 

  117.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  118.     set(_dpf_plugin_UI_TYPE "opengl")

  119.   endif()

  120. 

  121.   set(_dgl_library)

  122.   if(_dpf_plugin_FILES_UI)

  123.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  124.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  125.       set(_dgl_library dgl-cairo)

  126.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  127.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  128.       set(_dgl_library dgl-external)

  129.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  130.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  131.       set(_dgl_library dgl-opengl)

  132.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  133.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  134.       set(_dgl_library dgl-opengl3)

  135.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  136.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>> $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  137.       set(_dgl_library dgl-vulkan)

  138.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  139.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  140.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>)

  141.       set(_dgl_library dgl-external)

  142.     else()

  143.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  144.     endif()

  145.   else()

  146.     set(_dpf_plugin_UI_TYPE "")

  147.   endif()

  148. 

  149.   set(_dgl_has_ui OFF)

  150.   if(_dgl_library)

  151.     set(_dgl_has_ui ON)

  152.   endif()

  153. 

  154.   ###

  155.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  156.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  157.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  158. 

  159.   ###

  160.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  161.   target_include_directories("${NAME}" PUBLIC

  162.     "${DPF_ROOT_DIR}/distrho")

  163. 

  164.   if(_dpf_plugin_USE_FILE_BROWSER)

  165.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  166.   endif()

  167. 

  168.   if(_dpf_plugin_USE_WEB_VIEW)

  169.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  170.   endif()

  171. 

  172.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  173.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  174.   endif()

  175. 

  176.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  177.     target_link_libraries("${NAME}" PRIVATE "dl")

  178.   endif()

  179. 

  180.   if(_dgl_library)

  181.     # make sure that all code will see DGL_* definitions

  182.     target_link_libraries("${NAME}" PUBLIC

  183.       "${_dgl_library}-definitions"

  184.       dgl-system-libs-definitions

  185.       dgl-system-libs)

  186.   endif()

  187. 

  188.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  189.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  190. 

  191.   if(_dgl_library)

  192.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  193.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  194.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  195.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  196.       if(_dpf_plugin_USE_WEB_VIEW)

  197.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  198.       endif()

  199.     endif()

  200.     # add the files containing C++17 or Objective-C classes

  201.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  202.   else()

  203.     add_library("${NAME}-ui" INTERFACE)

  204.   endif()

  205. 

  206.   ###

  207.   foreach(_target ${_dpf_plugin_TARGETS})

  208.     if(_target STREQUAL "jack")

  209.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  210.     elseif(_target STREQUAL "ladspa")

  211.       dpf__build_ladspa("${NAME}")

  212.     elseif(_target STREQUAL "dssi")

  213.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  214.     elseif(_target STREQUAL "lv2")

  215.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  216.     elseif(_target STREQUAL "vst2")

  217.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  218.     elseif(_target STREQUAL "vst3")

  219.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  220.     elseif(_target STREQUAL "clap")

  221.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  222.     elseif(_target STREQUAL "au")

  223.       if (APPLE)

  224.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  225.       endif()

  226.     elseif(_target STREQUAL "static")

  227.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  228.     else()

  229.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  230.     endif()

  231.   endforeach()

  232. endfunction()

  233. 

  234. # ------------------------------------------------------------------------------

  235. # DPF private functions (prefixed with `dpf__`)

  236. # ------------------------------------------------------------------------------

  237. 

  238. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  239. #       to the output directory.

  240. #

  241. 

  242. # dpf__build_jack

  243. # ------------------------------------------------------------------------------

  244. #

  245. # Add build rules for a JACK/Standalone program.

  246. #

  247. function(dpf__build_jack NAME HAS_UI)

  248.   dpf__create_dummy_source_list(_no_srcs)

  249. 

  250.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  251.   dpf__add_plugin_main("${NAME}-jack" "jack")

  252.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  253.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  254.   set_target_properties("${NAME}-jack" PROPERTIES

  255.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  256.     OUTPUT_NAME "${NAME}")

  257. 

  258.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  259.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  260. 

  261.   find_package(PkgConfig)

  262.   pkg_check_modules(SDL2 "sdl2")

  263.   if(SDL2_FOUND)

  264.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  265.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  266.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  267.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  268.   endif()

  269. 

  270.   if(APPLE OR WIN32)

  271.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  272.   else()

  273.     find_package(Threads)

  274.     pkg_check_modules(ALSA "alsa")

  275.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  276.     if(ALSA_FOUND)

  277.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  278.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  279.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  280.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  281.     endif()

  282.     if(PULSEAUDIO_FOUND)

  283.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  284.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  285.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  286.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  287.     endif()

  288.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  289.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  290.     endif()

  291.   endif()

  292. 

  293.   # for RtAudio native fallback

  294.   if(APPLE)

  295.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  296.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  297.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  298.     target_link_libraries("${NAME}-jack" PRIVATE

  299.       "${APPLE_COREAUDIO_FRAMEWORK}"

  300.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  301.       "${APPLE_COREMIDI_FRAMEWORK}")

  302.   elseif(WIN32)

  303.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  304.     if(HAS_UI AND MINGW)

  305.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  306.     endif()

  307.   endif()

  308. endfunction()

  309. 

  310. # dpf__build_ladspa

  311. # ------------------------------------------------------------------------------

  312. #

  313. # Add build rules for a LADSPA plugin.

  314. #

  315. function(dpf__build_ladspa NAME)

  316.   dpf__create_dummy_source_list(_no_srcs)

  317. 

  318.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  319.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  320.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  321.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  322.   set_target_properties("${NAME}-ladspa" PROPERTIES

  323.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  324.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  325.     OUTPUT_NAME "${NAME}-ladspa"

  326.     PREFIX "")

  327. endfunction()

  328. 

  329. # dpf__build_dssi

  330. # ------------------------------------------------------------------------------

  331. #

  332. # Add build rules for a DSSI plugin.

  333. #

  334. function(dpf__build_dssi NAME HAS_UI)

  335.   find_package(PkgConfig)

  336.   pkg_check_modules(LIBLO "liblo")

  337.   if(NOT LIBLO_FOUND)

  338.     dpf__warn_once_only(missing_liblo

  339.       "liblo is not found, skipping the `dssi` plugin targets")

  340.     return()

  341.   endif()

  342. 

  343.   dpf__create_dummy_source_list(_no_srcs)

  344. 

  345.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  346.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  347.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  348.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  349.   set_target_properties("${NAME}-dssi" PROPERTIES

  350.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  351.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  352.     OUTPUT_NAME "${NAME}-dssi"

  353.     PREFIX "")

  354. 

  355.   if(HAS_UI)

  356.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  357.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  358.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  359.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  360.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  361.       OUTPUT_NAME "${NAME}_ui")

  362. 

  363.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  364.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  365.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  366.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  367.   endif()

  368. endfunction()

  369. 

  370. # dpf__build_lv2

  371. # ------------------------------------------------------------------------------

  372. #

  373. # Add build rules for an LV2 plugin.

  374. #

  375. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  376.   dpf__create_dummy_source_list(_no_srcs)

  377. 

  378.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  379.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  380.   if(HAS_UI AND MONOLITHIC)

  381.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  382.   else()

  383.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  384.   endif()

  385.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  386.   set_target_properties("${NAME}-lv2" PROPERTIES

  387.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  388.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  389.     OUTPUT_NAME "${NAME}_dsp"

  390.     PREFIX "")

  391. 

  392.   if(HAS_UI)

  393.     if(MONOLITHIC)

  394.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  395.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  396.       set_target_properties("${NAME}-lv2" PROPERTIES

  397.         OUTPUT_NAME "${NAME}")

  398.     else()

  399.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  400.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  401.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  402.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  403.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  404.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  405.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  406.         OUTPUT_NAME "${NAME}_ui"

  407.         PREFIX "")

  408.     endif()

  409.   endif()

  410. 

  411.   dpf__add_lv2_ttl_generator()

  412.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  413. 

  414.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  415. 

  416.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  417.     COMMAND

  418.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  419.     "$<TARGET_FILE:lv2_ttl_generator>"

  420.     "$<TARGET_FILE:${NAME}-lv2>"

  421.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  422.     DEPENDS lv2_ttl_generator)

  423. endfunction()

  424. 

  425. # dpf__build_vst2

  426. # ------------------------------------------------------------------------------

  427. #

  428. # Add build rules for a VST2 plugin.

  429. #

  430. function(dpf__build_vst2 NAME HAS_UI)

  431.   dpf__create_dummy_source_list(_no_srcs)

  432. 

  433.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  434.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  435.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  436.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  437.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  438.   set_target_properties("${NAME}-vst2" PROPERTIES

  439.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  440.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  441.     OUTPUT_NAME "${NAME}-vst2"

  442.     PREFIX "")

  443.   if(APPLE)

  444.     set_target_properties("${NAME}-vst2" PROPERTIES

  445.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  446.       OUTPUT_NAME "${NAME}"

  447.       SUFFIX "")

  448.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  449.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  450.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  451.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  452.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  453.   endif()

  454. endfunction()

  455. 

  456. # dpf__determine_vst3_package_architecture

  457. # ------------------------------------------------------------------------------

  458. #

  459. # Determines the package architecture for a VST3 plugin target.

  460. #

  461. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  462.   # if set by variable, override the detection

  463.   if(DPF_VST3_ARCHITECTURE)

  464.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  465.     return()

  466.   endif()

  467. 

  468.   # not used on Apple, which supports universal binary

  469.   if(APPLE)

  470.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  471.     return()

  472.   endif()

  473. 

  474.   # identify the target processor (special case of MSVC, problematic sometimes)

  475.   if(MSVC)

  476.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  477.   else()

  478.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  479.   endif()

  480. 

  481.   # transform the processor name to a format that VST3 recognizes

  482.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  483.     set(vst3_package_arch "x86_64")

  484.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  485.     if(WIN32)

  486.       set(vst3_package_arch "x86")

  487.     else()

  488.       set(vst3_package_arch "i386")

  489.     endif()

  490.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*|ppc(64)?(le)?)$")

  491.     set(vst3_package_arch "${vst3_system_arch}")

  492.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  493.     set(vst3_package_arch "aarch64")

  494.   else()

  495.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  496.   endif()

  497. 

  498.   # TODO: the detections for Windows arm/arm64 when supported

  499. 

  500.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  501. endfunction()

  502. 

  503. # dpf__build_vst3

  504. # ------------------------------------------------------------------------------

  505. #

  506. # Add build rules for a VST3 plugin.

  507. #

  508. function(dpf__build_vst3 NAME HAS_UI)

  509.   dpf__determine_vst3_package_architecture(vst3_arch)

  510. 

  511.   dpf__create_dummy_source_list(_no_srcs)

  512. 

  513.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  514.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  515.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  516.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  517.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  518.   set_target_properties("${NAME}-vst3" PROPERTIES

  519.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  520.     OUTPUT_NAME "${NAME}"

  521.     PREFIX "")

  522. 

  523.   if(APPLE)

  524.     set_target_properties("${NAME}-vst3" PROPERTIES

  525.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  526.       SUFFIX "")

  527.   elseif(WIN32)

  528.     set_target_properties("${NAME}-vst3" PROPERTIES

  529.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  530.   else()

  531.     set_target_properties("${NAME}-vst3" PROPERTIES

  532.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  533.   endif()

  534. 

  535.   if(APPLE)

  536.     # Uses the same macOS bundle template as VST2

  537.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  538.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  539.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  540.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  541.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  542.   endif()

  543. endfunction()

  544. 

  545. # dpf__build_clap

  546. # ------------------------------------------------------------------------------

  547. #

  548. # Add build rules for a CLAP plugin.

  549. #

  550. function(dpf__build_clap NAME HAS_UI)

  551.   dpf__create_dummy_source_list(_no_srcs)

  552. 

  553.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  554.   dpf__add_plugin_main("${NAME}-clap" "clap")

  555.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  556.   dpf__set_module_export_list("${NAME}-clap" "clap")

  557.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  558.   set_target_properties("${NAME}-clap" PROPERTIES

  559.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  560.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  561.     OUTPUT_NAME "${NAME}"

  562.     PREFIX ""

  563.     SUFFIX ".clap")

  564. 

  565.   if(APPLE)

  566.     set_target_properties("${NAME}-clap" PROPERTIES

  567.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  568.       OUTPUT_NAME "${NAME}"

  569.       SUFFIX "")

  570.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  571.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  572.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  573.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  574.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  575.   endif()

  576. endfunction()

  577. 

  578. # dpf__build_au

  579. # ------------------------------------------------------------------------------

  580. #

  581. # Add build rules for an AUv2 plugin.

  582. #

  583. function(dpf__build_au NAME HAS_UI)

  584.   dpf__create_dummy_source_list(_no_srcs)

  585. 

  586.   dpf__add_module("${NAME}-au" ${_no_srcs})

  587.   dpf__add_plugin_main("${NAME}-au" "au")

  588.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  589.   dpf__set_module_export_list("${NAME}-au" "au")

  590.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  591.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  592.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  593.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  594.   target_link_libraries("${NAME}-au" PRIVATE

  595.     "${NAME}-dsp"

  596.     "${NAME}-ui"

  597.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  598.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  599.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  600.   set_target_properties("${NAME}-au" PROPERTIES

  601.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  602.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  603.     OUTPUT_NAME "${NAME}"

  604.     PREFIX ""

  605.     SUFFIX "")

  606. 

  607.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  608.   dpf__add_plugin_main("${NAME}-export" "export")

  609.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  610.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  611. 

  612.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  613. 

  614.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  615.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  616.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents"

  617.     DEPENDS "${NAME}-export")

  618. 

  619.   add_dependencies("${NAME}-au" "${NAME}-export")

  620. 

  621.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  622.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  623. endfunction()

  624. 

  625. # dpf__build_static

  626. # ------------------------------------------------------------------------------

  627. #

  628. # Add build rules for a static library.

  629. #

  630. function(dpf__build_static NAME HAS_UI)

  631.   dpf__create_dummy_source_list(_no_srcs)

  632. 

  633.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  634.   dpf__add_plugin_main("${NAME}-static" "static")

  635.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  636.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  637. 

  638.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  639.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  640.   foreach(src ${dsp_srcs})

  641.     target_sources("${NAME}-static" PRIVATE ${src})

  642.   endforeach()

  643.   foreach(src ${ui_srcs})

  644.     target_sources("${NAME}-static" PRIVATE ${src})

  645.   endforeach()

  646. 

  647.   set_target_properties("${NAME}-static" PROPERTIES

  648.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  649.     OUTPUT_NAME "${NAME}"

  650.     PREFIX "")

  651. endfunction()

  652. 

  653. # dpf__add_dgl_cairo

  654. # ------------------------------------------------------------------------------

  655. #

  656. # Add the Cairo variant of DGL, if not already available.

  657. #

  658. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER)

  659.   if(TARGET dgl-cairo)

  660.     return()

  661.   endif()

  662. 

  663.   find_package(PkgConfig)

  664.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  665. 

  666.   link_directories(${CAIRO_LIBRARY_DIRS})

  667. 

  668.   dpf__add_static_library(dgl-cairo STATIC

  669.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  670.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  671.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  672.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  673.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  674.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  675.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  676.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  677.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  678.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  679.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  680.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  681.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  682.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  683.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  684.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  685.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  686.   if(SHARED_RESOURCES)

  687.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  688.   else()

  689.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  690.   endif()

  691.   if(APPLE)

  692.     target_sources(dgl-cairo PRIVATE

  693.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  694.   else()

  695.     target_sources(dgl-cairo PRIVATE

  696.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  697.   endif()

  698.   target_include_directories(dgl-cairo PUBLIC

  699.     "${DPF_ROOT_DIR}/dgl")

  700.   target_include_directories(dgl-cairo PUBLIC

  701.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  702. 

  703.   if(USE_FILE_BROWSER)

  704.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  705.   endif()

  706. 

  707.   dpf__add_dgl_system_libs()

  708.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  709. 

  710.   add_library(dgl-cairo-definitions INTERFACE)

  711.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  712. 

  713.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  714.   if(MINGW)

  715.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  716.   else()

  717.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  718.   endif()

  719.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  720. endfunction()

  721. 

  722. # dpf__add_dgl_external

  723. # ------------------------------------------------------------------------------

  724. #

  725. # Add the external variant of DGL, if not already available.

  726. #

  727. function(dpf__add_dgl_external USE_FILE_BROWSER)

  728.   if(TARGET dgl-external)

  729.     return()

  730.   endif()

  731. 

  732.   dpf__add_static_library(dgl-external STATIC

  733.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  734.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  735.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  736.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  737.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  738.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  739.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  740.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  741.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  742.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  743.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  744.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  745.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  746.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  747.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  748.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  749.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  750. 

  751.   if(APPLE)

  752.     target_sources(dgl-external PRIVATE

  753.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  754.   else()

  755.     target_sources(dgl-external PRIVATE

  756.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  757.   endif()

  758.   target_include_directories(dgl-external PUBLIC

  759.     "${DPF_ROOT_DIR}/dgl")

  760.   target_include_directories(dgl-external PUBLIC

  761.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  762. 

  763.   if(USE_FILE_BROWSER)

  764.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  765.   endif()

  766. 

  767.   dpf__add_dgl_system_libs()

  768.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  769.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  770. 

  771.   add_library(dgl-external-definitions INTERFACE)

  772.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  773. 

  774.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  775.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  776. endfunction()

  777. 

  778. # dpf__add_dgl_opengl

  779. # ------------------------------------------------------------------------------

  780. #

  781. # Add the OpenGL variant of DGL, if not already available.

  782. #

  783. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER)

  784.   if(TARGET dgl-opengl)

  785.     return()

  786.   endif()

  787. 

  788.   if(NOT OpenGL_GL_PREFERENCE)

  789.     set(OpenGL_GL_PREFERENCE "LEGACY")

  790.   endif()

  791. 

  792.   find_package(OpenGL REQUIRED)

  793. 

  794.   dpf__add_static_library(dgl-opengl STATIC

  795.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  796.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  797.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  798.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  799.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  800.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  801.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  802.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  803.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  804.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  805.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  806.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  807.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  808.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  809.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  810.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  811.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  812.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  813.   if(SHARED_RESOURCES)

  814.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  815.   else()

  816.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  817.   endif()

  818.   if(APPLE)

  819.     target_sources(dgl-opengl PRIVATE

  820.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  821.   else()

  822.     target_sources(dgl-opengl PRIVATE

  823.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  824.   endif()

  825.   target_include_directories(dgl-opengl PUBLIC

  826.     "${DPF_ROOT_DIR}/dgl")

  827.   target_include_directories(dgl-opengl PUBLIC

  828.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  829. 

  830.   if(APPLE)

  831.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  832.   endif()

  833. 

  834.   if(USE_FILE_BROWSER)

  835.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  836.   endif()

  837. 

  838.   dpf__add_dgl_system_libs()

  839.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  840. 

  841.   add_library(dgl-opengl-definitions INTERFACE)

  842.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  843. 

  844.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  845.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  846. endfunction()

  847. 

  848. # dpf__add_dgl_opengl3

  849. # ------------------------------------------------------------------------------

  850. #

  851. # Add the OpenGL3 variant of DGL, if not already available.

  852. #

  853. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER)

  854.   if(TARGET dgl-opengl3)

  855.     return()

  856.   endif()

  857. 

  858.   if(NOT OpenGL_GL_PREFERENCE)

  859.     set(OpenGL_GL_PREFERENCE "LEGACY")

  860.   endif()

  861. 

  862.   find_package(OpenGL REQUIRED)

  863. 

  864.   dpf__add_static_library(dgl-opengl3 STATIC

  865.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  866.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  867.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  868.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  869.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  870.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  871.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  883.   if(SHARED_RESOURCES)

  884.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  885.   else()

  886.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  887.   endif()

  888.   if(APPLE)

  889.     target_sources(dgl-opengl3 PRIVATE

  890.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  891.   else()

  892.     target_sources(dgl-opengl3 PRIVATE

  893.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  894.   endif()

  895.   target_include_directories(dgl-opengl3 PUBLIC

  896.     "${DPF_ROOT_DIR}/dgl")

  897.   target_include_directories(dgl-opengl3 PUBLIC

  898.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  899. 

  900.   if(APPLE)

  901.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  902.   endif()

  903. 

  904.   if(USE_FILE_BROWSER)

  905.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  906.   endif()

  907. 

  908.   dpf__add_dgl_system_libs()

  909.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  910. 

  911.   add_library(dgl-opengl3-definitions INTERFACE)

  912.   target_compile_definitions(dgl-opengl3-definitions INTERFACE "DGL_USE_OPENGL3" "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  913. 

  914.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  915.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  916. endfunction()

  917. 

  918. # dpf__add_dgl_vulkan

  919. # ------------------------------------------------------------------------------

  920. #

  921. # Add the Vulkan variant of DGL, if not already available.

  922. #

  923. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER)

  924.   if(TARGET dgl-vulkan)

  925.     return()

  926.   endif()

  927. 

  928.   find_package(Vulkan REQUIRED)

  929. 

  930.   dpf__add_static_library(dgl-vulkan STATIC

  931.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  932.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  933.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  934.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  935.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  936.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  937.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  938.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  939.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  940.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  941.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  944.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  945.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  946.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  948.   if(NO_SHARED_RESOURCES)

  949.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  950.   else()

  951.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  952.   endif()

  953.   if(APPLE)

  954.     target_sources(dgl-vulkan PRIVATE

  955.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  956.   else()

  957.     target_sources(dgl-vulkan PRIVATE

  958.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  959.   endif()

  960.   target_include_directories(dgl-vulkan PUBLIC

  961.     "${DPF_ROOT_DIR}/dgl")

  962.   target_include_directories(dgl-vulkan PUBLIC

  963.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  964. 

  965.   if(APPLE)

  966.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  967.   endif()

  968. 

  969.   if(USE_FILE_BROWSER)

  970.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  971.   endif()

  972. 

  973.   dpf__add_dgl_system_libs()

  974.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  975. 

  976.   add_library(dgl-vulkan-definitions INTERFACE)

  977.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  978. 

  979.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  980.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  981. endfunction()

  982. 

  983. # dpf__add_plugin_specific_ui_sources

  984. # ------------------------------------------------------------------------------

  985. #

  986. # Compile system specific files, for now it is just Objective-C code

  987. #

  988. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  989.   if(APPLE)

  990.     target_sources("${NAME}" PRIVATE

  991.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  992.   elseif(WIN32 AND USE_WEB_VIEW)

  993.     target_sources("${NAME}" PRIVATE

  994.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  995.   endif()

  996. endfunction()

  997. 

  998. # dpf__add_dgl_system_libs

  999. # ------------------------------------------------------------------------------

  1000. #

  1001. # Find system libraries required by DGL and add them as an interface target.

  1002. #

  1003. function(dpf__add_dgl_system_libs)

  1004.   if(TARGET dgl-system-libs)

  1005.     return()

  1006.   endif()

  1007.   add_library(dgl-system-libs INTERFACE)

  1008.   add_library(dgl-system-libs-definitions INTERFACE)

  1009.   if(APPLE)

  1010.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1011.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1012.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1013.   elseif(EMSCRIPTEN)

  1014.   elseif(HAIKU)

  1015.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1016.   elseif(WIN32)

  1017.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1018.   else()

  1019.     find_package(PkgConfig)

  1020.     pkg_check_modules(DBUS "dbus-1")

  1021.     if(DBUS_FOUND)

  1022.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1023.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1024.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1025.     endif()

  1026.     find_package(X11 REQUIRED)

  1027.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1028.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1029.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1030.     if(X11_Xcursor_FOUND)

  1031.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1032.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1033.     endif()

  1034.     if(X11_Xext_FOUND)

  1035.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1036.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1037.     endif()

  1038.     if(X11_Xrandr_FOUND)

  1039.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1040.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1041.     endif()

  1042.     if(X11_XSync_FOUND)

  1043.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1044.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1045.     endif()

  1046.    endif()

  1047. 

  1048.    if(MSVC)

  1049.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1050.      foreach(_gl_header "glext.h")

  1051.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1052.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1053.        endif()

  1054.      endforeach()

  1055.      foreach(_khr_header "khrplatform.h")

  1056.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1057.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1058.        endif()

  1059.      endforeach()

  1060.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1061.    endif()

  1062. 

  1063.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1064. endfunction()

  1065. 

  1066. # dpf__add_executable

  1067. # ------------------------------------------------------------------------------

  1068. #

  1069. # Adds an executable target, and set some default properties on the target.

  1070. #

  1071. function(dpf__add_executable NAME)

  1072.   add_executable("${NAME}" ${ARGN})

  1073.   dpf__set_target_defaults("${NAME}")

  1074.   if(MINGW)

  1075.     target_link_libraries("${NAME}" PRIVATE "-static")

  1076.   endif()

  1077. endfunction()

  1078. 

  1079. # dpf__add_module

  1080. # ------------------------------------------------------------------------------

  1081. #

  1082. # Adds a module target, and set some default properties on the target.

  1083. #

  1084. function(dpf__add_module NAME)

  1085.   add_library("${NAME}" MODULE ${ARGN})

  1086.   dpf__set_target_defaults("${NAME}")

  1087.   if(APPLE)

  1088.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1089.   elseif(MINGW)

  1090.     target_link_libraries("${NAME}" PRIVATE "-static")

  1091.   endif()

  1092. endfunction()

  1093. 

  1094. # dpf__add_static_library

  1095. # ------------------------------------------------------------------------------

  1096. #

  1097. # Adds a static library target, and set some default properties on the target.

  1098. #

  1099. function(dpf__add_static_library NAME)

  1100.   add_library("${NAME}" STATIC ${ARGN})

  1101.   dpf__set_target_defaults("${NAME}")

  1102. endfunction()

  1103. 

  1104. # dpf__set_module_export_list

  1105. # ------------------------------------------------------------------------------

  1106. #

  1107. # Applies a list of exported symbols to the module target.

  1108. #

  1109. function(dpf__set_module_export_list NAME EXPORTS)

  1110.   if(WIN32)

  1111.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1112.   elseif(APPLE)

  1113.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1114.       "-Xlinker" "-exported_symbols_list"

  1115.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1116.   else()

  1117.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1118.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1119.   endif()

  1120. endfunction()

  1121. 

  1122. # dpf__set_target_defaults

  1123. # ------------------------------------------------------------------------------

  1124. #

  1125. # Set default properties which must apply to all DPF-defined targets.

  1126. #

  1127. function(dpf__set_target_defaults NAME)

  1128.   set_target_properties("${NAME}" PROPERTIES

  1129.     POSITION_INDEPENDENT_CODE TRUE

  1130.     C_VISIBILITY_PRESET "hidden"

  1131.     CXX_VISIBILITY_PRESET "hidden"

  1132.     VISIBILITY_INLINES_HIDDEN TRUE)

  1133.   if(WIN32)

  1134.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1135.   endif()

  1136.   if (MINGW)

  1137.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1138.   endif()

  1139.   if (MSVC)

  1140.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1141.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1142.   endif()

  1143.   if (CMAKE_COMPILER_IS_GNUCXX)

  1144.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1145.   endif()

  1146. endfunction()

  1147. 

  1148. # dpf__add_plugin_main

  1149. # ------------------------------------------------------------------------------

  1150. #

  1151. # Adds plugin code to the given target.

  1152. #

  1153. function(dpf__add_plugin_main NAME TARGET)

  1154.   target_sources("${NAME}" PRIVATE

  1155.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1156.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1157. endfunction()

  1158. 

  1159. # dpf__add_ui_main

  1160. # ------------------------------------------------------------------------------

  1161. #

  1162. # Adds UI code to the given target (only if the target has UI).

  1163. #

  1164. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1165.   if(HAS_UI)

  1166.     target_sources("${NAME}" PRIVATE

  1167.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1168.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1169.   endif()

  1170. endfunction()

  1171. 

  1172. # dpf__add_plugin_target_definition

  1173. # ------------------------------------------------------------------------------

  1174. #

  1175. # Adds the plugins target macro definition.

  1176. # This selects which entry file is compiled according to the target type.

  1177. #

  1178. function(dpf__add_plugin_target_definition NAME TARGET)

  1179.   string(TOUPPER "${TARGET}" _upperTarget)

  1180.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1181. endfunction()

  1182. 

  1183. # dpf__add_lv2_ttl_generator

  1184. # ------------------------------------------------------------------------------

  1185. #

  1186. # Build the LV2 TTL generator.

  1187. #

  1188. function(dpf__add_lv2_ttl_generator)

  1189.   if(TARGET lv2_ttl_generator)

  1190.     return()

  1191.   endif()

  1192.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1193.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1194.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1195.   endif()

  1196. endfunction()

  1197. 

  1198. # dpf__ensure_sources_non_empty

  1199. # ------------------------------------------------------------------------------

  1200. #

  1201. # Ensure the given source list contains at least one file.

  1202. # The function appends an empty source file to the list if necessary.

  1203. # This is useful when CMake does not permit to add targets without sources.

  1204. #

  1205. function(dpf__ensure_sources_non_empty VAR)

  1206.   if(NOT "" STREQUAL "${${VAR}}")

  1207.     return()

  1208.   endif()

  1209.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1210.   if(NOT EXISTS "${_file}")

  1211.     file(WRITE "${_file}" "")

  1212.   endif()

  1213.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1214. endfunction()

  1215. 

  1216. # dpf__create_dummy_source_list

  1217. # ------------------------------------------------------------------------------

  1218. #

  1219. # Create a dummy source list which is equivalent to compiling nothing.

  1220. # This is only for compatibility with older CMake versions, which refuse to add

  1221. # targets without any sources.

  1222. #

  1223. macro(dpf__create_dummy_source_list VAR)

  1224.   set("${VAR}")

  1225.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1226.     dpf__ensure_sources_non_empty("${VAR}")

  1227.   endif()

  1228. endmacro()

  1229. 

  1230. # dpf__target_link_directories

  1231. # ------------------------------------------------------------------------------

  1232. #

  1233. # Call `target_link_directories` if cmake >= 3.13,

  1234. # otherwise fallback to global `link_directories`.

  1235. #

  1236. macro(dpf__target_link_directories NAME DIRS)

  1237.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1238.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1239.   else()

  1240.     link_directories(${DIRS})

  1241.   endif()

  1242. endmacro()

  1243. 

  1244. # dpf__warn_once

  1245. # ------------------------------------------------------------------------------

  1246. #

  1247. # Prints a warning message once only.

  1248. #

  1249. function(dpf__warn_once_only TOKEN MESSAGE)

  1250.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1251.   if(NOT _warned)

  1252.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1253.     message(WARNING "${MESSAGE}")

  1254.   endif()

  1255. endfunction()