DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1059 Commits
7 Branches
91MB
Tree: 3bfe7ccc7a
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '3bfe7ccc7a'
${ noResults }
DPF/cmake/DPF-plugin.cmake

598 lines
20KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.   else()

  139.     add_library("${NAME}-ui" INTERFACE)

  140.   endif()

  141. 

  142.   ###

  143.   foreach(_target ${_dpf_plugin_TARGETS})

  144.     if(_target STREQUAL "jack")

  145.       dpf__build_jack("${NAME}" "${_dgl_library}")

  146.     elseif(_target STREQUAL "ladspa")

  147.       dpf__build_ladspa("${NAME}")

  148.     elseif(_target STREQUAL "dssi")

  149.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  150.     elseif(_target STREQUAL "lv2")

  151.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  152.     elseif(_target STREQUAL "vst2")

  153.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  154.     else()

  155.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  156.     endif()

  157.   endforeach()

  158. endfunction()

  159. 

  160. # ------------------------------------------------------------------------------

  161. # DPF private functions (prefixed with `dpf__`)

  162. # ------------------------------------------------------------------------------

  163. 

  164. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  165. #       to the output directory.

  166. #

  167. 

  168. # dpf__build_jack

  169. # ------------------------------------------------------------------------------

  170. #

  171. # Add build rules for a JACK program.

  172. #

  173. function(dpf__build_jack NAME DGL_LIBRARY)

  174.   find_package(PkgConfig)

  175.   pkg_check_modules(JACK "jack")

  176.   if(NOT JACK_FOUND)

  177.     dpf__warn_once_only(missing_jack

  178.       "JACK is not found, skipping the `jack` plugin targets")

  179.     return()

  180.   endif()

  181. 

  182.   link_directories(${JACK_LIBRARY_DIRS})

  183. 

  184.   dpf__create_dummy_source_list(_no_srcs)

  185. 

  186.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  187.   dpf__add_plugin_main("${NAME}-jack" "jack")

  188.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  189.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  190.   set_target_properties("${NAME}-jack" PROPERTIES

  191.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  192.     OUTPUT_NAME "${NAME}")

  193. 

  194.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  195.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  196. endfunction()

  197. 

  198. # dpf__build_ladspa

  199. # ------------------------------------------------------------------------------

  200. #

  201. # Add build rules for a DSSI plugin.

  202. #

  203. function(dpf__build_ladspa NAME)

  204.   dpf__create_dummy_source_list(_no_srcs)

  205. 

  206.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  207.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  208.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  209.   set_target_properties("${NAME}-ladspa" PROPERTIES

  210.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  211.     OUTPUT_NAME "${NAME}-ladspa"

  212.     PREFIX "")

  213. endfunction()

  214. 

  215. # dpf__build_dssi

  216. # ------------------------------------------------------------------------------

  217. #

  218. # Add build rules for a DSSI plugin.

  219. #

  220. function(dpf__build_dssi NAME DGL_LIBRARY)

  221.   find_package(PkgConfig)

  222.   pkg_check_modules(LIBLO "liblo")

  223.   if(NOT LIBLO_FOUND)

  224.     dpf__warn_once_only(missing_liblo

  225.       "liblo is not found, skipping the `dssi` plugin targets")

  226.     return()

  227.   endif()

  228. 

  229.   link_directories(${LIBLO_LIBRARY_DIRS})

  230. 

  231.   dpf__create_dummy_source_list(_no_srcs)

  232. 

  233.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  234.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  235.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  236.   set_target_properties("${NAME}-dssi" PROPERTIES

  237.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  238.     OUTPUT_NAME "${NAME}-dssi"

  239.     PREFIX "")

  240. 

  241.   if(DGL_LIBRARY)

  242.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  243.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  244.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  245.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  246.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  247.       OUTPUT_NAME "${NAME}_ui")

  248. 

  249.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  250.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  251.   endif()

  252. endfunction()

  253. 

  254. # dpf__build_lv2

  255. # ------------------------------------------------------------------------------

  256. #

  257. # Add build rules for a LV2 plugin.

  258. #

  259. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  260.   dpf__create_dummy_source_list(_no_srcs)

  261. 

  262.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  263.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  264.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  265.   set_target_properties("${NAME}-lv2" PROPERTIES

  266.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  267.     OUTPUT_NAME "${NAME}_dsp"

  268.     PREFIX "")

  269. 

  270.   if(DGL_LIBRARY)

  271.     if(MONOLITHIC)

  272.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  273.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  274.       set_target_properties("${NAME}-lv2" PROPERTIES

  275.         OUTPUT_NAME "${NAME}")

  276.     else()

  277.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  278.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  279.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  280.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  281.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  282.         OUTPUT_NAME "${NAME}_ui"

  283.         PREFIX "")

  284.     endif()

  285.   endif()

  286. 

  287.   dpf__add_lv2_ttl_generator()

  288.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  289. 

  290.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  291.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  292.     "$<TARGET_FILE:lv2_ttl_generator>"

  293.     "$<TARGET_FILE:${NAME}-lv2>"

  294.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  295. endfunction()

  296. 

  297. # dpf__build_vst2

  298. # ------------------------------------------------------------------------------

  299. #

  300. # Add build rules for a VST2 plugin.

  301. #

  302. function(dpf__build_vst2 NAME DGL_LIBRARY)

  303.   dpf__create_dummy_source_list(_no_srcs)

  304. 

  305.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  306.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  307.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  308.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  309.   set_target_properties("${NAME}-vst2" PROPERTIES

  310.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  311.     OUTPUT_NAME "${NAME}-vst2"

  312.     PREFIX "")

  313. endfunction()

  314. 

  315. # dpf__add_dgl_cairo

  316. # ------------------------------------------------------------------------------

  317. #

  318. # Add the Cairo variant of DGL, if not already available.

  319. #

  320. function(dpf__add_dgl_cairo)

  321.   if(TARGET dgl-cairo)

  322.     return()

  323.   endif()

  324. 

  325.   find_package(PkgConfig)

  326.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  327. 

  328.   link_directories(${CAIRO_LIBRARY_DIRS})

  329. 

  330.   dpf__add_static_library(dgl-cairo STATIC

  331.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  333.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  335.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  336.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  337.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  338.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  339.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  340.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  341.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  342.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  343.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  344.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  345.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  346.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  347.   if(NOT APPLE)

  348.     target_sources(dgl-cairo PRIVATE

  349.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  350.   else()

  351.     target_sources(dgl-cairo PRIVATE

  352.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  353.   endif()

  354.   target_include_directories(dgl-cairo PUBLIC

  355.     "${DPF_ROOT_DIR}/dgl")

  356.   target_include_directories(dgl-cairo PRIVATE

  357.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  358. 

  359.   dpf__add_dgl_system_libs()

  360.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  361. 

  362.   add_library(dgl-cairo-definitions INTERFACE)

  363.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  364. 

  365.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  366.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  367. endfunction()

  368. 

  369. # dpf__add_dgl_opengl

  370. # ------------------------------------------------------------------------------

  371. #

  372. # Add the OpenGL variant of DGL, if not already available.

  373. #

  374. function(dpf__add_dgl_opengl)

  375.   if(TARGET dgl-opengl)

  376.     return()

  377.   endif()

  378. 

  379.   if(NOT OpenGL_GL_PREFERENCE)

  380.     set(OpenGL_GL_PREFERENCE "LEGACY")

  381.   endif()

  382. 

  383.   find_package(OpenGL REQUIRED)

  384. 

  385.   dpf__add_static_library(dgl-opengl STATIC

  386.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  387.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  388.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  389.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  390.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  391.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  392.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  393.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  394.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  395.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  396.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  397.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  398.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  399.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  400.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  401.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  402.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  403.   if(NOT APPLE)

  404.     target_sources(dgl-opengl PRIVATE

  405.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  406.   else()

  407.     target_sources(dgl-opengl PRIVATE

  408.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  409.   endif()

  410.   target_include_directories(dgl-opengl PUBLIC

  411.     "${DPF_ROOT_DIR}/dgl")

  412.   target_include_directories(dgl-opengl PRIVATE

  413.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  414. 

  415.   dpf__add_dgl_system_libs()

  416.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  417. 

  418.   add_library(dgl-opengl-definitions INTERFACE)

  419.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  420. 

  421.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  422.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  423. endfunction()

  424. 

  425. # dpf__add_dgl_system_libs

  426. # ------------------------------------------------------------------------------

  427. #

  428. # Find system libraries required by DGL and add them as an interface target.

  429. #

  430. function(dpf__add_dgl_system_libs)

  431.   if(TARGET dgl-system-libs)

  432.     return()

  433.   endif()

  434.   add_library(dgl-system-libs INTERFACE)

  435.   add_library(dgl-system-libs-definitions INTERFACE)

  436.   if(HAIKU)

  437.     target_link_libraries(dgl-system-libs INTERFACE "be")

  438.   elseif(WIN32)

  439.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  440.   elseif(APPLE)

  441.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  442.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}")

  443.   else()

  444.     find_package(X11 REQUIRED)

  445.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  446.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  447.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  448.   endif()

  449.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  450. endfunction()

  451. 

  452. # dpf__add_executable

  453. # ------------------------------------------------------------------------------

  454. #

  455. # Adds an executable target, and set some default properties on the target.

  456. #

  457. function(dpf__add_executable NAME)

  458.   add_executable("${NAME}" ${ARGN})

  459.   set_target_properties("${NAME}" PROPERTIES

  460.     POSITION_INDEPENDENT_CODE TRUE

  461.     C_VISIBILITY_PRESET "hidden"

  462.     CXX_VISIBILITY_PRESET "hidden"

  463.     VISIBILITY_INLINES_HIDDEN TRUE)

  464. endfunction()

  465. 

  466. # dpf__add_module

  467. # ------------------------------------------------------------------------------

  468. #

  469. # Adds a module target, and set some default properties on the target.

  470. #

  471. function(dpf__add_module NAME)

  472.   add_library("${NAME}" MODULE ${ARGN})

  473.   set_target_properties("${NAME}" PROPERTIES

  474.     POSITION_INDEPENDENT_CODE TRUE

  475.     C_VISIBILITY_PRESET "hidden"

  476.     CXX_VISIBILITY_PRESET "hidden"

  477.     VISIBILITY_INLINES_HIDDEN TRUE)

  478.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  479.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  480.   endif()

  481. endfunction()

  482. 

  483. # dpf__add_static_library

  484. # ------------------------------------------------------------------------------

  485. #

  486. # Adds a static library target, and set some default properties on the target.

  487. #

  488. function(dpf__add_static_library NAME)

  489.   add_library("${NAME}" STATIC ${ARGN})

  490.   set_target_properties("${NAME}" PROPERTIES

  491.     POSITION_INDEPENDENT_CODE TRUE

  492.     C_VISIBILITY_PRESET "hidden"

  493.     CXX_VISIBILITY_PRESET "hidden"

  494.     VISIBILITY_INLINES_HIDDEN TRUE)

  495. endfunction()

  496. 

  497. # dpf__add_plugin_main

  498. # ------------------------------------------------------------------------------

  499. #

  500. # Adds plugin code to the given target.

  501. #

  502. function(dpf__add_plugin_main NAME TARGET)

  503.   target_sources("${NAME}" PRIVATE

  504.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  505.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  506. endfunction()

  507. 

  508. # dpf__add_ui_main

  509. # ------------------------------------------------------------------------------

  510. #

  511. # Adds UI code to the given target (only if the target has UI).

  512. #

  513. function(dpf__add_ui_main NAME TARGET HAS_UI)

  514.   if(HAS_UI)

  515.     target_sources("${NAME}" PRIVATE

  516.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  517.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  518.   endif()

  519. endfunction()

  520. 

  521. # dpf__add_plugin_target_definition

  522. # ------------------------------------------------------------------------------

  523. #

  524. # Adds the plugins target macro definition.

  525. # This selects which entry file is compiled according to the target type.

  526. #

  527. function(dpf__add_plugin_target_definition NAME TARGET)

  528.   string(TOUPPER "${TARGET}" _upperTarget)

  529. 

  530.   # resolve the alias into the proper name

  531.   # the name "vst2" is new, "vst" is legacy

  532.   if(_upperTarget STREQUAL "VST2")

  533.     set(_upperTarget "VST")

  534.   endif()

  535. 

  536.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  537. endfunction()

  538. 

  539. # dpf__add_lv2_ttl_generator

  540. # ------------------------------------------------------------------------------

  541. #

  542. # Build the LV2 TTL generator.

  543. #

  544. function(dpf__add_lv2_ttl_generator)

  545.   if(TARGET lv2_ttl_generator)

  546.     return()

  547.   endif()

  548.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  549.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  550.     target_link_libraries(lv2_ttl_generator "dl")

  551.   endif()

  552. endfunction()

  553. 

  554. # dpf__ensure_sources_non_empty

  555. # ------------------------------------------------------------------------------

  556. #

  557. # Ensure the given source list contains at least one file.

  558. # The function appends an empty source file to the list if necessary.

  559. # This is useful when CMake does not permit to add targets without sources.

  560. #

  561. function(dpf__ensure_sources_non_empty VAR)

  562.   if(NOT "" STREQUAL "${${VAR}}")

  563.     return()

  564.   endif()

  565.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  566.   if(NOT EXISTS "${_file}")

  567.     file(WRITE "${_file}" "")

  568.   endif()

  569.   set("${VAR}" "${_file}" PARENT_SCOPE)

  570. endfunction()

  571. 

  572. # dpf__create_dummy_source_list

  573. # ------------------------------------------------------------------------------

  574. #

  575. # Create a dummy source list which is equivalent to compiling nothing.

  576. # This is only for compatibility with older CMake versions, which refuse to add

  577. # targets without any sources.

  578. #

  579. macro(dpf__create_dummy_source_list VAR)

  580.   set("${VAR}")

  581.   if(CMAKE_VERSION VERSION_LESS "3.11")

  582.     dpf__ensure_sources_non_empty("${VAR}")

  583.   endif()

  584. endmacro()

  585. 

  586. # dpf__warn_once

  587. # ------------------------------------------------------------------------------

  588. #

  589. # Prints a warning message once only.

  590. #

  591. function(dpf__warn_once_only TOKEN MESSAGE)

  592.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  593.   if(NOT _warned)

  594.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  595.     message(WARNING "${MESSAGE}")

  596.   endif()

  597. endfunction()