DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2031 Commits
7 Branches
60MB
Tree: 4b284735c9
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '4b284735c9'
${ noResults }
DPF/cmake/DPF-plugin.cmake

894 lines
31KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type: `opengl` (default), `cairo`

  79. #

  80. #   `MONOLITHIC`

  81. #       build LV2 as a single binary for UI and DSP

  82. #

  83. #   `FILES_DSP` <file1>...<fileN>

  84. #       list of sources which are part of the DSP

  85. #

  86. #   `FILES_UI` <file1>...<fileN>

  87. #       list of sources which are part of the UI

  88. #       empty indicates the plugin does not have UI

  89. #

  90. #   `FILES_COMMON` <file1>...<fileN>

  91. #       list of sources which are part of both DSP and UI

  92. #

  93. function(dpf_add_plugin NAME)

  94.   set(options MONOLITHIC NO_SHARED_RESOURCES)

  95.   set(oneValueArgs UI_TYPE)

  96.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  97.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  98. 

  99.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  100.     set(_dpf_plugin_UI_TYPE "opengl")

  101.   endif()

  102. 

  103.   set(_dgl_library)

  104.   if(_dpf_plugin_FILES_UI)

  105.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  106.       dpf__add_dgl_cairo("${_dpf_plugin_NO_SHARED_RESOURCES}")

  107.       set(_dgl_library dgl-cairo)

  108.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  109.       dpf__add_dgl_opengl("${_dpf_plugin_NO_SHARED_RESOURCES}")

  110.       set(_dgl_library dgl-opengl)

  111.     else()

  112.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  113.     endif()

  114.   endif()

  115. 

  116.   ###

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  119.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  120. 

  121.   ###

  122.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  123.   target_include_directories("${NAME}" PUBLIC

  124.     "${DPF_ROOT_DIR}/distrho")

  125. 

  126.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  127.     target_link_libraries("${NAME}" PRIVATE "dl")

  128.   endif()

  129. 

  130.   if(_dgl_library)

  131.     # make sure that all code will see DGL_* definitions

  132.     target_link_libraries("${NAME}" PUBLIC

  133.       "${_dgl_library}-definitions"

  134.       dgl-system-libs-definitions)

  135.   endif()

  136. 

  137.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  138.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  139. 

  140.   if(_dgl_library)

  141.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  142.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  143.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  144.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  145.     endif()

  146.     # add the files containing Objective-C classes

  147.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  148.   else()

  149.     add_library("${NAME}-ui" INTERFACE)

  150.   endif()

  151. 

  152.   ###

  153.   foreach(_target ${_dpf_plugin_TARGETS})

  154.     if(_target STREQUAL "jack")

  155.       dpf__build_jack("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "ladspa")

  157.       dpf__build_ladspa("${NAME}")

  158.     elseif(_target STREQUAL "dssi")

  159.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  160.     elseif(_target STREQUAL "lv2")

  161.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  162.     elseif(_target STREQUAL "vst2")

  163.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  164.     elseif(_target STREQUAL "vst3")

  165.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  166.     elseif(_target STREQUAL "clap")

  167.       dpf__build_clap("${NAME}" "${_dgl_library}")

  168.     else()

  169.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  170.     endif()

  171.   endforeach()

  172. endfunction()

  173. 

  174. # ------------------------------------------------------------------------------

  175. # DPF private functions (prefixed with `dpf__`)

  176. # ------------------------------------------------------------------------------

  177. 

  178. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  179. #       to the output directory.

  180. #

  181. 

  182. # dpf__build_jack

  183. # ------------------------------------------------------------------------------

  184. #

  185. # Add build rules for a JACK/Standalone program.

  186. #

  187. function(dpf__build_jack NAME DGL_LIBRARY)

  188.   dpf__create_dummy_source_list(_no_srcs)

  189. 

  190.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  191.   dpf__add_plugin_main("${NAME}-jack" "jack")

  192.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  193.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  194.   set_target_properties("${NAME}-jack" PROPERTIES

  195.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  196.     OUTPUT_NAME "${NAME}")

  197. 

  198.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  199. 

  200.   find_package(PkgConfig)

  201.   pkg_check_modules(SDL2 "sdl2")

  202.   if(SDL2_FOUND)

  203.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  204.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_INCLUDE_DIRS})

  205.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_LIBRARIES})

  206.     dpf__target_link_directories("${NAME}-jack" ${SDL2_LIBRARY_DIRS})

  207.   endif()

  208. 

  209.   if(APPLE OR WIN32)

  210.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  211.   else()

  212.     pkg_check_modules(ALSA "alsa")

  213.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  214.     if(ALSA_FOUND)

  215.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  216.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  217.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES})

  218.       dpf__target_link_directories("${NAME}-jack" ${ALSA_LIBRARY_DIRS})

  219.     endif()

  220.     if(PULSEAUDIO_FOUND)

  221.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  222.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  223.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES})

  224.       dpf__target_link_directories("${NAME}-jack" ${PULSEAUDIO_LIBRARY_DIRS})

  225.     endif()

  226.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  227.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  228.     endif()

  229.   endif()

  230. 

  231.   # for RtAudio native fallback

  232.   if(APPLE)

  233.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  234.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  235.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  236.     target_link_libraries("${NAME}-jack" PRIVATE

  237.       "${APPLE_COREAUDIO_FRAMEWORK}"

  238.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  239.       "${APPLE_COREMIDI_FRAMEWORK}")

  240.   endif()

  241. endfunction()

  242. 

  243. # dpf__build_ladspa

  244. # ------------------------------------------------------------------------------

  245. #

  246. # Add build rules for a LADSPA plugin.

  247. #

  248. function(dpf__build_ladspa NAME)

  249.   dpf__create_dummy_source_list(_no_srcs)

  250. 

  251.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  252.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  253.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  254.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  255.   set_target_properties("${NAME}-ladspa" PROPERTIES

  256.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  257.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  258.     OUTPUT_NAME "${NAME}-ladspa"

  259.     PREFIX "")

  260. endfunction()

  261. 

  262. # dpf__build_dssi

  263. # ------------------------------------------------------------------------------

  264. #

  265. # Add build rules for a DSSI plugin.

  266. #

  267. function(dpf__build_dssi NAME DGL_LIBRARY)

  268.   find_package(PkgConfig)

  269.   pkg_check_modules(LIBLO "liblo")

  270.   if(NOT LIBLO_FOUND)

  271.     dpf__warn_once_only(missing_liblo

  272.       "liblo is not found, skipping the `dssi` plugin targets")

  273.     return()

  274.   endif()

  275. 

  276.   dpf__create_dummy_source_list(_no_srcs)

  277. 

  278.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  279.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  280.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  281.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  282.   set_target_properties("${NAME}-dssi" PROPERTIES

  283.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  284.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  285.     OUTPUT_NAME "${NAME}-dssi"

  286.     PREFIX "")

  287. 

  288.   if(DGL_LIBRARY)

  289.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  290.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  291.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  292.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  293.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  294.       OUTPUT_NAME "${NAME}_ui")

  295. 

  296.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  297.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  298.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  299.     dpf__target_link_directories("${NAME}-dssi-ui" ${LIBLO_LIBRARY_DIRS})

  300.   endif()

  301. endfunction()

  302. 

  303. # dpf__build_lv2

  304. # ------------------------------------------------------------------------------

  305. #

  306. # Add build rules for an LV2 plugin.

  307. #

  308. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  309.   dpf__create_dummy_source_list(_no_srcs)

  310. 

  311.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  312.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  313.   if(DGL_LIBRARY AND MONOLITHIC)

  314.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  315.   else()

  316.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  317.   endif()

  318.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  319.   set_target_properties("${NAME}-lv2" PROPERTIES

  320.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  321.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  322.     OUTPUT_NAME "${NAME}_dsp"

  323.     PREFIX "")

  324. 

  325.   if(DGL_LIBRARY)

  326.     if(MONOLITHIC)

  327.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  328.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  329.       set_target_properties("${NAME}-lv2" PROPERTIES

  330.         OUTPUT_NAME "${NAME}")

  331.     else()

  332.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  333.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  334.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  335.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  336.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  337.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  338.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  339.         OUTPUT_NAME "${NAME}_ui"

  340.         PREFIX "")

  341.     endif()

  342.   endif()

  343. 

  344.   dpf__add_lv2_ttl_generator()

  345.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  346. 

  347.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  348.     COMMAND

  349.     "$<TARGET_FILE:lv2_ttl_generator>"

  350.     "$<TARGET_FILE:${NAME}-lv2>"

  351.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  352.     DEPENDS lv2_ttl_generator)

  353. endfunction()

  354. 

  355. # dpf__build_vst2

  356. # ------------------------------------------------------------------------------

  357. #

  358. # Add build rules for a VST2 plugin.

  359. #

  360. function(dpf__build_vst2 NAME DGL_LIBRARY)

  361.   dpf__create_dummy_source_list(_no_srcs)

  362. 

  363.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  364.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  365.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  366.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  367.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  368.   set_target_properties("${NAME}-vst2" PROPERTIES

  369.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  370.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  371.     OUTPUT_NAME "${NAME}-vst2"

  372.     PREFIX "")

  373.   if(APPLE)

  374.     set_target_properties("${NAME}-vst2" PROPERTIES

  375.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  376.       OUTPUT_NAME "${NAME}"

  377.       SUFFIX "")

  378.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  379.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  380.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  381.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  382.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  383.   endif()

  384. endfunction()

  385. 

  386. # dpf__determine_vst3_package_architecture

  387. # ------------------------------------------------------------------------------

  388. #

  389. # Determines the package architecture for a VST3 plugin target.

  390. #

  391. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  392.   # if set by variable, override the detection

  393.   if(DPF_VST3_ARCHITECTURE)

  394.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  395.     return()

  396.   endif()

  397. 

  398.   # not used on Apple, which supports universal binary

  399.   if(APPLE)

  400.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  401.     return()

  402.   endif()

  403. 

  404.   # identify the target processor (special case of MSVC, problematic sometimes)

  405.   if(MSVC)

  406.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  407.   else()

  408.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  409.   endif()

  410. 

  411.   # transform the processor name to a format that VST3 recognizes

  412.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  413.     set(vst3_package_arch "x86_64")

  414.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  415.     if(WIN32)

  416.       set(vst3_package_arch "x86")

  417.     else()

  418.       set(vst3_package_arch "i386")

  419.     endif()

  420.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  421.     set(vst3_package_arch "${vst3_system_arch}")

  422.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  423.     set(vst3_package_arch "aarch64")

  424.   else()

  425.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  426.   endif()

  427. 

  428.   # TODO: the detections for Windows arm/arm64 when supported

  429. 

  430.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  431. endfunction()

  432. 

  433. # dpf__build_vst3

  434. # ------------------------------------------------------------------------------

  435. #

  436. # Add build rules for a VST3 plugin.

  437. #

  438. function(dpf__build_vst3 NAME DGL_LIBRARY)

  439.   dpf__determine_vst3_package_architecture(vst3_arch)

  440. 

  441.   dpf__create_dummy_source_list(_no_srcs)

  442. 

  443.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  444.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  445.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  446.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  447.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  448.   set_target_properties("${NAME}-vst3" PROPERTIES

  449.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  450.     OUTPUT_NAME "${NAME}"

  451.     PREFIX "")

  452. 

  453.   if(APPLE)

  454.     set_target_properties("${NAME}-vst3" PROPERTIES

  455.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  456.       SUFFIX "")

  457.   elseif(WIN32)

  458.     set_target_properties("${NAME}-vst3" PROPERTIES

  459.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  460.   else()

  461.     set_target_properties("${NAME}-vst3" PROPERTIES

  462.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  463.   endif()

  464. 

  465.   if(APPLE)

  466.     # Uses the same macOS bundle template as VST2

  467.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  468.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  469.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  470.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  471.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  472.   endif()

  473. endfunction()

  474. 

  475. # dpf__build_clap

  476. # ------------------------------------------------------------------------------

  477. #

  478. # Add build rules for a VST2 plugin.

  479. #

  480. function(dpf__build_clap NAME DGL_LIBRARY)

  481.   dpf__create_dummy_source_list(_no_srcs)

  482. 

  483.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  484.   dpf__add_plugin_main("${NAME}-clap" "clap")

  485.   dpf__add_ui_main("${NAME}-clap" "clap" "${DGL_LIBRARY}")

  486.   dpf__set_module_export_list("${NAME}-clap" "clap")

  487.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  488.   set_target_properties("${NAME}-clap" PROPERTIES

  489.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  490.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  491.     OUTPUT_NAME "${NAME}"

  492.     PREFIX ""

  493.     SUFFIX ".clap")

  494. 

  495.   if(APPLE)

  496.     set_target_properties("${NAME}-clap" PROPERTIES

  497.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  498.       OUTPUT_NAME "${NAME}"

  499.       SUFFIX "")

  500.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  501.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  502.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  503.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  504.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  505.   endif()

  506. endfunction()

  507. 

  508. # dpf__add_dgl_cairo

  509. # ------------------------------------------------------------------------------

  510. #

  511. # Add the Cairo variant of DGL, if not already available.

  512. #

  513. function(dpf__add_dgl_cairo NO_SHARED_RESOURCES)

  514.   if(TARGET dgl-cairo)

  515.     return()

  516.   endif()

  517. 

  518.   find_package(PkgConfig)

  519.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  520. 

  521.   link_directories(${CAIRO_LIBRARY_DIRS})

  522. 

  523.   dpf__add_static_library(dgl-cairo STATIC

  524.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  525.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  526.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  528.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  530.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  531.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  532.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  533.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  534.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  535.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  536.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  537.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  538.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  539.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  540.   if(NO_SHARED_RESOURCES)

  541.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  542.   else()

  543.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  544.   endif()

  545.   if(NOT APPLE)

  546.     target_sources(dgl-cairo PRIVATE

  547.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  548.   else()

  549.     target_sources(dgl-cairo PRIVATE

  550.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  551.   endif()

  552.   target_include_directories(dgl-cairo PUBLIC

  553.     "${DPF_ROOT_DIR}/dgl")

  554.   target_include_directories(dgl-cairo PUBLIC

  555.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  556. 

  557.   dpf__add_dgl_system_libs()

  558.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  559. 

  560.   add_library(dgl-cairo-definitions INTERFACE)

  561.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  562. 

  563.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  564.   if(MINGW)

  565.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  566.   else()

  567.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  568.   endif()

  569.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  570. endfunction()

  571. 

  572. # dpf__add_dgl_opengl

  573. # ------------------------------------------------------------------------------

  574. #

  575. # Add the OpenGL variant of DGL, if not already available.

  576. #

  577. function(dpf__add_dgl_opengl NO_SHARED_RESOURCES)

  578.   if(TARGET dgl-opengl)

  579.     return()

  580.   endif()

  581. 

  582.   if(NOT OpenGL_GL_PREFERENCE)

  583.     set(OpenGL_GL_PREFERENCE "LEGACY")

  584.   endif()

  585. 

  586.   find_package(OpenGL REQUIRED)

  587. 

  588.   dpf__add_static_library(dgl-opengl STATIC

  589.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  590.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  591.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  592.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  593.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  594.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  595.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  596.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  597.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  598.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  599.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  600.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  601.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  602.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  603.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  604.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  605.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  606.   if(NO_SHARED_RESOURCES)

  607.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  608.   else()

  609.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  610.   endif()

  611.   if(NOT APPLE)

  612.     target_sources(dgl-opengl PRIVATE

  613.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  614.   else()

  615.     target_sources(dgl-opengl PRIVATE

  616.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  617.   endif()

  618.   target_include_directories(dgl-opengl PUBLIC

  619.     "${DPF_ROOT_DIR}/dgl")

  620.   target_include_directories(dgl-opengl PUBLIC

  621.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  622. 

  623.   if(APPLE)

  624.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  625.   endif()

  626. 

  627.   dpf__add_dgl_system_libs()

  628.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  629. 

  630.   add_library(dgl-opengl-definitions INTERFACE)

  631.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  632. 

  633.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  634.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  635. endfunction()

  636. 

  637. # dpf__add_plugin_specific_ui_sources

  638. # ------------------------------------------------------------------------------

  639. #

  640. # Compile system specific files, for now it is just Objective-C code

  641. #

  642. function(dpf__add_plugin_specific_ui_sources NAME)

  643.   if(APPLE)

  644.     target_sources("${NAME}" PRIVATE

  645.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  646.   endif()

  647. endfunction()

  648. 

  649. # dpf__add_dgl_system_libs

  650. # ------------------------------------------------------------------------------

  651. #

  652. # Find system libraries required by DGL and add them as an interface target.

  653. #

  654. function(dpf__add_dgl_system_libs)

  655.   if(TARGET dgl-system-libs)

  656.     return()

  657.   endif()

  658.   add_library(dgl-system-libs INTERFACE)

  659.   add_library(dgl-system-libs-definitions INTERFACE)

  660.   if(HAIKU)

  661.     target_link_libraries(dgl-system-libs INTERFACE "be")

  662.   elseif(WIN32)

  663.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  664.   elseif(APPLE)

  665.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  666.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  667.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  668.   else()

  669.     find_package(X11 REQUIRED)

  670.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  671.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  672.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  673.     if(X11_Xcursor_FOUND)

  674.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  675.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  676.     endif()

  677.     if(X11_Xext_FOUND)

  678.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  679.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  680.     endif()

  681.     if(X11_Xrandr_FOUND)

  682.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  683.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  684.     endif()

  685.     if(X11_XSync_FOUND)

  686.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  687.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  688.     endif()

  689.    endif()

  690. 

  691.    if(MSVC)

  692.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  693.      foreach(_gl_header "glext.h")

  694.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  695.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  696.        endif()

  697.      endforeach()

  698.      foreach(_khr_header "khrplatform.h")

  699.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  700.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  701.        endif()

  702.      endforeach()

  703.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  704.    endif()

  705. 

  706.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  707. endfunction()

  708. 

  709. # dpf__add_executable

  710. # ------------------------------------------------------------------------------

  711. #

  712. # Adds an executable target, and set some default properties on the target.

  713. #

  714. function(dpf__add_executable NAME)

  715.   add_executable("${NAME}" ${ARGN})

  716.   dpf__set_target_defaults("${NAME}")

  717.   if(MINGW)

  718.     target_link_libraries("${NAME}" PRIVATE "-static")

  719.   endif()

  720. endfunction()

  721. 

  722. # dpf__add_module

  723. # ------------------------------------------------------------------------------

  724. #

  725. # Adds a module target, and set some default properties on the target.

  726. #

  727. function(dpf__add_module NAME)

  728.   add_library("${NAME}" MODULE ${ARGN})

  729.   dpf__set_target_defaults("${NAME}")

  730.   if(MINGW)

  731.     target_link_libraries("${NAME}" PRIVATE "-static")

  732.   endif()

  733. endfunction()

  734. 

  735. # dpf__add_static_library

  736. # ------------------------------------------------------------------------------

  737. #

  738. # Adds a static library target, and set some default properties on the target.

  739. #

  740. function(dpf__add_static_library NAME)

  741.   add_library("${NAME}" STATIC ${ARGN})

  742.   dpf__set_target_defaults("${NAME}")

  743. endfunction()

  744. 

  745. # dpf__set_module_export_list

  746. # ------------------------------------------------------------------------------

  747. #

  748. # Applies a list of exported symbols to the module target.

  749. #

  750. function(dpf__set_module_export_list NAME EXPORTS)

  751.   if(WIN32)

  752.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  753.   elseif(APPLE)

  754.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  755.       "-Xlinker" "-exported_symbols_list"

  756.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  757.   else()

  758.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  759.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  760.   endif()

  761. endfunction()

  762. 

  763. # dpf__set_target_defaults

  764. # ------------------------------------------------------------------------------

  765. #

  766. # Set default properties which must apply to all DPF-defined targets.

  767. #

  768. function(dpf__set_target_defaults NAME)

  769.   set_target_properties("${NAME}" PROPERTIES

  770.     POSITION_INDEPENDENT_CODE TRUE

  771.     C_VISIBILITY_PRESET "hidden"

  772.     CXX_VISIBILITY_PRESET "hidden"

  773.     VISIBILITY_INLINES_HIDDEN TRUE)

  774.   if(WIN32)

  775.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  776.   endif()

  777.   if (MINGW)

  778.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  779.   endif()

  780.   if (MSVC)

  781.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  782.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  783.   endif()

  784. endfunction()

  785. 

  786. # dpf__add_plugin_main

  787. # ------------------------------------------------------------------------------

  788. #

  789. # Adds plugin code to the given target.

  790. #

  791. function(dpf__add_plugin_main NAME TARGET)

  792.   target_sources("${NAME}" PRIVATE

  793.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  794.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  795. endfunction()

  796. 

  797. # dpf__add_ui_main

  798. # ------------------------------------------------------------------------------

  799. #

  800. # Adds UI code to the given target (only if the target has UI).

  801. #

  802. function(dpf__add_ui_main NAME TARGET HAS_UI)

  803.   if(HAS_UI)

  804.     target_sources("${NAME}" PRIVATE

  805.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  806.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  807.   endif()

  808. endfunction()

  809. 

  810. # dpf__add_plugin_target_definition

  811. # ------------------------------------------------------------------------------

  812. #

  813. # Adds the plugins target macro definition.

  814. # This selects which entry file is compiled according to the target type.

  815. #

  816. function(dpf__add_plugin_target_definition NAME TARGET)

  817.   string(TOUPPER "${TARGET}" _upperTarget)

  818.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  819. endfunction()

  820. 

  821. # dpf__add_lv2_ttl_generator

  822. # ------------------------------------------------------------------------------

  823. #

  824. # Build the LV2 TTL generator.

  825. #

  826. function(dpf__add_lv2_ttl_generator)

  827.   if(TARGET lv2_ttl_generator)

  828.     return()

  829.   endif()

  830.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  831.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  832.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  833.   endif()

  834. endfunction()

  835. 

  836. # dpf__ensure_sources_non_empty

  837. # ------------------------------------------------------------------------------

  838. #

  839. # Ensure the given source list contains at least one file.

  840. # The function appends an empty source file to the list if necessary.

  841. # This is useful when CMake does not permit to add targets without sources.

  842. #

  843. function(dpf__ensure_sources_non_empty VAR)

  844.   if(NOT "" STREQUAL "${${VAR}}")

  845.     return()

  846.   endif()

  847.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  848.   if(NOT EXISTS "${_file}")

  849.     file(WRITE "${_file}" "")

  850.   endif()

  851.   set("${VAR}" "${_file}" PARENT_SCOPE)

  852. endfunction()

  853. 

  854. # dpf__create_dummy_source_list

  855. # ------------------------------------------------------------------------------

  856. #

  857. # Create a dummy source list which is equivalent to compiling nothing.

  858. # This is only for compatibility with older CMake versions, which refuse to add

  859. # targets without any sources.

  860. #

  861. macro(dpf__create_dummy_source_list VAR)

  862.   set("${VAR}")

  863.   if(CMAKE_VERSION VERSION_LESS "3.11")

  864.     dpf__ensure_sources_non_empty("${VAR}")

  865.   endif()

  866. endmacro()

  867. 

  868. # dpf__target_link_directories

  869. # ------------------------------------------------------------------------------

  870. #

  871. # Call `target_link_directories` if cmake >= 3.13,

  872. # otherwise fallback to global `link_directories`.

  873. #

  874. macro(dpf__target_link_directories NAME DIRS)

  875.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  876.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  877.   else()

  878.     link_directories(${DIRS})

  879.   endif()

  880. endmacro()

  881. 

  882. # dpf__warn_once

  883. # ------------------------------------------------------------------------------

  884. #

  885. # Prints a warning message once only.

  886. #

  887. function(dpf__warn_once_only TOKEN MESSAGE)

  888.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  889.   if(NOT _warned)

  890.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  891.     message(WARNING "${MESSAGE}")

  892.   endif()

  893. endfunction()