DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2467 Commits
7 Branches
79MB
Tree: 34fc4c4ee6
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '34fc4c4ee6'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1751 lines
62KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `FORCE_NATIVE_AUDIO_FALLBACK`

  108. #       force the JACK/Standalone format to use native audio fallback instead of JACK

  109. #

  110. #   `SKIP_NATIVE_AUDIO_FALLBACK`

  111. #       force the JACK/Standalone format to always use JACK, skipping native audio fallback

  112. #

  113. #   `USE_FILE_BROWSER`

  114. #       enable file browser dialog APIs

  115. #

  116. #   `USE_WEB_VIEW`

  117. #       enable web browser view APIs

  118. #

  119. function(dpf_add_plugin NAME)

  120.   set(options MONOLITHIC NO_SHARED_RESOURCES FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER USE_WEB_VIEW)

  121.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  122.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  123.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  124. 

  125.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  126.     set(_dpf_plugin_UI_TYPE "opengl")

  127.   endif()

  128. 

  129.   set(_dgl_library)

  130.   if(_dpf_plugin_FILES_UI)

  131.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  132.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  133.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  134.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  135.       set(_dgl_library dgl-cairo)

  136.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  137.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  138.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  139.       set(_dgl_library dgl-external)

  140.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  141.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  142.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  143.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  144.       set(_dgl_library dgl-gles2)

  145.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  146.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  147.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  148.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  149.       set(_dgl_library dgl-gles3)

  150.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  151.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  152.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  153.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  154.       set(_dgl_library dgl-opengl)

  155.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  156.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  157.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  158.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  159.       set(_dgl_library dgl-opengl3)

  160.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  161.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  162.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  163.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  164.       set(_dgl_library dgl-vulkan)

  165.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  166.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  167.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  168.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  169.       set(_dgl_library dgl-external)

  170.     else()

  171.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  172.     endif()

  173.   else()

  174.     set(_dpf_plugin_UI_TYPE "")

  175.   endif()

  176. 

  177.   set(_dgl_has_ui OFF)

  178.   if(_dgl_library)

  179.     set(_dgl_has_ui ON)

  180.   endif()

  181. 

  182.   ###

  183.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  184.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  185.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  186. 

  187.   ###

  188.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  189.   target_include_directories("${NAME}" PUBLIC

  190.     "${DPF_ROOT_DIR}/distrho")

  191. 

  192.   if(_dpf_plugin_USE_FILE_BROWSER)

  193.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  194.   endif()

  195. 

  196.   if(_dpf_plugin_USE_WEB_VIEW)

  197.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  198.   endif()

  199. 

  200.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  201.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  202.   endif()

  203. 

  204.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  205.     target_link_libraries("${NAME}" PRIVATE "dl")

  206.   endif()

  207. 

  208.   if(_dgl_library)

  209.     # make sure that all code will see DGL_* definitions

  210.     target_link_libraries("${NAME}" PUBLIC

  211.       "${_dgl_library}-definitions"

  212.       dgl-system-libs-definitions

  213.       dgl-system-libs)

  214.   endif()

  215. 

  216.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  217.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  218. 

  219.   if(_dgl_library)

  220.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  221.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  222.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  223.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  224.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  225.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  226.           OUTPUT_STRIP_TRAILING_WHITESPACE

  227.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  228.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  229.       endif()

  230.     endif()

  231.     # add the files containing C++17 or Objective-C classes

  232.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  233.   else()

  234.     add_library("${NAME}-ui" INTERFACE)

  235.   endif()

  236. 

  237.   ###

  238.   foreach(_target ${_dpf_plugin_TARGETS})

  239.     if(_target STREQUAL "jack")

  240.       dpf__build_jack("${NAME}"

  241.                       "${_dgl_has_ui}"

  242.                       "${_dpf_plugin_FORCE_NATIVE_AUDIO_FALLBACK}"

  243.                       "${_dpf_plugin_SKIP_NATIVE_AUDIO_FALLBACK}"

  244.                       "${_dpf_plugin_USE_FILE_BROWSER}")

  245.     elseif(_target STREQUAL "ladspa")

  246.       dpf__build_ladspa("${NAME}")

  247.     elseif(_target STREQUAL "dssi")

  248.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  249.     elseif(_target STREQUAL "lv2")

  250.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  251.     elseif(_target STREQUAL "vst2")

  252.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  253.     elseif(_target STREQUAL "vst3")

  254.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  255.     elseif(_target STREQUAL "clap")

  256.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  257.     elseif(_target STREQUAL "au")

  258.       if (APPLE)

  259.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  260.       endif()

  261.     elseif(_target STREQUAL "static")

  262.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  263.     else()

  264.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  265.     endif()

  266.   endforeach()

  267. endfunction()

  268. 

  269. # dpf_add_executable(target <args...>)

  270. # ------------------------------------------------------------------------------

  271. #

  272. # Add a simple executable built using the DISTRHO Plugin Framework.

  273. #

  274. # ------------------------------------------------------------------------------

  275. # Arguments:

  276. #

  277. #   `UI_TYPE` <type>

  278. #       the user interface type, can be one of the following:

  279. #          - cairo

  280. #          - external

  281. #          - gles2

  282. #          - gles3

  283. #          - opengl (default)

  284. #          - opengl3

  285. #          - vulkan

  286. #          - webview

  287. #

  288. #   `NO_SHARED_RESOURCES`

  289. #       do not build DPF shared resources (fonts, etc)

  290. #

  291. #   `USE_FILE_BROWSER`

  292. #       enable file browser dialog APIs

  293. #

  294. #   `USE_WEB_VIEW`

  295. #       enable web browser view APIs

  296. #

  297. function(dpf_add_executable NAME)

  298.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  299.   set(oneValueArgs UI_TYPE)

  300.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  301. 

  302.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  303.     set(_dpf_plugin_UI_TYPE "opengl")

  304.   endif()

  305. 

  306.   set(_dgl_library)

  307.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  308.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  309.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  310.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  311.     set(_dgl_library dgl-cairo)

  312.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  313.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  314.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  315.     set(_dgl_library dgl-external)

  316.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  317.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  318.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  319.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  320.     set(_dgl_library dgl-gles2)

  321.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  322.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  323.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  324.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  325.     set(_dgl_library dgl-gles3)

  326.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  327.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  328.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  329.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  330.     set(_dgl_library dgl-opengl)

  331.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  332.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  333.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  334.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  335.     set(_dgl_library dgl-opengl3)

  336.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  337.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  338.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  339.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  340.     set(_dgl_library dgl-vulkan)

  341.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  342.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  343.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  344.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  345.     set(_dgl_library dgl-external)

  346.   else()

  347.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  348.   endif()

  349. 

  350.   set(_dgl_has_ui OFF)

  351.   if(_dgl_library)

  352.     set(_dgl_has_ui ON)

  353.   endif()

  354. 

  355.   dpf__create_dummy_source_list(_no_srcs)

  356.   dpf__add_executable("${NAME}" ${_no_srcs})

  357.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  358.   set_target_properties("${NAME}" PROPERTIES

  359.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  360.     OUTPUT_NAME "${NAME}")

  361. 

  362.   if(EMSCRIPTEN)

  363.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  364.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  365.     target_link_options("${NAME}"

  366.       PRIVATE

  367.         -sEXPORTED_RUNTIME_METHODS=dynCall)

  368.   endif()

  369. 

  370.   if(_dpf_plugin_USE_FILE_BROWSER)

  371.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  372.     if(EMSCRIPTEN)

  373.       target_link_options("${NAME}" PRIVATE -sEXPORTED_RUNTIME_METHODS=FS,cwrap)

  374.     endif()

  375.   endif()

  376. 

  377.   if(_dpf_plugin_USE_WEB_VIEW)

  378.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  379.   endif()

  380. 

  381.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  382.     target_link_libraries("${NAME}" PRIVATE "dl")

  383.   endif()

  384. 

  385.   if(_dgl_library)

  386.     # make sure that all code will see DGL_* definitions

  387.     target_link_libraries("${NAME}" PUBLIC

  388.       "${_dgl_library}"

  389.       "${_dgl_library}-definitions"

  390.       dgl-system-libs-definitions

  391.       dgl-system-libs)

  392.     # extra linkage for linux web view

  393.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  394.       target_link_libraries("${NAME}" PRIVATE "rt")

  395.     endif()

  396.     # add the files containing C++17 or Objective-C classes

  397.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  398.   endif()

  399. endfunction()

  400. 

  401. # ------------------------------------------------------------------------------

  402. # DPF private functions (prefixed with `dpf__`)

  403. # ------------------------------------------------------------------------------

  404. 

  405. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  406. #       to the output directory.

  407. #

  408. 

  409. # dpf__build_jack

  410. # ------------------------------------------------------------------------------

  411. #

  412. # Add build rules for a JACK/Standalone program.

  413. #

  414. function(dpf__build_jack NAME HAS_UI FORCE_NATIVE_AUDIO_FALLBACK SKIP_NATIVE_AUDIO_FALLBACK USE_FILE_BROWSER)

  415.   dpf__create_dummy_source_list(_no_srcs)

  416. 

  417.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  418.   dpf__add_plugin_main("${NAME}-jack" "jack")

  419.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  420.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  421.   set_target_properties("${NAME}-jack" PROPERTIES

  422.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  423.     OUTPUT_NAME "${NAME}")

  424. 

  425.   if(EMSCRIPTEN)

  426.     configure_file("${DPF_ROOT_DIR}/utils/emscripten.html.in"

  427.       "${PROJECT_BINARY_DIR}/bin/${NAME}.html" @ONLY)

  428.     target_link_options("${NAME}-jack"

  429.       PRIVATE

  430.         -sEXPORTED_RUNTIME_METHODS=dynCall

  431.         $<$<BOOL:${USE_FILE_BROWSER}>:-sEXPORTED_RUNTIME_METHODS=FS,cwrap>)

  432.   endif()

  433. 

  434.   if(NOT FORCE_NATIVE_AUDIO_FALLBACK)

  435.     target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  436.     target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  437.   endif()

  438. 

  439.   if(SKIP_NATIVE_AUDIO_FALLBACK)

  440.     return()

  441.   endif()

  442. 

  443.   find_package(PkgConfig QUIET)

  444.   if(PKG_CONFIG_FOUND)

  445.     pkg_check_modules(SDL2 "sdl2")

  446.   else()

  447.     set(SDL2_FOUND FALSE)

  448.   endif()

  449.   if(SDL2_FOUND)

  450.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  451.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  452.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  453.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  454.   endif()

  455. 

  456.   if(APPLE OR WIN32)

  457.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  458.   elseif(EMSCRIPTEN)

  459.   else()

  460.     find_package(Threads)

  461.     pkg_check_modules(ALSA "alsa")

  462.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  463.     if(ALSA_FOUND)

  464.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  465.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  466.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  467.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  468.     endif()

  469.     if(PULSEAUDIO_FOUND)

  470.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  471.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  472.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  473.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  474.     endif()

  475.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  476.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  477.     endif()

  478.   endif()

  479. 

  480.   # for RtAudio native fallback

  481.   if(APPLE)

  482.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  483.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  484.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  485.     target_link_libraries("${NAME}-jack" PRIVATE

  486.       "${APPLE_COREAUDIO_FRAMEWORK}"

  487.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  488.       "${APPLE_COREMIDI_FRAMEWORK}")

  489.   elseif(WIN32)

  490.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  491.     if(HAS_UI AND MINGW)

  492.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  493.     endif()

  494.   endif()

  495. endfunction()

  496. 

  497. # dpf__build_ladspa

  498. # ------------------------------------------------------------------------------

  499. #

  500. # Add build rules for a LADSPA plugin.

  501. #

  502. function(dpf__build_ladspa NAME)

  503.   dpf__create_dummy_source_list(_no_srcs)

  504. 

  505.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  506.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  507.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  508.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  509.   set_target_properties("${NAME}-ladspa" PROPERTIES

  510.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  511.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  512.     OUTPUT_NAME "${NAME}-ladspa"

  513.     PREFIX "")

  514. endfunction()

  515. 

  516. # dpf__build_dssi

  517. # ------------------------------------------------------------------------------

  518. #

  519. # Add build rules for a DSSI plugin.

  520. #

  521. function(dpf__build_dssi NAME HAS_UI)

  522.   find_package(PkgConfig QUIET)

  523.   if(PKG_CONFIG_FOUND)

  524.     pkg_check_modules(LIBLO "liblo")

  525.   else()

  526.     set(LIBLO_FOUND FALSE)

  527.   endif()

  528.   if(NOT LIBLO_FOUND)

  529.     dpf__warn_once_only(missing_liblo

  530.       "liblo is not found, skipping the `dssi` plugin targets")

  531.     return()

  532.   endif()

  533. 

  534.   dpf__create_dummy_source_list(_no_srcs)

  535. 

  536.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  537.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  538.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  539.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  540.   set_target_properties("${NAME}-dssi" PROPERTIES

  541.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  542.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  543.     OUTPUT_NAME "${NAME}-dssi"

  544.     PREFIX "")

  545. 

  546.   if(HAS_UI)

  547.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  548.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  549.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  550.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  551.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  552.       OUTPUT_NAME "${NAME}_ui")

  553. 

  554.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  555.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  556.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  557.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  558.   endif()

  559. endfunction()

  560. 

  561. # dpf__build_lv2

  562. # ------------------------------------------------------------------------------

  563. #

  564. # Add build rules for an LV2 plugin.

  565. #

  566. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  567.   dpf__create_dummy_source_list(_no_srcs)

  568. 

  569.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  570.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  571.   if(HAS_UI AND MONOLITHIC)

  572.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  573.   else()

  574.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  575.   endif()

  576.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  577.   set_target_properties("${NAME}-lv2" PROPERTIES

  578.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  579.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  580.     OUTPUT_NAME "${NAME}_dsp"

  581.     PREFIX "")

  582. 

  583.   if(HAS_UI)

  584.     if(MONOLITHIC)

  585.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  586.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  587.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  588.       set_target_properties("${NAME}-lv2" PROPERTIES

  589.         OUTPUT_NAME "${NAME}")

  590.     else()

  591.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  592.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  593.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  594.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  595.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  596.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  597.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  598.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  599.         OUTPUT_NAME "${NAME}_ui"

  600.         PREFIX "")

  601.     endif()

  602.   endif()

  603. 

  604.   dpf__add_lv2_ttl_generator()

  605.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  606. 

  607.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  608. 

  609.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  610.     COMMAND

  611.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  612.     "$<TARGET_FILE:lv2_ttl_generator>"

  613.     "$<TARGET_FILE:${NAME}-lv2>"

  614.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  615. endfunction()

  616. 

  617. # dpf__build_vst2

  618. # ------------------------------------------------------------------------------

  619. #

  620. # Add build rules for a VST2 plugin.

  621. #

  622. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  623.   dpf__create_dummy_source_list(_no_srcs)

  624. 

  625.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  626.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  627.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  628.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  629.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  630.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  631.   set_target_properties("${NAME}-vst2" PROPERTIES

  632.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  633.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  634.     OUTPUT_NAME "${NAME}-vst2"

  635.     PREFIX "")

  636.   if(APPLE)

  637.     set_target_properties("${NAME}-vst2" PROPERTIES

  638.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  639.       OUTPUT_NAME "${NAME}"

  640.       SUFFIX "")

  641.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  642.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  643.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  644.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  645.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  646.   endif()

  647. endfunction()

  648. 

  649. # dpf__determine_vst3_package_architecture

  650. # ------------------------------------------------------------------------------

  651. #

  652. # Determines the package architecture for a VST3 plugin target.

  653. #

  654. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  655.   # if set by variable, override the detection

  656.   if(DPF_VST3_ARCHITECTURE)

  657.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  658.     return()

  659.   endif()

  660. 

  661.   # not used on Apple, which supports universal binary

  662.   if(APPLE)

  663.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  664.     return()

  665.   endif()

  666. 

  667.   # identify the target processor (special case of MSVC, problematic sometimes)

  668.   if(MSVC)

  669.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  670.   else()

  671.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  672.   endif()

  673. 

  674.   # transform the processor name to a format that VST3 recognizes

  675.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  676.     set(vst3_package_arch "x86_64")

  677.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  678.     if(WIN32)

  679.       set(vst3_package_arch "x86")

  680.     else()

  681.       set(vst3_package_arch "i386")

  682.     endif()

  683.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  684.     set(vst3_package_arch "${vst3_system_arch}")

  685.   else()

  686.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  687.   endif()

  688. 

  689.   # TODO: the detections for Windows arm/arm64 when supported

  690. 

  691.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  692. endfunction()

  693. 

  694. # dpf__build_vst3

  695. # ------------------------------------------------------------------------------

  696. #

  697. # Add build rules for a VST3 plugin.

  698. #

  699. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  700.   dpf__determine_vst3_package_architecture(vst3_arch)

  701. 

  702.   dpf__create_dummy_source_list(_no_srcs)

  703. 

  704.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  705.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  706.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  707.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  708.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  709.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  710.   set_target_properties("${NAME}-vst3" PROPERTIES

  711.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  712.     OUTPUT_NAME "${NAME}"

  713.     PREFIX "")

  714. 

  715.   if(APPLE)

  716.     set_target_properties("${NAME}-vst3" PROPERTIES

  717.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  718.       SUFFIX "")

  719.   elseif(WIN32)

  720.     set_target_properties("${NAME}-vst3" PROPERTIES

  721.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  722.   else()

  723.     set_target_properties("${NAME}-vst3" PROPERTIES

  724.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  725.   endif()

  726. 

  727.   if(APPLE)

  728.     # Uses the same macOS bundle template as VST2

  729.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  730.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  731.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  732.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  733.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  734.   endif()

  735. endfunction()

  736. 

  737. # dpf__build_clap

  738. # ------------------------------------------------------------------------------

  739. #

  740. # Add build rules for a CLAP plugin.

  741. #

  742. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  743.   dpf__create_dummy_source_list(_no_srcs)

  744. 

  745.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  746.   dpf__add_plugin_main("${NAME}-clap" "clap")

  747.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  748.   dpf__set_module_export_list("${NAME}-clap" "clap")

  749.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  750.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  751.   set_target_properties("${NAME}-clap" PROPERTIES

  752.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  753.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  754.     OUTPUT_NAME "${NAME}"

  755.     PREFIX ""

  756.     SUFFIX ".clap")

  757. 

  758.   if(APPLE)

  759.     set_target_properties("${NAME}-clap" PROPERTIES

  760.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  761.       OUTPUT_NAME "${NAME}"

  762.       SUFFIX "")

  763.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  764.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  765.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  766.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  767.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  768.   endif()

  769. endfunction()

  770. 

  771. # dpf__build_au

  772. # ------------------------------------------------------------------------------

  773. #

  774. # Add build rules for an AUv2 plugin.

  775. #

  776. function(dpf__build_au NAME HAS_UI)

  777.   dpf__create_dummy_source_list(_no_srcs)

  778. 

  779.   dpf__add_module("${NAME}-au" ${_no_srcs})

  780.   dpf__add_plugin_main("${NAME}-au" "au")

  781.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  782.   dpf__set_module_export_list("${NAME}-au" "au")

  783.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  784.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  785.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  786.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  787.   target_link_libraries("${NAME}-au" PRIVATE

  788.     "${NAME}-dsp"

  789.     "${NAME}-ui"

  790.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  791.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  792.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  793.   set_target_properties("${NAME}-au" PROPERTIES

  794.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  795.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  796.     OUTPUT_NAME "${NAME}"

  797.     PREFIX ""

  798.     SUFFIX "")

  799. 

  800.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  801.   dpf__add_plugin_main("${NAME}-export" "export")

  802.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  803.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  804. 

  805.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  806. 

  807.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  808.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  809.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  810. 

  811.   add_dependencies("${NAME}-au" "${NAME}-export")

  812. 

  813.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  814.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  815. endfunction()

  816. 

  817. # dpf__build_static

  818. # ------------------------------------------------------------------------------

  819. #

  820. # Add build rules for a static library.

  821. #

  822. function(dpf__build_static NAME HAS_UI)

  823.   dpf__create_dummy_source_list(_no_srcs)

  824. 

  825.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  826.   dpf__add_plugin_main("${NAME}-static" "static")

  827.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  828.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  829. 

  830.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  831.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  832.   foreach(src ${dsp_srcs})

  833.     target_sources("${NAME}-static" PRIVATE ${src})

  834.   endforeach()

  835.   foreach(src ${ui_srcs})

  836.     target_sources("${NAME}-static" PRIVATE ${src})

  837.   endforeach()

  838. 

  839.   set_target_properties("${NAME}-static" PROPERTIES

  840.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  841.     OUTPUT_NAME "${NAME}"

  842.     PREFIX "")

  843. endfunction()

  844. 

  845. # dpf__add_dgl_cairo

  846. # ------------------------------------------------------------------------------

  847. #

  848. # Add the Cairo variant of DGL, if not already available.

  849. #

  850. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  851.   if(TARGET dgl-cairo)

  852.     return()

  853.   endif()

  854. 

  855.   find_package(PkgConfig REQUIRED)

  856.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  857. 

  858.   link_directories(${CAIRO_LIBRARY_DIRS})

  859. 

  860.   dpf__add_static_library(dgl-cairo STATIC

  861.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  862.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  863.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  864.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  865.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  866.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  867.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  868.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  869.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  870.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  871.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  872.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  873.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  874.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  875.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  876.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  877.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  878.   if(SHARED_RESOURCES)

  879.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  880.   else()

  881.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  882.   endif()

  883.   if(APPLE)

  884.     target_sources(dgl-cairo PRIVATE

  885.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  886.   else()

  887.     target_sources(dgl-cairo PRIVATE

  888.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  889.   endif()

  890.   target_include_directories(dgl-cairo PUBLIC

  891.     "${DPF_ROOT_DIR}/dgl")

  892.   target_include_directories(dgl-cairo PUBLIC

  893.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  894. 

  895.   if(USE_FILE_BROWSER)

  896.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  897.   endif()

  898. 

  899.   if(USE_WEB_VIEW)

  900.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  901.     if(APPLE)

  902.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  903.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  904.     elseif(WIN32)

  905.       target_sources(dgl-cairo PRIVATE

  906.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  907.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  908.         PROPERTIES

  909.           COMPILE_FLAGS

  910.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  911.     endif()

  912.   endif()

  913. 

  914.   dpf__add_dgl_system_libs()

  915.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  916. 

  917.   add_library(dgl-cairo-definitions INTERFACE)

  918.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  919. 

  920.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  921.   if(MINGW)

  922.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  923.   else()

  924.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  925.   endif()

  926.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  927. endfunction()

  928. 

  929. # dpf__add_dgl_external

  930. # ------------------------------------------------------------------------------

  931. #

  932. # Add the external variant of DGL, if not already available.

  933. #

  934. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  935.   if(TARGET dgl-external)

  936.     return()

  937.   endif()

  938. 

  939.   dpf__add_static_library(dgl-external STATIC

  940.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  941.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  942.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  943.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  944.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  945.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  946.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  947.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  948.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  949.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  950.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  951.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  952.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  953.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  954.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  955.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  956.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  957. 

  958.   if(APPLE)

  959.     target_sources(dgl-external PRIVATE

  960.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  961.   else()

  962.     target_sources(dgl-external PRIVATE

  963.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  964.   endif()

  965.   target_include_directories(dgl-external PUBLIC

  966.     "${DPF_ROOT_DIR}/dgl")

  967.   target_include_directories(dgl-external PUBLIC

  968.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  969. 

  970.   if(USE_FILE_BROWSER)

  971.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  972.   endif()

  973. 

  974.   if(USE_WEB_VIEW)

  975.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  976.     if(APPLE)

  977.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  978.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  979.     elseif(WIN32)

  980.       target_sources(dgl-external PRIVATE

  981.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  982.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  983.         PROPERTIES

  984.           COMPILE_FLAGS

  985.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  986.     endif()

  987.   endif()

  988. 

  989.   dpf__add_dgl_system_libs()

  990.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  991.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  992. 

  993.   add_library(dgl-external-definitions INTERFACE)

  994.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  995. 

  996.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  997.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  998. endfunction()

  999. 

  1000. # dpf__add_dgl_gles2

  1001. # ------------------------------------------------------------------------------

  1002. #

  1003. # Add the GLESv2 variant of DGL, if not already available.

  1004. #

  1005. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1006.   if(TARGET dgl-gles2)

  1007.     return()

  1008.   endif()

  1009. 

  1010.   if(NOT OpenGL_GL_PREFERENCE)

  1011.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1012.   endif()

  1013. 

  1014.   find_package(OpenGL REQUIRED)

  1015. 

  1016.   dpf__add_static_library(dgl-gles2 STATIC

  1017.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1018.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1019.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1020.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1021.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1022.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1023.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1024.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1025.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1026.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1027.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1028.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1029.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1030.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1031.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1032.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1033.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1034.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1035.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1036.   if(SHARED_RESOURCES)

  1037.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1038.   else()

  1039.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1040.   endif()

  1041.   if(APPLE)

  1042.     target_sources(dgl-gles2 PRIVATE

  1043.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1044.   else()

  1045.     target_sources(dgl-gles2 PRIVATE

  1046.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1047.   endif()

  1048.   target_include_directories(dgl-gles2 PUBLIC

  1049.     "${DPF_ROOT_DIR}/dgl")

  1050.   target_include_directories(dgl-gles2 PUBLIC

  1051.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1052. 

  1053.   if(APPLE)

  1054.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1055.   endif()

  1056. 

  1057.   if(USE_FILE_BROWSER)

  1058.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1059.   endif()

  1060. 

  1061.   if(USE_WEB_VIEW)

  1062.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1063.     if(APPLE)

  1064.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1065.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1066.     elseif(WIN32)

  1067.       target_sources(dgl-gles2 PRIVATE

  1068.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1069.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1070.         PROPERTIES

  1071.           COMPILE_FLAGS

  1072.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1073.     endif()

  1074.   endif()

  1075. 

  1076.   dpf__add_dgl_system_libs()

  1077.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1078.   target_link_options(dgl-gles2

  1079.     INTERFACE

  1080.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1081.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1082.   )

  1083. 

  1084.   add_library(dgl-gles2-definitions INTERFACE)

  1085.   target_compile_definitions(dgl-gles2-definitions

  1086.     INTERFACE

  1087.       DGL_USE_OPENGL3

  1088.       DGL_USE_GLES

  1089.       DGL_USE_GLES2

  1090.       DGL_OPENGL

  1091.       HAVE_OPENGL

  1092.       HAVE_DGL

  1093.   )

  1094. 

  1095.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1096.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1097. endfunction()

  1098. 

  1099. # dpf__add_dgl_gles3

  1100. # ------------------------------------------------------------------------------

  1101. #

  1102. # Add the GLESv3 variant of DGL, if not already available.

  1103. #

  1104. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1105.   if(TARGET dgl-gles3)

  1106.     return()

  1107.   endif()

  1108. 

  1109.   if(NOT OpenGL_GL_PREFERENCE)

  1110.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1111.   endif()

  1112. 

  1113.   find_package(OpenGL REQUIRED)

  1114. 

  1115.   dpf__add_static_library(dgl-gles3 STATIC

  1116.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1117.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1118.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1119.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1120.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1121.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1122.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1123.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1124.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1125.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1126.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1127.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1128.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1129.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1130.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1131.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1132.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1133.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1134.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1135.   if(SHARED_RESOURCES)

  1136.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1137.   else()

  1138.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1139.   endif()

  1140.   if(APPLE)

  1141.     target_sources(dgl-gles3 PRIVATE

  1142.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1143.   else()

  1144.     target_sources(dgl-gles3 PRIVATE

  1145.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1146.   endif()

  1147.   target_include_directories(dgl-gles3 PUBLIC

  1148.     "${DPF_ROOT_DIR}/dgl")

  1149.   target_include_directories(dgl-gles3 PUBLIC

  1150.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1151. 

  1152.   if(APPLE)

  1153.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1154.   endif()

  1155. 

  1156.   if(USE_FILE_BROWSER)

  1157.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1158.   endif()

  1159. 

  1160.   if(USE_WEB_VIEW)

  1161.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1162.     if(APPLE)

  1163.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1164.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1165.     elseif(WIN32)

  1166.       target_sources(dgl-gles3 PRIVATE

  1167.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1168.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1169.         PROPERTIES

  1170.           COMPILE_FLAGS

  1171.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1172.     endif()

  1173.   endif()

  1174. 

  1175.   dpf__add_dgl_system_libs()

  1176.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1177.   target_link_options(dgl-gles3

  1178.     INTERFACE

  1179.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=3>

  1180.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=3>

  1181.   )

  1182. 

  1183.   add_library(dgl-gles3-definitions INTERFACE)

  1184.   target_compile_definitions(dgl-gles3-definitions

  1185.     INTERFACE

  1186.       DGL_USE_OPENGL3

  1187.       DGL_USE_GLES

  1188.       DGL_USE_GLES3

  1189.       DGL_OPENGL

  1190.       HAVE_OPENGL

  1191.       HAVE_DGL

  1192.   )

  1193. 

  1194.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1195.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1196. endfunction()

  1197. 

  1198. # dpf__add_dgl_opengl

  1199. # ------------------------------------------------------------------------------

  1200. #

  1201. # Add the OpenGL variant of DGL, if not already available.

  1202. #

  1203. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1204.   if(TARGET dgl-opengl)

  1205.     return()

  1206.   endif()

  1207. 

  1208.   if(NOT OpenGL_GL_PREFERENCE)

  1209.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1210.   endif()

  1211. 

  1212.   find_package(OpenGL REQUIRED)

  1213. 

  1214.   dpf__add_static_library(dgl-opengl STATIC

  1215.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1216.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1217.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1218.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1219.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1220.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1221.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1222.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1223.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1224.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1225.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1226.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1227.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1228.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1229.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1230.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1231.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1232.     "${DPF_ROOT_DIR}/dgl/src/OpenGL2.cpp"

  1233.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1234.   if(SHARED_RESOURCES)

  1235.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1236.   else()

  1237.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1238.   endif()

  1239.   if(APPLE)

  1240.     target_sources(dgl-opengl PRIVATE

  1241.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1242.   else()

  1243.     target_sources(dgl-opengl PRIVATE

  1244.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1245.   endif()

  1246.   target_include_directories(dgl-opengl PUBLIC

  1247.     "${DPF_ROOT_DIR}/dgl")

  1248.   target_include_directories(dgl-opengl PUBLIC

  1249.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1250. 

  1251.   if(APPLE)

  1252.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1253.   endif()

  1254. 

  1255.   if(USE_FILE_BROWSER)

  1256.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1257.   endif()

  1258. 

  1259.   if(USE_WEB_VIEW)

  1260.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1261.     if(APPLE)

  1262.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1263.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1264.     elseif(WIN32)

  1265.       target_sources(dgl-opengl PRIVATE

  1266.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1267.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1268.         PROPERTIES

  1269.           COMPILE_FLAGS

  1270.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1271.     endif()

  1272.   endif()

  1273. 

  1274.   dpf__add_dgl_system_libs()

  1275.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1276.   target_link_options(dgl-opengl

  1277.     INTERFACE

  1278.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1279.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1280.   )

  1281. 

  1282.   add_library(dgl-opengl-definitions INTERFACE)

  1283.   target_compile_definitions(dgl-opengl-definitions

  1284.     INTERFACE

  1285.       DGL_OPENGL

  1286.       HAVE_OPENGL

  1287.       HAVE_DGL

  1288.   )

  1289. 

  1290.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1291.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1292. endfunction()

  1293. 

  1294. # dpf__add_dgl_opengl3

  1295. # ------------------------------------------------------------------------------

  1296. #

  1297. # Add the OpenGL3 variant of DGL, if not already available.

  1298. #

  1299. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1300.   if(TARGET dgl-opengl3)

  1301.     return()

  1302.   endif()

  1303. 

  1304.   if(NOT OpenGL_GL_PREFERENCE)

  1305.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1306.   endif()

  1307. 

  1308.   find_package(OpenGL REQUIRED)

  1309. 

  1310.   dpf__add_static_library(dgl-opengl3 STATIC

  1311.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1312.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1313.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1314.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1315.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1316.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1317.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1318.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1319.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1320.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1321.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1322.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1323.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1324.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1325.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1326.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1327.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1328.     "${DPF_ROOT_DIR}/dgl/src/OpenGL3.cpp"

  1329.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1330.   if(SHARED_RESOURCES)

  1331.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1332.   else()

  1333.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1334.   endif()

  1335.   if(APPLE)

  1336.     target_sources(dgl-opengl3 PRIVATE

  1337.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1338.   else()

  1339.     target_sources(dgl-opengl3 PRIVATE

  1340.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1341.   endif()

  1342.   target_include_directories(dgl-opengl3 PUBLIC

  1343.     "${DPF_ROOT_DIR}/dgl")

  1344.   target_include_directories(dgl-opengl3 PUBLIC

  1345.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1346. 

  1347.   if(APPLE)

  1348.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1349.   endif()

  1350. 

  1351.   if(USE_FILE_BROWSER)

  1352.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1353.   endif()

  1354. 

  1355.   if(USE_WEB_VIEW)

  1356.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1357.     if(APPLE)

  1358.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1359.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1360.     elseif(WIN32)

  1361.       target_sources(dgl-opengl3 PRIVATE

  1362.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1363.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1364.         PROPERTIES

  1365.           COMPILE_FLAGS

  1366.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1367.     endif()

  1368.   endif()

  1369. 

  1370.   dpf__add_dgl_system_libs()

  1371.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1372. 

  1373.   add_library(dgl-opengl3-definitions INTERFACE)

  1374.   target_compile_definitions(dgl-opengl3-definitions

  1375.     INTERFACE

  1376.       DGL_USE_OPENGL3

  1377.       DGL_OPENGL

  1378.       HAVE_OPENGL

  1379.       HAVE_DGL

  1380.   )

  1381. 

  1382.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1383.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1384. endfunction()

  1385. 

  1386. # dpf__add_dgl_vulkan

  1387. # ------------------------------------------------------------------------------

  1388. #

  1389. # Add the Vulkan variant of DGL, if not already available.

  1390. #

  1391. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1392.   if(TARGET dgl-vulkan)

  1393.     return()

  1394.   endif()

  1395. 

  1396.   find_package(Vulkan REQUIRED)

  1397. 

  1398.   dpf__add_static_library(dgl-vulkan STATIC

  1399.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1400.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1401.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1402.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1403.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1404.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1405.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1406.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1407.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1408.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1409.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1410.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1411.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1412.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1413.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1414.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1415.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1416.   if(NO_SHARED_RESOURCES)

  1417.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1418.   else()

  1419.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1420.   endif()

  1421.   if(APPLE)

  1422.     target_sources(dgl-vulkan PRIVATE

  1423.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1424.   else()

  1425.     target_sources(dgl-vulkan PRIVATE

  1426.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1427.   endif()

  1428.   target_include_directories(dgl-vulkan PUBLIC

  1429.     "${DPF_ROOT_DIR}/dgl")

  1430.   target_include_directories(dgl-vulkan PUBLIC

  1431.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1432. 

  1433.   if(APPLE)

  1434.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1435.   endif()

  1436. 

  1437.   if(USE_FILE_BROWSER)

  1438.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1439.   endif()

  1440. 

  1441.   if(USE_WEB_VIEW)

  1442.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1443.     if(APPLE)

  1444.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1445.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1446.     elseif(WIN32)

  1447.       target_sources(dgl-vulkan PRIVATE

  1448.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1449.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1450.         PROPERTIES

  1451.           COMPILE_FLAGS

  1452.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1453.     endif()

  1454.   endif()

  1455. 

  1456.   dpf__add_dgl_system_libs()

  1457.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1458. 

  1459.   add_library(dgl-vulkan-definitions INTERFACE)

  1460.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1461. 

  1462.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1463.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1464. endfunction()

  1465. 

  1466. # dpf__add_plugin_specific_ui_sources

  1467. # ------------------------------------------------------------------------------

  1468. #

  1469. # Compile system specific files

  1470. #

  1471. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1472.   if(APPLE)

  1473.     target_sources("${NAME}" PRIVATE

  1474.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1475.     if(USE_WEB_VIEW)

  1476.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1477.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1478.     endif()

  1479.   elseif(WIN32 AND USE_WEB_VIEW)

  1480.     target_sources("${NAME}" PRIVATE

  1481.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1482.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1483.       PROPERTIES

  1484.         COMPILE_FLAGS

  1485.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1486.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1487.   endif()

  1488. endfunction()

  1489. 

  1490. # dpf__add_dgl_system_libs

  1491. # ------------------------------------------------------------------------------

  1492. #

  1493. # Find system libraries required by DGL and add them as an interface target.

  1494. #

  1495. function(dpf__add_dgl_system_libs)

  1496.   if(TARGET dgl-system-libs)

  1497.     return()

  1498.   endif()

  1499.   add_library(dgl-system-libs INTERFACE)

  1500.   add_library(dgl-system-libs-definitions INTERFACE)

  1501.   if(APPLE)

  1502.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1503.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1504.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1505.   elseif(EMSCRIPTEN)

  1506.   elseif(HAIKU)

  1507.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1508.   elseif(WIN32)

  1509.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1510.   else()

  1511.     find_package(PkgConfig REQUIRED)

  1512.     pkg_check_modules(DBUS "dbus-1")

  1513.     if(DBUS_FOUND)

  1514.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1515.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1516.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1517.     endif()

  1518.     find_package(X11 REQUIRED)

  1519.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1520.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1521.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1522.     if(X11_Xcursor_FOUND)

  1523.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1524.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1525.     endif()

  1526.     if(X11_Xext_FOUND)

  1527.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1528.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1529.     endif()

  1530.     if(X11_Xrandr_FOUND)

  1531.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1532.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1533.     endif()

  1534.     if(X11_XSync_FOUND)

  1535.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1536.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1537.     endif()

  1538.    endif()

  1539. 

  1540.    if(MSVC)

  1541.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1542.      foreach(_gl_header "glext.h")

  1543.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1544.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1545.        endif()

  1546.      endforeach()

  1547.      foreach(_khr_header "khrplatform.h")

  1548.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1549.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1550.        endif()

  1551.      endforeach()

  1552.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1553.    endif()

  1554. 

  1555.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1556. endfunction()

  1557. 

  1558. # dpf__add_executable

  1559. # ------------------------------------------------------------------------------

  1560. #

  1561. # Adds an executable target, and set some default properties on the target.

  1562. #

  1563. function(dpf__add_executable NAME)

  1564.   add_executable("${NAME}" ${ARGN})

  1565.   dpf__set_target_defaults("${NAME}")

  1566.   if(MINGW)

  1567.     target_link_libraries("${NAME}" PRIVATE "-static")

  1568.   endif()

  1569. endfunction()

  1570. 

  1571. # dpf__add_module

  1572. # ------------------------------------------------------------------------------

  1573. #

  1574. # Adds a module target, and set some default properties on the target.

  1575. #

  1576. function(dpf__add_module NAME)

  1577.   add_library("${NAME}" MODULE ${ARGN})

  1578.   dpf__set_target_defaults("${NAME}")

  1579.   if(APPLE)

  1580.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1581.   elseif(MINGW)

  1582.     target_link_libraries("${NAME}" PRIVATE "-static")

  1583.   endif()

  1584. endfunction()

  1585. 

  1586. # dpf__add_static_library

  1587. # ------------------------------------------------------------------------------

  1588. #

  1589. # Adds a static library target, and set some default properties on the target.

  1590. #

  1591. function(dpf__add_static_library NAME)

  1592.   add_library("${NAME}" STATIC ${ARGN})

  1593.   dpf__set_target_defaults("${NAME}")

  1594. endfunction()

  1595. 

  1596. # dpf__set_module_export_list

  1597. # ------------------------------------------------------------------------------

  1598. #

  1599. # Applies a list of exported symbols to the module target.

  1600. #

  1601. function(dpf__set_module_export_list NAME EXPORTS)

  1602.   if(WIN32)

  1603.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1604.   elseif(APPLE)

  1605.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1606.       "-Xlinker" "-exported_symbols_list"

  1607.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1608.   else()

  1609.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1610.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1611.   endif()

  1612. endfunction()

  1613. 

  1614. # dpf__set_target_defaults

  1615. # ------------------------------------------------------------------------------

  1616. #

  1617. # Set default properties which must apply to all DPF-defined targets.

  1618. #

  1619. function(dpf__set_target_defaults NAME)

  1620.   set_target_properties("${NAME}" PROPERTIES

  1621.     POSITION_INDEPENDENT_CODE TRUE

  1622.     C_VISIBILITY_PRESET "hidden"

  1623.     CXX_VISIBILITY_PRESET "hidden"

  1624.     VISIBILITY_INLINES_HIDDEN TRUE)

  1625.   if(WIN32)

  1626.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1627.   endif()

  1628.   if (MINGW)

  1629.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1630.   endif()

  1631.   if (MSVC)

  1632.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1633.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1634.   endif()

  1635.   if (CMAKE_COMPILER_IS_GNUCXX)

  1636.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1637.   endif()

  1638.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1639.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1640.   endif()

  1641. endfunction()

  1642. 

  1643. # dpf__add_plugin_main

  1644. # ------------------------------------------------------------------------------

  1645. #

  1646. # Adds plugin code to the given target.

  1647. #

  1648. function(dpf__add_plugin_main NAME TARGET)

  1649.   target_sources("${NAME}" PRIVATE

  1650.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1651.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1652. endfunction()

  1653. 

  1654. # dpf__add_ui_main

  1655. # ------------------------------------------------------------------------------

  1656. #

  1657. # Adds UI code to the given target (only if the target has UI).

  1658. #

  1659. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1660.   if(HAS_UI)

  1661.     target_sources("${NAME}" PRIVATE

  1662.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1663.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1664.   endif()

  1665. endfunction()

  1666. 

  1667. # dpf__add_plugin_target_definition

  1668. # ------------------------------------------------------------------------------

  1669. #

  1670. # Adds the plugins target macro definition.

  1671. # This selects which entry file is compiled according to the target type.

  1672. #

  1673. function(dpf__add_plugin_target_definition NAME TARGET)

  1674.   string(TOUPPER "${TARGET}" _upperTarget)

  1675.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1676. endfunction()

  1677. 

  1678. # dpf__add_lv2_ttl_generator

  1679. # ------------------------------------------------------------------------------

  1680. #

  1681. # Build the LV2 TTL generator.

  1682. #

  1683. function(dpf__add_lv2_ttl_generator)

  1684.   if(TARGET lv2_ttl_generator)

  1685.     return()

  1686.   endif()

  1687.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1688.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1689.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1690.   endif()

  1691. endfunction()

  1692. 

  1693. # dpf__ensure_sources_non_empty

  1694. # ------------------------------------------------------------------------------

  1695. #

  1696. # Ensure the given source list contains at least one file.

  1697. # The function appends an empty source file to the list if necessary.

  1698. # This is useful when CMake does not permit to add targets without sources.

  1699. #

  1700. function(dpf__ensure_sources_non_empty VAR)

  1701.   if(NOT "" STREQUAL "${${VAR}}")

  1702.     return()

  1703.   endif()

  1704.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1705.   if(NOT EXISTS "${_file}")

  1706.     file(WRITE "${_file}" "")

  1707.   endif()

  1708.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1709. endfunction()

  1710. 

  1711. # dpf__create_dummy_source_list

  1712. # ------------------------------------------------------------------------------

  1713. #

  1714. # Create a dummy source list which is equivalent to compiling nothing.

  1715. # This is only for compatibility with older CMake versions, which refuse to add

  1716. # targets without any sources.

  1717. #

  1718. macro(dpf__create_dummy_source_list VAR)

  1719.   set("${VAR}")

  1720.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1721.     dpf__ensure_sources_non_empty("${VAR}")

  1722.   endif()

  1723. endmacro()

  1724. 

  1725. # dpf__target_link_directories

  1726. # ------------------------------------------------------------------------------

  1727. #

  1728. # Call `target_link_directories` if cmake >= 3.13,

  1729. # otherwise fallback to global `link_directories`.

  1730. #

  1731. macro(dpf__target_link_directories NAME DIRS)

  1732.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1733.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1734.   else()

  1735.     link_directories(${DIRS})

  1736.   endif()

  1737. endmacro()

  1738. 

  1739. # dpf__warn_once

  1740. # ------------------------------------------------------------------------------

  1741. #

  1742. # Prints a warning message once only.

  1743. #

  1744. function(dpf__warn_once_only TOKEN MESSAGE)

  1745.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1746.   if(NOT _warned)

  1747.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1748.     message(WARNING "${MESSAGE}")

  1749.   endif()

  1750. endfunction()