DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2156 Commits
7 Branches
295MB
Tree: 4d783d76cb
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '4d783d76cb'
${ noResults }
DPF/cmake/DPF-plugin.cmake

942 lines
33KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`, `external`

  79. #

  80. #   `FILES_COMMON` <file1>...<fileN>

  81. #       list of sources which are part of both DSP and UI

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `MODGUI_CLASS_NAME`

  91. #       class name to use for modgui builds

  92. #

  93. #   `MONOLITHIC`

  94. #       build LV2 as a single binary for UI and DSP

  95. #

  96. #   `NO_SHARED_RESOURCES`

  97. #       do not build DPF shared resources (fonts, etc)

  98. #

  99. function(dpf_add_plugin NAME)

  100.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  101.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  102.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  103.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  104. 

  105.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  106.     set(_dpf_plugin_UI_TYPE "opengl")

  107.   endif()

  108. 

  109.   set(_dgl_library)

  110.   set(_dgl_external OFF)

  111.   if(_dpf_plugin_FILES_UI)

  112.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  113.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  114.       set(_dgl_library dgl-cairo)

  115.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  116.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  117.       set(_dgl_library dgl-opengl)

  118.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  119.       set(_dgl_external ON)

  120.     else()

  121.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  122.     endif()

  123.   endif()

  124. 

  125.   set(_dgl_has_ui OFF)

  126.   if(_dgl_library OR _dgl_external)

  127.     set(_dgl_has_ui ON)

  128.   endif()

  129. 

  130.   ###

  131.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  132.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  133.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  134. 

  135.   ###

  136.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  137.   target_include_directories("${NAME}" PUBLIC

  138.     "${DPF_ROOT_DIR}/distrho")

  139. 

  140.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  141.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  142.   endif()

  143. 

  144.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  145.     target_link_libraries("${NAME}" PRIVATE "dl")

  146.   endif()

  147. 

  148.   if(_dgl_library AND NOT _dgl_external)

  149.     # make sure that all code will see DGL_* definitions

  150.     target_link_libraries("${NAME}" PUBLIC

  151.       "${_dgl_library}-definitions"

  152.       dgl-system-libs-definitions

  153.       dgl-system-libs)

  154.   endif()

  155. 

  156.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  157.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  158. 

  159.   if(_dgl_library AND NOT _dgl_external)

  160.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  161.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  162.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  163.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  164.     endif()

  165.     # add the files containing Objective-C classes

  166.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  167.   elseif(_dgl_external)

  168.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  169.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}")

  170.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  171.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  172.     endif()

  173.     # add the files containing Objective-C classes

  174.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  175.   else()

  176.     add_library("${NAME}-ui" INTERFACE)

  177.   endif()

  178. 

  179.   ###

  180.   foreach(_target ${_dpf_plugin_TARGETS})

  181.     if(_target STREQUAL "jack")

  182.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  183.     elseif(_target STREQUAL "ladspa")

  184.       dpf__build_ladspa("${NAME}")

  185.     elseif(_target STREQUAL "dssi")

  186.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  187.     elseif(_target STREQUAL "lv2")

  188.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}")

  189.     elseif(_target STREQUAL "vst2")

  190.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}")

  191.     elseif(_target STREQUAL "vst3")

  192.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}")

  193.     elseif(_target STREQUAL "clap")

  194.       dpf__build_clap("${NAME}" "${_dgl_has_ui}")

  195.     else()

  196.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  197.     endif()

  198.   endforeach()

  199. endfunction()

  200. 

  201. # ------------------------------------------------------------------------------

  202. # DPF private functions (prefixed with `dpf__`)

  203. # ------------------------------------------------------------------------------

  204. 

  205. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  206. #       to the output directory.

  207. #

  208. 

  209. # dpf__build_jack

  210. # ------------------------------------------------------------------------------

  211. #

  212. # Add build rules for a JACK/Standalone program.

  213. #

  214. function(dpf__build_jack NAME HAS_UI)

  215.   dpf__create_dummy_source_list(_no_srcs)

  216. 

  217.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  218.   dpf__add_plugin_main("${NAME}-jack" "jack")

  219.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  220.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  221.   set_target_properties("${NAME}-jack" PROPERTIES

  222.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  223.     OUTPUT_NAME "${NAME}")

  224. 

  225.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  226.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  227. 

  228.   find_package(PkgConfig)

  229.   pkg_check_modules(SDL2 "sdl2")

  230.   if(SDL2_FOUND)

  231.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  232.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  233.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  234.     dpf__target_link_directories("${NAME}-jack" ${SDL2_STATIC_LIBRARY_DIRS})

  235.   endif()

  236. 

  237.   if(APPLE OR WIN32)

  238.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  239.   else()

  240.     find_package(Threads)

  241.     pkg_check_modules(ALSA "alsa")

  242.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  243.     if(ALSA_FOUND)

  244.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  245.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  246.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  247.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  248.     endif()

  249.     if(PULSEAUDIO_FOUND)

  250.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  251.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  252.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  253.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  254.     endif()

  255.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  256.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  257.     endif()

  258.   endif()

  259. 

  260.   # for RtAudio native fallback

  261.   if(APPLE)

  262.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  263.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  264.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  265.     target_link_libraries("${NAME}-jack" PRIVATE

  266.       "${APPLE_COREAUDIO_FRAMEWORK}"

  267.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  268.       "${APPLE_COREMIDI_FRAMEWORK}")

  269.   elseif(WIN32)

  270.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  271.     if(HAS_UI AND MINGW)

  272.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  273.     endif()

  274.   endif()

  275. endfunction()

  276. 

  277. # dpf__build_ladspa

  278. # ------------------------------------------------------------------------------

  279. #

  280. # Add build rules for a LADSPA plugin.

  281. #

  282. function(dpf__build_ladspa NAME)

  283.   dpf__create_dummy_source_list(_no_srcs)

  284. 

  285.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  286.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  287.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  288.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  289.   set_target_properties("${NAME}-ladspa" PROPERTIES

  290.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  291.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  292.     OUTPUT_NAME "${NAME}-ladspa"

  293.     PREFIX "")

  294. endfunction()

  295. 

  296. # dpf__build_dssi

  297. # ------------------------------------------------------------------------------

  298. #

  299. # Add build rules for a DSSI plugin.

  300. #

  301. function(dpf__build_dssi NAME HAS_UI)

  302.   find_package(PkgConfig)

  303.   pkg_check_modules(LIBLO "liblo")

  304.   if(NOT LIBLO_FOUND)

  305.     dpf__warn_once_only(missing_liblo

  306.       "liblo is not found, skipping the `dssi` plugin targets")

  307.     return()

  308.   endif()

  309. 

  310.   dpf__create_dummy_source_list(_no_srcs)

  311. 

  312.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  313.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  314.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  315.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  316.   set_target_properties("${NAME}-dssi" PROPERTIES

  317.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  318.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  319.     OUTPUT_NAME "${NAME}-dssi"

  320.     PREFIX "")

  321. 

  322.   if(HAS_UI)

  323.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  324.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  325.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  326.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  327.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  328.       OUTPUT_NAME "${NAME}_ui")

  329. 

  330.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  331.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  332.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  333.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  334.   endif()

  335. endfunction()

  336. 

  337. # dpf__build_lv2

  338. # ------------------------------------------------------------------------------

  339. #

  340. # Add build rules for an LV2 plugin.

  341. #

  342. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC)

  343.   dpf__create_dummy_source_list(_no_srcs)

  344. 

  345.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  346.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  347.   if(HAS_UI AND MONOLITHIC)

  348.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  349.   else()

  350.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  351.   endif()

  352.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  353.   set_target_properties("${NAME}-lv2" PROPERTIES

  354.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  355.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  356.     OUTPUT_NAME "${NAME}_dsp"

  357.     PREFIX "")

  358. 

  359.   if(HAS_UI)

  360.     if(MONOLITHIC)

  361.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  362.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  363.       set_target_properties("${NAME}-lv2" PROPERTIES

  364.         OUTPUT_NAME "${NAME}")

  365.     else()

  366.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  367.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  368.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  369.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  370.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  371.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  372.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  373.         OUTPUT_NAME "${NAME}_ui"

  374.         PREFIX "")

  375.     endif()

  376.   endif()

  377. 

  378.   dpf__add_lv2_ttl_generator()

  379.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  380. 

  381.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  382.     COMMAND

  383.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  384.     "$<TARGET_FILE:lv2_ttl_generator>"

  385.     "$<TARGET_FILE:${NAME}-lv2>"

  386.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  387.     DEPENDS lv2_ttl_generator)

  388. endfunction()

  389. 

  390. # dpf__build_vst2

  391. # ------------------------------------------------------------------------------

  392. #

  393. # Add build rules for a VST2 plugin.

  394. #

  395. function(dpf__build_vst2 NAME HAS_UI)

  396.   dpf__create_dummy_source_list(_no_srcs)

  397. 

  398.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  399.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  400.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  401.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  402.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  403.   set_target_properties("${NAME}-vst2" PROPERTIES

  404.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  405.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  406.     OUTPUT_NAME "${NAME}-vst2"

  407.     PREFIX "")

  408.   if(APPLE)

  409.     set_target_properties("${NAME}-vst2" PROPERTIES

  410.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  411.       OUTPUT_NAME "${NAME}"

  412.       SUFFIX "")

  413.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  414.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  415.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  416.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  417.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  418.   endif()

  419. endfunction()

  420. 

  421. # dpf__determine_vst3_package_architecture

  422. # ------------------------------------------------------------------------------

  423. #

  424. # Determines the package architecture for a VST3 plugin target.

  425. #

  426. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  427.   # if set by variable, override the detection

  428.   if(DPF_VST3_ARCHITECTURE)

  429.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  430.     return()

  431.   endif()

  432. 

  433.   # not used on Apple, which supports universal binary

  434.   if(APPLE)

  435.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  436.     return()

  437.   endif()

  438. 

  439.   # identify the target processor (special case of MSVC, problematic sometimes)

  440.   if(MSVC)

  441.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  442.   else()

  443.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  444.   endif()

  445. 

  446.   # transform the processor name to a format that VST3 recognizes

  447.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  448.     set(vst3_package_arch "x86_64")

  449.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  450.     if(WIN32)

  451.       set(vst3_package_arch "x86")

  452.     else()

  453.       set(vst3_package_arch "i386")

  454.     endif()

  455.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  456.     set(vst3_package_arch "${vst3_system_arch}")

  457.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  458.     set(vst3_package_arch "aarch64")

  459.   else()

  460.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  461.   endif()

  462. 

  463.   # TODO: the detections for Windows arm/arm64 when supported

  464. 

  465.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  466. endfunction()

  467. 

  468. # dpf__build_vst3

  469. # ------------------------------------------------------------------------------

  470. #

  471. # Add build rules for a VST3 plugin.

  472. #

  473. function(dpf__build_vst3 NAME HAS_UI)

  474.   dpf__determine_vst3_package_architecture(vst3_arch)

  475. 

  476.   dpf__create_dummy_source_list(_no_srcs)

  477. 

  478.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  479.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  480.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  481.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  482.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  483.   set_target_properties("${NAME}-vst3" PROPERTIES

  484.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  485.     OUTPUT_NAME "${NAME}"

  486.     PREFIX "")

  487. 

  488.   if(APPLE)

  489.     set_target_properties("${NAME}-vst3" PROPERTIES

  490.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  491.       SUFFIX "")

  492.   elseif(WIN32)

  493.     set_target_properties("${NAME}-vst3" PROPERTIES

  494.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  495.   else()

  496.     set_target_properties("${NAME}-vst3" PROPERTIES

  497.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  498.   endif()

  499. 

  500.   if(APPLE)

  501.     # Uses the same macOS bundle template as VST2

  502.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  503.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  504.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  505.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  506.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  507.   endif()

  508. endfunction()

  509. 

  510. # dpf__build_clap

  511. # ------------------------------------------------------------------------------

  512. #

  513. # Add build rules for a VST2 plugin.

  514. #

  515. function(dpf__build_clap NAME HAS_UI)

  516.   dpf__create_dummy_source_list(_no_srcs)

  517. 

  518.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  519.   dpf__add_plugin_main("${NAME}-clap" "clap")

  520.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  521.   dpf__set_module_export_list("${NAME}-clap" "clap")

  522.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  523.   set_target_properties("${NAME}-clap" PROPERTIES

  524.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  525.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  526.     OUTPUT_NAME "${NAME}"

  527.     PREFIX ""

  528.     SUFFIX ".clap")

  529. 

  530.   if(APPLE)

  531.     set_target_properties("${NAME}-clap" PROPERTIES

  532.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  533.       OUTPUT_NAME "${NAME}"

  534.       SUFFIX "")

  535.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  536.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  537.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  538.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  539.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  540.   endif()

  541. endfunction()

  542. 

  543. # dpf__add_dgl_cairo

  544. # ------------------------------------------------------------------------------

  545. #

  546. # Add the Cairo variant of DGL, if not already available.

  547. #

  548. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  549.   if(TARGET dgl-cairo)

  550.     return()

  551.   endif()

  552. 

  553.   find_package(PkgConfig)

  554.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  555. 

  556.   link_directories(${CAIRO_LIBRARY_DIRS})

  557. 

  558.   dpf__add_static_library(dgl-cairo STATIC

  559.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  560.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  561.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  562.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  563.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  564.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  565.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  566.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  567.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  568.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  569.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  570.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  571.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  572.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  573.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  574.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  575.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  576.   if(NO_SHARED_RESOURCES)

  577.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  578.   else()

  579.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  580.   endif()

  581.   if(NOT APPLE)

  582.     target_sources(dgl-cairo PRIVATE

  583.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  584.   else()

  585.     target_sources(dgl-cairo PRIVATE

  586.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  587.   endif()

  588.   target_include_directories(dgl-cairo PUBLIC

  589.     "${DPF_ROOT_DIR}/dgl")

  590.   target_include_directories(dgl-cairo PUBLIC

  591.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  592. 

  593.   dpf__add_dgl_system_libs()

  594.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  595. 

  596.   add_library(dgl-cairo-definitions INTERFACE)

  597.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  598. 

  599.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  600.   if(MINGW)

  601.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  602.   else()

  603.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  604.   endif()

  605.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  606. endfunction()

  607. 

  608. # dpf__add_dgl_opengl

  609. # ------------------------------------------------------------------------------

  610. #

  611. # Add the OpenGL variant of DGL, if not already available.

  612. #

  613. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  614.   if(TARGET dgl-opengl)

  615.     return()

  616.   endif()

  617. 

  618.   if(NOT OpenGL_GL_PREFERENCE)

  619.     set(OpenGL_GL_PREFERENCE "LEGACY")

  620.   endif()

  621. 

  622.   find_package(OpenGL REQUIRED)

  623. 

  624.   dpf__add_static_library(dgl-opengl STATIC

  625.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  626.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  627.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  628.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  629.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  630.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  631.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  632.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  633.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  634.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  635.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  636.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  637.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  638.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  639.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  640.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  641.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  642.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  643.   if(NO_SHARED_RESOURCES)

  644.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  645.   else()

  646.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  647.   endif()

  648.   if(NOT APPLE)

  649.     target_sources(dgl-opengl PRIVATE

  650.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  651.   else()

  652.     target_sources(dgl-opengl PRIVATE

  653.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  654.   endif()

  655.   target_include_directories(dgl-opengl PUBLIC

  656.     "${DPF_ROOT_DIR}/dgl")

  657.   target_include_directories(dgl-opengl PUBLIC

  658.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  659. 

  660.   if(APPLE)

  661.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  662.   endif()

  663. 

  664.   dpf__add_dgl_system_libs()

  665.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  666. 

  667.   add_library(dgl-opengl-definitions INTERFACE)

  668.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  669. 

  670.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  671.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  672. endfunction()

  673. 

  674. # dpf__add_plugin_specific_ui_sources

  675. # ------------------------------------------------------------------------------

  676. #

  677. # Compile system specific files, for now it is just Objective-C code

  678. #

  679. function(dpf__add_plugin_specific_ui_sources NAME)

  680.   if(APPLE)

  681.     target_sources("${NAME}" PRIVATE

  682.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  683.   endif()

  684. endfunction()

  685. 

  686. # dpf__add_dgl_system_libs

  687. # ------------------------------------------------------------------------------

  688. #

  689. # Find system libraries required by DGL and add them as an interface target.

  690. #

  691. function(dpf__add_dgl_system_libs)

  692.   if(TARGET dgl-system-libs)

  693.     return()

  694.   endif()

  695.   add_library(dgl-system-libs INTERFACE)

  696.   add_library(dgl-system-libs-definitions INTERFACE)

  697.   if(APPLE)

  698.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  699.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  700.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  701.   elseif(EMSCRIPTEN)

  702.   elseif(HAIKU)

  703.     target_link_libraries(dgl-system-libs INTERFACE "be")

  704.   elseif(WIN32)

  705.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  706.   else()

  707.     find_package(PkgConfig)

  708.     pkg_check_modules(DBUS "dbus-1")

  709.     if(DBUS_FOUND)

  710.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  711.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  712.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  713.     endif()

  714.     find_package(X11 REQUIRED)

  715.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  716.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  717.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  718.     if(X11_Xcursor_FOUND)

  719.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  720.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  721.     endif()

  722.     if(X11_Xext_FOUND)

  723.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  724.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  725.     endif()

  726.     if(X11_Xrandr_FOUND)

  727.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  728.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  729.     endif()

  730.     if(X11_XSync_FOUND)

  731.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  732.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  733.     endif()

  734.    endif()

  735. 

  736.    if(MSVC)

  737.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  738.      foreach(_gl_header "glext.h")

  739.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  740.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  741.        endif()

  742.      endforeach()

  743.      foreach(_khr_header "khrplatform.h")

  744.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  745.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  746.        endif()

  747.      endforeach()

  748.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  749.    endif()

  750. 

  751.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  752. endfunction()

  753. 

  754. # dpf__add_executable

  755. # ------------------------------------------------------------------------------

  756. #

  757. # Adds an executable target, and set some default properties on the target.

  758. #

  759. function(dpf__add_executable NAME)

  760.   add_executable("${NAME}" ${ARGN})

  761.   dpf__set_target_defaults("${NAME}")

  762.   if(MINGW)

  763.     target_link_libraries("${NAME}" PRIVATE "-static")

  764.   endif()

  765. endfunction()

  766. 

  767. # dpf__add_module

  768. # ------------------------------------------------------------------------------

  769. #

  770. # Adds a module target, and set some default properties on the target.

  771. #

  772. function(dpf__add_module NAME)

  773.   add_library("${NAME}" MODULE ${ARGN})

  774.   dpf__set_target_defaults("${NAME}")

  775.   if(MINGW)

  776.     target_link_libraries("${NAME}" PRIVATE "-static")

  777.   endif()

  778. endfunction()

  779. 

  780. # dpf__add_static_library

  781. # ------------------------------------------------------------------------------

  782. #

  783. # Adds a static library target, and set some default properties on the target.

  784. #

  785. function(dpf__add_static_library NAME)

  786.   add_library("${NAME}" STATIC ${ARGN})

  787.   dpf__set_target_defaults("${NAME}")

  788. endfunction()

  789. 

  790. # dpf__set_module_export_list

  791. # ------------------------------------------------------------------------------

  792. #

  793. # Applies a list of exported symbols to the module target.

  794. #

  795. function(dpf__set_module_export_list NAME EXPORTS)

  796.   if(WIN32)

  797.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  798.   elseif(APPLE)

  799.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  800.       "-Xlinker" "-exported_symbols_list"

  801.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  802.   else()

  803.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  804.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  805.   endif()

  806. endfunction()

  807. 

  808. # dpf__set_target_defaults

  809. # ------------------------------------------------------------------------------

  810. #

  811. # Set default properties which must apply to all DPF-defined targets.

  812. #

  813. function(dpf__set_target_defaults NAME)

  814.   set_target_properties("${NAME}" PROPERTIES

  815.     POSITION_INDEPENDENT_CODE TRUE

  816.     C_VISIBILITY_PRESET "hidden"

  817.     CXX_VISIBILITY_PRESET "hidden"

  818.     VISIBILITY_INLINES_HIDDEN TRUE)

  819.   if(WIN32)

  820.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  821.   endif()

  822.   if (MINGW)

  823.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  824.   endif()

  825.   if (MSVC)

  826.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  827.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  828.   endif()

  829.   if (CMAKE_COMPILER_IS_GNUCXX)

  830.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  831.   endif()

  832. endfunction()

  833. 

  834. # dpf__add_plugin_main

  835. # ------------------------------------------------------------------------------

  836. #

  837. # Adds plugin code to the given target.

  838. #

  839. function(dpf__add_plugin_main NAME TARGET)

  840.   target_sources("${NAME}" PRIVATE

  841.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  842.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  843. endfunction()

  844. 

  845. # dpf__add_ui_main

  846. # ------------------------------------------------------------------------------

  847. #

  848. # Adds UI code to the given target (only if the target has UI).

  849. #

  850. function(dpf__add_ui_main NAME TARGET HAS_UI)

  851.   if(HAS_UI)

  852.     target_sources("${NAME}" PRIVATE

  853.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  854.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  855.   endif()

  856. endfunction()

  857. 

  858. # dpf__add_plugin_target_definition

  859. # ------------------------------------------------------------------------------

  860. #

  861. # Adds the plugins target macro definition.

  862. # This selects which entry file is compiled according to the target type.

  863. #

  864. function(dpf__add_plugin_target_definition NAME TARGET)

  865.   string(TOUPPER "${TARGET}" _upperTarget)

  866.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  867. endfunction()

  868. 

  869. # dpf__add_lv2_ttl_generator

  870. # ------------------------------------------------------------------------------

  871. #

  872. # Build the LV2 TTL generator.

  873. #

  874. function(dpf__add_lv2_ttl_generator)

  875.   if(TARGET lv2_ttl_generator)

  876.     return()

  877.   endif()

  878.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  879.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  880.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  881.   endif()

  882. endfunction()

  883. 

  884. # dpf__ensure_sources_non_empty

  885. # ------------------------------------------------------------------------------

  886. #

  887. # Ensure the given source list contains at least one file.

  888. # The function appends an empty source file to the list if necessary.

  889. # This is useful when CMake does not permit to add targets without sources.

  890. #

  891. function(dpf__ensure_sources_non_empty VAR)

  892.   if(NOT "" STREQUAL "${${VAR}}")

  893.     return()

  894.   endif()

  895.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  896.   if(NOT EXISTS "${_file}")

  897.     file(WRITE "${_file}" "")

  898.   endif()

  899.   set("${VAR}" "${_file}" PARENT_SCOPE)

  900. endfunction()

  901. 

  902. # dpf__create_dummy_source_list

  903. # ------------------------------------------------------------------------------

  904. #

  905. # Create a dummy source list which is equivalent to compiling nothing.

  906. # This is only for compatibility with older CMake versions, which refuse to add

  907. # targets without any sources.

  908. #

  909. macro(dpf__create_dummy_source_list VAR)

  910.   set("${VAR}")

  911.   if(CMAKE_VERSION VERSION_LESS "3.11")

  912.     dpf__ensure_sources_non_empty("${VAR}")

  913.   endif()

  914. endmacro()

  915. 

  916. # dpf__target_link_directories

  917. # ------------------------------------------------------------------------------

  918. #

  919. # Call `target_link_directories` if cmake >= 3.13,

  920. # otherwise fallback to global `link_directories`.

  921. #

  922. macro(dpf__target_link_directories NAME DIRS)

  923.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  924.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  925.   else()

  926.     link_directories(${DIRS})

  927.   endif()

  928. endmacro()

  929. 

  930. # dpf__warn_once

  931. # ------------------------------------------------------------------------------

  932. #

  933. # Prints a warning message once only.

  934. #

  935. function(dpf__warn_once_only TOKEN MESSAGE)

  936.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  937.   if(NOT _warned)

  938.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  939.     message(WARNING "${MESSAGE}")

  940.   endif()

  941. endfunction()