DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
887 Commits
7 Branches
91MB
Tree: 34e19396e1
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '34e19396e1'
${ noResults }
DPF/cmake/DPF-plugin.cmake

558 lines
18KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. # ```

  32. 

  33. include(CMakeParseArguments)

  34. 

  35. # ------------------------------------------------------------------------------

  36. # DPF public functions

  37. # ------------------------------------------------------------------------------

  38. 

  39. # dpf_add_plugin(name <args...>)

  40. # ------------------------------------------------------------------------------

  41. #

  42. # Add a plugin built using the DISTRHO Plugin Framework.

  43. #

  44. # ------------------------------------------------------------------------------

  45. # Created targets:

  46. #

  47. #   `<name>`

  48. #       static library: the common part of the plugin

  49. #       The public properties set on this target apply to both DSP and UI.

  50. #

  51. #   `<name>-dsp`

  52. #       static library: the DSP part of the plugin

  53. #       The public properties set on this target apply to the DSP only.

  54. #

  55. #   `<name>-ui`

  56. #       static library: the UI part of the plugin

  57. #       The public properties set on this target apply to the UI only.

  58. #

  59. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  60. #       This is target-dependent and not intended for public use.

  61. #

  62. # ------------------------------------------------------------------------------

  63. # Arguments:

  64. #

  65. #   `TARGETS` <tgt1>...<tgtN>

  66. #       a list of one of more of the following target types:

  67. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst`

  68. #

  69. #   `UI_TYPE` <type>

  70. #       the user interface type: `opengl` (default), `cairo`

  71. #

  72. #   `MONOLITHIC`

  73. #       build LV2 as a single binary for UI and DSP

  74. #

  75. #   `FILES_DSP` <file1>...<fileN>

  76. #       list of sources which are part of the DSP

  77. #

  78. #   `FILES_UI` <file1>...<fileN>

  79. #       list of sources which are part of the UI

  80. #       empty indicates the plugin does not have UI

  81. #

  82. #   `FILES_COMMON` <file1>...<fileN>

  83. #       list of sources which are part of both DSP and UI

  84. #

  85. function(dpf_add_plugin NAME)

  86.   set(options MONOLITHIC)

  87.   set(oneValueArgs UI_TYPE)

  88.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  89.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  90. 

  91.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  92.     set(_dpf_plugin_UI_TYPE "opengl")

  93.   endif()

  94. 

  95.   set(_dgl_library)

  96.   if(_dpf_plugin_FILES_UI)

  97.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  98.       dpf__add_dgl_cairo()

  99.       set(_dgl_library dgl-cairo)

  100.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  101.       dpf__add_dgl_opengl()

  102.       set(_dgl_library dgl-opengl)

  103.     else()

  104.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  105.     endif()

  106.   endif()

  107. 

  108.   ###

  109.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  110.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  111.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  112. 

  113.   ###

  114.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  115.   target_include_directories("${NAME}" PUBLIC

  116.     "${DPF_ROOT_DIR}/distrho")

  117. 

  118.   if(_dgl_library)

  119.     # make sure that all code will see DGL_* definitions

  120.     target_link_libraries("${NAME}" PUBLIC "${_dgl_library}-definitions")

  121.   endif()

  122. 

  123.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  124.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  125. 

  126.   if(_dgl_library)

  127.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  128.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  129.   else()

  130.     add_library("${NAME}-ui" INTERFACE)

  131.   endif()

  132. 

  133.   ###

  134.   foreach(_target ${_dpf_plugin_TARGETS})

  135.     if(_target STREQUAL "jack")

  136.       dpf__build_jack("${NAME}" "${_dgl_library}")

  137.     elseif(_target STREQUAL "ladspa")

  138.       dpf__build_ladspa("${NAME}")

  139.     elseif(_target STREQUAL "dssi")

  140.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  141.     elseif(_target STREQUAL "lv2")

  142.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  143.     elseif(_target STREQUAL "vst")

  144.       dpf__build_vst("${NAME}" "${_dgl_library}")

  145.     else()

  146.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  147.     endif()

  148.   endforeach()

  149. endfunction()

  150. 

  151. # ------------------------------------------------------------------------------

  152. # DPF private functions (prefixed with `dpf__`)

  153. # ------------------------------------------------------------------------------

  154. 

  155. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  156. #       to the output directory.

  157. #

  158. 

  159. # dpf__build_jack

  160. # ------------------------------------------------------------------------------

  161. #

  162. # Add build rules for a JACK program.

  163. #

  164. function(dpf__build_jack NAME DGL_LIBRARY)

  165.   find_package(PkgConfig)

  166.   pkg_check_modules(JACK "jack")

  167.   if(NOT JACK_FOUND)

  168.     dpf__warn_once_only(missing_jack

  169.       "JACK is not found, skipping the `jack` plugin targets")

  170.     return()

  171.   endif()

  172. 

  173.   dpf__create_dummy_source_list(_no_srcs)

  174. 

  175.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  176.   dpf__add_plugin_main("${NAME}-jack" "jack")

  177.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  178.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  179.   set_target_properties("${NAME}-jack" PROPERTIES

  180.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  181.     OUTPUT_NAME "${NAME}")

  182. 

  183.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  184.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  185.   link_directories(${JACK_LIBRARY_DIRS})

  186. endfunction()

  187. 

  188. # dpf__build_ladspa

  189. # ------------------------------------------------------------------------------

  190. #

  191. # Add build rules for a DSSI plugin.

  192. #

  193. function(dpf__build_ladspa NAME)

  194.   dpf__create_dummy_source_list(_no_srcs)

  195. 

  196.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  197.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  198.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  199.   set_target_properties("${NAME}-ladspa" PROPERTIES

  200.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  201.     OUTPUT_NAME "${NAME}-ladspa"

  202.     PREFIX "")

  203. endfunction()

  204. 

  205. # dpf__build_dssi

  206. # ------------------------------------------------------------------------------

  207. #

  208. # Add build rules for a DSSI plugin.

  209. #

  210. function(dpf__build_dssi NAME DGL_LIBRARY)

  211.   find_package(PkgConfig)

  212.   pkg_check_modules(LIBLO "liblo")

  213.   if(NOT LIBLO_FOUND)

  214.     dpf__warn_once_only(missing_liblo

  215.       "liblo is not found, skipping the `dssi` plugin targets")

  216.     return()

  217.   endif()

  218. 

  219.   dpf__create_dummy_source_list(_no_srcs)

  220. 

  221.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  222.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  223.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  224.   set_target_properties("${NAME}-dssi" PROPERTIES

  225.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  226.     OUTPUT_NAME "${NAME}-dssi"

  227.     PREFIX "")

  228. 

  229.   if(DGL_LIBRARY)

  230.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  231.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  232.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  233.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  234.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  235.       OUTPUT_NAME "${NAME}_ui")

  236. 

  237.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  238.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  239.     link_directories(${LIBLO_LIBRARY_DIRS})

  240.   endif()

  241. endfunction()

  242. 

  243. # dpf__build_lv2

  244. # ------------------------------------------------------------------------------

  245. #

  246. # Add build rules for a LV2 plugin.

  247. #

  248. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  249.   dpf__create_dummy_source_list(_no_srcs)

  250. 

  251.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  252.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  253.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  254.   set_target_properties("${NAME}-lv2" PROPERTIES

  255.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  256.     OUTPUT_NAME "${NAME}_dsp"

  257.     PREFIX "")

  258. 

  259.   if(DGL_LIBRARY)

  260.     if(MONOLITHIC)

  261.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  262.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  263.       set_target_properties("${NAME}-lv2" PROPERTIES

  264.         OUTPUT_NAME "${NAME}")

  265.     else()

  266.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  267.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  268.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  269.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  270.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  271.         OUTPUT_NAME "${NAME}_ui"

  272.         PREFIX "")

  273.     endif()

  274.   endif()

  275. 

  276.   dpf__add_lv2_ttl_generator()

  277.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  278. 

  279.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  280.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  281.     "$<TARGET_FILE:lv2_ttl_generator>"

  282.     "$<TARGET_FILE:${NAME}-lv2>"

  283.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  284. endfunction()

  285. 

  286. # dpf__build_vst

  287. # ------------------------------------------------------------------------------

  288. #

  289. # Add build rules for a VST plugin.

  290. #

  291. function(dpf__build_vst NAME DGL_LIBRARY)

  292.   dpf__create_dummy_source_list(_no_srcs)

  293. 

  294.   dpf__add_module("${NAME}-vst" ${_no_srcs})

  295.   dpf__add_plugin_main("${NAME}-vst" "vst")

  296.   dpf__add_ui_main("${NAME}-vst" "vst" "${DGL_LIBRARY}")

  297.   target_link_libraries("${NAME}-vst" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  298.   set_target_properties("${NAME}-vst" PROPERTIES

  299.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  300.     OUTPUT_NAME "${NAME}-vst"

  301.     PREFIX "")

  302. endfunction()

  303. 

  304. # dpf__add_dgl_cairo

  305. # ------------------------------------------------------------------------------

  306. #

  307. # Add the Cairo variant of DGL, if not already available.

  308. #

  309. function(dpf__add_dgl_cairo)

  310.   if(TARGET dgl-cairo)

  311.     return()

  312.   endif()

  313. 

  314.   find_package(PkgConfig)

  315.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  316. 

  317.   dpf__add_static_library(dgl-cairo STATIC

  318.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  319.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  320.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  321.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  322.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  323.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  324.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp"

  325.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  326.   if(NOT APPLE)

  327.     target_sources(dgl-cairo PRIVATE

  328.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  329.   else()

  330.     target_sources(dgl-cairo PRIVATE

  331.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  332.   endif()

  333.   target_include_directories(dgl-cairo PUBLIC

  334.     "${DPF_ROOT_DIR}/dgl")

  335. 

  336.   dpf__add_dgl_system_libs()

  337.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  338. 

  339.   add_library(dgl-cairo-definitions INTERFACE)

  340.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  341. 

  342.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  343.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  344.   link_directories(${CAIRO_LIBRARY_DIRS})

  345. endfunction()

  346. 

  347. # dpf__add_dgl_opengl

  348. # ------------------------------------------------------------------------------

  349. #

  350. # Add the OpenGL variant of DGL, if not already available.

  351. #

  352. function(dpf__add_dgl_opengl)

  353.   if(TARGET dgl-opengl)

  354.     return()

  355.   endif()

  356. 

  357.   if(NOT OpenGL_GL_PREFERENCE)

  358.     set(OpenGL_GL_PREFERENCE "LEGACY")

  359.   endif()

  360. 

  361.   find_package(OpenGL REQUIRED)

  362. 

  363.   dpf__add_static_library(dgl-opengl STATIC

  364.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  365.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  366.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  367.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  368.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  369.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  370.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  371.     "${DPF_ROOT_DIR}/dgl/src/Image.cpp"

  372.     "${DPF_ROOT_DIR}/dgl/src/ImageWidgets.cpp"

  373.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp"

  374.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  375.   if(NOT APPLE)

  376.     target_sources(dgl-opengl PRIVATE

  377.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  378.   else()

  379.     target_sources(dgl-opengl PRIVATE

  380.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  381.   endif()

  382.   target_include_directories(dgl-opengl PUBLIC

  383.     "${DPF_ROOT_DIR}/dgl")

  384. 

  385.   dpf__add_dgl_system_libs()

  386.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  387. 

  388.   add_library(dgl-opengl-definitions INTERFACE)

  389.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  390. 

  391.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  392.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  393. endfunction()

  394. 

  395. # dpf__add_dgl_system_libs

  396. # ------------------------------------------------------------------------------

  397. #

  398. # Find system libraries required by DGL and add them as an interface target.

  399. #

  400. function(dpf__add_dgl_system_libs)

  401.   if(TARGET dgl-system-libs)

  402.     return()

  403.   endif()

  404.   add_library(dgl-system-libs INTERFACE)

  405.   if(HAIKU)

  406.     target_link_libraries(dgl-system-libs INTERFACE "be")

  407.   elseif(WIN32)

  408.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  409.   elseif(APPLE)

  410.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  411.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}")

  412.   else()

  413.     find_package(X11 REQUIRED)

  414.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  415.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  416.   endif()

  417. endfunction()

  418. 

  419. # dpf__add_executable

  420. # ------------------------------------------------------------------------------

  421. #

  422. # Adds an executable target, and set some default properties on the target.

  423. #

  424. function(dpf__add_executable NAME)

  425.   add_executable("${NAME}" ${ARGN})

  426.   set_target_properties("${NAME}" PROPERTIES

  427.     POSITION_INDEPENDENT_CODE TRUE

  428.     C_VISIBILITY_PRESET "hidden"

  429.     CXX_VISIBILITY_PRESET "hidden"

  430.     VISIBILITY_INLINES_HIDDEN TRUE)

  431. endfunction()

  432. 

  433. # dpf__add_module

  434. # ------------------------------------------------------------------------------

  435. #

  436. # Adds a module target, and set some default properties on the target.

  437. #

  438. function(dpf__add_module NAME)

  439.   add_library("${NAME}" MODULE ${ARGN})

  440.   set_target_properties("${NAME}" PROPERTIES

  441.     POSITION_INDEPENDENT_CODE TRUE

  442.     C_VISIBILITY_PRESET "hidden"

  443.     CXX_VISIBILITY_PRESET "hidden"

  444.     VISIBILITY_INLINES_HIDDEN TRUE)

  445.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  446.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  447.   endif()

  448. endfunction()

  449. 

  450. # dpf__add_static_library

  451. # ------------------------------------------------------------------------------

  452. #

  453. # Adds a static library target, and set some default properties on the target.

  454. #

  455. function(dpf__add_static_library NAME)

  456.   add_library("${NAME}" STATIC ${ARGN})

  457.   set_target_properties("${NAME}" PROPERTIES

  458.     POSITION_INDEPENDENT_CODE TRUE

  459.     C_VISIBILITY_PRESET "hidden"

  460.     CXX_VISIBILITY_PRESET "hidden"

  461.     VISIBILITY_INLINES_HIDDEN TRUE)

  462. endfunction()

  463. 

  464. # dpf__add_plugin_main

  465. # ------------------------------------------------------------------------------

  466. #

  467. # Adds plugin code to the given target.

  468. #

  469. function(dpf__add_plugin_main NAME TARGET)

  470.   target_sources("${NAME}" PRIVATE

  471.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  472.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  473. endfunction()

  474. 

  475. # dpf__add_ui_main

  476. # ------------------------------------------------------------------------------

  477. #

  478. # Adds UI code to the given target (only if the target has UI).

  479. #

  480. function(dpf__add_ui_main NAME TARGET HAS_UI)

  481.   if(HAS_UI)

  482.     target_sources("${NAME}" PRIVATE

  483.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  484.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  485.   endif()

  486. endfunction()

  487. 

  488. # dpf__add_plugin_target_definition

  489. # ------------------------------------------------------------------------------

  490. #

  491. # Adds the plugins target macro definition.

  492. # This selects which entry file is compiled according to the target type.

  493. #

  494. function(dpf__add_plugin_target_definition NAME TARGET)

  495.   string(TOUPPER "${TARGET}" _upperTarget)

  496.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  497. endfunction()

  498. 

  499. # dpf__add_lv2_ttl_generator

  500. # ------------------------------------------------------------------------------

  501. #

  502. # Build the LV2 TTL generator.

  503. #

  504. function(dpf__add_lv2_ttl_generator)

  505.   if(TARGET lv2_ttl_generator)

  506.     return()

  507.   endif()

  508.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  509.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  510.     target_link_libraries(lv2_ttl_generator "dl")

  511.   endif()

  512. endfunction()

  513. 

  514. # dpf__ensure_sources_non_empty

  515. # ------------------------------------------------------------------------------

  516. #

  517. # Ensure the given source list contains at least one file.

  518. # The function appends an empty source file to the list if necessary.

  519. # This is useful when CMake does not permit to add targets without sources.

  520. #

  521. function(dpf__ensure_sources_non_empty VAR)

  522.   if(NOT "" STREQUAL "${${VAR}}")

  523.     return()

  524.   endif()

  525.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  526.   if(NOT EXISTS "${_file}")

  527.     file(WRITE "${_file}" "")

  528.   endif()

  529.   set("${VAR}" "${_file}" PARENT_SCOPE)

  530. endfunction()

  531. 

  532. # dpf__create_dummy_source_list

  533. # ------------------------------------------------------------------------------

  534. #

  535. # Create a dummy source list which is equivalent to compiling nothing.

  536. # This is only for compatibility with older CMake versions, which refuse to add

  537. # targets without any sources.

  538. #

  539. macro(dpf__create_dummy_source_list VAR)

  540.   set("${VAR}")

  541.   if(CMAKE_VERSION VERSION_LESS "3.11")

  542.     dpf__ensure_sources_non_empty("${VAR}")

  543.   endif()

  544. endmacro()

  545. 

  546. # dpf__warn_once

  547. # ------------------------------------------------------------------------------

  548. #

  549. # Prints a warning message once only.

  550. #

  551. function(dpf__warn_once_only TOKEN MESSAGE)

  552.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  553.   if(NOT _warned)

  554.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  555.     message(WARNING "${MESSAGE}")

  556.   endif()

  557. endfunction()