DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
2442 Commits
6 Branches
50MB
Tree: 157692d557
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '157692d557'
${ noResults }
DPF/cmake/DPF-plugin.cmake

1702 lines
60KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. # Copyright (C) 2022-2024 Filipe Coelho <falktx@falktx.com>

  4. #

  5. # SPDX-License-Identifier: ISC

  6. 

  7. # ------------------------------------------------------------------------------

  8. # CMake support module for the DISTRHO Plugin Framework

  9. #

  10. # The purpose of this module is to help building music plugins easily, when the

  11. # project uses CMake as its build system.

  12. #

  13. # In order to use the helpers provided by this module, a plugin author should

  14. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  15. # The usage of this function is documented below in greater detail.

  16. #

  17. # Example project `CMakeLists.txt`:

  18. #

  19. # ```

  20. # cmake_minimum_required(VERSION 3.7)

  21. # project(MyPlugin)

  22. #

  23. # add_subdirectory(DPF)

  24. #

  25. # dpf_add_plugin(MyPlugin

  26. #   TARGETS clap lv2 vst2 vst3

  27. #   UI_TYPE opengl

  28. #   FILES_DSP

  29. #       src/MyPlugin.cpp

  30. #   FILES_UI

  31. #       src/MyUI.cpp)

  32. #

  33. # target_include_directories(MyPlugin

  34. #   PUBLIC src)

  35. # ```

  36. #

  37. # Important: note that properties, such as include directories, definitions,

  38. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  39. # propagate into all the plugin targets.

  40. 

  41. include(CMakeParseArguments)

  42. 

  43. # ------------------------------------------------------------------------------

  44. # DPF public functions

  45. # ------------------------------------------------------------------------------

  46. 

  47. # dpf_add_plugin(name <args...>)

  48. # ------------------------------------------------------------------------------

  49. #

  50. # Add a plugin built using the DISTRHO Plugin Framework.

  51. #

  52. # ------------------------------------------------------------------------------

  53. # Created targets:

  54. #

  55. #   `<name>`

  56. #       static library: the common part of the plugin

  57. #       The public properties set on this target apply to both DSP and UI.

  58. #

  59. #   `<name>-dsp`

  60. #       static library: the DSP part of the plugin

  61. #       The public properties set on this target apply to the DSP only.

  62. #

  63. #   `<name>-ui`

  64. #       static library: the UI part of the plugin

  65. #       The public properties set on this target apply to the UI only.

  66. #

  67. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  68. #       This is target-dependent and not intended for public use.

  69. #

  70. # ------------------------------------------------------------------------------

  71. # Arguments:

  72. #

  73. #   `TARGETS` <tgt1>...<tgtN>

  74. #       a list of one of more of the following target types:

  75. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`, `clap`

  76. #

  77. #   `UI_TYPE` <type>

  78. #       the user interface type, can be one of the following:

  79. #          - cairo

  80. #          - external

  81. #          - gles2

  82. #          - gles3

  83. #          - opengl (default)

  84. #          - opengl3

  85. #          - vulkan

  86. #          - webview

  87. #

  88. #   `FILES_COMMON` <file1>...<fileN>

  89. #       list of sources which are part of both DSP and UI

  90. #

  91. #   `FILES_DSP` <file1>...<fileN>

  92. #       list of sources which are part of the DSP

  93. #

  94. #   `FILES_UI` <file1>...<fileN>

  95. #       list of sources which are part of the UI

  96. #       empty indicates the plugin does not have UI

  97. #

  98. #   `MODGUI_CLASS_NAME`

  99. #       class name to use for modgui builds

  100. #

  101. #   `MONOLITHIC`

  102. #       build LV2 as a single binary for UI and DSP

  103. #

  104. #   `NO_SHARED_RESOURCES`

  105. #       do not build DPF shared resources (fonts, etc)

  106. #

  107. #   `USE_FILE_BROWSER`

  108. #       enable file browser dialog APIs

  109. #

  110. #   `USE_WEB_VIEW`

  111. #       enable web browser view APIs

  112. #

  113. function(dpf_add_plugin NAME)

  114.   set(options MONOLITHIC NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  115.   set(oneValueArgs MODGUI_CLASS_NAME UI_TYPE)

  116.   set(multiValueArgs FILES_COMMON FILES_DSP FILES_UI TARGETS)

  117.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  118. 

  119.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  120.     set(_dpf_plugin_UI_TYPE "opengl")

  121.   endif()

  122. 

  123.   set(_dgl_library)

  124.   if(_dpf_plugin_FILES_UI)

  125.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  126.       dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  127.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  128.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  129.       set(_dgl_library dgl-cairo)

  130.     elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  131.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  132.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  133.       set(_dgl_library dgl-external)

  134.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  135.       dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  136.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  137.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  138.       set(_dgl_library dgl-gles2)

  139.     elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  140.       dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  141.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  142.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  143.       set(_dgl_library dgl-gles3)

  144.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  145.       dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  146.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  147.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  148.       set(_dgl_library dgl-opengl)

  149.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  150.       dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  151.                            $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  152.                            $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  153.       set(_dgl_library dgl-opengl3)

  154.     elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  155.       dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  156.                           $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  157.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  158.       set(_dgl_library dgl-vulkan)

  159.     elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  160.       set(_dpf_plugin_USE_WEB_VIEW TRUE)

  161.       dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  162.                             $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  163.       set(_dgl_library dgl-external)

  164.     else()

  165.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  166.     endif()

  167.   else()

  168.     set(_dpf_plugin_UI_TYPE "")

  169.   endif()

  170. 

  171.   set(_dgl_has_ui OFF)

  172.   if(_dgl_library)

  173.     set(_dgl_has_ui ON)

  174.   endif()

  175. 

  176.   ###

  177.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  178.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  179.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  180. 

  181.   ###

  182.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  183.   target_include_directories("${NAME}" PUBLIC

  184.     "${DPF_ROOT_DIR}/distrho")

  185. 

  186.   if(_dpf_plugin_USE_FILE_BROWSER)

  187.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  188.   endif()

  189. 

  190.   if(_dpf_plugin_USE_WEB_VIEW)

  191.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  192.   endif()

  193. 

  194.   if(_dpf_plugin_MODGUI_CLASS_NAME)

  195.     target_compile_definitions("${NAME}" PUBLIC "DISTRHO_PLUGIN_MODGUI_CLASS_NAME=\"${_dpf_plugin_MODGUI_CLASS_NAME}\"")

  196.   endif()

  197. 

  198.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  199.     target_link_libraries("${NAME}" PRIVATE "dl")

  200.   endif()

  201. 

  202.   if(_dgl_library)

  203.     # make sure that all code will see DGL_* definitions

  204.     target_link_libraries("${NAME}" PUBLIC

  205.       "${_dgl_library}-definitions"

  206.       dgl-system-libs-definitions

  207.       dgl-system-libs)

  208.   endif()

  209. 

  210.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  211.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  212. 

  213.   if(_dgl_library)

  214.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  215.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  216.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  217.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  218.       if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  219.         execute_process(COMMAND ${CMAKE_C_COMPILER} -print-file-name=Scrt1.o

  220.           OUTPUT_STRIP_TRAILING_WHITESPACE

  221.           OUTPUT_VARIABLE _dpf_plugin_shared_crt)

  222.         target_link_libraries("${NAME}-ui" PRIVATE "rt")

  223.       endif()

  224.     endif()

  225.     # add the files containing C++17 or Objective-C classes

  226.     dpf__add_plugin_specific_ui_sources("${NAME}-ui" "${_dpf_plugin_USE_WEB_VIEW}")

  227.   else()

  228.     add_library("${NAME}-ui" INTERFACE)

  229.   endif()

  230. 

  231.   ###

  232.   foreach(_target ${_dpf_plugin_TARGETS})

  233.     if(_target STREQUAL "jack")

  234.       dpf__build_jack("${NAME}" "${_dgl_has_ui}")

  235.     elseif(_target STREQUAL "ladspa")

  236.       dpf__build_ladspa("${NAME}")

  237.     elseif(_target STREQUAL "dssi")

  238.       dpf__build_dssi("${NAME}" "${_dgl_has_ui}")

  239.     elseif(_target STREQUAL "lv2")

  240.       dpf__build_lv2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_MONOLITHIC}" "${_dpf_plugin_shared_crt}")

  241.     elseif(_target STREQUAL "vst2")

  242.       dpf__build_vst2("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  243.     elseif(_target STREQUAL "vst3")

  244.       dpf__build_vst3("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  245.     elseif(_target STREQUAL "clap")

  246.       dpf__build_clap("${NAME}" "${_dgl_has_ui}" "${_dpf_plugin_shared_crt}")

  247.     elseif(_target STREQUAL "au")

  248.       if (APPLE)

  249.         dpf__build_au("${NAME}" "${_dgl_has_ui}")

  250.       endif()

  251.     elseif(_target STREQUAL "static")

  252.       dpf__build_static("${NAME}" "${_dgl_has_ui}")

  253.     else()

  254.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  255.     endif()

  256.   endforeach()

  257. endfunction()

  258. 

  259. # dpf_add_executable(target <args...>)

  260. # ------------------------------------------------------------------------------

  261. #

  262. # Add a simple executable built using the DISTRHO Plugin Framework.

  263. #

  264. # ------------------------------------------------------------------------------

  265. # Arguments:

  266. #

  267. #   `UI_TYPE` <type>

  268. #       the user interface type, can be one of the following:

  269. #          - cairo

  270. #          - external

  271. #          - gles2

  272. #          - gles3

  273. #          - opengl (default)

  274. #          - opengl3

  275. #          - vulkan

  276. #          - webview

  277. #

  278. #   `NO_SHARED_RESOURCES`

  279. #       do not build DPF shared resources (fonts, etc)

  280. #

  281. #   `USE_FILE_BROWSER`

  282. #       enable file browser dialog APIs

  283. #

  284. #   `USE_WEB_VIEW`

  285. #       enable web browser view APIs

  286. #

  287. function(dpf_add_executable NAME)

  288.   set(options NO_SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  289.   set(oneValueArgs UI_TYPE)

  290.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  291. 

  292.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  293.     set(_dpf_plugin_UI_TYPE "opengl")

  294.   endif()

  295. 

  296.   set(_dgl_library)

  297.   if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  298.     dpf__add_dgl_cairo($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  299.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  300.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  301.     set(_dgl_library dgl-cairo)

  302.   elseif(_dpf_plugin_UI_TYPE STREQUAL "external")

  303.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  304.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  305.     set(_dgl_library dgl-external)

  306.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles2")

  307.     dpf__add_dgl_gles2($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  308.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  309.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  310.     set(_dgl_library dgl-gles2)

  311.   elseif(_dpf_plugin_UI_TYPE STREQUAL "gles3")

  312.     dpf__add_dgl_gles3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  313.                        $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  314.                        $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  315.     set(_dgl_library dgl-gles3)

  316.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  317.     dpf__add_dgl_opengl($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  318.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  319.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  320.     set(_dgl_library dgl-opengl)

  321.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl3")

  322.     dpf__add_dgl_opengl3($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  323.                          $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  324.                          $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  325.     set(_dgl_library dgl-opengl3)

  326.   elseif(_dpf_plugin_UI_TYPE STREQUAL "vulkan")

  327.     dpf__add_dgl_vulkan($<NOT:$<BOOL:${_dpf_plugin_NO_SHARED_RESOURCES}>>

  328.                         $<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  329.                         $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  330.     set(_dgl_library dgl-vulkan)

  331.   elseif(_dpf_plugin_UI_TYPE STREQUAL "webview")

  332.     set(_dpf_plugin_USE_WEB_VIEW TRUE)

  333.     dpf__add_dgl_external($<BOOL:${_dpf_plugin_USE_FILE_BROWSER}>

  334.                           $<BOOL:${_dpf_plugin_USE_WEB_VIEW}>)

  335.     set(_dgl_library dgl-external)

  336.   else()

  337.     message(FATAL_ERROR "Unrecognized UI type for executable: ${_dpf_plugin_UI_TYPE}")

  338.   endif()

  339. 

  340.   set(_dgl_has_ui OFF)

  341.   if(_dgl_library)

  342.     set(_dgl_has_ui ON)

  343.   endif()

  344. 

  345.   dpf__create_dummy_source_list(_no_srcs)

  346.   dpf__add_executable("${NAME}" ${_no_srcs})

  347.   target_include_directories("${NAME}" PUBLIC "${DPF_ROOT_DIR}/distrho")

  348. 

  349.   if(_dpf_plugin_USE_FILE_BROWSER)

  350.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_FILE_BROWSER")

  351.   endif()

  352. 

  353.   if(_dpf_plugin_USE_WEB_VIEW)

  354.     target_compile_definitions("${NAME}" PUBLIC "DGL_USE_WEB_VIEW")

  355.   endif()

  356. 

  357.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  358.     target_link_libraries("${NAME}" PRIVATE "dl")

  359.   endif()

  360. 

  361.   if(_dgl_library)

  362.     # make sure that all code will see DGL_* definitions

  363.     target_link_libraries("${NAME}" PUBLIC

  364.       "${_dgl_library}"

  365.       "${_dgl_library}-definitions"

  366.       dgl-system-libs-definitions

  367.       dgl-system-libs)

  368.     # extra linkage for linux web view

  369.     if(LINUX AND _dpf_plugin_USE_WEB_VIEW)

  370.       target_link_libraries("${NAME}" PRIVATE "rt")

  371.     endif()

  372.     # add the files containing C++17 or Objective-C classes

  373.     dpf__add_plugin_specific_ui_sources("${NAME}" "${_dpf_plugin_USE_WEB_VIEW}")

  374.   endif()

  375. endfunction()

  376. 

  377. # ------------------------------------------------------------------------------

  378. # DPF private functions (prefixed with `dpf__`)

  379. # ------------------------------------------------------------------------------

  380. 

  381. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  382. #       to the output directory.

  383. #

  384. 

  385. # dpf__build_jack

  386. # ------------------------------------------------------------------------------

  387. #

  388. # Add build rules for a JACK/Standalone program.

  389. #

  390. function(dpf__build_jack NAME HAS_UI)

  391.   dpf__create_dummy_source_list(_no_srcs)

  392. 

  393.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  394.   dpf__add_plugin_main("${NAME}-jack" "jack")

  395.   dpf__add_ui_main("${NAME}-jack" "jack" "${HAS_UI}")

  396.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  397.   set_target_properties("${NAME}-jack" PROPERTIES

  398.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  399.     OUTPUT_NAME "${NAME}")

  400. 

  401.   target_compile_definitions("${NAME}" PUBLIC "HAVE_JACK")

  402.   target_compile_definitions("${NAME}-jack" PRIVATE "HAVE_GETTIMEOFDAY")

  403. 

  404.   find_package(PkgConfig QUIET)

  405.   if(PKG_CONFIG_FOUND)

  406.     pkg_check_modules(SDL2 "sdl2")

  407.   else()

  408.     set(SDL2_FOUND FALSE)

  409.   endif()

  410.   if(SDL2_FOUND)

  411.     target_compile_definitions("${NAME}" PUBLIC "HAVE_SDL2")

  412.     target_include_directories("${NAME}-jack" PRIVATE ${SDL2_STATIC_INCLUDE_DIRS})

  413.     target_link_libraries("${NAME}-jack" PRIVATE ${SDL2_STATIC_LIBRARIES})

  414.     dpf__target_link_directories("${NAME}-jack" "${SDL2_STATIC_LIBRARY_DIRS}")

  415.   endif()

  416. 

  417.   if(APPLE OR WIN32)

  418.     target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  419.   else()

  420.     find_package(Threads)

  421.     pkg_check_modules(ALSA "alsa")

  422.     pkg_check_modules(PULSEAUDIO "libpulse-simple")

  423.     if(ALSA_FOUND)

  424.       target_compile_definitions("${NAME}" PUBLIC "HAVE_ALSA")

  425.       target_include_directories("${NAME}-jack" PRIVATE ${ALSA_INCLUDE_DIRS})

  426.       target_link_libraries("${NAME}-jack" PRIVATE ${ALSA_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  427.       dpf__target_link_directories("${NAME}-jack" "${ALSA_LIBRARY_DIRS}")

  428.     endif()

  429.     if(PULSEAUDIO_FOUND)

  430.       target_compile_definitions("${NAME}" PUBLIC "HAVE_PULSEAUDIO")

  431.       target_include_directories("${NAME}-jack" PRIVATE ${PULSEAUDIO_INCLUDE_DIRS})

  432.       target_link_libraries("${NAME}-jack" PRIVATE ${PULSEAUDIO_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})

  433.       dpf__target_link_directories("${NAME}-jack" "${PULSEAUDIO_LIBRARY_DIRS}")

  434.     endif()

  435.     if(ALSA_FOUND OR PULSEAUDIO_FOUND)

  436.       target_compile_definitions("${NAME}" PUBLIC "HAVE_RTAUDIO")

  437.     endif()

  438.   endif()

  439. 

  440.   # for RtAudio native fallback

  441.   if(APPLE)

  442.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  443.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  444.     find_library(APPLE_COREMIDI_FRAMEWORK "CoreMIDI")

  445.     target_link_libraries("${NAME}-jack" PRIVATE

  446.       "${APPLE_COREAUDIO_FRAMEWORK}"

  447.       "${APPLE_COREFOUNDATION_FRAMEWORK}"

  448.       "${APPLE_COREMIDI_FRAMEWORK}")

  449.   elseif(WIN32)

  450.     target_link_libraries("${NAME}-jack" PRIVATE "ksuser" "mfplat" "mfuuid" "ole32" "winmm" "wmcodecdspuuid")

  451.     if(HAS_UI AND MINGW)

  452.       set_target_properties("${NAME}-jack" PROPERTIES WIN32_EXECUTABLE TRUE)

  453.     endif()

  454.   endif()

  455. endfunction()

  456. 

  457. # dpf__build_ladspa

  458. # ------------------------------------------------------------------------------

  459. #

  460. # Add build rules for a LADSPA plugin.

  461. #

  462. function(dpf__build_ladspa NAME)

  463.   dpf__create_dummy_source_list(_no_srcs)

  464. 

  465.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  466.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  467.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  468.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  469.   set_target_properties("${NAME}-ladspa" PROPERTIES

  470.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  471.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  472.     OUTPUT_NAME "${NAME}-ladspa"

  473.     PREFIX "")

  474. endfunction()

  475. 

  476. # dpf__build_dssi

  477. # ------------------------------------------------------------------------------

  478. #

  479. # Add build rules for a DSSI plugin.

  480. #

  481. function(dpf__build_dssi NAME HAS_UI)

  482.   find_package(PkgConfig QUIET)

  483.   if(PKG_CONFIG_FOUND)

  484.     pkg_check_modules(LIBLO "liblo")

  485.   else()

  486.     set(LIBLO_FOUND FALSE)

  487.   endif()

  488.   if(NOT LIBLO_FOUND)

  489.     dpf__warn_once_only(missing_liblo

  490.       "liblo is not found, skipping the `dssi` plugin targets")

  491.     return()

  492.   endif()

  493. 

  494.   dpf__create_dummy_source_list(_no_srcs)

  495. 

  496.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  497.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  498.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  499.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  500.   set_target_properties("${NAME}-dssi" PROPERTIES

  501.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  502.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  503.     OUTPUT_NAME "${NAME}-dssi"

  504.     PREFIX "")

  505. 

  506.   if(HAS_UI)

  507.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  508.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${HAS_UI}")

  509.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  510.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  511.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  512.       OUTPUT_NAME "${NAME}_ui")

  513. 

  514.     target_compile_definitions("${NAME}" PUBLIC "HAVE_LIBLO")

  515.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  516.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  517.     dpf__target_link_directories("${NAME}-dssi-ui" "${LIBLO_LIBRARY_DIRS}")

  518.   endif()

  519. endfunction()

  520. 

  521. # dpf__build_lv2

  522. # ------------------------------------------------------------------------------

  523. #

  524. # Add build rules for an LV2 plugin.

  525. #

  526. function(dpf__build_lv2 NAME HAS_UI MONOLITHIC EXTRA_UI_LINK_OPTS)

  527.   dpf__create_dummy_source_list(_no_srcs)

  528. 

  529.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  530.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  531.   if(HAS_UI AND MONOLITHIC)

  532.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  533.   else()

  534.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  535.   endif()

  536.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  537.   set_target_properties("${NAME}-lv2" PROPERTIES

  538.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  539.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  540.     OUTPUT_NAME "${NAME}_dsp"

  541.     PREFIX "")

  542. 

  543.   if(HAS_UI)

  544.     if(MONOLITHIC)

  545.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${HAS_UI}")

  546.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  547.       target_link_options("${NAME}-lv2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  548.       set_target_properties("${NAME}-lv2" PROPERTIES

  549.         OUTPUT_NAME "${NAME}")

  550.     else()

  551.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  552.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${HAS_UI}")

  553.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  554.       target_link_options("${NAME}-lv2-ui" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  555.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  556.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  557.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  558.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  559.         OUTPUT_NAME "${NAME}_ui"

  560.         PREFIX "")

  561.     endif()

  562.   endif()

  563. 

  564.   dpf__add_lv2_ttl_generator()

  565.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  566. 

  567.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  568. 

  569.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  570.     COMMAND

  571.     ${CMAKE_CROSSCOMPILING_EMULATOR}

  572.     "$<TARGET_FILE:lv2_ttl_generator>"

  573.     "$<TARGET_FILE:${NAME}-lv2>"

  574.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  575. endfunction()

  576. 

  577. # dpf__build_vst2

  578. # ------------------------------------------------------------------------------

  579. #

  580. # Add build rules for a VST2 plugin.

  581. #

  582. function(dpf__build_vst2 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  583.   dpf__create_dummy_source_list(_no_srcs)

  584. 

  585.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  586.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  587.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${HAS_UI}")

  588.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  589.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  590.   target_link_options("${NAME}-vst2" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  591.   set_target_properties("${NAME}-vst2" PROPERTIES

  592.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  593.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  594.     OUTPUT_NAME "${NAME}-vst2"

  595.     PREFIX "")

  596.   if(APPLE)

  597.     set_target_properties("${NAME}-vst2" PROPERTIES

  598.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  599.       OUTPUT_NAME "${NAME}"

  600.       SUFFIX "")

  601.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  602.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  603.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  604.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  605.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  606.   endif()

  607. endfunction()

  608. 

  609. # dpf__determine_vst3_package_architecture

  610. # ------------------------------------------------------------------------------

  611. #

  612. # Determines the package architecture for a VST3 plugin target.

  613. #

  614. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  615.   # if set by variable, override the detection

  616.   if(DPF_VST3_ARCHITECTURE)

  617.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  618.     return()

  619.   endif()

  620. 

  621.   # not used on Apple, which supports universal binary

  622.   if(APPLE)

  623.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  624.     return()

  625.   endif()

  626. 

  627.   # identify the target processor (special case of MSVC, problematic sometimes)

  628.   if(MSVC)

  629.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  630.   else()

  631.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  632.   endif()

  633. 

  634.   # transform the processor name to a format that VST3 recognizes

  635.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  636.     set(vst3_package_arch "x86_64")

  637.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  638.     if(WIN32)

  639.       set(vst3_package_arch "x86")

  640.     else()

  641.       set(vst3_package_arch "i386")

  642.     endif()

  643.   elseif(vst3_system_arch MATCHES "^(armv[3-9][a-z]*|aarch64|loongarch64|ppc(64)?(le)?)$")

  644.     set(vst3_package_arch "${vst3_system_arch}")

  645.   else()

  646.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  647.   endif()

  648. 

  649.   # TODO: the detections for Windows arm/arm64 when supported

  650. 

  651.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  652. endfunction()

  653. 

  654. # dpf__build_vst3

  655. # ------------------------------------------------------------------------------

  656. #

  657. # Add build rules for a VST3 plugin.

  658. #

  659. function(dpf__build_vst3 NAME HAS_UI EXTRA_UI_LINK_OPTS)

  660.   dpf__determine_vst3_package_architecture(vst3_arch)

  661. 

  662.   dpf__create_dummy_source_list(_no_srcs)

  663. 

  664.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  665.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  666.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${HAS_UI}")

  667.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  668.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  669.   target_link_options("${NAME}-vst3" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  670.   set_target_properties("${NAME}-vst3" PROPERTIES

  671.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  672.     OUTPUT_NAME "${NAME}"

  673.     PREFIX "")

  674. 

  675.   if(APPLE)

  676.     set_target_properties("${NAME}-vst3" PROPERTIES

  677.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  678.       SUFFIX "")

  679.   elseif(WIN32)

  680.     set_target_properties("${NAME}-vst3" PROPERTIES

  681.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  682.   else()

  683.     set_target_properties("${NAME}-vst3" PROPERTIES

  684.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  685.   endif()

  686. 

  687.   if(APPLE)

  688.     # Uses the same macOS bundle template as VST2

  689.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  690.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  691.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  692.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  693.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  694.   endif()

  695. endfunction()

  696. 

  697. # dpf__build_clap

  698. # ------------------------------------------------------------------------------

  699. #

  700. # Add build rules for a CLAP plugin.

  701. #

  702. function(dpf__build_clap NAME HAS_UI EXTRA_UI_LINK_OPTS)

  703.   dpf__create_dummy_source_list(_no_srcs)

  704. 

  705.   dpf__add_module("${NAME}-clap" ${_no_srcs})

  706.   dpf__add_plugin_main("${NAME}-clap" "clap")

  707.   dpf__add_ui_main("${NAME}-clap" "clap" "${HAS_UI}")

  708.   dpf__set_module_export_list("${NAME}-clap" "clap")

  709.   target_link_libraries("${NAME}-clap" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  710.   target_link_options("${NAME}-clap" PRIVATE "${EXTRA_UI_LINK_OPTS}")

  711.   set_target_properties("${NAME}-clap" PROPERTIES

  712.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  713.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/clap/$<0:>"

  714.     OUTPUT_NAME "${NAME}"

  715.     PREFIX ""

  716.     SUFFIX ".clap")

  717. 

  718.   if(APPLE)

  719.     set_target_properties("${NAME}-clap" PROPERTIES

  720.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/MacOS/$<0:>"

  721.       OUTPUT_NAME "${NAME}"

  722.       SUFFIX "")

  723.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  724.     configure_file("${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/Info.plist"

  725.       "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents/Info.plist" @ONLY)

  726.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  727.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.clap/Contents")

  728.   endif()

  729. endfunction()

  730. 

  731. # dpf__build_au

  732. # ------------------------------------------------------------------------------

  733. #

  734. # Add build rules for an AUv2 plugin.

  735. #

  736. function(dpf__build_au NAME HAS_UI)

  737.   dpf__create_dummy_source_list(_no_srcs)

  738. 

  739.   dpf__add_module("${NAME}-au" ${_no_srcs})

  740.   dpf__add_plugin_main("${NAME}-au" "au")

  741.   dpf__add_ui_main("${NAME}-au" "au" "${HAS_UI}")

  742.   dpf__set_module_export_list("${NAME}-au" "au")

  743.   find_library(APPLE_AUDIOTOOLBOX_FRAMEWORK "AudioToolbox")

  744.   find_library(APPLE_AUDIOUNIT_FRAMEWORK "AudioUnit")

  745.   find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  746.   target_compile_options("${NAME}-au" PRIVATE "-ObjC++")

  747.   target_link_libraries("${NAME}-au" PRIVATE

  748.     "${NAME}-dsp"

  749.     "${NAME}-ui"

  750.     "${APPLE_AUDIOTOOLBOX_FRAMEWORK}"

  751.     "${APPLE_AUDIOUNIT_FRAMEWORK}"

  752.     "${APPLE_COREFOUNDATION_FRAMEWORK}")

  753.   set_target_properties("${NAME}-au" PROPERTIES

  754.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents/MacOS/$<0:>"

  755.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/au/$<0:>"

  756.     OUTPUT_NAME "${NAME}"

  757.     PREFIX ""

  758.     SUFFIX "")

  759. 

  760.   dpf__add_executable("${NAME}-export" ${_no_srcs})

  761.   dpf__add_plugin_main("${NAME}-export" "export")

  762.   dpf__add_ui_main("${NAME}-export" "export" "${HAS_UI}")

  763.   target_link_libraries("${NAME}-export" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  764. 

  765.   separate_arguments(CMAKE_CROSSCOMPILING_EMULATOR)

  766. 

  767.   add_custom_command(TARGET "${NAME}-au" POST_BUILD

  768.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR} "$<TARGET_FILE:${NAME}-export>" "${NAME}"

  769.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  770. 

  771.   add_dependencies("${NAME}-au" "${NAME}-export")

  772. 

  773.   file(COPY "${DPF_ROOT_DIR}/utils/plugin.bundle/Contents/PkgInfo"

  774.     DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.component/Contents")

  775. endfunction()

  776. 

  777. # dpf__build_static

  778. # ------------------------------------------------------------------------------

  779. #

  780. # Add build rules for a static library.

  781. #

  782. function(dpf__build_static NAME HAS_UI)

  783.   dpf__create_dummy_source_list(_no_srcs)

  784. 

  785.   dpf__add_module("${NAME}-static" ${_no_srcs} STATIC)

  786.   dpf__add_plugin_main("${NAME}-static" "static")

  787.   dpf__add_ui_main("${NAME}-static" "static" "${HAS_UI}")

  788.   target_link_libraries("${NAME}-static" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  789. 

  790.   get_target_property(dsp_srcs "${NAME}-dsp" SOURCES)

  791.   get_target_property(ui_srcs "${NAME}-ui" SOURCES)

  792.   foreach(src ${dsp_srcs})

  793.     target_sources("${NAME}-static" PRIVATE ${src})

  794.   endforeach()

  795.   foreach(src ${ui_srcs})

  796.     target_sources("${NAME}-static" PRIVATE ${src})

  797.   endforeach()

  798. 

  799.   set_target_properties("${NAME}-static" PROPERTIES

  800.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  801.     OUTPUT_NAME "${NAME}"

  802.     PREFIX "")

  803. endfunction()

  804. 

  805. # dpf__add_dgl_cairo

  806. # ------------------------------------------------------------------------------

  807. #

  808. # Add the Cairo variant of DGL, if not already available.

  809. #

  810. function(dpf__add_dgl_cairo SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  811.   if(TARGET dgl-cairo)

  812.     return()

  813.   endif()

  814. 

  815.   find_package(PkgConfig REQUIRED)

  816.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  817. 

  818.   link_directories(${CAIRO_LIBRARY_DIRS})

  819. 

  820.   dpf__add_static_library(dgl-cairo STATIC

  821.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  822.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  823.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  824.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  825.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  826.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  827.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  828.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  829.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  830.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  831.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  832.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  833.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  834.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  835.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  836.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  837.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  838.   if(SHARED_RESOURCES)

  839.     target_sources(dgl-cairo PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  840.   else()

  841.     target_compile_definitions(dgl-cairo PUBLIC "DGL_NO_SHARED_RESOURCES")

  842.   endif()

  843.   if(APPLE)

  844.     target_sources(dgl-cairo PRIVATE

  845.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  846.   else()

  847.     target_sources(dgl-cairo PRIVATE

  848.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  849.   endif()

  850.   target_include_directories(dgl-cairo PUBLIC

  851.     "${DPF_ROOT_DIR}/dgl")

  852.   target_include_directories(dgl-cairo PUBLIC

  853.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  854. 

  855.   if(USE_FILE_BROWSER)

  856.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  857.   endif()

  858. 

  859.   if(USE_WEB_VIEW)

  860.     target_compile_definitions(dgl-cairo PUBLIC "DGL_USE_FILE_BROWSER")

  861.     if(APPLE)

  862.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  863.       target_link_libraries(dgl-cairo PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  864.     elseif(WIN32)

  865.       target_sources(dgl-cairo PRIVATE

  866.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  867.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  868.         PROPERTIES

  869.           COMPILE_FLAGS

  870.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  871.     endif()

  872.   endif()

  873. 

  874.   dpf__add_dgl_system_libs()

  875.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  876. 

  877.   add_library(dgl-cairo-definitions INTERFACE)

  878.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  879. 

  880.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  881.   if(MINGW)

  882.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  883.   else()

  884.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  885.   endif()

  886.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  887. endfunction()

  888. 

  889. # dpf__add_dgl_external

  890. # ------------------------------------------------------------------------------

  891. #

  892. # Add the external variant of DGL, if not already available.

  893. #

  894. function(dpf__add_dgl_external USE_FILE_BROWSER USE_WEB_VIEW)

  895.   if(TARGET dgl-external)

  896.     return()

  897.   endif()

  898. 

  899.   dpf__add_static_library(dgl-external STATIC

  900.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  901.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  902.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  903.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  904.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  905.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  906.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  907.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  908.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  909.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  910.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  911.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  912.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  913.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  914.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  915.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  916.     "${DPF_ROOT_DIR}/dgl/src/Stub.cpp")

  917. 

  918.   if(APPLE)

  919.     target_sources(dgl-external PRIVATE

  920.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  921.   else()

  922.     target_sources(dgl-external PRIVATE

  923.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  924.   endif()

  925.   target_include_directories(dgl-external PUBLIC

  926.     "${DPF_ROOT_DIR}/dgl")

  927.   target_include_directories(dgl-external PUBLIC

  928.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  929. 

  930.   if(USE_FILE_BROWSER)

  931.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_FILE_BROWSER")

  932.   endif()

  933. 

  934.   if(USE_WEB_VIEW)

  935.     target_compile_definitions(dgl-external PUBLIC "DGL_USE_WEB_VIEW")

  936.     if(APPLE)

  937.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  938.       target_link_libraries(dgl-external PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  939.     elseif(WIN32)

  940.       target_sources(dgl-external PRIVATE

  941.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  942.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  943.         PROPERTIES

  944.           COMPILE_FLAGS

  945.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  946.     endif()

  947.   endif()

  948. 

  949.   dpf__add_dgl_system_libs()

  950.   target_compile_definitions(dgl-external PUBLIC "DGL_NO_SHARED_RESOURCES")

  951.   target_link_libraries(dgl-external PRIVATE dgl-system-libs)

  952. 

  953.   add_library(dgl-external-definitions INTERFACE)

  954.   target_compile_definitions(dgl-external-definitions INTERFACE "DGL_EXTERNAL" "HAVE_DGL")

  955. 

  956.   target_include_directories(dgl-external PUBLIC "${OPENGL_INCLUDE_DIR}")

  957.   target_link_libraries(dgl-external PRIVATE dgl-external-definitions "${OPENGL_gl_LIBRARY}")

  958. endfunction()

  959. 

  960. # dpf__add_dgl_gles2

  961. # ------------------------------------------------------------------------------

  962. #

  963. # Add the GLESv2 variant of DGL, if not already available.

  964. #

  965. function(dpf__add_dgl_gles2 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  966.   if(TARGET dgl-gles2)

  967.     return()

  968.   endif()

  969. 

  970.   if(NOT OpenGL_GL_PREFERENCE)

  971.     set(OpenGL_GL_PREFERENCE "LEGACY")

  972.   endif()

  973. 

  974.   find_package(OpenGL REQUIRED)

  975. 

  976.   dpf__add_static_library(dgl-gles2 STATIC

  977.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  978.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  979.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  980.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  981.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  982.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  983.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  984.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  985.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  986.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  987.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  988.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  989.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  990.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  991.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  992.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  993.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  994.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  995.   if(SHARED_RESOURCES)

  996.     target_sources(dgl-gles2 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  997.   else()

  998.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_NO_SHARED_RESOURCES")

  999.   endif()

  1000.   if(APPLE)

  1001.     target_sources(dgl-gles2 PRIVATE

  1002.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1003.   else()

  1004.     target_sources(dgl-gles2 PRIVATE

  1005.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1006.   endif()

  1007.   target_include_directories(dgl-gles2 PUBLIC

  1008.     "${DPF_ROOT_DIR}/dgl")

  1009.   target_include_directories(dgl-gles2 PUBLIC

  1010.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1011. 

  1012.   if(APPLE)

  1013.     target_compile_definitions(dgl-gles2 PUBLIC "GL_SILENCE_DEPRECATION")

  1014.   endif()

  1015. 

  1016.   if(USE_FILE_BROWSER)

  1017.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_FILE_BROWSER")

  1018.   endif()

  1019. 

  1020.   if(USE_WEB_VIEW)

  1021.     target_compile_definitions(dgl-gles2 PUBLIC "DGL_USE_WEB_VIEW")

  1022.     if(APPLE)

  1023.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1024.       target_link_libraries(dgl-gles2 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1025.     elseif(WIN32)

  1026.       target_sources(dgl-gles2 PRIVATE

  1027.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1028.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1029.         PROPERTIES

  1030.           COMPILE_FLAGS

  1031.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1032.     endif()

  1033.   endif()

  1034. 

  1035.   dpf__add_dgl_system_libs()

  1036.   target_link_libraries(dgl-gles2 PRIVATE dgl-system-libs)

  1037.   target_link_options(dgl-gles2

  1038.     INTERFACE

  1039.       $<$<BOOL:${EMSCRIPTEN}>:-sMIN_WEBGL_VERSION=2>

  1040.       $<$<BOOL:${EMSCRIPTEN}>:-sMAX_WEBGL_VERSION=2>

  1041.   )

  1042. 

  1043.   add_library(dgl-gles2-definitions INTERFACE)

  1044.   target_compile_definitions(dgl-gles2-definitions

  1045.     INTERFACE

  1046.       DGL_USE_OPENGL3

  1047.       DGL_USE_GLES

  1048.       DGL_USE_GLES2

  1049.       DGL_OPENGL

  1050.       HAVE_OPENGL

  1051.       HAVE_DGL

  1052.   )

  1053. 

  1054.   target_include_directories(dgl-gles2 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1055.   target_link_libraries(dgl-gles2 PRIVATE dgl-gles2-definitions "${OPENGL_gl_LIBRARY}")

  1056. endfunction()

  1057. 

  1058. # dpf__add_dgl_gles3

  1059. # ------------------------------------------------------------------------------

  1060. #

  1061. # Add the GLESv3 variant of DGL, if not already available.

  1062. #

  1063. function(dpf__add_dgl_gles3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1064.   if(TARGET dgl-gles3)

  1065.     return()

  1066.   endif()

  1067. 

  1068.   if(NOT OpenGL_GL_PREFERENCE)

  1069.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1070.   endif()

  1071. 

  1072.   find_package(OpenGL REQUIRED)

  1073. 

  1074.   dpf__add_static_library(dgl-gles3 STATIC

  1075.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1076.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1077.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1078.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1079.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1080.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1081.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1082.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1083.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1084.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1085.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1086.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1087.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1088.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1089.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1090.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1091.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1092.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1093.   if(SHARED_RESOURCES)

  1094.     target_sources(dgl-gles3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1095.   else()

  1096.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1097.   endif()

  1098.   if(APPLE)

  1099.     target_sources(dgl-gles3 PRIVATE

  1100.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1101.   else()

  1102.     target_sources(dgl-gles3 PRIVATE

  1103.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1104.   endif()

  1105.   target_include_directories(dgl-gles3 PUBLIC

  1106.     "${DPF_ROOT_DIR}/dgl")

  1107.   target_include_directories(dgl-gles3 PUBLIC

  1108.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1109. 

  1110.   if(APPLE)

  1111.     target_compile_definitions(dgl-gles3 PUBLIC "GL_SILENCE_DEPRECATION")

  1112.   endif()

  1113. 

  1114.   if(USE_FILE_BROWSER)

  1115.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_FILE_BROWSER")

  1116.   endif()

  1117. 

  1118.   if(USE_WEB_VIEW)

  1119.     target_compile_definitions(dgl-gles3 PUBLIC "DGL_USE_WEB_VIEW")

  1120.     if(APPLE)

  1121.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1122.       target_link_libraries(dgl-gles3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1123.     elseif(WIN32)

  1124.       target_sources(dgl-gles3 PRIVATE

  1125.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1126.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1127.         PROPERTIES

  1128.           COMPILE_FLAGS

  1129.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1130.     endif()

  1131.   endif()

  1132. 

  1133.   dpf__add_dgl_system_libs()

  1134.   target_link_libraries(dgl-gles3 PRIVATE dgl-system-libs)

  1135. 

  1136.   add_library(dgl-gles3-definitions INTERFACE)

  1137.   target_compile_definitions(dgl-gles3-definitions

  1138.     INTERFACE

  1139.       DGL_USE_OPENGL3

  1140.       DGL_USE_GLES

  1141.       DGL_USE_GLES3

  1142.       DGL_OPENGL

  1143.       HAVE_OPENGL

  1144.       HAVE_DGL

  1145.   )

  1146. 

  1147.   target_include_directories(dgl-gles3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1148.   target_link_libraries(dgl-gles3 PRIVATE dgl-gles3-definitions "${OPENGL_gl_LIBRARY}")

  1149. endfunction()

  1150. 

  1151. # dpf__add_dgl_opengl

  1152. # ------------------------------------------------------------------------------

  1153. #

  1154. # Add the OpenGL variant of DGL, if not already available.

  1155. #

  1156. function(dpf__add_dgl_opengl SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1157.   if(TARGET dgl-opengl)

  1158.     return()

  1159.   endif()

  1160. 

  1161.   if(NOT OpenGL_GL_PREFERENCE)

  1162.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1163.   endif()

  1164. 

  1165.   find_package(OpenGL REQUIRED)

  1166. 

  1167.   dpf__add_static_library(dgl-opengl STATIC

  1168.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1169.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1170.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1171.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1172.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1173.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1174.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1175.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1176.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1177.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1178.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1179.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1180.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1181.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1182.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1183.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1184.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1185.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1186.   if(SHARED_RESOURCES)

  1187.     target_sources(dgl-opengl PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1188.   else()

  1189.     target_compile_definitions(dgl-opengl PUBLIC "DGL_NO_SHARED_RESOURCES")

  1190.   endif()

  1191.   if(APPLE)

  1192.     target_sources(dgl-opengl PRIVATE

  1193.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1194.   else()

  1195.     target_sources(dgl-opengl PRIVATE

  1196.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1197.   endif()

  1198.   target_include_directories(dgl-opengl PUBLIC

  1199.     "${DPF_ROOT_DIR}/dgl")

  1200.   target_include_directories(dgl-opengl PUBLIC

  1201.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1202. 

  1203.   if(APPLE)

  1204.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  1205.   endif()

  1206. 

  1207.   if(USE_FILE_BROWSER)

  1208.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_FILE_BROWSER")

  1209.   endif()

  1210. 

  1211.   if(USE_WEB_VIEW)

  1212.     target_compile_definitions(dgl-opengl PUBLIC "DGL_USE_WEB_VIEW")

  1213.     if(APPLE)

  1214.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1215.       target_link_libraries(dgl-opengl PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1216.     elseif(WIN32)

  1217.       target_sources(dgl-opengl PRIVATE

  1218.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1219.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1220.         PROPERTIES

  1221.           COMPILE_FLAGS

  1222.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1223.     endif()

  1224.   endif()

  1225. 

  1226.   dpf__add_dgl_system_libs()

  1227.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  1228.   target_link_options(dgl-opengl

  1229.     INTERFACE

  1230.       $<$<BOOL:${EMSCRIPTEN}>:-sLEGACY_GL_EMULATION>

  1231.       $<$<BOOL:${EMSCRIPTEN}>:-sGL_UNSAFE_OPTS=0>

  1232.   )

  1233. 

  1234.   add_library(dgl-opengl-definitions INTERFACE)

  1235.   target_compile_definitions(dgl-opengl-definitions

  1236.     INTERFACE

  1237.       DGL_OPENGL

  1238.       HAVE_OPENGL

  1239.       HAVE_DGL

  1240.   )

  1241. 

  1242.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  1243.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  1244. endfunction()

  1245. 

  1246. # dpf__add_dgl_opengl3

  1247. # ------------------------------------------------------------------------------

  1248. #

  1249. # Add the OpenGL3 variant of DGL, if not already available.

  1250. #

  1251. function(dpf__add_dgl_opengl3 SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1252.   if(TARGET dgl-opengl3)

  1253.     return()

  1254.   endif()

  1255. 

  1256.   if(NOT OpenGL_GL_PREFERENCE)

  1257.     set(OpenGL_GL_PREFERENCE "LEGACY")

  1258.   endif()

  1259. 

  1260.   find_package(OpenGL REQUIRED)

  1261. 

  1262.   dpf__add_static_library(dgl-opengl3 STATIC

  1263.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1264.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1265.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1266.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1267.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1268.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1269.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1270.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1271.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1272.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1273.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1274.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1275.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1276.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1277.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1278.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1279.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  1280.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  1281.   if(SHARED_RESOURCES)

  1282.     target_sources(dgl-opengl3 PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1283.   else()

  1284.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_NO_SHARED_RESOURCES")

  1285.   endif()

  1286.   if(APPLE)

  1287.     target_sources(dgl-opengl3 PRIVATE

  1288.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1289.   else()

  1290.     target_sources(dgl-opengl3 PRIVATE

  1291.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1292.   endif()

  1293.   target_include_directories(dgl-opengl3 PUBLIC

  1294.     "${DPF_ROOT_DIR}/dgl")

  1295.   target_include_directories(dgl-opengl3 PUBLIC

  1296.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1297. 

  1298.   if(APPLE)

  1299.     target_compile_definitions(dgl-opengl3 PUBLIC "GL_SILENCE_DEPRECATION")

  1300.   endif()

  1301. 

  1302.   if(USE_FILE_BROWSER)

  1303.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_FILE_BROWSER")

  1304.   endif()

  1305. 

  1306.   if(USE_WEB_VIEW)

  1307.     target_compile_definitions(dgl-opengl3 PUBLIC "DGL_USE_WEB_VIEW")

  1308.     if(APPLE)

  1309.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1310.       target_link_libraries(dgl-opengl3 PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1311.     elseif(WIN32)

  1312.       target_sources(dgl-opengl3 PRIVATE

  1313.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1314.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1315.         PROPERTIES

  1316.           COMPILE_FLAGS

  1317.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1318.     endif()

  1319.   endif()

  1320. 

  1321.   dpf__add_dgl_system_libs()

  1322.   target_link_libraries(dgl-opengl3 PRIVATE dgl-system-libs)

  1323. 

  1324.   add_library(dgl-opengl3-definitions INTERFACE)

  1325.   target_compile_definitions(dgl-opengl3-definitions

  1326.     INTERFACE

  1327.       DGL_USE_OPENGL3

  1328.       DGL_OPENGL

  1329.       HAVE_OPENGL

  1330.       HAVE_DGL

  1331.   )

  1332. 

  1333.   target_include_directories(dgl-opengl3 PUBLIC "${OPENGL_INCLUDE_DIR}")

  1334.   target_link_libraries(dgl-opengl3 PRIVATE dgl-opengl3-definitions "${OPENGL_gl_LIBRARY}")

  1335. endfunction()

  1336. 

  1337. # dpf__add_dgl_vulkan

  1338. # ------------------------------------------------------------------------------

  1339. #

  1340. # Add the Vulkan variant of DGL, if not already available.

  1341. #

  1342. function(dpf__add_dgl_vulkan SHARED_RESOURCES USE_FILE_BROWSER USE_WEB_VIEW)

  1343.   if(TARGET dgl-vulkan)

  1344.     return()

  1345.   endif()

  1346. 

  1347.   find_package(Vulkan REQUIRED)

  1348. 

  1349.   dpf__add_static_library(dgl-vulkan STATIC

  1350.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  1351.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  1352.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  1353.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  1354.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  1355.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  1356.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  1357.     "${DPF_ROOT_DIR}/dgl/src/Layout.cpp"

  1358.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  1359.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  1360.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  1361.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  1362.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  1363.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  1364.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  1365.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  1366.     "${DPF_ROOT_DIR}/dgl/src/Vulkan.cpp")

  1367.   if(NO_SHARED_RESOURCES)

  1368.     target_sources(dgl-vulkan PRIVATE "${DPF_ROOT_DIR}/dgl/src/Resources.cpp")

  1369.   else()

  1370.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_NO_SHARED_RESOURCES")

  1371.   endif()

  1372.   if(APPLE)

  1373.     target_sources(dgl-vulkan PRIVATE

  1374.       "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  1375.   else()

  1376.     target_sources(dgl-vulkan PRIVATE

  1377.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  1378.   endif()

  1379.   target_include_directories(dgl-vulkan PUBLIC

  1380.     "${DPF_ROOT_DIR}/dgl")

  1381.   target_include_directories(dgl-vulkan PUBLIC

  1382.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  1383. 

  1384.   if(APPLE)

  1385.     target_compile_definitions(dgl-vulkan PUBLIC "GL_SILENCE_DEPRECATION")

  1386.   endif()

  1387. 

  1388.   if(USE_FILE_BROWSER)

  1389.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_FILE_BROWSER")

  1390.   endif()

  1391. 

  1392.   if(USE_WEB_VIEW)

  1393.     target_compile_definitions(dgl-vulkan PUBLIC "DGL_USE_WEB_VIEW")

  1394.     if(APPLE)

  1395.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1396.       target_link_libraries(dgl-vulkan PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1397.     elseif(WIN32)

  1398.       target_sources(dgl-vulkan PRIVATE

  1399.         "${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp")

  1400.       set_source_files_properties("${DPF_ROOT_DIR}/dgl/src/WebViewWin32.cpp"

  1401.         PROPERTIES

  1402.           COMPILE_FLAGS

  1403.             $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1404.     endif()

  1405.   endif()

  1406. 

  1407.   dpf__add_dgl_system_libs()

  1408.   target_link_libraries(dgl-vulkan PRIVATE dgl-system-libs)

  1409. 

  1410.   add_library(dgl-vulkan-definitions INTERFACE)

  1411.   target_compile_definitions(dgl-vulkan-definitions INTERFACE "DGL_VULKAN" "HAVE_VULKAN" "HAVE_DGL")

  1412. 

  1413.   target_include_directories(dgl-vulkan PUBLIC "${OPENGL_INCLUDE_DIR}")

  1414.   target_link_libraries(dgl-vulkan PRIVATE dgl-vulkan-definitions "${OPENGL_gl_LIBRARY}")

  1415. endfunction()

  1416. 

  1417. # dpf__add_plugin_specific_ui_sources

  1418. # ------------------------------------------------------------------------------

  1419. #

  1420. # Compile system specific files

  1421. #

  1422. function(dpf__add_plugin_specific_ui_sources NAME USE_WEB_VIEW)

  1423.   if(APPLE)

  1424.     target_sources("${NAME}" PRIVATE

  1425.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  1426.     if(USE_WEB_VIEW)

  1427.       find_library(APPLE_WEBKIT_FRAMEWORK "WebKit")

  1428.       target_link_libraries("${NAME}" PRIVATE "${APPLE_WEBKIT_FRAMEWORK}")

  1429.     endif()

  1430.   elseif(WIN32 AND USE_WEB_VIEW)

  1431.     target_sources("${NAME}" PRIVATE

  1432.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp")

  1433.     set_source_files_properties("${DPF_ROOT_DIR}/distrho/DistrhoUI_win32.cpp"

  1434.       PROPERTIES

  1435.         COMPILE_FLAGS

  1436.           $<IF:$<BOOL:${MSVC}>,/std:c++17,-std=gnu++17>)

  1437.     target_link_libraries("${NAME}" PRIVATE "ole32" "uuid")

  1438.   endif()

  1439. endfunction()

  1440. 

  1441. # dpf__add_dgl_system_libs

  1442. # ------------------------------------------------------------------------------

  1443. #

  1444. # Find system libraries required by DGL and add them as an interface target.

  1445. #

  1446. function(dpf__add_dgl_system_libs)

  1447.   if(TARGET dgl-system-libs)

  1448.     return()

  1449.   endif()

  1450.   add_library(dgl-system-libs INTERFACE)

  1451.   add_library(dgl-system-libs-definitions INTERFACE)

  1452.   if(APPLE)

  1453.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  1454.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  1455.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  1456.   elseif(EMSCRIPTEN)

  1457.   elseif(HAIKU)

  1458.     target_link_libraries(dgl-system-libs INTERFACE "be")

  1459.   elseif(WIN32)

  1460.     target_link_libraries(dgl-system-libs INTERFACE "comdlg32" "dwmapi" "gdi32")

  1461.   else()

  1462.     find_package(PkgConfig REQUIRED)

  1463.     pkg_check_modules(DBUS "dbus-1")

  1464.     if(DBUS_FOUND)

  1465.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_DBUS")

  1466.       target_include_directories(dgl-system-libs INTERFACE "${DBUS_INCLUDE_DIRS}")

  1467.       target_link_libraries(dgl-system-libs INTERFACE "${DBUS_LIBRARIES}")

  1468.     endif()

  1469.     find_package(X11 REQUIRED)

  1470.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  1471.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  1472.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  1473.     if(X11_Xcursor_FOUND)

  1474.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  1475.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  1476.     endif()

  1477.     if(X11_Xext_FOUND)

  1478.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  1479.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  1480.     endif()

  1481.     if(X11_Xrandr_FOUND)

  1482.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  1483.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  1484.     endif()

  1485.     if(X11_XSync_FOUND)

  1486.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  1487.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  1488.     endif()

  1489.    endif()

  1490. 

  1491.    if(MSVC)

  1492.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  1493.      foreach(_gl_header "glext.h")

  1494.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  1495.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  1496.        endif()

  1497.      endforeach()

  1498.      foreach(_khr_header "khrplatform.h")

  1499.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  1500.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  1501.        endif()

  1502.      endforeach()

  1503.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  1504.    endif()

  1505. 

  1506.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  1507. endfunction()

  1508. 

  1509. # dpf__add_executable

  1510. # ------------------------------------------------------------------------------

  1511. #

  1512. # Adds an executable target, and set some default properties on the target.

  1513. #

  1514. function(dpf__add_executable NAME)

  1515.   add_executable("${NAME}" ${ARGN})

  1516.   dpf__set_target_defaults("${NAME}")

  1517.   if(MINGW)

  1518.     target_link_libraries("${NAME}" PRIVATE "-static")

  1519.   endif()

  1520. endfunction()

  1521. 

  1522. # dpf__add_module

  1523. # ------------------------------------------------------------------------------

  1524. #

  1525. # Adds a module target, and set some default properties on the target.

  1526. #

  1527. function(dpf__add_module NAME)

  1528.   add_library("${NAME}" MODULE ${ARGN})

  1529.   dpf__set_target_defaults("${NAME}")

  1530.   if(APPLE)

  1531.     set_target_properties("${NAME}" PROPERTIES SUFFIX ".dylib")

  1532.   elseif(MINGW)

  1533.     target_link_libraries("${NAME}" PRIVATE "-static")

  1534.   endif()

  1535. endfunction()

  1536. 

  1537. # dpf__add_static_library

  1538. # ------------------------------------------------------------------------------

  1539. #

  1540. # Adds a static library target, and set some default properties on the target.

  1541. #

  1542. function(dpf__add_static_library NAME)

  1543.   add_library("${NAME}" STATIC ${ARGN})

  1544.   dpf__set_target_defaults("${NAME}")

  1545. endfunction()

  1546. 

  1547. # dpf__set_module_export_list

  1548. # ------------------------------------------------------------------------------

  1549. #

  1550. # Applies a list of exported symbols to the module target.

  1551. #

  1552. function(dpf__set_module_export_list NAME EXPORTS)

  1553.   if(WIN32)

  1554.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  1555.   elseif(APPLE)

  1556.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1557.       "-Xlinker" "-exported_symbols_list"

  1558.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  1559.   else()

  1560.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  1561.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  1562.   endif()

  1563. endfunction()

  1564. 

  1565. # dpf__set_target_defaults

  1566. # ------------------------------------------------------------------------------

  1567. #

  1568. # Set default properties which must apply to all DPF-defined targets.

  1569. #

  1570. function(dpf__set_target_defaults NAME)

  1571.   set_target_properties("${NAME}" PROPERTIES

  1572.     POSITION_INDEPENDENT_CODE TRUE

  1573.     C_VISIBILITY_PRESET "hidden"

  1574.     CXX_VISIBILITY_PRESET "hidden"

  1575.     VISIBILITY_INLINES_HIDDEN TRUE)

  1576.   if(WIN32)

  1577.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  1578.   endif()

  1579.   if (MINGW)

  1580.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  1581.   endif()

  1582.   if (MSVC)

  1583.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  1584.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  1585.   endif()

  1586.   if (CMAKE_COMPILER_IS_GNUCXX)

  1587.     target_compile_options("${NAME}" PUBLIC "-fno-gnu-unique")

  1588.   endif()

  1589.   if ((NOT APPLE) AND (NOT EMSCRIPTEN) AND (NOT MSVC))

  1590.     target_link_options("${NAME}" PUBLIC "-Wl,--no-undefined")

  1591.   endif()

  1592. endfunction()

  1593. 

  1594. # dpf__add_plugin_main

  1595. # ------------------------------------------------------------------------------

  1596. #

  1597. # Adds plugin code to the given target.

  1598. #

  1599. function(dpf__add_plugin_main NAME TARGET)

  1600.   target_sources("${NAME}" PRIVATE

  1601.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  1602.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1603. endfunction()

  1604. 

  1605. # dpf__add_ui_main

  1606. # ------------------------------------------------------------------------------

  1607. #

  1608. # Adds UI code to the given target (only if the target has UI).

  1609. #

  1610. function(dpf__add_ui_main NAME TARGET HAS_UI)

  1611.   if(HAS_UI)

  1612.     target_sources("${NAME}" PRIVATE

  1613.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  1614.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  1615.   endif()

  1616. endfunction()

  1617. 

  1618. # dpf__add_plugin_target_definition

  1619. # ------------------------------------------------------------------------------

  1620. #

  1621. # Adds the plugins target macro definition.

  1622. # This selects which entry file is compiled according to the target type.

  1623. #

  1624. function(dpf__add_plugin_target_definition NAME TARGET)

  1625.   string(TOUPPER "${TARGET}" _upperTarget)

  1626.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  1627. endfunction()

  1628. 

  1629. # dpf__add_lv2_ttl_generator

  1630. # ------------------------------------------------------------------------------

  1631. #

  1632. # Build the LV2 TTL generator.

  1633. #

  1634. function(dpf__add_lv2_ttl_generator)

  1635.   if(TARGET lv2_ttl_generator)

  1636.     return()

  1637.   endif()

  1638.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  1639.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  1640.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  1641.   endif()

  1642. endfunction()

  1643. 

  1644. # dpf__ensure_sources_non_empty

  1645. # ------------------------------------------------------------------------------

  1646. #

  1647. # Ensure the given source list contains at least one file.

  1648. # The function appends an empty source file to the list if necessary.

  1649. # This is useful when CMake does not permit to add targets without sources.

  1650. #

  1651. function(dpf__ensure_sources_non_empty VAR)

  1652.   if(NOT "" STREQUAL "${${VAR}}")

  1653.     return()

  1654.   endif()

  1655.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  1656.   if(NOT EXISTS "${_file}")

  1657.     file(WRITE "${_file}" "")

  1658.   endif()

  1659.   set("${VAR}" "${_file}" PARENT_SCOPE)

  1660. endfunction()

  1661. 

  1662. # dpf__create_dummy_source_list

  1663. # ------------------------------------------------------------------------------

  1664. #

  1665. # Create a dummy source list which is equivalent to compiling nothing.

  1666. # This is only for compatibility with older CMake versions, which refuse to add

  1667. # targets without any sources.

  1668. #

  1669. macro(dpf__create_dummy_source_list VAR)

  1670.   set("${VAR}")

  1671.   if(CMAKE_VERSION VERSION_LESS "3.11")

  1672.     dpf__ensure_sources_non_empty("${VAR}")

  1673.   endif()

  1674. endmacro()

  1675. 

  1676. # dpf__target_link_directories

  1677. # ------------------------------------------------------------------------------

  1678. #

  1679. # Call `target_link_directories` if cmake >= 3.13,

  1680. # otherwise fallback to global `link_directories`.

  1681. #

  1682. macro(dpf__target_link_directories NAME DIRS)

  1683.   if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.13")

  1684.     target_link_directories("${NAME}" PUBLIC ${DIRS})

  1685.   else()

  1686.     link_directories(${DIRS})

  1687.   endif()

  1688. endmacro()

  1689. 

  1690. # dpf__warn_once

  1691. # ------------------------------------------------------------------------------

  1692. #

  1693. # Prints a warning message once only.

  1694. #

  1695. function(dpf__warn_once_only TOKEN MESSAGE)

  1696.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  1697.   if(NOT _warned)

  1698.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  1699.     message(WARNING "${MESSAGE}")

  1700.   endif()

  1701. endfunction()