DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2028 Commits
7 Branches
295MB
Tree: 30cf55aa15
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '30cf55aa15'
${ noResults }
DPF/cmake/DPF-plugin.cmake

835 lines
29KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS clap lv2 vst2 vst3

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  126.     target_link_libraries("${NAME}" PRIVATE "dl")

  127.   endif()

  128. 

  129.   if(_dgl_library)

  130.     # make sure that all code will see DGL_* definitions

  131.     target_link_libraries("${NAME}" PUBLIC

  132.       "${_dgl_library}-definitions"

  133.       dgl-system-libs-definitions)

  134.   endif()

  135. 

  136.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  137.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  138. 

  139.   if(_dgl_library)

  140.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  141.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  142.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  143.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  144.     endif()

  145.     # add the files containing Objective-C classes

  146.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  147.   else()

  148.     add_library("${NAME}-ui" INTERFACE)

  149.   endif()

  150. 

  151.   ###

  152.   foreach(_target ${_dpf_plugin_TARGETS})

  153.     if(_target STREQUAL "jack")

  154.       dpf__build_jack("${NAME}" "${_dgl_library}")

  155.     elseif(_target STREQUAL "ladspa")

  156.       dpf__build_ladspa("${NAME}")

  157.     elseif(_target STREQUAL "dssi")

  158.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  159.     elseif(_target STREQUAL "lv2")

  160.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  161.     elseif(_target STREQUAL "vst2")

  162.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  163.     elseif(_target STREQUAL "vst3")

  164.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  165.     elseif(_target STREQUAL "clap")

  166.       dpf__build_clap("${NAME}" "${_dgl_library}")

  167.     else()

  168.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  169.     endif()

  170.   endforeach()

  171. endfunction()

  172. 

  173. # ------------------------------------------------------------------------------

  174. # DPF private functions (prefixed with `dpf__`)

  175. # ------------------------------------------------------------------------------

  176. 

  177. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  178. #       to the output directory.

  179. #

  180. 

  181. # dpf__build_jack

  182. # ------------------------------------------------------------------------------

  183. #

  184. # Add build rules for a JACK program.

  185. #

  186. function(dpf__build_jack NAME DGL_LIBRARY)

  187.   dpf__create_dummy_source_list(_no_srcs)

  188. 

  189.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  190.   dpf__add_plugin_main("${NAME}-jack" "jack")

  191.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  192.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  193.   set_target_properties("${NAME}-jack" PROPERTIES

  194.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  195.     OUTPUT_NAME "${NAME}")

  196. 

  197.   # for RtAudio native fallback

  198.   if(APPLE)

  199.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  200.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  201.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  202.   endif()

  203. endfunction()

  204. 

  205. # dpf__build_ladspa

  206. # ------------------------------------------------------------------------------

  207. #

  208. # Add build rules for a LADSPA plugin.

  209. #

  210. function(dpf__build_ladspa NAME)

  211.   dpf__create_dummy_source_list(_no_srcs)

  212. 

  213.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  214.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  215.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  216.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  217.   set_target_properties("${NAME}-ladspa" PROPERTIES

  218.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  219.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  220.     OUTPUT_NAME "${NAME}-ladspa"

  221.     PREFIX "")

  222. endfunction()

  223. 

  224. # dpf__build_dssi

  225. # ------------------------------------------------------------------------------

  226. #

  227. # Add build rules for a DSSI plugin.

  228. #

  229. function(dpf__build_dssi NAME DGL_LIBRARY)

  230.   find_package(PkgConfig)

  231.   pkg_check_modules(LIBLO "liblo")

  232.   if(NOT LIBLO_FOUND)

  233.     dpf__warn_once_only(missing_liblo

  234.       "liblo is not found, skipping the `dssi` plugin targets")

  235.     return()

  236.   endif()

  237. 

  238.   link_directories(${LIBLO_LIBRARY_DIRS})

  239. 

  240.   dpf__create_dummy_source_list(_no_srcs)

  241. 

  242.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  243.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  244.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  245.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  246.   set_target_properties("${NAME}-dssi" PROPERTIES

  247.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  248.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  249.     OUTPUT_NAME "${NAME}-dssi"

  250.     PREFIX "")

  251. 

  252.   if(DGL_LIBRARY)

  253.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  254.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  255.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  256.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  257.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  258.       OUTPUT_NAME "${NAME}_ui")

  259. 

  260.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  261.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  262.   endif()

  263. endfunction()

  264. 

  265. # dpf__build_lv2

  266. # ------------------------------------------------------------------------------

  267. #

  268. # Add build rules for an LV2 plugin.

  269. #

  270. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  271.   dpf__create_dummy_source_list(_no_srcs)

  272. 

  273.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  274.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  275.   if(DGL_LIBRARY AND MONOLITHIC)

  276.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  277.   else()

  278.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  279.   endif()

  280.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  281.   set_target_properties("${NAME}-lv2" PROPERTIES

  282.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  283.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  284.     OUTPUT_NAME "${NAME}_dsp"

  285.     PREFIX "")

  286. 

  287.   if(DGL_LIBRARY)

  288.     if(MONOLITHIC)

  289.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  290.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  291.       set_target_properties("${NAME}-lv2" PROPERTIES

  292.         OUTPUT_NAME "${NAME}")

  293.     else()

  294.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  295.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  296.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  297.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  298.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  299.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  300.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  301.         OUTPUT_NAME "${NAME}_ui"

  302.         PREFIX "")

  303.     endif()

  304.   endif()

  305. 

  306.   dpf__add_lv2_ttl_generator()

  307.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  308. 

  309.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  310.     COMMAND

  311.     "$<TARGET_FILE:lv2_ttl_generator>"

  312.     "$<TARGET_FILE:${NAME}-lv2>"

  313.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  314.     DEPENDS lv2_ttl_generator)

  315. endfunction()

  316. 

  317. # dpf__build_vst2

  318. # ------------------------------------------------------------------------------

  319. #

  320. # Add build rules for a VST2 plugin.

  321. #

  322. function(dpf__build_vst2 NAME DGL_LIBRARY)

  323.   dpf__create_dummy_source_list(_no_srcs)

  324. 

  325.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  326.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  327.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  328.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  329.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  330.   set_target_properties("${NAME}-vst2" PROPERTIES

  331.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  332.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  333.     OUTPUT_NAME "${NAME}-vst2"

  334.     PREFIX "")

  335.   if(APPLE)

  336.     set_target_properties("${NAME}-vst2" PROPERTIES

  337.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  338.       OUTPUT_NAME "${NAME}"

  339.       SUFFIX "")

  340.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  341.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  342.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  343.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  344.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  345.   endif()

  346. endfunction()

  347. 

  348. # dpf__determine_vst3_package_architecture

  349. # ------------------------------------------------------------------------------

  350. #

  351. # Determines the package architecture for a VST3 plugin target.

  352. #

  353. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  354.   # if set by variable, override the detection

  355.   if(DPF_VST3_ARCHITECTURE)

  356.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  357.     return()

  358.   endif()

  359. 

  360.   # not used on Apple, which supports universal binary

  361.   if(APPLE)

  362.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  363.     return()

  364.   endif()

  365. 

  366.   # identify the target processor (special case of MSVC, problematic sometimes)

  367.   if(MSVC)

  368.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  369.   else()

  370.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  371.   endif()

  372. 

  373.   # transform the processor name to a format that VST3 recognizes

  374.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  375.     set(vst3_package_arch "x86_64")

  376.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  377.     if(WIN32)

  378.       set(vst3_package_arch "x86")

  379.     else()

  380.       set(vst3_package_arch "i386")

  381.     endif()

  382.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  383.     set(vst3_package_arch "${vst3_system_arch}")

  384.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  385.     set(vst3_package_arch "aarch64")

  386.   else()

  387.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  388.   endif()

  389. 

  390.   # TODO: the detections for Windows arm/arm64 when supported

  391. 

  392.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  393. endfunction()

  394. 

  395. # dpf__build_vst3

  396. # ------------------------------------------------------------------------------

  397. #

  398. # Add build rules for a VST3 plugin.

  399. #

  400. function(dpf__build_vst3 NAME DGL_LIBRARY)

  401.   dpf__determine_vst3_package_architecture(vst3_arch)

  402. 

  403.   dpf__create_dummy_source_list(_no_srcs)

  404. 

  405.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  406.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  407.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  408.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  409.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  410.   set_target_properties("${NAME}-vst3" PROPERTIES

  411.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  412.     OUTPUT_NAME "${NAME}"

  413.     PREFIX "")

  414. 

  415.   if(APPLE)

  416.     set_target_properties("${NAME}-vst3" PROPERTIES

  417.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  418.       SUFFIX "")

  419.   elseif(WIN32)

  420.     set_target_properties("${NAME}-vst3" PROPERTIES

  421.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  422.   else()

  423.     set_target_properties("${NAME}-vst3" PROPERTIES

  424.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  425.   endif()

  426. 

  427.   if(APPLE)

  428.     # Uses the same macOS bundle template as VST2

  429.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  430.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  431.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  432.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  433.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  434.   endif()

  435. endfunction()

  436. 

  437. # dpf__build_clap

  438. # ------------------------------------------------------------------------------

  439. #

  440. # Add build rules for a VST2 plugin.

  441. #

  442. function(dpf__build_clap NAME DGL_LIBRARY)

  443.   dpf__create_dummy_source_list(_no_srcs)

  444. 

  445.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  446.   dpf__add_plugin_main("${NAME}-clap" "clap")

  447.   dpf__add_ui_main("${NAME}-clap" "clap" "${DGL_LIBRARY}")

  448.   dpf__set_module_export_list("${NAME}-clap" "clap")

  449.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  450.   set_target_properties("${NAME}-clap" PROPERTIES

  451.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  452.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  453.     OUTPUT_NAME "${NAME}"

  454.     PREFIX ""

  455.     SUFFIX ".clap")

  456. 

  457.   if(APPLE)

  458.     set_target_properties("${NAME}-clap" PROPERTIES

  459.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  460.       OUTPUT_NAME "${NAME}"

  461.       SUFFIX "")

  462.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  463.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  464.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  465.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  466.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  467.   endif()

  468. endfunction()

  469. 

  470. # dpf__add_dgl_cairo

  471. # ------------------------------------------------------------------------------

  472. #

  473. # Add the Cairo variant of DGL, if not already available.

  474. #

  475. function(dpf__add_dgl_cairo)

  476.   if(TARGET dgl-cairo)

  477.     return()

  478.   endif()

  479. 

  480.   find_package(PkgConfig)

  481.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  482. 

  483.   link_directories(${CAIRO_LIBRARY_DIRS})

  484. 

  485.   dpf__add_static_library(dgl-cairo STATIC

  486.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  487.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  488.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  489.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  490.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  491.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  492.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  493.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  494.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  495.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  496.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  497.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  498.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  499.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  500.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  501.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  502.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  503.   if(NOT APPLE)

  504.     target_sources(dgl-cairo PRIVATE

  505.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  506.   else()

  507.     target_sources(dgl-opengl PRIVATE

  508.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  509.   endif()

  510.   target_include_directories(dgl-cairo PUBLIC

  511.     "${DPF_ROOT_DIR}/dgl")

  512.   target_include_directories(dgl-cairo PUBLIC

  513.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  514. 

  515.   dpf__add_dgl_system_libs()

  516.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  517. 

  518.   add_library(dgl-cairo-definitions INTERFACE)

  519.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  520. 

  521.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  522.   if(MINGW)

  523.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  524.   else()

  525.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  526.   endif()

  527.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  528. endfunction()

  529. 

  530. # dpf__add_dgl_opengl

  531. # ------------------------------------------------------------------------------

  532. #

  533. # Add the OpenGL variant of DGL, if not already available.

  534. #

  535. function(dpf__add_dgl_opengl)

  536.   if(TARGET dgl-opengl)

  537.     return()

  538.   endif()

  539. 

  540.   if(NOT OpenGL_GL_PREFERENCE)

  541.     set(OpenGL_GL_PREFERENCE "LEGACY")

  542.   endif()

  543. 

  544.   find_package(OpenGL REQUIRED)

  545. 

  546.   dpf__add_static_library(dgl-opengl STATIC

  547.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  548.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  549.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  550.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  551.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  552.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  553.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  554.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  555.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  556.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  557.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  558.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  559.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  560.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  561.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  562.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  563.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  564.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  565.   if(NOT APPLE)

  566.     target_sources(dgl-opengl PRIVATE

  567.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  568.   else()

  569.     target_sources(dgl-opengl PRIVATE

  570.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  571.   endif()

  572.   target_include_directories(dgl-opengl PUBLIC

  573.     "${DPF_ROOT_DIR}/dgl")

  574.   target_include_directories(dgl-opengl PUBLIC

  575.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  576. 

  577.   if(APPLE)

  578.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  579.   endif()

  580. 

  581.   dpf__add_dgl_system_libs()

  582.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  583. 

  584.   add_library(dgl-opengl-definitions INTERFACE)

  585.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  586. 

  587.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  588.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  589. endfunction()

  590. 

  591. # dpf__add_plugin_specific_ui_sources

  592. # ------------------------------------------------------------------------------

  593. #

  594. # Compile system specific files, for now it is just Objective-C code

  595. #

  596. function(dpf__add_plugin_specific_ui_sources NAME)

  597.   if(APPLE)

  598.     target_sources("${NAME}" PRIVATE

  599.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  600.   endif()

  601. endfunction()

  602. 

  603. # dpf__add_dgl_system_libs

  604. # ------------------------------------------------------------------------------

  605. #

  606. # Find system libraries required by DGL and add them as an interface target.

  607. #

  608. function(dpf__add_dgl_system_libs)

  609.   if(TARGET dgl-system-libs)

  610.     return()

  611.   endif()

  612.   add_library(dgl-system-libs INTERFACE)

  613.   add_library(dgl-system-libs-definitions INTERFACE)

  614.   if(HAIKU)

  615.     target_link_libraries(dgl-system-libs INTERFACE "be")

  616.   elseif(WIN32)

  617.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  618.   elseif(APPLE)

  619.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  620.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  621.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  622.   else()

  623.     find_package(X11 REQUIRED)

  624.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  625.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  626.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  627.     if(X11_Xcursor_FOUND)

  628.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  629.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  630.     endif()

  631.     if(X11_Xext_FOUND)

  632.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  633.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  634.     endif()

  635.     if(X11_Xrandr_FOUND)

  636.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  637.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  638.     endif()

  639.     if(X11_XSync_FOUND)

  640.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  641.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  642.     endif()

  643.    endif()

  644. 

  645.    if(MSVC)

  646.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  647.      foreach(_gl_header "glext.h")

  648.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  649.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  650.        endif()

  651.      endforeach()

  652.      foreach(_khr_header "khrplatform.h")

  653.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  654.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  655.        endif()

  656.      endforeach()

  657.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  658.    endif()

  659. 

  660.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  661. endfunction()

  662. 

  663. # dpf__add_executable

  664. # ------------------------------------------------------------------------------

  665. #

  666. # Adds an executable target, and set some default properties on the target.

  667. #

  668. function(dpf__add_executable NAME)

  669.   add_executable("${NAME}" ${ARGN})

  670.   dpf__set_target_defaults("${NAME}")

  671.   if(MINGW)

  672.     target_link_libraries("${NAME}" PRIVATE "-static")

  673.   endif()

  674. endfunction()

  675. 

  676. # dpf__add_module

  677. # ------------------------------------------------------------------------------

  678. #

  679. # Adds a module target, and set some default properties on the target.

  680. #

  681. function(dpf__add_module NAME)

  682.   add_library("${NAME}" MODULE ${ARGN})

  683.   dpf__set_target_defaults("${NAME}")

  684.   if(MINGW)

  685.     target_link_libraries("${NAME}" PRIVATE "-static")

  686.   endif()

  687. endfunction()

  688. 

  689. # dpf__add_static_library

  690. # ------------------------------------------------------------------------------

  691. #

  692. # Adds a static library target, and set some default properties on the target.

  693. #

  694. function(dpf__add_static_library NAME)

  695.   add_library("${NAME}" STATIC ${ARGN})

  696.   dpf__set_target_defaults("${NAME}")

  697. endfunction()

  698. 

  699. # dpf__set_module_export_list

  700. # ------------------------------------------------------------------------------

  701. #

  702. # Applies a list of exported symbols to the module target.

  703. #

  704. function(dpf__set_module_export_list NAME EXPORTS)

  705.   if(WIN32)

  706.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  707.   elseif(APPLE)

  708.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  709.       "-Xlinker" "-exported_symbols_list"

  710.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  711.   else()

  712.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  713.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  714.   endif()

  715. endfunction()

  716. 

  717. # dpf__set_target_defaults

  718. # ------------------------------------------------------------------------------

  719. #

  720. # Set default properties which must apply to all DPF-defined targets.

  721. #

  722. function(dpf__set_target_defaults NAME)

  723.   set_target_properties("${NAME}" PROPERTIES

  724.     POSITION_INDEPENDENT_CODE TRUE

  725.     C_VISIBILITY_PRESET "hidden"

  726.     CXX_VISIBILITY_PRESET "hidden"

  727.     VISIBILITY_INLINES_HIDDEN TRUE)

  728.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  729.   if(WIN32)

  730.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  731.   endif()

  732.   if (MINGW)

  733.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  734.   endif()

  735.   if (MSVC)

  736.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  737.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  738.   endif()

  739. endfunction()

  740. 

  741. # dpf__add_plugin_main

  742. # ------------------------------------------------------------------------------

  743. #

  744. # Adds plugin code to the given target.

  745. #

  746. function(dpf__add_plugin_main NAME TARGET)

  747.   target_sources("${NAME}" PRIVATE

  748.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  749.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  750. endfunction()

  751. 

  752. # dpf__add_ui_main

  753. # ------------------------------------------------------------------------------

  754. #

  755. # Adds UI code to the given target (only if the target has UI).

  756. #

  757. function(dpf__add_ui_main NAME TARGET HAS_UI)

  758.   if(HAS_UI)

  759.     target_sources("${NAME}" PRIVATE

  760.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  761.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  762.   endif()

  763. endfunction()

  764. 

  765. # dpf__add_plugin_target_definition

  766. # ------------------------------------------------------------------------------

  767. #

  768. # Adds the plugins target macro definition.

  769. # This selects which entry file is compiled according to the target type.

  770. #

  771. function(dpf__add_plugin_target_definition NAME TARGET)

  772.   string(TOUPPER "${TARGET}" _upperTarget)

  773.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  774. endfunction()

  775. 

  776. # dpf__add_lv2_ttl_generator

  777. # ------------------------------------------------------------------------------

  778. #

  779. # Build the LV2 TTL generator.

  780. #

  781. function(dpf__add_lv2_ttl_generator)

  782.   if(TARGET lv2_ttl_generator)

  783.     return()

  784.   endif()

  785.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  786.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  787.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  788.   endif()

  789. endfunction()

  790. 

  791. # dpf__ensure_sources_non_empty

  792. # ------------------------------------------------------------------------------

  793. #

  794. # Ensure the given source list contains at least one file.

  795. # The function appends an empty source file to the list if necessary.

  796. # This is useful when CMake does not permit to add targets without sources.

  797. #

  798. function(dpf__ensure_sources_non_empty VAR)

  799.   if(NOT "" STREQUAL "${${VAR}}")

  800.     return()

  801.   endif()

  802.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  803.   if(NOT EXISTS "${_file}")

  804.     file(WRITE "${_file}" "")

  805.   endif()

  806.   set("${VAR}" "${_file}" PARENT_SCOPE)

  807. endfunction()

  808. 

  809. # dpf__create_dummy_source_list

  810. # ------------------------------------------------------------------------------

  811. #

  812. # Create a dummy source list which is equivalent to compiling nothing.

  813. # This is only for compatibility with older CMake versions, which refuse to add

  814. # targets without any sources.

  815. #

  816. macro(dpf__create_dummy_source_list VAR)

  817.   set("${VAR}")

  818.   if(CMAKE_VERSION VERSION_LESS "3.11")

  819.     dpf__ensure_sources_non_empty("${VAR}")

  820.   endif()

  821. endmacro()

  822. 

  823. # dpf__warn_once

  824. # ------------------------------------------------------------------------------

  825. #

  826. # Prints a warning message once only.

  827. #

  828. function(dpf__warn_once_only TOKEN MESSAGE)

  829.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  830.   if(NOT _warned)

  831.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  832.     message(WARNING "${MESSAGE}")

  833.   endif()

  834. endfunction()