DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2515 Commits
7 Branches
52MB
Tree: 484cf9a3aa
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '484cf9a3aa'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1757 lines
62KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `FORCE_NATIVE_AUDIO_FALLBACK`

  108. #       force the JACK/Standalone format to use native audio fallback instead of JACK

  109. #

  110. #   `SKIP_NATIVE_AUDIO_FALLBACK`

  111. #       force the JACK/Standalone format to always use JACK, skipping native audio fallback

  112. #

  113. #   `USE_FILE_BROWSER`

  114. #       enable file browser dialog APIs

  115. #

  116. #   `USE_WEB_VIEW`

  117. #       enable web browser view APIs

  118. #

  119. function(dpf_add_plugin NAME)

  120.   set(options MONOLITHIC NO_SHARED_RESOURCES FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER USE_WEB_VIEW)

  121.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  122.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  123.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  124. 

  125.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  126.     set(_dpf_plugin_UI_TYPE "opengl")

  127.   endif()

  128. 

  129.   set(_dgl_library)

  130.   if(_dpf_plugin_FILES_UI)

  131.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  132.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  133.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  134.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  135.       set(_dgl_library dgl-cairo)

  136.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  137.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  138.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  139.       set(_dgl_library dgl-external)

  140.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  141.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  142.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  143.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  144.       set(_dgl_library dgl-gles2)

  145.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  146.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  147.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  148.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  149.       set(_dgl_library dgl-gles3)

  150.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  151.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  152.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  153.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  154.       set(_dgl_library dgl-opengl)

  155.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  156.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  157.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  158.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  159.       set(_dgl_library dgl-opengl3)

  160.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  161.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  162.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  163.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  164.       set(_dgl_library dgl-vulkan)

  165.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  166.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  167.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  168.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  169.       set(_dgl_library dgl-external)

  170.     else()

  171.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  172.     endif()

  173.   else()

  174.     set(_dpf_plugin_UI_TYPE "")

  175.   endif()

  176. 

  177.   set(_dgl_has_ui OFF)

  178.   if(_dgl_library)

  179.     set(_dgl_has_ui ON)

  180.   endif()

  181. 

  182.   ###

  183.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  184.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  185.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  186. 

  187.   ###

  188.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  189.   target_include_directories("${NAME}" PUBLIC

  190.     "${DPF_ROOT_DIR}/distrho")

  191. 

  192.   if(_dpf_plugin_USE_FILE_BROWSER)

  193.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  194.   endif()

  195. 

  196.   if(_dpf_plugin_USE_WEB_VIEW)

  197.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  198.   endif()

  199. 

  200.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  201.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  202.   endif()

  203. 

  204.   find_package(Threads)

  205.   target_link_libraries("${NAME}" PUBLIC "${CMAKE_THREAD_LIBS_INIT}")

  206. 

  207.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  208.     target_link_libraries("${NAME}" PRIVATE "dl")

  209.   endif()

  210. 

  211.   if(_dgl_library)

  212.     # make sure that all code will see DGL_* definitions

  213.     target_link_libraries("${NAME}" PUBLIC

  214.       "${_dgl_library}-definitions"

  215.       dgl-system-libs-definitions

  216.       dgl-system-libs)

  217.   endif()

  218. 

  219.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  220.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  221. 

  222.   if(_dgl_library)

  223.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  224.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  225.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  226.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  227.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  228.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  229.           OUTPUT_STRIP_TRAILING_WHITESPACE

  230.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  231.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  232.       endif()

  233.     endif()

  234.     # add the files containing C++17 or Objective-C classes

  235.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  236.   else()

  237.     add_library("${NAME}-ui" INTERFACE)

  238.   endif()

  239. 

  240.   ###

  241.   foreach(_target ${_dpf_plugin_TARGETS})

  242.     if(_target STREQUAL "jack")

  243.       dpf__build_jack("${NAME}"

  244.                       "${_dgl_has_ui}"

  245.                       "${_dpf_plugin_FORCE_NATIVE_AUDIO_FALLBACK}"

  246.                       "${_dpf_plugin_SKIP_NATIVE_AUDIO_FALLBACK}"

  247.                       "${_dpf_plugin_USE_FILE_BROWSER}")

  248.     elseif(_target STREQUAL "ladspa")

  249.       dpf__build_ladspa("${NAME}")

  250.     elseif(_target STREQUAL "dssi")

  251.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  252.     elseif(_target STREQUAL "lv2")

  253.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  254.     elseif(_target STREQUAL "vst2")

  255.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  256.     elseif(_target STREQUAL "vst3")

  257.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  258.     elseif(_target STREQUAL "clap")

  259.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  260.     elseif(_target STREQUAL "au")

  261.       if (APPLE)

  262.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  263.       endif()

  264.     elseif(_target STREQUAL "static")

  265.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  266.     else()

  267.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  268.     endif()

  269.   endforeach()

  270. endfunction()

  271. 

  272. # dpf_add_executable(target <args...>)

  273. # ------------------------------------------------------------------------------

  274. #

  275. # Add a simple executable built using the DISTRHO Plugin Framework.

  276. #

  277. # ------------------------------------------------------------------------------

  278. # Arguments:

  279. #

  280. #   `UI_TYPE` <type>

  281. #       the user interface type, can be one of the following:

  282. #          - cairo

  283. #          - external

  284. #          - gles2

  285. #          - gles3

  286. #          - opengl (default)

  287. #          - opengl3

  288. #          - vulkan

  289. #          - webview

  290. #

  291. #   `NO_SHARED_RESOURCES`

  292. #       do not build DPF shared resources (fonts, etc)

  293. #

  294. #   `USE_FILE_BROWSER`

  295. #       enable file browser dialog APIs

  296. #

  297. #   `USE_WEB_VIEW`

  298. #       enable web browser view APIs

  299. #

  300. function(dpf_add_executable NAME)

  301.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  302.   set(oneValueArgs UI_TYPE)

  303.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  304. 

  305.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  306.     set(_dpf_plugin_UI_TYPE "opengl")

  307.   endif()

  308. 

  309.   set(_dgl_library)

  310.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  311.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  312.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  313.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  314.     set(_dgl_library dgl-cairo)

  315.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  316.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  317.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  318.     set(_dgl_library dgl-external)

  319.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  320.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  321.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  322.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  323.     set(_dgl_library dgl-gles2)

  324.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  325.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  326.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  327.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  328.     set(_dgl_library dgl-gles3)

  329.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  330.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  331.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  332.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  333.     set(_dgl_library dgl-opengl)

  334.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  335.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  336.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  337.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  338.     set(_dgl_library dgl-opengl3)

  339.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  340.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  341.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  342.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  343.     set(_dgl_library dgl-vulkan)

  344.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  345.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  346.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  347.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  348.     set(_dgl_library dgl-external)

  349.   else()

  350.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  351.   endif()

  352. 

  353.   set(_dgl_has_ui OFF)

  354.   if(_dgl_library)

  355.     set(_dgl_has_ui ON)

  356.   endif()

  357. 

  358.   dpf__create_dummy_source_list(_no_srcs)

  359.   dpf__add_executable("${NAME}" ${_no_srcs})

  360.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  361.   set_target_properties("${NAME}" PROPERTIES

  362.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  363.     OUTPUT_NAME "${NAME}")

  364. 

  365.   if(EMSCRIPTEN)

  366.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  367.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  368.     target_link_options("${NAME}"

  369.       PRIVATE

  370.         -sEXPORTED_RUNTIME_METHODS=dynCall)

  371.   endif()

  372. 

  373.   if(_dpf_plugin_USE_FILE_BROWSER)

  374.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  375.     if(EMSCRIPTEN)

  376.       target_link_options("${NAME}" PRIVATE -sEXPORTED_RUNTIME_METHODS=FS,cwrap)

  377.     endif()

  378.   endif()

  379. 

  380.   if(_dpf_plugin_USE_WEB_VIEW)

  381.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  382.   endif()

  383. 

  384.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  385.     target_link_libraries("${NAME}" PRIVATE "dl")

  386.   endif()

  387. 

  388.   if(_dgl_library)

  389.     # make sure that all code will see DGL_* definitions

  390.     target_link_libraries("${NAME}" PUBLIC

  391.       "${_dgl_library}"

  392.       "${_dgl_library}-definitions"

  393.       dgl-system-libs-definitions

  394.       dgl-system-libs)

  395.     # extra linkage for linux web view

  396.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  397.       target_link_libraries("${NAME}" PRIVATE "rt")

  398.     endif()

  399.     # add the files containing C++17 or Objective-C classes

  400.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  401.   endif()

  402. endfunction()

  403. 

  404. # ------------------------------------------------------------------------------

  405. # DPF private functions (prefixed with `dpf__`)

  406. # ------------------------------------------------------------------------------

  407. 

  408. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  409. #       to the output directory.

  410. #

  411. 

  412. # dpf__build_jack

  413. # ------------------------------------------------------------------------------

  414. #

  415. # Add build rules for a JACK/Standalone program.

  416. #

  417. function(dpf__build_jack NAME HAS_UI FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER)

  418.   dpf__create_dummy_source_list(_no_srcs)

  419. 

  420.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  421.   dpf__add_plugin_main("${NAME}-jack" "jack")

  422.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  423.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  424.   set_target_properties("${NAME}-jack" PROPERTIES

  425.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  426.     OUTPUT_NAME "${NAME}")

  427. 

  428.   if(EMSCRIPTEN)

  429.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  430.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  431.     target_link_options("${NAME}-jack"

  432.       PRIVATE

  433.         -sEXPORTED_RUNTIME_METHODS=dynCall

  434.         $<$<BOOL:${USE_FILE_BROWSER}>:-sEXPORTED_RUNTIME_METHODS=FS,cwrap>)

  435.   endif()

  436. 

  437.   if(NOT FORCE_NATIVE_AUDIO_FALLBACK)

  438.     target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  439.     target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  440.   endif()

  441. 

  442.   if(SKIP_NATIVE_AUDIO_FALLBACK)

  443.     return()

  444.   endif()

  445. 

  446.   find_package(PkgConfig QUIET)

  447.   if(PKG_CONFIG_FOUND)

  448.     pkg_check_modules(SDL2 "sdl2")

  449.   else()

  450.     set(SDL2_FOUND FALSE)

  451.   endif()

  452.   if(SDL2_FOUND)

  453.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  454.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  455.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  456.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  457.   endif()

  458. 

  459.   if(APPLE OR WIN32)

  460.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  461.   elseif(EMSCRIPTEN)

  462.   else()

  463.     pkg_check_modules(ALSA "alsa")

  464.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  465.     if(ALSA_FOUND)

  466.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  467.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  468.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES})

  469.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  470.     endif()

  471.     if(PULSEAUDIO_FOUND)

  472.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  473.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  474.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES})

  475.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  476.     endif()

  477.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  478.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  479.     endif()

  480.   endif()

  481. 

  482.   # for RtAudio native fallback

  483.   if(APPLE)

  484.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  485.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  486.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  487.     target_link_libraries("${NAME}-jack" PRIVATE

  488.       "${APPLE_COREAUDIO_FRAMEWORK}"

  489.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  490.       "${APPLE_COREMIDI_FRAMEWORK}")

  491.   elseif(WIN32)

  492.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  493.     if(HAS_UI AND MINGW)

  494.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  495.     endif()

  496.   endif()

  497. endfunction()

  498. 

  499. # dpf__build_ladspa

  500. # ------------------------------------------------------------------------------

  501. #

  502. # Add build rules for a LADSPA plugin.

  503. #

  504. function(dpf__build_ladspa NAME)

  505.   dpf__create_dummy_source_list(_no_srcs)

  506. 

  507.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  508.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  509.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  510.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  511.   set_target_properties("${NAME}-ladspa" PROPERTIES

  512.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  513.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  514.     OUTPUT_NAME "${NAME}-ladspa"

  515.     PREFIX "")

  516. endfunction()

  517. 

  518. # dpf__build_dssi

  519. # ------------------------------------------------------------------------------

  520. #

  521. # Add build rules for a DSSI plugin.

  522. #

  523. function(dpf__build_dssi NAME HAS_UI)

  524.   find_package(PkgConfig QUIET)

  525.   if(PKG_CONFIG_FOUND)

  526.     pkg_check_modules(LIBLO "liblo")

  527.   else()

  528.     set(LIBLO_FOUND FALSE)

  529.   endif()

  530.   if(NOT LIBLO_FOUND)

  531.     dpf__warn_once_only(missing_liblo

  532.       "liblo is not found, skipping the `dssi` plugin targets")

  533.     return()

  534.   endif()

  535. 

  536.   dpf__create_dummy_source_list(_no_srcs)

  537. 

  538.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  539.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  540.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  541.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  542.   set_target_properties("${NAME}-dssi" PROPERTIES

  543.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  544.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  545.     OUTPUT_NAME "${NAME}-dssi"

  546.     PREFIX "")

  547. 

  548.   if(HAS_UI)

  549.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  550.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  551.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  552.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  553.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  554.       OUTPUT_NAME "${NAME}_ui")

  555. 

  556.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  557.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  558.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  559.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  560.   endif()

  561. endfunction()

  562. 

  563. # dpf__build_lv2

  564. # ------------------------------------------------------------------------------

  565. #

  566. # Add build rules for an LV2 plugin.

  567. #

  568. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  569.   dpf__create_dummy_source_list(_no_srcs)

  570. 

  571.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  572.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  573.   if(HAS_UI AND MONOLITHIC)

  574.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  575.   else()

  576.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  577.   endif()

  578.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  579.   set_target_properties("${NAME}-lv2" PROPERTIES

  580.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  581.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  582.     OUTPUT_NAME "${NAME}_dsp"

  583.     PREFIX "")

  584. 

  585.   # helper property for custom outside handling

  586.   set_target_properties("${NAME}" PROPERTIES

  587.     LV2_BUNDLE "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  588. 

  589.   if(HAS_UI)

  590.     if(MONOLITHIC)

  591.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  592.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  593.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  594.       set_target_properties("${NAME}-lv2" PROPERTIES

  595.         OUTPUT_NAME "${NAME}")

  596.     else()

  597.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  598.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  599.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  600.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  601.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  602.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  603.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  604.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  605.         OUTPUT_NAME "${NAME}_ui"

  606.         PREFIX "")

  607.     endif()

  608.   endif()

  609. 

  610.   dpf__add_lv2_ttl_generator()

  611.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  612. 

  613.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  614. 

  615.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  616.     COMMAND

  617.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  618.     "$<TARGET_FILE:lv2_ttl_generator>"

  619.     "$<TARGET_FILE:${NAME}-lv2>"

  620.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  621. endfunction()

  622. 

  623. # dpf__build_vst2

  624. # ------------------------------------------------------------------------------

  625. #

  626. # Add build rules for a VST2 plugin.

  627. #

  628. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  629.   dpf__create_dummy_source_list(_no_srcs)

  630. 

  631.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  632.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  633.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  634.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  635.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  636.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  637.   set_target_properties("${NAME}-vst2" PROPERTIES

  638.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  639.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  640.     OUTPUT_NAME "${NAME}-vst2"

  641.     PREFIX "")

  642.   if(APPLE)

  643.     set_target_properties("${NAME}-vst2" PROPERTIES

  644.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  645.       OUTPUT_NAME "${NAME}"

  646.       SUFFIX "")

  647.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  648.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  649.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  650.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  651.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  652.   endif()

  653. endfunction()

  654. 

  655. # dpf__determine_vst3_package_architecture

  656. # ------------------------------------------------------------------------------

  657. #

  658. # Determines the package architecture for a VST3 plugin target.

  659. #

  660. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  661.   # if set by variable, override the detection

  662.   if(DPF_VST3_ARCHITECTURE)

  663.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  664.     return()

  665.   endif()

  666. 

  667.   # not used on Apple, which supports universal binary

  668.   if(APPLE)

  669.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  670.     return()

  671.   endif()

  672. 

  673.   # identify the target processor (special case of MSVC, problematic sometimes)

  674.   if(MSVC)

  675.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  676.   else()

  677.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  678.   endif()

  679. 

  680.   # transform the processor name to a format that VST3 recognizes

  681.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  682.     set(vst3_package_arch "x86_64")

  683.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  684.     if(WIN32)

  685.       set(vst3_package_arch "x86")

  686.     else()

  687.       set(vst3_package_arch "i386")

  688.     endif()

  689.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  690.     set(vst3_package_arch "${vst3_system_arch}")

  691.   else()

  692.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  693.   endif()

  694. 

  695.   # TODO: the detections for Windows arm/arm64 when supported

  696. 

  697.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  698. endfunction()

  699. 

  700. # dpf__build_vst3

  701. # ------------------------------------------------------------------------------

  702. #

  703. # Add build rules for a VST3 plugin.

  704. #

  705. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  706.   dpf__determine_vst3_package_architecture(vst3_arch)

  707. 

  708.   dpf__create_dummy_source_list(_no_srcs)

  709. 

  710.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  711.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  712.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  713.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  714.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  715.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  716.   set_target_properties("${NAME}-vst3" PROPERTIES

  717.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  718.     OUTPUT_NAME "${NAME}"

  719.     PREFIX "")

  720. 

  721.   if(APPLE)

  722.     set_target_properties("${NAME}-vst3" PROPERTIES

  723.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  724.       SUFFIX "")

  725.   elseif(WIN32)

  726.     set_target_properties("${NAME}-vst3" PROPERTIES

  727.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  728.   else()

  729.     set_target_properties("${NAME}-vst3" PROPERTIES

  730.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  731.   endif()

  732. 

  733.   if(APPLE)

  734.     # Uses the same macOS bundle template as VST2

  735.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  736.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  737.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  738.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  739.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  740.   endif()

  741. endfunction()

  742. 

  743. # dpf__build_clap

  744. # ------------------------------------------------------------------------------

  745. #

  746. # Add build rules for a CLAP plugin.

  747. #

  748. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  749.   dpf__create_dummy_source_list(_no_srcs)

  750. 

  751.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  752.   dpf__add_plugin_main("${NAME}-clap" "clap")

  753.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  754.   dpf__set_module_export_list("${NAME}-clap" "clap")

  755.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  756.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  757.   set_target_properties("${NAME}-clap" PROPERTIES

  758.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  759.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  760.     OUTPUT_NAME "${NAME}"

  761.     PREFIX ""

  762.     SUFFIX ".clap")

  763. 

  764.   if(APPLE)

  765.     set_target_properties("${NAME}-clap" PROPERTIES

  766.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  767.       OUTPUT_NAME "${NAME}"

  768.       SUFFIX "")

  769.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  770.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  771.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  772.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  773.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  774.   endif()

  775. endfunction()

  776. 

  777. # dpf__build_au

  778. # ------------------------------------------------------------------------------

  779. #

  780. # Add build rules for an AUv2 plugin.

  781. #

  782. function(dpf__build_au NAME HAS_UI)

  783.   dpf__create_dummy_source_list(_no_srcs)

  784. 

  785.   dpf__add_module("${NAME}-au" ${_no_srcs})

  786.   dpf__add_plugin_main("${NAME}-au" "au")

  787.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  788.   dpf__set_module_export_list("${NAME}-au" "au")

  789.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  790.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  791.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  792.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  793.   target_link_libraries("${NAME}-au" PRIVATE

  794.     "${NAME}-dsp"

  795.     "${NAME}-ui"

  796.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  797.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  798.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  799.   set_target_properties("${NAME}-au" PROPERTIES

  800.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  801.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  802.     OUTPUT_NAME "${NAME}"

  803.     PREFIX ""

  804.     SUFFIX "")

  805. 

  806.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  807.   dpf__add_plugin_main("${NAME}-export" "export")

  808.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  809.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  810. 

  811.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  812. 

  813.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  814.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  815.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  816. 

  817.   add_dependencies("${NAME}-au" "${NAME}-export")

  818. 

  819.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  820.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  821. endfunction()

  822. 

  823. # dpf__build_static

  824. # ------------------------------------------------------------------------------

  825. #

  826. # Add build rules for a static library.

  827. #

  828. function(dpf__build_static NAME HAS_UI)

  829.   dpf__create_dummy_source_list(_no_srcs)

  830. 

  831.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  832.   dpf__add_plugin_main("${NAME}-static" "static")

  833.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  834.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  835. 

  836.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  837.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  838.   foreach(src ${dsp_srcs})

  839.     target_sources("${NAME}-static" PRIVATE ${src})

  840.   endforeach()

  841.   foreach(src ${ui_srcs})

  842.     target_sources("${NAME}-static" PRIVATE ${src})

  843.   endforeach()

  844. 

  845.   set_target_properties("${NAME}-static" PROPERTIES

  846.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  847.     OUTPUT_NAME "${NAME}"

  848.     PREFIX "")

  849. endfunction()

  850. 

  851. # dpf__add_dgl_cairo

  852. # ------------------------------------------------------------------------------

  853. #

  854. # Add the Cairo variant of DGL, if not already available.

  855. #

  856. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  857.   if(TARGET dgl-cairo)

  858.     return()

  859.   endif()

  860. 

  861.   find_package(PkgConfig REQUIRED)

  862.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  863. 

  864.   link_directories(${CAIRO_LIBRARY_DIRS})

  865. 

  866.   dpf__add_static_library(dgl-cairo STATIC

  867.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  868.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  869.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  870.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  871.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  878.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  879.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  880.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  881.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  882.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  883.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  884.   if(SHARED_RESOURCES)

  885.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  886.   else()

  887.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  888.   endif()

  889.   if(APPLE)

  890.     target_sources(dgl-cairo PRIVATE

  891.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  892.   else()

  893.     target_sources(dgl-cairo PRIVATE

  894.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  895.   endif()

  896.   target_include_directories(dgl-cairo PUBLIC

  897.     "${DPF_ROOT_DIR}/dgl")

  898.   target_include_directories(dgl-cairo PUBLIC

  899.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  900. 

  901.   if(USE_FILE_BROWSER)

  902.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  903.   endif()

  904. 

  905.   if(USE_WEB_VIEW)

  906.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  907.     if(APPLE)

  908.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  909.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  910.     elseif(WIN32)

  911.       target_sources(dgl-cairo PRIVATE

  912.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  913.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  914.         PROPERTIES

  915.           COMPILE_FLAGS

  916.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  917.     endif()

  918.   endif()

  919. 

  920.   dpf__add_dgl_system_libs()

  921.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  922. 

  923.   add_library(dgl-cairo-definitions INTERFACE)

  924.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  925. 

  926.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  927.   if(MINGW)

  928.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  929.   else()

  930.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  931.   endif()

  932.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  933. endfunction()

  934. 

  935. # dpf__add_dgl_external

  936. # ------------------------------------------------------------------------------

  937. #

  938. # Add the external variant of DGL, if not already available.

  939. #

  940. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  941.   if(TARGET dgl-external)

  942.     return()

  943.   endif()

  944. 

  945.   dpf__add_static_library(dgl-external STATIC

  946.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  956.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  957.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  958.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  959.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  960.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  961.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  962.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  963. 

  964.   if(APPLE)

  965.     target_sources(dgl-external PRIVATE

  966.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  967.   else()

  968.     target_sources(dgl-external PRIVATE

  969.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  970.   endif()

  971.   target_include_directories(dgl-external PUBLIC

  972.     "${DPF_ROOT_DIR}/dgl")

  973.   target_include_directories(dgl-external PUBLIC

  974.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  975. 

  976.   if(USE_FILE_BROWSER)

  977.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  978.   endif()

  979. 

  980.   if(USE_WEB_VIEW)

  981.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  982.     if(APPLE)

  983.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  984.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  985.     elseif(WIN32)

  986.       target_sources(dgl-external PRIVATE

  987.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  988.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  989.         PROPERTIES

  990.           COMPILE_FLAGS

  991.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  992.     endif()

  993.   endif()

  994. 

  995.   dpf__add_dgl_system_libs()

  996.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  997.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  998. 

  999.   add_library(dgl-external-definitions INTERFACE)

  1000.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  1001. 

  1002.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  1003.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  1004. endfunction()

  1005. 

  1006. # dpf__add_dgl_gles2

  1007. # ------------------------------------------------------------------------------

  1008. #

  1009. # Add the GLESv2 variant of DGL, if not already available.

  1010. #

  1011. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1012.   if(TARGET dgl-gles2)

  1013.     return()

  1014.   endif()

  1015. 

  1016.   if(NOT OpenGL_GL_PREFERENCE)

  1017.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1018.   endif()

  1019. 

  1020.   find_package(OpenGL REQUIRED)

  1021. 

  1022.   dpf__add_static_library(dgl-gles2 STATIC

  1023.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1024.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1025.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1026.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1027.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1028.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1029.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1030.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1031.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1032.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1033.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1034.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1035.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1036.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1037.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1038.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1039.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1040.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1041.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1042.   if(SHARED_RESOURCES)

  1043.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1044.   else()

  1045.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1046.   endif()

  1047.   if(APPLE)

  1048.     target_sources(dgl-gles2 PRIVATE

  1049.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1050.   else()

  1051.     target_sources(dgl-gles2 PRIVATE

  1052.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1053.   endif()

  1054.   target_include_directories(dgl-gles2 PUBLIC

  1055.     "${DPF_ROOT_DIR}/dgl")

  1056.   target_include_directories(dgl-gles2 PUBLIC

  1057.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1058. 

  1059.   if(APPLE)

  1060.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1061.   endif()

  1062. 

  1063.   if(USE_FILE_BROWSER)

  1064.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1065.   endif()

  1066. 

  1067.   if(USE_WEB_VIEW)

  1068.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1069.     if(APPLE)

  1070.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1071.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1072.     elseif(WIN32)

  1073.       target_sources(dgl-gles2 PRIVATE

  1074.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1075.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1076.         PROPERTIES

  1077.           COMPILE_FLAGS

  1078.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1079.     endif()

  1080.   endif()

  1081. 

  1082.   dpf__add_dgl_system_libs()

  1083.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1084.   target_link_options(dgl-gles2

  1085.     INTERFACE

  1086.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1087.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1088.   )

  1089. 

  1090.   add_library(dgl-gles2-definitions INTERFACE)

  1091.   target_compile_definitions(dgl-gles2-definitions

  1092.     INTERFACE

  1093.       DGL_USE_OPENGL3

  1094.       DGL_USE_GLES

  1095.       DGL_USE_GLES2

  1096.       DGL_OPENGL

  1097.       HAVE_OPENGL

  1098.       HAVE_DGL

  1099.   )

  1100. 

  1101.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1102.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1103. endfunction()

  1104. 

  1105. # dpf__add_dgl_gles3

  1106. # ------------------------------------------------------------------------------

  1107. #

  1108. # Add the GLESv3 variant of DGL, if not already available.

  1109. #

  1110. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1111.   if(TARGET dgl-gles3)

  1112.     return()

  1113.   endif()

  1114. 

  1115.   if(NOT OpenGL_GL_PREFERENCE)

  1116.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1117.   endif()

  1118. 

  1119.   find_package(OpenGL REQUIRED)

  1120. 

  1121.   dpf__add_static_library(dgl-gles3 STATIC

  1122.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1123.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1124.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1125.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1126.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1127.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1128.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1129.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1130.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1131.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1132.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1133.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1134.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1135.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1136.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1137.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1138.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1139.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1140.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1141.   if(SHARED_RESOURCES)

  1142.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1143.   else()

  1144.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1145.   endif()

  1146.   if(APPLE)

  1147.     target_sources(dgl-gles3 PRIVATE

  1148.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1149.   else()

  1150.     target_sources(dgl-gles3 PRIVATE

  1151.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1152.   endif()

  1153.   target_include_directories(dgl-gles3 PUBLIC

  1154.     "${DPF_ROOT_DIR}/dgl")

  1155.   target_include_directories(dgl-gles3 PUBLIC

  1156.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1157. 

  1158.   if(APPLE)

  1159.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1160.   endif()

  1161. 

  1162.   if(USE_FILE_BROWSER)

  1163.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1164.   endif()

  1165. 

  1166.   if(USE_WEB_VIEW)

  1167.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1168.     if(APPLE)

  1169.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1170.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1171.     elseif(WIN32)

  1172.       target_sources(dgl-gles3 PRIVATE

  1173.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1174.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1175.         PROPERTIES

  1176.           COMPILE_FLAGS

  1177.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1178.     endif()

  1179.   endif()

  1180. 

  1181.   dpf__add_dgl_system_libs()

  1182.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1183.   target_link_options(dgl-gles3

  1184.     INTERFACE

  1185.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=3>

  1186.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=3>

  1187.   )

  1188. 

  1189.   add_library(dgl-gles3-definitions INTERFACE)

  1190.   target_compile_definitions(dgl-gles3-definitions

  1191.     INTERFACE

  1192.       DGL_USE_OPENGL3

  1193.       DGL_USE_GLES

  1194.       DGL_USE_GLES3

  1195.       DGL_OPENGL

  1196.       HAVE_OPENGL

  1197.       HAVE_DGL

  1198.   )

  1199. 

  1200.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1201.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1202. endfunction()

  1203. 

  1204. # dpf__add_dgl_opengl

  1205. # ------------------------------------------------------------------------------

  1206. #

  1207. # Add the OpenGL variant of DGL, if not already available.

  1208. #

  1209. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1210.   if(TARGET dgl-opengl)

  1211.     return()

  1212.   endif()

  1213. 

  1214.   if(NOT OpenGL_GL_PREFERENCE)

  1215.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1216.   endif()

  1217. 

  1218.   find_package(OpenGL REQUIRED)

  1219. 

  1220.   dpf__add_static_library(dgl-opengl STATIC

  1221.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1222.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1223.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1224.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1225.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1226.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1227.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1228.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1229.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1230.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1231.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1232.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1233.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1234.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1235.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1236.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1237.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1238.     "${DPF_ROOT_DIR}/dgl/src/OpenGL2.cpp"

  1239.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1240.   if(SHARED_RESOURCES)

  1241.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1242.   else()

  1243.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1244.   endif()

  1245.   if(APPLE)

  1246.     target_sources(dgl-opengl PRIVATE

  1247.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1248.   else()

  1249.     target_sources(dgl-opengl PRIVATE

  1250.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1251.   endif()

  1252.   target_include_directories(dgl-opengl PUBLIC

  1253.     "${DPF_ROOT_DIR}/dgl")

  1254.   target_include_directories(dgl-opengl PUBLIC

  1255.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1256. 

  1257.   if(APPLE)

  1258.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1259.   endif()

  1260. 

  1261.   if(USE_FILE_BROWSER)

  1262.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1263.   endif()

  1264. 

  1265.   if(USE_WEB_VIEW)

  1266.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1267.     if(APPLE)

  1268.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1269.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1270.     elseif(WIN32)

  1271.       target_sources(dgl-opengl PRIVATE

  1272.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1273.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1274.         PROPERTIES

  1275.           COMPILE_FLAGS

  1276.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1277.     endif()

  1278.   endif()

  1279. 

  1280.   dpf__add_dgl_system_libs()

  1281.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1282.   target_link_options(dgl-opengl

  1283.     INTERFACE

  1284.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1285.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1286.   )

  1287. 

  1288.   add_library(dgl-opengl-definitions INTERFACE)

  1289.   target_compile_definitions(dgl-opengl-definitions

  1290.     INTERFACE

  1291.       DGL_OPENGL

  1292.       HAVE_OPENGL

  1293.       HAVE_DGL

  1294.   )

  1295. 

  1296.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1297.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1298. endfunction()

  1299. 

  1300. # dpf__add_dgl_opengl3

  1301. # ------------------------------------------------------------------------------

  1302. #

  1303. # Add the OpenGL3 variant of DGL, if not already available.

  1304. #

  1305. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1306.   if(TARGET dgl-opengl3)

  1307.     return()

  1308.   endif()

  1309. 

  1310.   if(NOT OpenGL_GL_PREFERENCE)

  1311.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1312.   endif()

  1313. 

  1314.   find_package(OpenGL REQUIRED)

  1315. 

  1316.   dpf__add_static_library(dgl-opengl3 STATIC

  1317.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1318.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1319.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1320.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1321.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1322.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1323.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1324.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1325.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1326.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1327.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1328.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1329.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1330.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1331.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1332.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1333.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1334.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1335.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1336.   if(SHARED_RESOURCES)

  1337.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1338.   else()

  1339.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1340.   endif()

  1341.   if(APPLE)

  1342.     target_sources(dgl-opengl3 PRIVATE

  1343.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1344.   else()

  1345.     target_sources(dgl-opengl3 PRIVATE

  1346.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1347.   endif()

  1348.   target_include_directories(dgl-opengl3 PUBLIC

  1349.     "${DPF_ROOT_DIR}/dgl")

  1350.   target_include_directories(dgl-opengl3 PUBLIC

  1351.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1352. 

  1353.   if(APPLE)

  1354.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1355.   endif()

  1356. 

  1357.   if(USE_FILE_BROWSER)

  1358.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1359.   endif()

  1360. 

  1361.   if(USE_WEB_VIEW)

  1362.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1363.     if(APPLE)

  1364.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1365.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1366.     elseif(WIN32)

  1367.       target_sources(dgl-opengl3 PRIVATE

  1368.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1369.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1370.         PROPERTIES

  1371.           COMPILE_FLAGS

  1372.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1373.     endif()

  1374.   endif()

  1375. 

  1376.   dpf__add_dgl_system_libs()

  1377.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1378. 

  1379.   add_library(dgl-opengl3-definitions INTERFACE)

  1380.   target_compile_definitions(dgl-opengl3-definitions

  1381.     INTERFACE

  1382.       DGL_USE_OPENGL3

  1383.       DGL_OPENGL

  1384.       HAVE_OPENGL

  1385.       HAVE_DGL

  1386.   )

  1387. 

  1388.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1389.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1390. endfunction()

  1391. 

  1392. # dpf__add_dgl_vulkan

  1393. # ------------------------------------------------------------------------------

  1394. #

  1395. # Add the Vulkan variant of DGL, if not already available.

  1396. #

  1397. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1398.   if(TARGET dgl-vulkan)

  1399.     return()

  1400.   endif()

  1401. 

  1402.   find_package(Vulkan REQUIRED)

  1403. 

  1404.   dpf__add_static_library(dgl-vulkan STATIC

  1405.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1406.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1407.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1408.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1409.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1410.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1411.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1412.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1413.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1414.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1415.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1416.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1417.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1418.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1419.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1420.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1421.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1422.   if(NO_SHARED_RESOURCES)

  1423.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1424.   else()

  1425.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1426.   endif()

  1427.   if(APPLE)

  1428.     target_sources(dgl-vulkan PRIVATE

  1429.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1430.   else()

  1431.     target_sources(dgl-vulkan PRIVATE

  1432.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1433.   endif()

  1434.   target_include_directories(dgl-vulkan PUBLIC

  1435.     "${DPF_ROOT_DIR}/dgl")

  1436.   target_include_directories(dgl-vulkan PUBLIC

  1437.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1438. 

  1439.   if(APPLE)

  1440.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1441.   endif()

  1442. 

  1443.   if(USE_FILE_BROWSER)

  1444.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1445.   endif()

  1446. 

  1447.   if(USE_WEB_VIEW)

  1448.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1449.     if(APPLE)

  1450.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1451.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1452.     elseif(WIN32)

  1453.       target_sources(dgl-vulkan PRIVATE

  1454.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1455.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1456.         PROPERTIES

  1457.           COMPILE_FLAGS

  1458.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1459.     endif()

  1460.   endif()

  1461. 

  1462.   dpf__add_dgl_system_libs()

  1463.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1464. 

  1465.   add_library(dgl-vulkan-definitions INTERFACE)

  1466.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1467. 

  1468.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1469.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1470. endfunction()

  1471. 

  1472. # dpf__add_plugin_specific_ui_sources

  1473. # ------------------------------------------------------------------------------

  1474. #

  1475. # Compile system specific files

  1476. #

  1477. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1478.   if(APPLE)

  1479.     target_sources("${NAME}" PRIVATE

  1480.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1481.     if(USE_WEB_VIEW)

  1482.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1483.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1484.     endif()

  1485.   elseif(WIN32 AND USE_WEB_VIEW)

  1486.     target_sources("${NAME}" PRIVATE

  1487.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1488.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1489.       PROPERTIES

  1490.         COMPILE_FLAGS

  1491.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1492.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1493.   endif()

  1494. endfunction()

  1495. 

  1496. # dpf__add_dgl_system_libs

  1497. # ------------------------------------------------------------------------------

  1498. #

  1499. # Find system libraries required by DGL and add them as an interface target.

  1500. #

  1501. function(dpf__add_dgl_system_libs)

  1502.   if(TARGET dgl-system-libs)

  1503.     return()

  1504.   endif()

  1505.   add_library(dgl-system-libs INTERFACE)

  1506.   add_library(dgl-system-libs-definitions INTERFACE)

  1507.   if(APPLE)

  1508.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1509.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1510.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1511.   elseif(EMSCRIPTEN)

  1512.   elseif(HAIKU)

  1513.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1514.   elseif(WIN32)

  1515.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1516.   else()

  1517.     find_package(PkgConfig REQUIRED)

  1518.     pkg_check_modules(DBUS "dbus-1")

  1519.     if(DBUS_FOUND)

  1520.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1521.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1522.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1523.     endif()

  1524.     find_package(X11 REQUIRED)

  1525.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1526.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1527.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1528.     if(X11_Xcursor_FOUND)

  1529.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1530.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1531.     endif()

  1532.     if(X11_Xext_FOUND)

  1533.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1534.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1535.     endif()

  1536.     if(X11_Xrandr_FOUND)

  1537.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1538.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1539.     endif()

  1540.     if(X11_XSync_FOUND)

  1541.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1542.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1543.     endif()

  1544.    endif()

  1545. 

  1546.    if(MSVC)

  1547.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1548.      foreach(_gl_header "glext.h")

  1549.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1550.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1551.        endif()

  1552.      endforeach()

  1553.      foreach(_khr_header "khrplatform.h")

  1554.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1555.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1556.        endif()

  1557.      endforeach()

  1558.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1559.    endif()

  1560. 

  1561.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1562. endfunction()

  1563. 

  1564. # dpf__add_executable

  1565. # ------------------------------------------------------------------------------

  1566. #

  1567. # Adds an executable target, and set some default properties on the target.

  1568. #

  1569. function(dpf__add_executable NAME)

  1570.   add_executable("${NAME}" ${ARGN})

  1571.   dpf__set_target_defaults("${NAME}")

  1572.   if(MINGW)

  1573.     target_link_libraries("${NAME}" PRIVATE "-static")

  1574.   endif()

  1575. endfunction()

  1576. 

  1577. # dpf__add_module

  1578. # ------------------------------------------------------------------------------

  1579. #

  1580. # Adds a module target, and set some default properties on the target.

  1581. #

  1582. function(dpf__add_module NAME)

  1583.   add_library("${NAME}" MODULE ${ARGN})

  1584.   dpf__set_target_defaults("${NAME}")

  1585.   if(APPLE)

  1586.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1587.   elseif(MINGW)

  1588.     target_link_libraries("${NAME}" PRIVATE "-static")

  1589.   endif()

  1590. endfunction()

  1591. 

  1592. # dpf__add_static_library

  1593. # ------------------------------------------------------------------------------

  1594. #

  1595. # Adds a static library target, and set some default properties on the target.

  1596. #

  1597. function(dpf__add_static_library NAME)

  1598.   add_library("${NAME}" STATIC ${ARGN})

  1599.   dpf__set_target_defaults("${NAME}")

  1600. endfunction()

  1601. 

  1602. # dpf__set_module_export_list

  1603. # ------------------------------------------------------------------------------

  1604. #

  1605. # Applies a list of exported symbols to the module target.

  1606. #

  1607. function(dpf__set_module_export_list NAME EXPORTS)

  1608.   if(WIN32)

  1609.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1610.   elseif(APPLE)

  1611.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1612.       "-Xlinker" "-exported_symbols_list"

  1613.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1614.   else()

  1615.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1616.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1617.   endif()

  1618. endfunction()

  1619. 

  1620. # dpf__set_target_defaults

  1621. # ------------------------------------------------------------------------------

  1622. #

  1623. # Set default properties which must apply to all DPF-defined targets.

  1624. #

  1625. function(dpf__set_target_defaults NAME)

  1626.   set_target_properties("${NAME}" PROPERTIES

  1627.     POSITION_INDEPENDENT_CODE TRUE

  1628.     C_VISIBILITY_PRESET "hidden"

  1629.     CXX_VISIBILITY_PRESET "hidden"

  1630.     VISIBILITY_INLINES_HIDDEN TRUE)

  1631.   if(WIN32)

  1632.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1633.   endif()

  1634.   if (MINGW)

  1635.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1636.   endif()

  1637.   if (MSVC)

  1638.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1639.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1640.   endif()

  1641.   if (CMAKE_COMPILER_IS_GNUCXX)

  1642.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1643.   endif()

  1644.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1645.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1646.   endif()

  1647. endfunction()

  1648. 

  1649. # dpf__add_plugin_main

  1650. # ------------------------------------------------------------------------------

  1651. #

  1652. # Adds plugin code to the given target.

  1653. #

  1654. function(dpf__add_plugin_main NAME TARGET)

  1655.   target_sources("${NAME}" PRIVATE

  1656.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1657.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1658. endfunction()

  1659. 

  1660. # dpf__add_ui_main

  1661. # ------------------------------------------------------------------------------

  1662. #

  1663. # Adds UI code to the given target (only if the target has UI).

  1664. #

  1665. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1666.   if(HAS_UI)

  1667.     target_sources("${NAME}" PRIVATE

  1668.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1669.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1670.   endif()

  1671. endfunction()

  1672. 

  1673. # dpf__add_plugin_target_definition

  1674. # ------------------------------------------------------------------------------

  1675. #

  1676. # Adds the plugins target macro definition.

  1677. # This selects which entry file is compiled according to the target type.

  1678. #

  1679. function(dpf__add_plugin_target_definition NAME TARGET)

  1680.   string(TOUPPER "${TARGET}" _upperTarget)

  1681.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1682. endfunction()

  1683. 

  1684. # dpf__add_lv2_ttl_generator

  1685. # ------------------------------------------------------------------------------

  1686. #

  1687. # Build the LV2 TTL generator.

  1688. #

  1689. function(dpf__add_lv2_ttl_generator)

  1690.   if(TARGET lv2_ttl_generator)

  1691.     return()

  1692.   endif()

  1693.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1694.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1695.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1696.   endif()

  1697. endfunction()

  1698. 

  1699. # dpf__ensure_sources_non_empty

  1700. # ------------------------------------------------------------------------------

  1701. #

  1702. # Ensure the given source list contains at least one file.

  1703. # The function appends an empty source file to the list if necessary.

  1704. # This is useful when CMake does not permit to add targets without sources.

  1705. #

  1706. function(dpf__ensure_sources_non_empty VAR)

  1707.   if(NOT "" STREQUAL "${${VAR}}")

  1708.     return()

  1709.   endif()

  1710.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1711.   if(NOT EXISTS "${_file}")

  1712.     file(WRITE "${_file}" "")

  1713.   endif()

  1714.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1715. endfunction()

  1716. 

  1717. # dpf__create_dummy_source_list

  1718. # ------------------------------------------------------------------------------

  1719. #

  1720. # Create a dummy source list which is equivalent to compiling nothing.

  1721. # This is only for compatibility with older CMake versions, which refuse to add

  1722. # targets without any sources.

  1723. #

  1724. macro(dpf__create_dummy_source_list VAR)

  1725.   set("${VAR}")

  1726.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1727.     dpf__ensure_sources_non_empty("${VAR}")

  1728.   endif()

  1729. endmacro()

  1730. 

  1731. # dpf__target_link_directories

  1732. # ------------------------------------------------------------------------------

  1733. #

  1734. # Call `target_link_directories` if cmake >= 3.13,

  1735. # otherwise fallback to global `link_directories`.

  1736. #

  1737. macro(dpf__target_link_directories NAME DIRS)

  1738.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1739.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1740.   else()

  1741.     link_directories(${DIRS})

  1742.   endif()

  1743. endmacro()

  1744. 

  1745. # dpf__warn_once

  1746. # ------------------------------------------------------------------------------

  1747. #

  1748. # Prints a warning message once only.

  1749. #

  1750. function(dpf__warn_once_only TOKEN MESSAGE)

  1751.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1752.   if(NOT _warned)

  1753.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1754.     message(WARNING "${MESSAGE}")

  1755.   endif()

  1756. endfunction()