DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1158 Commits
7 Branches
89MB
Tree: 40e93a475a
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '40e93a475a'
${ noResults }
DPF/cmake/DPF-plugin.cmake

668 lines
23KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     else()

  157.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  158.     endif()

  159.   endforeach()

  160. endfunction()

  161. 

  162. # ------------------------------------------------------------------------------

  163. # DPF private functions (prefixed with `dpf__`)

  164. # ------------------------------------------------------------------------------

  165. 

  166. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  167. #       to the output directory.

  168. #

  169. 

  170. # dpf__build_jack

  171. # ------------------------------------------------------------------------------

  172. #

  173. # Add build rules for a JACK program.

  174. #

  175. function(dpf__build_jack NAME DGL_LIBRARY)

  176.   dpf__create_dummy_source_list(_no_srcs)

  177. 

  178.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  179.   dpf__add_plugin_main("${NAME}-jack" "jack")

  180.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  181.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  182.   set_target_properties("${NAME}-jack" PROPERTIES

  183.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  184.     OUTPUT_NAME "${NAME}")

  185. 

  186.   # Note: libjack will be linked at runtime

  187.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  188.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  189.   endif()

  190. endfunction()

  191. 

  192. # dpf__build_ladspa

  193. # ------------------------------------------------------------------------------

  194. #

  195. # Add build rules for a DSSI plugin.

  196. #

  197. function(dpf__build_ladspa NAME)

  198.   dpf__create_dummy_source_list(_no_srcs)

  199. 

  200.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  201.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  202.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  203.   set_target_properties("${NAME}-ladspa" PROPERTIES

  204.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  205.     OUTPUT_NAME "${NAME}-ladspa"

  206.     PREFIX "")

  207. endfunction()

  208. 

  209. # dpf__build_dssi

  210. # ------------------------------------------------------------------------------

  211. #

  212. # Add build rules for a DSSI plugin.

  213. #

  214. function(dpf__build_dssi NAME DGL_LIBRARY)

  215.   find_package(PkgConfig)

  216.   pkg_check_modules(LIBLO "liblo")

  217.   if(NOT LIBLO_FOUND)

  218.     dpf__warn_once_only(missing_liblo

  219.       "liblo is not found, skipping the `dssi` plugin targets")

  220.     return()

  221.   endif()

  222. 

  223.   link_directories(${LIBLO_LIBRARY_DIRS})

  224. 

  225.   dpf__create_dummy_source_list(_no_srcs)

  226. 

  227.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  228.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  229.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  230.   set_target_properties("${NAME}-dssi" PROPERTIES

  231.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  232.     OUTPUT_NAME "${NAME}-dssi"

  233.     PREFIX "")

  234. 

  235.   if(DGL_LIBRARY)

  236.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  237.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  238.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  239.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  240.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  241.       OUTPUT_NAME "${NAME}_ui")

  242. 

  243.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  244.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  245.   endif()

  246. endfunction()

  247. 

  248. # dpf__build_lv2

  249. # ------------------------------------------------------------------------------

  250. #

  251. # Add build rules for a LV2 plugin.

  252. #

  253. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  254.   dpf__create_dummy_source_list(_no_srcs)

  255. 

  256.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  257.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  258.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  259.   set_target_properties("${NAME}-lv2" PROPERTIES

  260.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  261.     OUTPUT_NAME "${NAME}_dsp"

  262.     PREFIX "")

  263. 

  264.   if(DGL_LIBRARY)

  265.     if(MONOLITHIC)

  266.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  267.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  268.       set_target_properties("${NAME}-lv2" PROPERTIES

  269.         OUTPUT_NAME "${NAME}")

  270.     else()

  271.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  272.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  273.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  274.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  275.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  276.         OUTPUT_NAME "${NAME}_ui"

  277.         PREFIX "")

  278.     endif()

  279.   endif()

  280. 

  281.   dpf__add_lv2_ttl_generator()

  282.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  283. 

  284.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  285.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  286.     "$<TARGET_FILE:lv2_ttl_generator>"

  287.     "$<TARGET_FILE:${NAME}-lv2>"

  288.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  289.     DEPENDS lv2_ttl_generator)

  290. endfunction()

  291. 

  292. # dpf__build_vst2

  293. # ------------------------------------------------------------------------------

  294. #

  295. # Add build rules for a VST2 plugin.

  296. #

  297. function(dpf__build_vst2 NAME DGL_LIBRARY)

  298.   dpf__create_dummy_source_list(_no_srcs)

  299. 

  300.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  301.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  302.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  303.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  304.   set_target_properties("${NAME}-vst2" PROPERTIES

  305.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  306.     OUTPUT_NAME "${NAME}-vst2"

  307.     PREFIX "")

  308. endfunction()

  309. 

  310. # dpf__add_dgl_cairo

  311. # ------------------------------------------------------------------------------

  312. #

  313. # Add the Cairo variant of DGL, if not already available.

  314. #

  315. function(dpf__add_dgl_cairo)

  316.   if(TARGET dgl-cairo)

  317.     return()

  318.   endif()

  319. 

  320.   find_package(PkgConfig)

  321.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  322. 

  323.   link_directories(${CAIRO_LIBRARY_DIRS})

  324. 

  325.   dpf__add_static_library(dgl-cairo STATIC

  326.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  327.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  328.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  329.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  330.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  331.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  333.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  342.   if(NOT APPLE)

  343.     target_sources(dgl-cairo PRIVATE

  344.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  345.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  346.     #target_sources(dgl-opengl PRIVATE

  347.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  348.   endif()

  349.   target_include_directories(dgl-cairo PUBLIC

  350.     "${DPF_ROOT_DIR}/dgl")

  351.   target_include_directories(dgl-cairo PUBLIC

  352.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  353. 

  354.   dpf__add_dgl_system_libs()

  355.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  356. 

  357.   add_library(dgl-cairo-definitions INTERFACE)

  358.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  359. 

  360.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  361.   if(MINGW)

  362.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  363.   else()

  364.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  365.   endif()

  366.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  367. endfunction()

  368. 

  369. # dpf__add_dgl_opengl

  370. # ------------------------------------------------------------------------------

  371. #

  372. # Add the OpenGL variant of DGL, if not already available.

  373. #

  374. function(dpf__add_dgl_opengl)

  375.   if(TARGET dgl-opengl)

  376.     return()

  377.   endif()

  378. 

  379.   if(NOT OpenGL_GL_PREFERENCE)

  380.     set(OpenGL_GL_PREFERENCE "LEGACY")

  381.   endif()

  382. 

  383.   find_package(OpenGL REQUIRED)

  384. 

  385.   dpf__add_static_library(dgl-opengl STATIC

  386.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  387.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  388.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  389.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  390.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  391.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  392.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  393.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  394.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  403.   if(NOT APPLE)

  404.     target_sources(dgl-opengl PRIVATE

  405.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  406.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  407.     #target_sources(dgl-opengl PRIVATE

  408.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  409.   endif()

  410.   target_include_directories(dgl-opengl PUBLIC

  411.     "${DPF_ROOT_DIR}/dgl")

  412.   target_include_directories(dgl-opengl PUBLIC

  413.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  414. 

  415.   if(APPLE)

  416.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  417.   endif()

  418. 

  419.   dpf__add_dgl_system_libs()

  420.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  421. 

  422.   add_library(dgl-opengl-definitions INTERFACE)

  423.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  424. 

  425.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  426.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  427. endfunction()

  428. 

  429. # dpf__add_plugin_specific_ui_sources

  430. # ------------------------------------------------------------------------------

  431. #

  432. # Compile plugin-specific UI sources into the target designated by the given

  433. # name. There are some special considerations here:

  434. # - On most platforms, sources can be compiled only once, as part of DGL;

  435. # - On macOS, for any sources which define Objective-C interfaces, these must

  436. #   be recompiled for each plugin under a unique namespace. In this case, the

  437. #   name must be a plugin-specific identifier, and it will be used for computing

  438. #   the unique ID along with the project version.

  439. function(dpf__add_plugin_specific_ui_sources NAME)

  440.   if(APPLE)

  441.     target_sources("${NAME}" PRIVATE

  442.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  443.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  444.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  445.   endif()

  446. endfunction()

  447. 

  448. # dpf__add_dgl_system_libs

  449. # ------------------------------------------------------------------------------

  450. #

  451. # Find system libraries required by DGL and add them as an interface target.

  452. #

  453. function(dpf__add_dgl_system_libs)

  454.   if(TARGET dgl-system-libs)

  455.     return()

  456.   endif()

  457.   add_library(dgl-system-libs INTERFACE)

  458.   add_library(dgl-system-libs-definitions INTERFACE)

  459.   if(HAIKU)

  460.     target_link_libraries(dgl-system-libs INTERFACE "be")

  461.   elseif(WIN32)

  462.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  463.   elseif(APPLE)

  464.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  465.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  466.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  467.   else()

  468.     find_package(X11 REQUIRED)

  469.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  470.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  471.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  472.     if(X11_Xext_FOUND)

  473.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  474.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  475.     endif()

  476.     if(X11_XSync_FOUND)

  477.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  478.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  479.     endif()

  480.     if(X11_Xrandr_FOUND)

  481.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  482.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  483.     endif()

  484.     #if(X11_Xcursor_FOUND)

  485.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  486.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  487.     #endif()

  488.    endif()

  489. 

  490.    if(MSVC)

  491.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  492.      foreach(_gl_header "glext.h")

  493.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  494.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  495.        endif()

  496.      endforeach()

  497.      foreach(_khr_header "khrplatform.h")

  498.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  499.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  500.        endif()

  501.      endforeach()

  502.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  503.    endif()

  504. 

  505.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  506. endfunction()

  507. 

  508. # dpf__add_executable

  509. # ------------------------------------------------------------------------------

  510. #

  511. # Adds an executable target, and set some default properties on the target.

  512. #

  513. function(dpf__add_executable NAME)

  514.   add_executable("${NAME}" ${ARGN})

  515.   dpf__set_target_defaults("${NAME}")

  516.   if(MINGW)

  517.     target_link_libraries("${NAME}" PRIVATE "-static")

  518.   endif()

  519. endfunction()

  520. 

  521. # dpf__add_module

  522. # ------------------------------------------------------------------------------

  523. #

  524. # Adds a module target, and set some default properties on the target.

  525. #

  526. function(dpf__add_module NAME)

  527.   add_library("${NAME}" MODULE ${ARGN})

  528.   dpf__set_target_defaults("${NAME}")

  529.   if(MINGW)

  530.     target_link_libraries("${NAME}" PRIVATE "-static")

  531.   endif()

  532. endfunction()

  533. 

  534. # dpf__add_static_library

  535. # ------------------------------------------------------------------------------

  536. #

  537. # Adds a static library target, and set some default properties on the target.

  538. #

  539. function(dpf__add_static_library NAME)

  540.   add_library("${NAME}" STATIC ${ARGN})

  541.   dpf__set_target_defaults("${NAME}")

  542. endfunction()

  543. 

  544. # dpf__set_target_defaults

  545. # ------------------------------------------------------------------------------

  546. #

  547. # Set default properties which must apply to all DPF-defined targets.

  548. #

  549. function(dpf__set_target_defaults NAME)

  550.   set_target_properties("${NAME}" PROPERTIES

  551.     POSITION_INDEPENDENT_CODE TRUE

  552.     C_VISIBILITY_PRESET "hidden"

  553.     CXX_VISIBILITY_PRESET "hidden"

  554.     VISIBILITY_INLINES_HIDDEN TRUE)

  555.   if(WIN32)

  556.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  557.   endif()

  558.   if (MINGW)

  559.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  560.   endif()

  561.   if (MSVC)

  562.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  563.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  564.   endif()

  565. endfunction()

  566. 

  567. # dpf__add_plugin_main

  568. # ------------------------------------------------------------------------------

  569. #

  570. # Adds plugin code to the given target.

  571. #

  572. function(dpf__add_plugin_main NAME TARGET)

  573.   target_sources("${NAME}" PRIVATE

  574.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  575.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  576. endfunction()

  577. 

  578. # dpf__add_ui_main

  579. # ------------------------------------------------------------------------------

  580. #

  581. # Adds UI code to the given target (only if the target has UI).

  582. #

  583. function(dpf__add_ui_main NAME TARGET HAS_UI)

  584.   if(HAS_UI)

  585.     target_sources("${NAME}" PRIVATE

  586.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  587.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  588.   endif()

  589. endfunction()

  590. 

  591. # dpf__add_plugin_target_definition

  592. # ------------------------------------------------------------------------------

  593. #

  594. # Adds the plugins target macro definition.

  595. # This selects which entry file is compiled according to the target type.

  596. #

  597. function(dpf__add_plugin_target_definition NAME TARGET)

  598.   string(TOUPPER "${TARGET}" _upperTarget)

  599. 

  600.   # resolve the alias into the proper name

  601.   # the name "vst2" is new, "vst" is legacy

  602.   if(_upperTarget STREQUAL "VST2")

  603.     set(_upperTarget "VST")

  604.   endif()

  605. 

  606.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  607. endfunction()

  608. 

  609. # dpf__add_lv2_ttl_generator

  610. # ------------------------------------------------------------------------------

  611. #

  612. # Build the LV2 TTL generator.

  613. #

  614. function(dpf__add_lv2_ttl_generator)

  615.   if(TARGET lv2_ttl_generator)

  616.     return()

  617.   endif()

  618.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  619.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  620.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  621.   endif()

  622. endfunction()

  623. 

  624. # dpf__ensure_sources_non_empty

  625. # ------------------------------------------------------------------------------

  626. #

  627. # Ensure the given source list contains at least one file.

  628. # The function appends an empty source file to the list if necessary.

  629. # This is useful when CMake does not permit to add targets without sources.

  630. #

  631. function(dpf__ensure_sources_non_empty VAR)

  632.   if(NOT "" STREQUAL "${${VAR}}")

  633.     return()

  634.   endif()

  635.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  636.   if(NOT EXISTS "${_file}")

  637.     file(WRITE "${_file}" "")

  638.   endif()

  639.   set("${VAR}" "${_file}" PARENT_SCOPE)

  640. endfunction()

  641. 

  642. # dpf__create_dummy_source_list

  643. # ------------------------------------------------------------------------------

  644. #

  645. # Create a dummy source list which is equivalent to compiling nothing.

  646. # This is only for compatibility with older CMake versions, which refuse to add

  647. # targets without any sources.

  648. #

  649. macro(dpf__create_dummy_source_list VAR)

  650.   set("${VAR}")

  651.   if(CMAKE_VERSION VERSION_LESS "3.11")

  652.     dpf__ensure_sources_non_empty("${VAR}")

  653.   endif()

  654. endmacro()

  655. 

  656. # dpf__warn_once

  657. # ------------------------------------------------------------------------------

  658. #

  659. # Prints a warning message once only.

  660. #

  661. function(dpf__warn_once_only TOKEN MESSAGE)

  662.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  663.   if(NOT _warned)

  664.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  665.     message(WARNING "${MESSAGE}")

  666.   endif()

  667. endfunction()