DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1575 Commits
7 Branches
295MB
Tree: 2711cbefa4
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '2711cbefa4'
${ noResults }
DPF/cmake/DPF-plugin.cmake

804 lines
28KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2 vst3

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if(_dgl_library)

  126.     # make sure that all code will see DGL_* definitions

  127.     target_link_libraries("${NAME}" PUBLIC

  128.       "${_dgl_library}-definitions"

  129.       dgl-system-libs-definitions)

  130.   endif()

  131. 

  132.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  133.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  134. 

  135.   if(_dgl_library)

  136.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  137.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  138.     # add the files containing Objective-C classes, recompiled under namespace

  139.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  140.   else()

  141.     add_library("${NAME}-ui" INTERFACE)

  142.   endif()

  143. 

  144.   ###

  145.   foreach(_target ${_dpf_plugin_TARGETS})

  146.     if(_target STREQUAL "jack")

  147.       dpf__build_jack("${NAME}" "${_dgl_library}")

  148.     elseif(_target STREQUAL "ladspa")

  149.       dpf__build_ladspa("${NAME}")

  150.     elseif(_target STREQUAL "dssi")

  151.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  152.     elseif(_target STREQUAL "lv2")

  153.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  154.     elseif(_target STREQUAL "vst2")

  155.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  156.     elseif(_target STREQUAL "vst3")

  157.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  158.     else()

  159.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  160.     endif()

  161.   endforeach()

  162. endfunction()

  163. 

  164. # ------------------------------------------------------------------------------

  165. # DPF private functions (prefixed with `dpf__`)

  166. # ------------------------------------------------------------------------------

  167. 

  168. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  169. #       to the output directory.

  170. #

  171. 

  172. # dpf__build_jack

  173. # ------------------------------------------------------------------------------

  174. #

  175. # Add build rules for a JACK program.

  176. #

  177. function(dpf__build_jack NAME DGL_LIBRARY)

  178.   dpf__create_dummy_source_list(_no_srcs)

  179. 

  180.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  181.   dpf__add_plugin_main("${NAME}-jack" "jack")

  182.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  183.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  184.   set_target_properties("${NAME}-jack" PROPERTIES

  185.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  186.     OUTPUT_NAME "${NAME}")

  187. 

  188.   # Note: libjack will be linked at runtime

  189.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  190.     target_link_libraries("${NAME}-jack" PRIVATE "dl")

  191.   endif()

  192. 

  193.   # for RtAudio native fallback

  194.   if(APPLE)

  195.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  196.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  197.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  198.   endif()

  199. endfunction()

  200. 

  201. # dpf__build_ladspa

  202. # ------------------------------------------------------------------------------

  203. #

  204. # Add build rules for a LADSPA plugin.

  205. #

  206. function(dpf__build_ladspa NAME)

  207.   dpf__create_dummy_source_list(_no_srcs)

  208. 

  209.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  210.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  211.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  212.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  213.   set_target_properties("${NAME}-ladspa" PROPERTIES

  214.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  215.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  216.     OUTPUT_NAME "${NAME}-ladspa"

  217.     PREFIX "")

  218. endfunction()

  219. 

  220. # dpf__build_dssi

  221. # ------------------------------------------------------------------------------

  222. #

  223. # Add build rules for a DSSI plugin.

  224. #

  225. function(dpf__build_dssi NAME DGL_LIBRARY)

  226.   find_package(PkgConfig)

  227.   pkg_check_modules(LIBLO "liblo")

  228.   if(NOT LIBLO_FOUND)

  229.     dpf__warn_once_only(missing_liblo

  230.       "liblo is not found, skipping the `dssi` plugin targets")

  231.     return()

  232.   endif()

  233. 

  234.   link_directories(${LIBLO_LIBRARY_DIRS})

  235. 

  236.   dpf__create_dummy_source_list(_no_srcs)

  237. 

  238.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  239.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  240.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  241.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  242.   set_target_properties("${NAME}-dssi" PROPERTIES

  243.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  244.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  245.     OUTPUT_NAME "${NAME}-dssi"

  246.     PREFIX "")

  247. 

  248.   if(DGL_LIBRARY)

  249.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  250.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  251.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  252.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  253.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  254.       OUTPUT_NAME "${NAME}_ui")

  255. 

  256.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  257.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  258.   endif()

  259. endfunction()

  260. 

  261. # dpf__build_lv2

  262. # ------------------------------------------------------------------------------

  263. #

  264. # Add build rules for an LV2 plugin.

  265. #

  266. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  267.   dpf__create_dummy_source_list(_no_srcs)

  268. 

  269.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  270.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  271.   if(DGL_LIBRARY AND MONOLITHIC)

  272.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  273.   else()

  274.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  275.   endif()

  276.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  277.   set_target_properties("${NAME}-lv2" PROPERTIES

  278.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  279.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  280.     OUTPUT_NAME "${NAME}_dsp"

  281.     PREFIX "")

  282. 

  283.   if(DGL_LIBRARY)

  284.     if(MONOLITHIC)

  285.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  286.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  287.       set_target_properties("${NAME}-lv2" PROPERTIES

  288.         OUTPUT_NAME "${NAME}")

  289.     else()

  290.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  291.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  292.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  293.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  294.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  295.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  296.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  297.         OUTPUT_NAME "${NAME}_ui"

  298.         PREFIX "")

  299.     endif()

  300.   endif()

  301. 

  302.   dpf__add_lv2_ttl_generator()

  303.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  304. 

  305.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  306.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  307.     "$<TARGET_FILE:lv2_ttl_generator>"

  308.     "$<TARGET_FILE:${NAME}-lv2>"

  309.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  310.     DEPENDS lv2_ttl_generator)

  311. endfunction()

  312. 

  313. # dpf__build_vst2

  314. # ------------------------------------------------------------------------------

  315. #

  316. # Add build rules for a VST2 plugin.

  317. #

  318. function(dpf__build_vst2 NAME DGL_LIBRARY)

  319.   dpf__create_dummy_source_list(_no_srcs)

  320. 

  321.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  322.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  323.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  324.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  325.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  326.   set_target_properties("${NAME}-vst2" PROPERTIES

  327.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  328.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  329.     OUTPUT_NAME "${NAME}-vst2"

  330.     PREFIX "")

  331.   if(APPLE)

  332.     set_target_properties("${NAME}-vst2" PROPERTIES

  333.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  334.       OUTPUT_NAME "${NAME}"

  335.       SUFFIX "")

  336.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  337.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  338.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  339.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  340.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  341.   endif()

  342. endfunction()

  343. 

  344. # dpf__determine_vst3_package_architecture

  345. # ------------------------------------------------------------------------------

  346. #

  347. # Determines the package architecture for a VST3 plugin target.

  348. #

  349. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  350.   # if set by variable, override the detection

  351.   if(DPF_VST3_ARCHITECTURE)

  352.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  353.     return()

  354.   endif()

  355. 

  356.   # not used on Apple, which supports universal binary

  357.   if(APPLE)

  358.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  359.     return()

  360.   endif()

  361. 

  362.   # identify the target processor (special case of MSVC, problematic sometimes)

  363.   if(MSVC)

  364.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  365.   else()

  366.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  367.   endif()

  368. 

  369.   # transform the processor name to a format that VST3 recognizes

  370.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  371.     set(vst3_package_arch "x86_64")

  372.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  373.     if(WIN32)

  374.       set(vst3_package_arch "x86")

  375.     else()

  376.       set(vst3_package_arch "i386")

  377.     endif()

  378.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  379.     set(vst3_package_arch "${vst3_system_arch}")

  380.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  381.     set(vst3_package_arch "aarch64")

  382.   else()

  383.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  384.   endif()

  385. 

  386.   # TODO: the detections for Windows arm/arm64 when supported

  387. 

  388.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  389. endfunction()

  390. 

  391. # dpf__build_vst3

  392. # ------------------------------------------------------------------------------

  393. #

  394. # Add build rules for a VST3 plugin.

  395. #

  396. function(dpf__build_vst3 NAME DGL_LIBRARY)

  397.   dpf__determine_vst3_package_architecture(vst3_arch)

  398. 

  399.   dpf__create_dummy_source_list(_no_srcs)

  400. 

  401.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  402.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  403.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  404.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  405.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  406.   set_target_properties("${NAME}-vst3" PROPERTIES

  407.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  408.     OUTPUT_NAME "${NAME}"

  409.     PREFIX "")

  410. 

  411.   if(APPLE)

  412.     set_target_properties("${NAME}-vst3" PROPERTIES

  413.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  414.       SUFFIX "")

  415.   elseif(WIN32)

  416.     set_target_properties("${NAME}-vst3" PROPERTIES

  417.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  418.   else()

  419.     set_target_properties("${NAME}-vst3" PROPERTIES

  420.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  421.   endif()

  422. 

  423.   if(APPLE)

  424.     # Uses the same macOS bundle template as VST2

  425.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  426.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  427.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  428.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  429.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  430.   endif()

  431. endfunction()

  432. 

  433. # dpf__add_dgl_cairo

  434. # ------------------------------------------------------------------------------

  435. #

  436. # Add the Cairo variant of DGL, if not already available.

  437. #

  438. function(dpf__add_dgl_cairo)

  439.   if(TARGET dgl-cairo)

  440.     return()

  441.   endif()

  442. 

  443.   find_package(PkgConfig)

  444.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  445. 

  446.   link_directories(${CAIRO_LIBRARY_DIRS})

  447. 

  448.   dpf__add_static_library(dgl-cairo STATIC

  449.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  450.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  451.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  452.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  453.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  454.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  455.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  456.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  457.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  458.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  459.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  460.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  461.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  462.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  463.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  464.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  465.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  466.   if(NOT APPLE)

  467.     target_sources(dgl-cairo PRIVATE

  468.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  469.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  470.     #target_sources(dgl-opengl PRIVATE

  471.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  472.   endif()

  473.   target_include_directories(dgl-cairo PUBLIC

  474.     "${DPF_ROOT_DIR}/dgl")

  475.   target_include_directories(dgl-cairo PUBLIC

  476.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  477. 

  478.   dpf__add_dgl_system_libs()

  479.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  480. 

  481.   add_library(dgl-cairo-definitions INTERFACE)

  482.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  483. 

  484.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  485.   if(MINGW)

  486.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  487.   else()

  488.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  489.   endif()

  490.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  491. endfunction()

  492. 

  493. # dpf__add_dgl_opengl

  494. # ------------------------------------------------------------------------------

  495. #

  496. # Add the OpenGL variant of DGL, if not already available.

  497. #

  498. function(dpf__add_dgl_opengl)

  499.   if(TARGET dgl-opengl)

  500.     return()

  501.   endif()

  502. 

  503.   if(NOT OpenGL_GL_PREFERENCE)

  504.     set(OpenGL_GL_PREFERENCE "LEGACY")

  505.   endif()

  506. 

  507.   find_package(OpenGL REQUIRED)

  508. 

  509.   dpf__add_static_library(dgl-opengl STATIC

  510.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  511.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  512.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  513.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  514.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  515.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  516.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  517.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  518.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  519.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  520.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  521.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  522.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  523.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  524.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  525.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  526.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  528.   if(NOT APPLE)

  529.     target_sources(dgl-opengl PRIVATE

  530.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  531.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  532.     #target_sources(dgl-opengl PRIVATE

  533.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  534.   endif()

  535.   target_include_directories(dgl-opengl PUBLIC

  536.     "${DPF_ROOT_DIR}/dgl")

  537.   target_include_directories(dgl-opengl PUBLIC

  538.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  539. 

  540.   if(APPLE)

  541.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  542.   endif()

  543. 

  544.   dpf__add_dgl_system_libs()

  545.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  546. 

  547.   add_library(dgl-opengl-definitions INTERFACE)

  548.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  549. 

  550.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  551.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  552. endfunction()

  553. 

  554. # dpf__add_plugin_specific_ui_sources

  555. # ------------------------------------------------------------------------------

  556. #

  557. # Compile plugin-specific UI sources into the target designated by the given

  558. # name. There are some special considerations here:

  559. # - On most platforms, sources can be compiled only once, as part of DGL;

  560. # - On macOS, for any sources which define Objective-C interfaces, these must

  561. #   be recompiled for each plugin under a unique namespace. In this case, the

  562. #   name must be a plugin-specific identifier, and it will be used for computing

  563. #   the unique ID along with the project version.

  564. function(dpf__add_plugin_specific_ui_sources NAME)

  565.   if(APPLE)

  566.     target_sources("${NAME}" PRIVATE

  567.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  568.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  569.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  570.   endif()

  571. endfunction()

  572. 

  573. # dpf__add_dgl_system_libs

  574. # ------------------------------------------------------------------------------

  575. #

  576. # Find system libraries required by DGL and add them as an interface target.

  577. #

  578. function(dpf__add_dgl_system_libs)

  579.   if(TARGET dgl-system-libs)

  580.     return()

  581.   endif()

  582.   add_library(dgl-system-libs INTERFACE)

  583.   add_library(dgl-system-libs-definitions INTERFACE)

  584.   if(HAIKU)

  585.     target_link_libraries(dgl-system-libs INTERFACE "be")

  586.   elseif(WIN32)

  587.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  588.   elseif(APPLE)

  589.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  590.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  591.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  592.   else()

  593.     find_package(X11 REQUIRED)

  594.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  595.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  596.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  597.     if(X11_Xext_FOUND)

  598.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  599.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  600.     endif()

  601.     if(X11_XSync_FOUND)

  602.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  603.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  604.     endif()

  605.     if(X11_Xrandr_FOUND)

  606.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  607.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  608.     endif()

  609.     #if(X11_Xcursor_FOUND)

  610.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  611.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  612.     #endif()

  613.    endif()

  614. 

  615.    if(MSVC)

  616.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  617.      foreach(_gl_header "glext.h")

  618.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  619.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  620.        endif()

  621.      endforeach()

  622.      foreach(_khr_header "khrplatform.h")

  623.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  624.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  625.        endif()

  626.      endforeach()

  627.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  628.    endif()

  629. 

  630.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  631. endfunction()

  632. 

  633. # dpf__add_executable

  634. # ------------------------------------------------------------------------------

  635. #

  636. # Adds an executable target, and set some default properties on the target.

  637. #

  638. function(dpf__add_executable NAME)

  639.   add_executable("${NAME}" ${ARGN})

  640.   dpf__set_target_defaults("${NAME}")

  641.   if(MINGW)

  642.     target_link_libraries("${NAME}" PRIVATE "-static")

  643.   endif()

  644. endfunction()

  645. 

  646. # dpf__add_module

  647. # ------------------------------------------------------------------------------

  648. #

  649. # Adds a module target, and set some default properties on the target.

  650. #

  651. function(dpf__add_module NAME)

  652.   add_library("${NAME}" MODULE ${ARGN})

  653.   dpf__set_target_defaults("${NAME}")

  654.   if(MINGW)

  655.     target_link_libraries("${NAME}" PRIVATE "-static")

  656.   endif()

  657. endfunction()

  658. 

  659. # dpf__add_static_library

  660. # ------------------------------------------------------------------------------

  661. #

  662. # Adds a static library target, and set some default properties on the target.

  663. #

  664. function(dpf__add_static_library NAME)

  665.   add_library("${NAME}" STATIC ${ARGN})

  666.   dpf__set_target_defaults("${NAME}")

  667. endfunction()

  668. 

  669. # dpf__set_module_export_list

  670. # ------------------------------------------------------------------------------

  671. #

  672. # Applies a list of exported symbols to the module target.

  673. #

  674. function(dpf__set_module_export_list NAME EXPORTS)

  675.   if(WIN32)

  676.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  677.   elseif(APPLE)

  678.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  679.       "-Xlinker" "-exported_symbols_list"

  680.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  681.   else()

  682.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  683.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  684.   endif()

  685. endfunction()

  686. 

  687. # dpf__set_target_defaults

  688. # ------------------------------------------------------------------------------

  689. #

  690. # Set default properties which must apply to all DPF-defined targets.

  691. #

  692. function(dpf__set_target_defaults NAME)

  693.   set_target_properties("${NAME}" PROPERTIES

  694.     POSITION_INDEPENDENT_CODE TRUE

  695.     C_VISIBILITY_PRESET "hidden"

  696.     CXX_VISIBILITY_PRESET "hidden"

  697.     VISIBILITY_INLINES_HIDDEN TRUE)

  698.   if(WIN32)

  699.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  700.   endif()

  701.   if (MINGW)

  702.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  703.   endif()

  704.   if (MSVC)

  705.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  706.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  707.   endif()

  708. endfunction()

  709. 

  710. # dpf__add_plugin_main

  711. # ------------------------------------------------------------------------------

  712. #

  713. # Adds plugin code to the given target.

  714. #

  715. function(dpf__add_plugin_main NAME TARGET)

  716.   target_sources("${NAME}" PRIVATE

  717.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  718.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  719. endfunction()

  720. 

  721. # dpf__add_ui_main

  722. # ------------------------------------------------------------------------------

  723. #

  724. # Adds UI code to the given target (only if the target has UI).

  725. #

  726. function(dpf__add_ui_main NAME TARGET HAS_UI)

  727.   if(HAS_UI)

  728.     target_sources("${NAME}" PRIVATE

  729.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  730.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  731.   endif()

  732. endfunction()

  733. 

  734. # dpf__add_plugin_target_definition

  735. # ------------------------------------------------------------------------------

  736. #

  737. # Adds the plugins target macro definition.

  738. # This selects which entry file is compiled according to the target type.

  739. #

  740. function(dpf__add_plugin_target_definition NAME TARGET)

  741.   string(TOUPPER "${TARGET}" _upperTarget)

  742.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  743. endfunction()

  744. 

  745. # dpf__add_lv2_ttl_generator

  746. # ------------------------------------------------------------------------------

  747. #

  748. # Build the LV2 TTL generator.

  749. #

  750. function(dpf__add_lv2_ttl_generator)

  751.   if(TARGET lv2_ttl_generator)

  752.     return()

  753.   endif()

  754.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  755.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  756.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  757.   endif()

  758. endfunction()

  759. 

  760. # dpf__ensure_sources_non_empty

  761. # ------------------------------------------------------------------------------

  762. #

  763. # Ensure the given source list contains at least one file.

  764. # The function appends an empty source file to the list if necessary.

  765. # This is useful when CMake does not permit to add targets without sources.

  766. #

  767. function(dpf__ensure_sources_non_empty VAR)

  768.   if(NOT "" STREQUAL "${${VAR}}")

  769.     return()

  770.   endif()

  771.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  772.   if(NOT EXISTS "${_file}")

  773.     file(WRITE "${_file}" "")

  774.   endif()

  775.   set("${VAR}" "${_file}" PARENT_SCOPE)

  776. endfunction()

  777. 

  778. # dpf__create_dummy_source_list

  779. # ------------------------------------------------------------------------------

  780. #

  781. # Create a dummy source list which is equivalent to compiling nothing.

  782. # This is only for compatibility with older CMake versions, which refuse to add

  783. # targets without any sources.

  784. #

  785. macro(dpf__create_dummy_source_list VAR)

  786.   set("${VAR}")

  787.   if(CMAKE_VERSION VERSION_LESS "3.11")

  788.     dpf__ensure_sources_non_empty("${VAR}")

  789.   endif()

  790. endmacro()

  791. 

  792. # dpf__warn_once

  793. # ------------------------------------------------------------------------------

  794. #

  795. # Prints a warning message once only.

  796. #

  797. function(dpf__warn_once_only TOKEN MESSAGE)

  798.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  799.   if(NOT _warned)

  800.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  801.     message(WARNING "${MESSAGE}")

  802.   endif()

  803. endfunction()