DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1668 Commits
7 Branches
295MB
Tree: 116fee0381
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '116fee0381'
${ noResults }
DPF/cmake/DPF-plugin.cmake

814 lines
29KB
Raw Blame History 

  1. # DISTRHO Plugin Framework (DPF)

  2. # Copyright (C) 2021 Jean Pierre Cimalando <jp-dev@inbox.ru>

  3. #

  4. # SPDX-License-Identifier: ISC

  5. 

  6. # ------------------------------------------------------------------------------

  7. # CMake support module for the DISTRHO Plugin Framework

  8. #

  9. # The purpose of this module is to help building music plugins easily, when the

  10. # project uses CMake as its build system.

  11. #

  12. # In order to use the helpers provided by this module, a plugin author should

  13. # add DPF as a subproject, making the function `dpf_add_plugin` available.

  14. # The usage of this function is documented below in greater detail.

  15. #

  16. # Example project `CMakeLists.txt`:

  17. #

  18. # ```

  19. # cmake_minimum_required(VERSION 3.7)

  20. # project(MyPlugin)

  21. #

  22. # add_subdirectory(DPF)

  23. #

  24. # dpf_add_plugin(MyPlugin

  25. #   TARGETS lv2 vst2 vst3

  26. #   UI_TYPE opengl

  27. #   FILES_DSP

  28. #       src/MyPlugin.cpp

  29. #   FILES_UI

  30. #       src/MyUI.cpp)

  31. #

  32. # target_include_directories(MyPlugin

  33. #   PUBLIC src)

  34. # ```

  35. #

  36. # Important: note that properties, such as include directories, definitions,

  37. # and linked libraries *must* be marked with `PUBLIC` so they take effect and

  38. # propagate into all the plugin targets.

  39. 

  40. include(CMakeParseArguments)

  41. 

  42. # ------------------------------------------------------------------------------

  43. # DPF public functions

  44. # ------------------------------------------------------------------------------

  45. 

  46. # dpf_add_plugin(name <args...>)

  47. # ------------------------------------------------------------------------------

  48. #

  49. # Add a plugin built using the DISTRHO Plugin Framework.

  50. #

  51. # ------------------------------------------------------------------------------

  52. # Created targets:

  53. #

  54. #   `<name>`

  55. #       static library: the common part of the plugin

  56. #       The public properties set on this target apply to both DSP and UI.

  57. #

  58. #   `<name>-dsp`

  59. #       static library: the DSP part of the plugin

  60. #       The public properties set on this target apply to the DSP only.

  61. #

  62. #   `<name>-ui`

  63. #       static library: the UI part of the plugin

  64. #       The public properties set on this target apply to the UI only.

  65. #

  66. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  67. #       This is target-dependent and not intended for public use.

  68. #

  69. # ------------------------------------------------------------------------------

  70. # Arguments:

  71. #

  72. #   `TARGETS` <tgt1>...<tgtN>

  73. #       a list of one of more of the following target types:

  74. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst2`, `vst3`

  75. #

  76. #   `UI_TYPE` <type>

  77. #       the user interface type: `opengl` (default), `cairo`

  78. #

  79. #   `MONOLITHIC`

  80. #       build LV2 as a single binary for UI and DSP

  81. #

  82. #   `FILES_DSP` <file1>...<fileN>

  83. #       list of sources which are part of the DSP

  84. #

  85. #   `FILES_UI` <file1>...<fileN>

  86. #       list of sources which are part of the UI

  87. #       empty indicates the plugin does not have UI

  88. #

  89. #   `FILES_COMMON` <file1>...<fileN>

  90. #       list of sources which are part of both DSP and UI

  91. #

  92. function(dpf_add_plugin NAME)

  93.   set(options MONOLITHIC)

  94.   set(oneValueArgs UI_TYPE)

  95.   set(multiValueArgs TARGETS FILES_DSP FILES_UI FILES_COMMON)

  96.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  97. 

  98.   if("${_dpf_plugin_UI_TYPE}" STREQUAL "")

  99.     set(_dpf_plugin_UI_TYPE "opengl")

  100.   endif()

  101. 

  102.   set(_dgl_library)

  103.   if(_dpf_plugin_FILES_UI)

  104.     if(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  105.       dpf__add_dgl_cairo()

  106.       set(_dgl_library dgl-cairo)

  107.     elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  108.       dpf__add_dgl_opengl()

  109.       set(_dgl_library dgl-opengl)

  110.     else()

  111.       message(FATAL_ERROR "Unrecognized UI type for plugin: ${_dpf_plugin_UI_TYPE}")

  112.     endif()

  113.   endif()

  114. 

  115.   ###

  116.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  117.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  118.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  119. 

  120.   ###

  121.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  122.   target_include_directories("${NAME}" PUBLIC

  123.     "${DPF_ROOT_DIR}/distrho")

  124. 

  125.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  126.     target_link_libraries("${NAME}" PRIVATE "dl")

  127.   endif()

  128. 

  129.   if(_dgl_library)

  130.     # make sure that all code will see DGL_* definitions

  131.     target_link_libraries("${NAME}" PUBLIC

  132.       "${_dgl_library}-definitions"

  133.       dgl-system-libs-definitions)

  134.   endif()

  135. 

  136.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  137.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  138. 

  139.   if(_dgl_library)

  140.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  141.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  142.     if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  143.       target_link_libraries("${NAME}-ui" PRIVATE "dl")

  144.     endif()

  145.     # add the files containing Objective-C classes, recompiled under namespace

  146.     dpf__add_plugin_specific_ui_sources("${NAME}-ui")

  147.   else()

  148.     add_library("${NAME}-ui" INTERFACE)

  149.   endif()

  150. 

  151.   ###

  152.   foreach(_target ${_dpf_plugin_TARGETS})

  153.     if(_target STREQUAL "jack")

  154.       dpf__build_jack("${NAME}" "${_dgl_library}")

  155.     elseif(_target STREQUAL "ladspa")

  156.       dpf__build_ladspa("${NAME}")

  157.     elseif(_target STREQUAL "dssi")

  158.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  159.     elseif(_target STREQUAL "lv2")

  160.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  161.     elseif(_target STREQUAL "vst2")

  162.       dpf__build_vst2("${NAME}" "${_dgl_library}")

  163.     elseif(_target STREQUAL "vst3")

  164.       dpf__build_vst3("${NAME}" "${_dgl_library}")

  165.     else()

  166.       message(FATAL_ERROR "Unrecognized target type for plugin: ${_target}")

  167.     endif()

  168.   endforeach()

  169. endfunction()

  170. 

  171. # ------------------------------------------------------------------------------

  172. # DPF private functions (prefixed with `dpf__`)

  173. # ------------------------------------------------------------------------------

  174. 

  175. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  176. #       to the output directory.

  177. #

  178. 

  179. # dpf__build_jack

  180. # ------------------------------------------------------------------------------

  181. #

  182. # Add build rules for a JACK program.

  183. #

  184. function(dpf__build_jack NAME DGL_LIBRARY)

  185.   dpf__create_dummy_source_list(_no_srcs)

  186. 

  187.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  188.   dpf__add_plugin_main("${NAME}-jack" "jack")

  189.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  190.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  191.   set_target_properties("${NAME}-jack" PROPERTIES

  192.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  193.     OUTPUT_NAME "${NAME}")

  194. 

  195.   # for RtAudio native fallback

  196.   if(APPLE)

  197.     find_library(APPLE_COREAUDIO_FRAMEWORK "CoreAudio")

  198.     find_library(APPLE_COREFOUNDATION_FRAMEWORK "CoreFoundation")

  199.     target_link_libraries("${NAME}-jack" PRIVATE "${APPLE_COREAUDIO_FRAMEWORK}" "${APPLE_COREFOUNDATION_FRAMEWORK}")

  200.   endif()

  201. endfunction()

  202. 

  203. # dpf__build_ladspa

  204. # ------------------------------------------------------------------------------

  205. #

  206. # Add build rules for a LADSPA plugin.

  207. #

  208. function(dpf__build_ladspa NAME)

  209.   dpf__create_dummy_source_list(_no_srcs)

  210. 

  211.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  212.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  213.   dpf__set_module_export_list("${NAME}-ladspa" "ladspa")

  214.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  215.   set_target_properties("${NAME}-ladspa" PROPERTIES

  216.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  217.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/ladspa/$<0:>"

  218.     OUTPUT_NAME "${NAME}-ladspa"

  219.     PREFIX "")

  220. endfunction()

  221. 

  222. # dpf__build_dssi

  223. # ------------------------------------------------------------------------------

  224. #

  225. # Add build rules for a DSSI plugin.

  226. #

  227. function(dpf__build_dssi NAME DGL_LIBRARY)

  228.   find_package(PkgConfig)

  229.   pkg_check_modules(LIBLO "liblo")

  230.   if(NOT LIBLO_FOUND)

  231.     dpf__warn_once_only(missing_liblo

  232.       "liblo is not found, skipping the `dssi` plugin targets")

  233.     return()

  234.   endif()

  235. 

  236.   link_directories(${LIBLO_LIBRARY_DIRS})

  237. 

  238.   dpf__create_dummy_source_list(_no_srcs)

  239. 

  240.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  241.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  242.   dpf__set_module_export_list("${NAME}-dssi" "dssi")

  243.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  244.   set_target_properties("${NAME}-dssi" PROPERTIES

  245.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  246.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/dssi/$<0:>"

  247.     OUTPUT_NAME "${NAME}-dssi"

  248.     PREFIX "")

  249. 

  250.   if(DGL_LIBRARY)

  251.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  252.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  253.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  254.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  255.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  256.       OUTPUT_NAME "${NAME}_ui")

  257. 

  258.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  259.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  260.   endif()

  261. endfunction()

  262. 

  263. # dpf__build_lv2

  264. # ------------------------------------------------------------------------------

  265. #

  266. # Add build rules for an LV2 plugin.

  267. #

  268. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  269.   dpf__create_dummy_source_list(_no_srcs)

  270. 

  271.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  272.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  273.   if(DGL_LIBRARY AND MONOLITHIC)

  274.     dpf__set_module_export_list("${NAME}-lv2" "lv2")

  275.   else()

  276.     dpf__set_module_export_list("${NAME}-lv2" "lv2-dsp")

  277.   endif()

  278.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  279.   set_target_properties("${NAME}-lv2" PROPERTIES

  280.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  281.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  282.     OUTPUT_NAME "${NAME}_dsp"

  283.     PREFIX "")

  284. 

  285.   if(DGL_LIBRARY)

  286.     if(MONOLITHIC)

  287.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  288.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  289.       set_target_properties("${NAME}-lv2" PROPERTIES

  290.         OUTPUT_NAME "${NAME}")

  291.     else()

  292.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  293.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  294.       dpf__set_module_export_list("${NAME}-lv2-ui" "lv2-ui")

  295.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  296.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  297.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  298.         ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/lv2/$<0:>"

  299.         OUTPUT_NAME "${NAME}_ui"

  300.         PREFIX "")

  301.     endif()

  302.   endif()

  303. 

  304.   dpf__add_lv2_ttl_generator()

  305.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  306. 

  307.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  308.     COMMAND

  309.     "$<TARGET_FILE:lv2_ttl_generator>"

  310.     "$<TARGET_FILE:${NAME}-lv2>"

  311.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2"

  312.     DEPENDS lv2_ttl_generator)

  313. endfunction()

  314. 

  315. # dpf__build_vst2

  316. # ------------------------------------------------------------------------------

  317. #

  318. # Add build rules for a VST2 plugin.

  319. #

  320. function(dpf__build_vst2 NAME DGL_LIBRARY)

  321.   dpf__create_dummy_source_list(_no_srcs)

  322. 

  323.   dpf__add_module("${NAME}-vst2" ${_no_srcs})

  324.   dpf__add_plugin_main("${NAME}-vst2" "vst2")

  325.   dpf__add_ui_main("${NAME}-vst2" "vst2" "${DGL_LIBRARY}")

  326.   dpf__set_module_export_list("${NAME}-vst2" "vst2")

  327.   target_link_libraries("${NAME}-vst2" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  328.   set_target_properties("${NAME}-vst2" PROPERTIES

  329.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  330.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst2/$<0:>"

  331.     OUTPUT_NAME "${NAME}-vst2"

  332.     PREFIX "")

  333.   if(APPLE)

  334.     set_target_properties("${NAME}-vst2" PROPERTIES

  335.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/MacOS/$<0:>"

  336.       OUTPUT_NAME "${NAME}"

  337.       SUFFIX "")

  338.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  339.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  340.       "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents/Info.plist" @ONLY)

  341.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  342.       DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst/Contents")

  343.   endif()

  344. endfunction()

  345. 

  346. # dpf__determine_vst3_package_architecture

  347. # ------------------------------------------------------------------------------

  348. #

  349. # Determines the package architecture for a VST3 plugin target.

  350. #

  351. function(dpf__determine_vst3_package_architecture OUTPUT_VARIABLE)

  352.   # if set by variable, override the detection

  353.   if(DPF_VST3_ARCHITECTURE)

  354.     set("${OUTPUT_VARIABLE}" "${DPF_VST3_ARCHITECTURE}" PARENT_SCOPE)

  355.     return()

  356.   endif()

  357. 

  358.   # not used on Apple, which supports universal binary

  359.   if(APPLE)

  360.     set("${OUTPUT_VARIABLE}" "universal" PARENT_SCOPE)

  361.     return()

  362.   endif()

  363. 

  364.   # identify the target processor (special case of MSVC, problematic sometimes)

  365.   if(MSVC)

  366.     set(vst3_system_arch "${MSVC_CXX_ARCHITECTURE_ID}")

  367.   else()

  368.     set(vst3_system_arch "${CMAKE_SYSTEM_PROCESSOR}")

  369.   endif()

  370. 

  371.   # transform the processor name to a format that VST3 recognizes

  372.   if(vst3_system_arch MATCHES "^(x86_64|amd64|AMD64|x64|X64)$")

  373.     set(vst3_package_arch "x86_64")

  374.   elseif(vst3_system_arch MATCHES "^(i.86|x86|X86)$")

  375.     if(WIN32)

  376.       set(vst3_package_arch "x86")

  377.     else()

  378.       set(vst3_package_arch "i386")

  379.     endif()

  380.   elseif(vst3_system_arch MATCHES "^(armv[3-8][a-z]*)$")

  381.     set(vst3_package_arch "${vst3_system_arch}")

  382.   elseif(vst3_system_arch MATCHES "^(aarch64)$")

  383.     set(vst3_package_arch "aarch64")

  384.   else()

  385.     message(FATAL_ERROR "We don't know this architecture for VST3: ${vst3_system_arch}.")

  386.   endif()

  387. 

  388.   # TODO: the detections for Windows arm/arm64 when supported

  389. 

  390.   set("${OUTPUT_VARIABLE}" "${vst3_package_arch}" PARENT_SCOPE)

  391. endfunction()

  392. 

  393. # dpf__build_vst3

  394. # ------------------------------------------------------------------------------

  395. #

  396. # Add build rules for a VST3 plugin.

  397. #

  398. function(dpf__build_vst3 NAME DGL_LIBRARY)

  399.   dpf__determine_vst3_package_architecture(vst3_arch)

  400. 

  401.   dpf__create_dummy_source_list(_no_srcs)

  402. 

  403.   dpf__add_module("${NAME}-vst3" ${_no_srcs})

  404.   dpf__add_plugin_main("${NAME}-vst3" "vst3")

  405.   dpf__add_ui_main("${NAME}-vst3" "vst3" "${DGL_LIBRARY}")

  406.   dpf__set_module_export_list("${NAME}-vst3" "vst3")

  407.   target_link_libraries("${NAME}-vst3" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  408.   set_target_properties("${NAME}-vst3" PROPERTIES

  409.     ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/obj/vst3/$<0:>"

  410.     OUTPUT_NAME "${NAME}"

  411.     PREFIX "")

  412. 

  413.   if(APPLE)

  414.     set_target_properties("${NAME}-vst3" PROPERTIES

  415.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/MacOS/$<0:>"

  416.       SUFFIX "")

  417.   elseif(WIN32)

  418.     set_target_properties("${NAME}-vst3" PROPERTIES

  419.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-win/$<0:>" SUFFIX ".vst3")

  420.   else()

  421.     set_target_properties("${NAME}-vst3" PROPERTIES

  422.       LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/${vst3_arch}-linux/$<0:>")

  423.   endif()

  424. 

  425.   if(APPLE)

  426.     # Uses the same macOS bundle template as VST2

  427.     set(INFO_PLIST_PROJECT_NAME "${NAME}")

  428.     configure_file("${DPF_ROOT_DIR}/utils/plugin.vst/Contents/Info.plist"

  429.      "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents/Info.plist" @ONLY)

  430.     file(COPY "${DPF_ROOT_DIR}/utils/plugin.vst/Contents/PkgInfo"

  431.      DESTINATION "${PROJECT_BINARY_DIR}/bin/${NAME}.vst3/Contents")

  432.   endif()

  433. endfunction()

  434. 

  435. # dpf__add_dgl_cairo

  436. # ------------------------------------------------------------------------------

  437. #

  438. # Add the Cairo variant of DGL, if not already available.

  439. #

  440. function(dpf__add_dgl_cairo)

  441.   if(TARGET dgl-cairo)

  442.     return()

  443.   endif()

  444. 

  445.   find_package(PkgConfig)

  446.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  447. 

  448.   link_directories(${CAIRO_LIBRARY_DIRS})

  449. 

  450.   dpf__add_static_library(dgl-cairo STATIC

  451.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  452.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  453.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  454.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  455.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  456.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  457.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  458.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  459.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  460.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  461.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  462.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  463.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  464.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  465.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  466.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  467.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp")

  468.   if(NOT APPLE)

  469.     target_sources(dgl-cairo PRIVATE

  470.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  471.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  472.     #target_sources(dgl-opengl PRIVATE

  473.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  474.   endif()

  475.   target_include_directories(dgl-cairo PUBLIC

  476.     "${DPF_ROOT_DIR}/dgl")

  477.   target_include_directories(dgl-cairo PUBLIC

  478.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  479. 

  480.   dpf__add_dgl_system_libs()

  481.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  482. 

  483.   add_library(dgl-cairo-definitions INTERFACE)

  484.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO" "HAVE_DGL")

  485. 

  486.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  487.   if(MINGW)

  488.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_STATIC_LIBRARIES})

  489.   else()

  490.     target_link_libraries(dgl-cairo PRIVATE ${CAIRO_LIBRARIES})

  491.   endif()

  492.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions)

  493. endfunction()

  494. 

  495. # dpf__add_dgl_opengl

  496. # ------------------------------------------------------------------------------

  497. #

  498. # Add the OpenGL variant of DGL, if not already available.

  499. #

  500. function(dpf__add_dgl_opengl)

  501.   if(TARGET dgl-opengl)

  502.     return()

  503.   endif()

  504. 

  505.   if(NOT OpenGL_GL_PREFERENCE)

  506.     set(OpenGL_GL_PREFERENCE "LEGACY")

  507.   endif()

  508. 

  509.   find_package(OpenGL REQUIRED)

  510. 

  511.   dpf__add_static_library(dgl-opengl STATIC

  512.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  513.     "${DPF_ROOT_DIR}/dgl/src/ApplicationPrivateData.cpp"

  514.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  515.     "${DPF_ROOT_DIR}/dgl/src/EventHandlers.cpp"

  516.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  517.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  518.     "${DPF_ROOT_DIR}/dgl/src/ImageBaseWidgets.cpp"

  519.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  520.     "${DPF_ROOT_DIR}/dgl/src/SubWidget.cpp"

  521.     "${DPF_ROOT_DIR}/dgl/src/SubWidgetPrivateData.cpp"

  522.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidget.cpp"

  523.     "${DPF_ROOT_DIR}/dgl/src/TopLevelWidgetPrivateData.cpp"

  524.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  525.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp"

  526.     "${DPF_ROOT_DIR}/dgl/src/Window.cpp"

  527.     "${DPF_ROOT_DIR}/dgl/src/WindowPrivateData.cpp"

  528.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  529.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp")

  530.   if(NOT APPLE)

  531.     target_sources(dgl-opengl PRIVATE

  532.       "${DPF_ROOT_DIR}/dgl/src/pugl.cpp")

  533.   else() # Note: macOS pugl will be built as part of DistrhoUI_macOS.mm

  534.     #target_sources(dgl-opengl PRIVATE

  535.     #  "${DPF_ROOT_DIR}/dgl/src/pugl.mm")

  536.   endif()

  537.   target_include_directories(dgl-opengl PUBLIC

  538.     "${DPF_ROOT_DIR}/dgl")

  539.   target_include_directories(dgl-opengl PUBLIC

  540.     "${DPF_ROOT_DIR}/dgl/src/pugl-upstream/include")

  541. 

  542.   if(APPLE)

  543.     target_compile_definitions(dgl-opengl PUBLIC "GL_SILENCE_DEPRECATION")

  544.   endif()

  545. 

  546.   dpf__add_dgl_system_libs()

  547.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  548. 

  549.   add_library(dgl-opengl-definitions INTERFACE)

  550.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL" "HAVE_DGL")

  551. 

  552.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  553.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  554.   

  555.   if(USE_NANOVG_FREETYPE)

  556.     find_package(Freetype REQUIRED)

  557.     target_include_directories(dgl-opengl PUBLIC "${FREETYPE_INCLUDE_DIRS}")

  558.     target_link_libraries(dgl-opengl PUBLIC "${FREETYPE_LIBRARIES}")

  559.     add_definitions(-DFONS_USE_FREETYPE)

  560.   endif()

  561.   

  562. endfunction()

  563. 

  564. # dpf__add_plugin_specific_ui_sources

  565. # ------------------------------------------------------------------------------

  566. #

  567. # Compile plugin-specific UI sources into the target designated by the given

  568. # name. There are some special considerations here:

  569. # - On most platforms, sources can be compiled only once, as part of DGL;

  570. # - On macOS, for any sources which define Objective-C interfaces, these must

  571. #   be recompiled for each plugin under a unique namespace. In this case, the

  572. #   name must be a plugin-specific identifier, and it will be used for computing

  573. #   the unique ID along with the project version.

  574. function(dpf__add_plugin_specific_ui_sources NAME)

  575.   if(APPLE)

  576.     target_sources("${NAME}" PRIVATE

  577.       "${DPF_ROOT_DIR}/distrho/DistrhoUI_macOS.mm")

  578.     string(SHA256 _hash "${NAME}:${PROJECT_VERSION}")

  579.     target_compile_definitions("${NAME}" PUBLIC "PUGL_NAMESPACE=${_hash}")

  580.   endif()

  581. endfunction()

  582. 

  583. # dpf__add_dgl_system_libs

  584. # ------------------------------------------------------------------------------

  585. #

  586. # Find system libraries required by DGL and add them as an interface target.

  587. #

  588. function(dpf__add_dgl_system_libs)

  589.   if(TARGET dgl-system-libs)

  590.     return()

  591.   endif()

  592.   add_library(dgl-system-libs INTERFACE)

  593.   add_library(dgl-system-libs-definitions INTERFACE)

  594.   if(HAIKU)

  595.     target_link_libraries(dgl-system-libs INTERFACE "be")

  596.   elseif(WIN32)

  597.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  598.   elseif(APPLE)

  599.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  600.     find_library(APPLE_COREVIDEO_FRAMEWORK "CoreVideo")

  601.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}" "${APPLE_COREVIDEO_FRAMEWORK}")

  602.   else()

  603.     find_package(X11 REQUIRED)

  604.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  605.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  606.     target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_X11")

  607.     if(X11_Xext_FOUND)

  608.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xext_LIB}")

  609.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XEXT")

  610.     endif()

  611.     if(X11_XSync_FOUND)

  612.       target_link_libraries(dgl-system-libs INTERFACE "${X11_XSync_LIB}")

  613.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XSYNC")

  614.     endif()

  615.     if(X11_Xrandr_FOUND)

  616.       target_link_libraries(dgl-system-libs INTERFACE "${X11_Xrandr_LIB}")

  617.       target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XRANDR")

  618.     endif()

  619.     #if(X11_Xcursor_FOUND)

  620.     #  target_link_libraries(dgl-system-libs INTERFACE "${X11_Xcursor_LIB}")

  621.     #  target_compile_definitions(dgl-system-libs-definitions INTERFACE "HAVE_XCURSOR")

  622.     #endif()

  623.    endif()

  624. 

  625.    if(MSVC)

  626.      file(MAKE_DIRECTORY "${DPF_ROOT_DIR}/khronos/GL")

  627.      foreach(_gl_header "glext.h")

  628.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}")

  629.          file(DOWNLOAD "https://www.khronos.org/registry/OpenGL/api/GL/${_gl_header}" "${DPF_ROOT_DIR}/khronos/GL/${_gl_header}" SHOW_PROGRESS)

  630.        endif()

  631.      endforeach()

  632.      foreach(_khr_header "khrplatform.h")

  633.        if(NOT EXISTS "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}")

  634.          file(DOWNLOAD "https://www.khronos.org/registry/EGL/api/KHR/${_khr_header}" "${DPF_ROOT_DIR}/khronos/KHR/${_khr_header}" SHOW_PROGRESS)

  635.        endif()

  636.      endforeach()

  637.      target_include_directories(dgl-system-libs-definitions INTERFACE "${DPF_ROOT_DIR}/khronos")

  638.    endif()

  639. 

  640.   target_link_libraries(dgl-system-libs INTERFACE dgl-system-libs-definitions)

  641. endfunction()

  642. 

  643. # dpf__add_executable

  644. # ------------------------------------------------------------------------------

  645. #

  646. # Adds an executable target, and set some default properties on the target.

  647. #

  648. function(dpf__add_executable NAME)

  649.   add_executable("${NAME}" ${ARGN})

  650.   dpf__set_target_defaults("${NAME}")

  651.   if(MINGW)

  652.     target_link_libraries("${NAME}" PRIVATE "-static")

  653.   endif()

  654. endfunction()

  655. 

  656. # dpf__add_module

  657. # ------------------------------------------------------------------------------

  658. #

  659. # Adds a module target, and set some default properties on the target.

  660. #

  661. function(dpf__add_module NAME)

  662.   add_library("${NAME}" MODULE ${ARGN})

  663.   dpf__set_target_defaults("${NAME}")

  664.   if(MINGW)

  665.     target_link_libraries("${NAME}" PRIVATE "-static")

  666.   endif()

  667. endfunction()

  668. 

  669. # dpf__add_static_library

  670. # ------------------------------------------------------------------------------

  671. #

  672. # Adds a static library target, and set some default properties on the target.

  673. #

  674. function(dpf__add_static_library NAME)

  675.   add_library("${NAME}" STATIC ${ARGN})

  676.   dpf__set_target_defaults("${NAME}")

  677. endfunction()

  678. 

  679. # dpf__set_module_export_list

  680. # ------------------------------------------------------------------------------

  681. #

  682. # Applies a list of exported symbols to the module target.

  683. #

  684. function(dpf__set_module_export_list NAME EXPORTS)

  685.   if(WIN32)

  686.     target_sources("${NAME}" PRIVATE "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.def")

  687.   elseif(APPLE)

  688.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  689.       "-Xlinker" "-exported_symbols_list"

  690.       "-Xlinker" "${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.exp")

  691.   else()

  692.     set_property(TARGET "${NAME}" APPEND PROPERTY LINK_OPTIONS

  693.       "-Xlinker" "--version-script=${DPF_ROOT_DIR}/utils/symbols/${EXPORTS}.version")

  694.   endif()

  695. endfunction()

  696. 

  697. # dpf__set_target_defaults

  698. # ------------------------------------------------------------------------------

  699. #

  700. # Set default properties which must apply to all DPF-defined targets.

  701. #

  702. function(dpf__set_target_defaults NAME)

  703.   set_target_properties("${NAME}" PROPERTIES

  704.     POSITION_INDEPENDENT_CODE TRUE

  705.     C_VISIBILITY_PRESET "hidden"

  706.     CXX_VISIBILITY_PRESET "hidden"

  707.     VISIBILITY_INLINES_HIDDEN TRUE)

  708.   if(WIN32)

  709.     target_compile_definitions("${NAME}" PUBLIC "NOMINMAX")

  710.   endif()

  711.   if (MINGW)

  712.     target_compile_options("${NAME}" PUBLIC "-mstackrealign")

  713.   endif()

  714.   if (MSVC)

  715.     target_compile_options("${NAME}" PUBLIC "/UTF-8")

  716.     target_compile_definitions("${NAME}" PUBLIC "_CRT_SECURE_NO_WARNINGS")

  717.   endif()

  718. endfunction()

  719. 

  720. # dpf__add_plugin_main

  721. # ------------------------------------------------------------------------------

  722. #

  723. # Adds plugin code to the given target.

  724. #

  725. function(dpf__add_plugin_main NAME TARGET)

  726.   target_sources("${NAME}" PRIVATE

  727.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  728.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  729. endfunction()

  730. 

  731. # dpf__add_ui_main

  732. # ------------------------------------------------------------------------------

  733. #

  734. # Adds UI code to the given target (only if the target has UI).

  735. #

  736. function(dpf__add_ui_main NAME TARGET HAS_UI)

  737.   if(HAS_UI)

  738.     target_sources("${NAME}" PRIVATE

  739.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  740.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  741.   endif()

  742. endfunction()

  743. 

  744. # dpf__add_plugin_target_definition

  745. # ------------------------------------------------------------------------------

  746. #

  747. # Adds the plugins target macro definition.

  748. # This selects which entry file is compiled according to the target type.

  749. #

  750. function(dpf__add_plugin_target_definition NAME TARGET)

  751.   string(TOUPPER "${TARGET}" _upperTarget)

  752.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  753. endfunction()

  754. 

  755. # dpf__add_lv2_ttl_generator

  756. # ------------------------------------------------------------------------------

  757. #

  758. # Build the LV2 TTL generator.

  759. #

  760. function(dpf__add_lv2_ttl_generator)

  761.   if(TARGET lv2_ttl_generator)

  762.     return()

  763.   endif()

  764.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  765.   if((NOT WIN32) AND (NOT APPLE) AND (NOT HAIKU))

  766.     target_link_libraries(lv2_ttl_generator PRIVATE "dl")

  767.   endif()

  768. endfunction()

  769. 

  770. # dpf__ensure_sources_non_empty

  771. # ------------------------------------------------------------------------------

  772. #

  773. # Ensure the given source list contains at least one file.

  774. # The function appends an empty source file to the list if necessary.

  775. # This is useful when CMake does not permit to add targets without sources.

  776. #

  777. function(dpf__ensure_sources_non_empty VAR)

  778.   if(NOT "" STREQUAL "${${VAR}}")

  779.     return()

  780.   endif()

  781.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.c")

  782.   if(NOT EXISTS "${_file}")

  783.     file(WRITE "${_file}" "")

  784.   endif()

  785.   set("${VAR}" "${_file}" PARENT_SCOPE)

  786. endfunction()

  787. 

  788. # dpf__create_dummy_source_list

  789. # ------------------------------------------------------------------------------

  790. #

  791. # Create a dummy source list which is equivalent to compiling nothing.

  792. # This is only for compatibility with older CMake versions, which refuse to add

  793. # targets without any sources.

  794. #

  795. macro(dpf__create_dummy_source_list VAR)

  796.   set("${VAR}")

  797.   if(CMAKE_VERSION VERSION_LESS "3.11")

  798.     dpf__ensure_sources_non_empty("${VAR}")

  799.   endif()

  800. endmacro()

  801. 

  802. # dpf__warn_once

  803. # ------------------------------------------------------------------------------

  804. #

  805. # Prints a warning message once only.

  806. #

  807. function(dpf__warn_once_only TOKEN MESSAGE)

  808.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  809.   if(NOT _warned)

  810.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  811.     message(WARNING "${MESSAGE}")

  812.   endif()

  813. endfunction()