DISTRHO
/
DPF
mirror of https://github.com/DISTRHO/DPF
1
0
Fork 0
Code Releases 0 Activity
DISTRHO Plugin Framework
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
879 Commits
7 Branches
295MB
Tree: 0533e2e64b
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '0533e2e64b'
${ noResults }
DPF/cmake/DPF-plugin.cmake

518 lines
17KB
Raw Blame History 

  1. include(CMakeParseArguments)

  2. 

  3. # ------------------------------------------------------------------------------

  4. # DPF public functions

  5. # ------------------------------------------------------------------------------

  6. 

  7. # dpf_add_plugin(name <args...>)

  8. # ------------------------------------------------------------------------------

  9. #

  10. # Add a plugin built using the DISTRHO Plugin Framework.

  11. #

  12. # ------------------------------------------------------------------------------

  13. # Created targets:

  14. #

  15. #   `<name>`

  16. #       static library: the common part of the plugin

  17. #       The public properties set on this target apply to both DSP and UI.

  18. #

  19. #   `<name>-dsp`

  20. #       static library: the DSP part of the plugin

  21. #       The public properties set on this target apply to the DSP only.

  22. #

  23. #   `<name>-ui`

  24. #       static library: the UI part of the plugin

  25. #       The public properties set on this target apply to the UI only.

  26. #

  27. #   `<name>-<target>` for each target specified with the `TARGETS` argument.

  28. #       This is target-dependent and not intended for public use.

  29. #

  30. # ------------------------------------------------------------------------------

  31. # Arguments:

  32. #

  33. #   `TARGETS` <tgt1>...<tgtN>

  34. #       a list of one of more of the following target types:

  35. #       `jack`, `ladspa`, `dssi`, `lv2`, `vst`

  36. #

  37. #   `UI_TYPE` <type>

  38. #       the user interface type, if any: `cairo`, `opengl`

  39. #

  40. #   `MONOLITHIC`

  41. #       build LV2 as a single binary for UI and DSP

  42. #

  43. #   `FILES_DSP` <file1>...<fileN>

  44. #       list of sources which are part of the DSP

  45. #

  46. #   `FILES_UI` <file1>...<fileN>

  47. #       list of sources which are part of the UI

  48. #

  49. #   `FILES_COMMON` <file1>...<fileN>

  50. #       list of sources which are part of both DSP and UI

  51. #

  52. function(dpf_add_plugin NAME)

  53.   set(options MONOLITHIC)

  54.   set(oneValueArgs UI_TYPE)

  55.   set(multiValueArgs TARGETS FILES_DSP FILES_UI)

  56.   cmake_parse_arguments(_dpf_plugin "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  57. 

  58.   if(NOT _dpf_plugin_UI_TYPE)

  59.     set(_dgl_library)

  60.   elseif(_dpf_plugin_UI_TYPE STREQUAL "cairo")

  61.     dpf__add_dgl_cairo()

  62.     set(_dgl_library dgl-cairo)

  63.   elseif(_dpf_plugin_UI_TYPE STREQUAL "opengl")

  64.     dpf__add_dgl_opengl()

  65.     set(_dgl_library dgl-opengl)

  66.   else()

  67.     message(FATAL_ERROR "Unrecognized UI type for plugin: ${UI_TYPE}")

  68.   endif()

  69. 

  70.   ###

  71.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_COMMON)

  72.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_DSP)

  73.   dpf__ensure_sources_non_empty(_dpf_plugin_FILES_UI)

  74. 

  75.   ###

  76.   dpf__add_static_library("${NAME}" ${_dpf_plugin_FILES_COMMON})

  77.   target_include_directories("${NAME}" PUBLIC

  78.     "${DPF_ROOT_DIR}/distrho")

  79. 

  80.   if(_dgl_library)

  81.     # make sure that all code will see DGL_* definitions

  82.     target_link_libraries("${NAME}" PUBLIC "${_dgl_library}-definitions")

  83.   endif()

  84. 

  85.   dpf__add_static_library("${NAME}-dsp" ${_dpf_plugin_FILES_DSP})

  86.   target_link_libraries("${NAME}-dsp" PUBLIC "${NAME}")

  87. 

  88.   if(_dgl_library)

  89.     dpf__add_static_library("${NAME}-ui" ${_dpf_plugin_FILES_UI})

  90.     target_link_libraries("${NAME}-ui" PUBLIC "${NAME}" ${_dgl_library})

  91.   else()

  92.     add_library("${NAME}-ui" INTERFACE)

  93.   endif()

  94. 

  95.   ###

  96.   foreach(_target ${_dpf_plugin_TARGETS})

  97.     if(_target STREQUAL "jack")

  98.       dpf__build_jack("${NAME}" "${_dgl_library}")

  99.     elseif(_target STREQUAL "ladspa")

  100.       dpf__build_ladspa("${NAME}")

  101.     elseif(_target STREQUAL "dssi")

  102.       dpf__build_dssi("${NAME}" "${_dgl_library}")

  103.     elseif(_target STREQUAL "lv2")

  104.       dpf__build_lv2("${NAME}" "${_dgl_library}" "${_dpf_plugin_MONOLITHIC}")

  105.     elseif(_target STREQUAL "vst")

  106.       dpf__build_vst("${NAME}" "${_dgl_library}")

  107.     endif()

  108.   endforeach()

  109. endfunction()

  110. 

  111. # ------------------------------------------------------------------------------

  112. # DPF private functions (prefixed with `dpf__`)

  113. # ------------------------------------------------------------------------------

  114. 

  115. # Note: The $<0:> trick is to prevent MSVC from appending the build type

  116. #       to the output directory.

  117. #

  118. 

  119. # dpf__build_jack

  120. # ------------------------------------------------------------------------------

  121. #

  122. # Add build rules for a JACK program.

  123. #

  124. function(dpf__build_jack NAME DGL_LIBRARY)

  125.   find_package(PkgConfig)

  126.   pkg_check_modules(JACK "jack")

  127.   if(NOT JACK_FOUND)

  128.     dpf__warn_once_only(missing_jack

  129.       "JACK is not found, skipping the `jack` plugin targets")

  130.     return()

  131.   endif()

  132. 

  133.   dpf__create_dummy_source_list(_no_srcs)

  134. 

  135.   dpf__add_executable("${NAME}-jack" ${_no_srcs})

  136.   dpf__add_plugin_main("${NAME}-jack" "jack")

  137.   dpf__add_ui_main("${NAME}-jack" "jack" "${DGL_LIBRARY}")

  138.   target_link_libraries("${NAME}-jack" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  139.   set_target_properties("${NAME}-jack" PROPERTIES

  140.     RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  141.     OUTPUT_NAME "${NAME}")

  142. 

  143.   target_include_directories("${NAME}-jack" PRIVATE ${JACK_INCLUDE_DIRS})

  144.   target_link_libraries("${NAME}-jack" PRIVATE ${JACK_LIBRARIES})

  145.   link_directories(${JACK_LIBRARY_DIRS})

  146. endfunction()

  147. 

  148. # dpf__build_ladspa

  149. # ------------------------------------------------------------------------------

  150. #

  151. # Add build rules for a DSSI plugin.

  152. #

  153. function(dpf__build_ladspa NAME)

  154.   dpf__create_dummy_source_list(_no_srcs)

  155. 

  156.   dpf__add_module("${NAME}-ladspa" ${_no_srcs})

  157.   dpf__add_plugin_main("${NAME}-ladspa" "ladspa")

  158.   target_link_libraries("${NAME}-ladspa" PRIVATE "${NAME}-dsp")

  159.   set_target_properties("${NAME}-ladspa" PROPERTIES

  160.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  161.     OUTPUT_NAME "${NAME}-ladspa"

  162.     PREFIX "")

  163. endfunction()

  164. 

  165. # dpf__build_dssi

  166. # ------------------------------------------------------------------------------

  167. #

  168. # Add build rules for a DSSI plugin.

  169. #

  170. function(dpf__build_dssi NAME DGL_LIBRARY)

  171.   find_package(PkgConfig)

  172.   pkg_check_modules(LIBLO "liblo")

  173.   if(NOT LIBLO_FOUND)

  174.     dpf__warn_once_only(missing_liblo

  175.       "liblo is not found, skipping the `dssi` plugin targets")

  176.     return()

  177.   endif()

  178. 

  179.   dpf__create_dummy_source_list(_no_srcs)

  180. 

  181.   dpf__add_module("${NAME}-dssi" ${_no_srcs})

  182.   dpf__add_plugin_main("${NAME}-dssi" "dssi")

  183.   target_link_libraries("${NAME}-dssi" PRIVATE "${NAME}-dsp")

  184.   set_target_properties("${NAME}-dssi" PROPERTIES

  185.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  186.     OUTPUT_NAME "${NAME}-dssi"

  187.     PREFIX "")

  188. 

  189.   if(DGL_LIBRARY)

  190.     dpf__add_executable("${NAME}-dssi-ui" ${_no_srcs})

  191.     dpf__add_ui_main("${NAME}-dssi-ui" "dssi" "${DGL_LIBRARY}")

  192.     target_link_libraries("${NAME}-dssi-ui" PRIVATE "${NAME}-ui")

  193.     set_target_properties("${NAME}-dssi-ui" PROPERTIES

  194.       RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}-dssi/$<0:>"

  195.       OUTPUT_NAME "${NAME}_ui")

  196. 

  197.     target_include_directories("${NAME}-dssi-ui" PRIVATE ${LIBLO_INCLUDE_DIRS})

  198.     target_link_libraries("${NAME}-dssi-ui" PRIVATE ${LIBLO_LIBRARIES})

  199.     link_directories(${LIBLO_LIBRARY_DIRS})

  200.   endif()

  201. endfunction()

  202. 

  203. # dpf__build_lv2

  204. # ------------------------------------------------------------------------------

  205. #

  206. # Add build rules for a LV2 plugin.

  207. #

  208. function(dpf__build_lv2 NAME DGL_LIBRARY MONOLITHIC)

  209.   dpf__create_dummy_source_list(_no_srcs)

  210. 

  211.   dpf__add_module("${NAME}-lv2" ${_no_srcs})

  212.   dpf__add_plugin_main("${NAME}-lv2" "lv2")

  213.   target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-dsp")

  214.   set_target_properties("${NAME}-lv2" PROPERTIES

  215.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  216.     OUTPUT_NAME "${NAME}_dsp"

  217.     PREFIX "")

  218. 

  219.   if(DGL_LIBRARY)

  220.     if(MONOLITHIC)

  221.       dpf__add_ui_main("${NAME}-lv2" "lv2" "${DGL_LIBRARY}")

  222.       target_link_libraries("${NAME}-lv2" PRIVATE "${NAME}-ui")

  223.       set_target_properties("${NAME}-lv2" PROPERTIES

  224.         OUTPUT_NAME "${NAME}")

  225.     else()

  226.       dpf__add_module("${NAME}-lv2-ui" ${_no_srcs})

  227.       dpf__add_ui_main("${NAME}-lv2-ui" "lv2" "${DGL_LIBRARY}")

  228.       target_link_libraries("${NAME}-lv2-ui" PRIVATE "${NAME}-ui")

  229.       set_target_properties("${NAME}-lv2-ui" PROPERTIES

  230.         LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2/$<0:>"

  231.         OUTPUT_NAME "${NAME}_ui"

  232.         PREFIX "")

  233.     endif()

  234.   endif()

  235. 

  236.   dpf__add_lv2_ttl_generator()

  237.   add_dependencies("${NAME}-lv2" lv2_ttl_generator)

  238. 

  239.   add_custom_command(TARGET "${NAME}-lv2" POST_BUILD

  240.     COMMAND ${CMAKE_CROSSCOMPILING_EMULATOR}

  241.     "$<TARGET_FILE:lv2_ttl_generator>"

  242.     "$<TARGET_FILE:${NAME}-lv2>"

  243.     WORKING_DIRECTORY "${PROJECT_BINARY_DIR}/bin/${NAME}.lv2")

  244. endfunction()

  245. 

  246. # dpf__build_vst

  247. # ------------------------------------------------------------------------------

  248. #

  249. # Add build rules for a VST plugin.

  250. #

  251. function(dpf__build_vst NAME DGL_LIBRARY)

  252.   dpf__create_dummy_source_list(_no_srcs)

  253. 

  254.   dpf__add_module("${NAME}-vst" ${_no_srcs})

  255.   dpf__add_plugin_main("${NAME}-vst" "vst")

  256.   dpf__add_ui_main("${NAME}-vst" "vst" "${DGL_LIBRARY}")

  257.   target_link_libraries("${NAME}-vst" PRIVATE "${NAME}-dsp" "${NAME}-ui")

  258.   set_target_properties("${NAME}-vst" PROPERTIES

  259.     LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin/$<0:>"

  260.     OUTPUT_NAME "${NAME}-vst"

  261.     PREFIX "")

  262. endfunction()

  263. 

  264. # dpf__add_dgl_cairo

  265. # ------------------------------------------------------------------------------

  266. #

  267. # Add the Cairo variant of DGL, if not already available.

  268. #

  269. function(dpf__add_dgl_cairo)

  270.   if(TARGET dgl-cairo)

  271.     return()

  272.   endif()

  273. 

  274.   find_package(PkgConfig)

  275.   pkg_check_modules(CAIRO "cairo" REQUIRED)

  276. 

  277.   dpf__add_static_library(dgl-cairo EXCLUDE_FROM_ALL

  278.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  279.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  280.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  281.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  282.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  283.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  284.     "${DPF_ROOT_DIR}/dgl/src/Cairo.cpp"

  285.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  286.   if(NOT APPLE)

  287.     target_sources(dgl-cairo PRIVATE

  288.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  289.   else()

  290.     target_sources(dgl-cairo PRIVATE

  291.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  292.   endif()

  293.   target_include_directories(dgl-cairo PUBLIC

  294.     "${DPF_ROOT_DIR}/dgl")

  295. 

  296.   dpf__add_dgl_system_libs()

  297.   target_link_libraries(dgl-cairo PRIVATE dgl-system-libs)

  298. 

  299.   add_library(dgl-cairo-definitions INTERFACE)

  300.   target_compile_definitions(dgl-cairo-definitions INTERFACE "DGL_CAIRO" "HAVE_CAIRO")

  301. 

  302.   target_include_directories(dgl-cairo PUBLIC ${CAIRO_INCLUDE_DIRS})

  303.   target_link_libraries(dgl-cairo PRIVATE dgl-cairo-definitions ${CAIRO_LIBRARIES})

  304.   link_directories(${CAIRO_LIBRARY_DIRS})

  305. endfunction()

  306. 

  307. # dpf__add_dgl_opengl

  308. # ------------------------------------------------------------------------------

  309. #

  310. # Add the OpenGL variant of DGL, if not already available.

  311. #

  312. function(dpf__add_dgl_opengl)

  313.   if(TARGET dgl-opengl)

  314.     return()

  315.   endif()

  316. 

  317.   if(NOT OpenGL_GL_PREFERENCE)

  318.     set(OpenGL_GL_PREFERENCE "LEGACY")

  319.   endif()

  320. 

  321.   find_package(OpenGL REQUIRED)

  322. 

  323.   dpf__add_static_library(dgl-opengl EXCLUDE_FROM_ALL

  324.     "${DPF_ROOT_DIR}/dgl/src/Application.cpp"

  325.     "${DPF_ROOT_DIR}/dgl/src/Color.cpp"

  326.     "${DPF_ROOT_DIR}/dgl/src/Geometry.cpp"

  327.     "${DPF_ROOT_DIR}/dgl/src/ImageBase.cpp"

  328.     "${DPF_ROOT_DIR}/dgl/src/Resources.cpp"

  329.     "${DPF_ROOT_DIR}/dgl/src/Widget.cpp"

  330.     "${DPF_ROOT_DIR}/dgl/src/OpenGL.cpp"

  331.     "${DPF_ROOT_DIR}/dgl/src/Image.cpp"

  332.     "${DPF_ROOT_DIR}/dgl/src/ImageWidgets.cpp"

  333.     "${DPF_ROOT_DIR}/dgl/src/NanoVG.cpp"

  334.     "${DPF_ROOT_DIR}/dgl/src/WidgetPrivateData.cpp")

  335.   if(NOT APPLE)

  336.     target_sources(dgl-opengl PRIVATE

  337.       "${DPF_ROOT_DIR}/dgl/src/Window.cpp")

  338.   else()

  339.     target_sources(dgl-opengl PRIVATE

  340.       "${DPF_ROOT_DIR}/dgl/src/Window.mm")

  341.   endif()

  342.   target_include_directories(dgl-opengl PUBLIC

  343.     "${DPF_ROOT_DIR}/dgl")

  344. 

  345.   dpf__add_dgl_system_libs()

  346.   target_link_libraries(dgl-opengl PRIVATE dgl-system-libs)

  347. 

  348.   add_library(dgl-opengl-definitions INTERFACE)

  349.   target_compile_definitions(dgl-opengl-definitions INTERFACE "DGL_OPENGL" "HAVE_OPENGL")

  350. 

  351.   target_include_directories(dgl-opengl PUBLIC "${OPENGL_INCLUDE_DIR}")

  352.   target_link_libraries(dgl-opengl PRIVATE dgl-opengl-definitions "${OPENGL_gl_LIBRARY}")

  353. endfunction()

  354. 

  355. # dpf__add_dgl_system_libs

  356. # ------------------------------------------------------------------------------

  357. #

  358. # Find system libraries required by DGL and add them as an interface target.

  359. #

  360. function(dpf__add_dgl_system_libs)

  361.   if(TARGET dgl-system-libs)

  362.     return()

  363.   endif()

  364.   add_library(dgl-system-libs INTERFACE)

  365.   if(HAIKU)

  366.     target_link_libraries(dgl-system-libs INTERFACE "be")

  367.   elseif(WIN32)

  368.     target_link_libraries(dgl-system-libs INTERFACE "gdi32" "comdlg32")

  369.   elseif(APPLE)

  370.     find_library(APPLE_COCOA_FRAMEWORK "Cocoa")

  371.     target_link_libraries(dgl-system-libs INTERFACE "${APPLE_COCOA_FRAMEWORK}")

  372.   else()

  373.     find_package(X11 REQUIRED)

  374.     target_include_directories(dgl-system-libs INTERFACE "${X11_INCLUDE_DIR}")

  375.     target_link_libraries(dgl-system-libs INTERFACE "${X11_X11_LIB}")

  376.   endif()

  377. endfunction()

  378. 

  379. # dpf__add_executable

  380. # ------------------------------------------------------------------------------

  381. #

  382. # Adds an executable target, and set some default properties on the target.

  383. #

  384. function(dpf__add_executable NAME)

  385.   add_executable("${NAME}" ${ARGN})

  386.   set_target_properties("${NAME}" PROPERTIES

  387.     POSITION_INDEPENDENT_CODE TRUE

  388.     C_VISIBILITY_PRESET "hidden"

  389.     CXX_VISIBILITY_PRESET "hidden"

  390.     VISIBILITY_INLINES_HIDDEN TRUE)

  391. endfunction()

  392. 

  393. # dpf__add_module

  394. # ------------------------------------------------------------------------------

  395. #

  396. # Adds a module target, and set some default properties on the target.

  397. #

  398. function(dpf__add_module NAME)

  399.   add_library("${NAME}" MODULE ${ARGN})

  400.   set_target_properties("${NAME}" PROPERTIES

  401.     POSITION_INDEPENDENT_CODE TRUE

  402.     C_VISIBILITY_PRESET "hidden"

  403.     CXX_VISIBILITY_PRESET "hidden"

  404.     VISIBILITY_INLINES_HIDDEN TRUE)

  405.   if ((NOT WIN32 AND NOT APPLE) OR MINGW)

  406.     target_link_libraries("${NAME}" PRIVATE "-Wl,--no-undefined")

  407.   endif()

  408. endfunction()

  409. 

  410. # dpf__add_static_library

  411. # ------------------------------------------------------------------------------

  412. #

  413. # Adds a module target, and set some default properties on the target.

  414. #

  415. function(dpf__add_static_library NAME)

  416.   add_library("${NAME}" STATIC ${ARGN})

  417.   set_target_properties("${NAME}" PROPERTIES

  418.     POSITION_INDEPENDENT_CODE TRUE

  419.     C_VISIBILITY_PRESET "hidden"

  420.     CXX_VISIBILITY_PRESET "hidden"

  421.     VISIBILITY_INLINES_HIDDEN TRUE)

  422. endfunction()

  423. 

  424. # dpf__add_plugin_main

  425. # ------------------------------------------------------------------------------

  426. #

  427. # Adds plugin code to the given target.

  428. #

  429. function(dpf__add_plugin_main NAME TARGET)

  430.   target_sources("${NAME}" PRIVATE

  431.     "${DPF_ROOT_DIR}/distrho/DistrhoPluginMain.cpp")

  432.   dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  433. endfunction()

  434. 

  435. # dpf__add_ui_main

  436. # ------------------------------------------------------------------------------

  437. #

  438. # Adds UI code to the given target (only if the target has UI).

  439. #

  440. function(dpf__add_ui_main NAME TARGET HAS_UI)

  441.   if(HAS_UI)

  442.     target_sources("${NAME}" PRIVATE

  443.       "${DPF_ROOT_DIR}/distrho/DistrhoUIMain.cpp")

  444.     dpf__add_plugin_target_definition("${NAME}" "${TARGET}")

  445.   endif()

  446. endfunction()

  447. 

  448. # dpf__add_plugin_target_definition

  449. # ------------------------------------------------------------------------------

  450. #

  451. # Adds the plugins target macro definition.

  452. # This selects which entry file is compiled according to the target type.

  453. #

  454. function(dpf__add_plugin_target_definition NAME TARGET)

  455.   string(TOUPPER "${TARGET}" _upperTarget)

  456.   target_compile_definitions("${NAME}" PRIVATE "DISTRHO_PLUGIN_TARGET_${_upperTarget}")

  457. endfunction()

  458. 

  459. # dpf__add_lv2_ttl_generator

  460. # ------------------------------------------------------------------------------

  461. #

  462. # Build the LV2 TTL generator.

  463. #

  464. function(dpf__add_lv2_ttl_generator)

  465.   if(TARGET lv2_ttl_generator)

  466.     return()

  467.   endif()

  468.   add_executable(lv2_ttl_generator "${DPF_ROOT_DIR}/utils/lv2-ttl-generator/lv2_ttl_generator.c")

  469.   if(NOT WINDOWS AND NOT APPLE AND NOT HAIKU)

  470.     target_link_libraries(lv2_ttl_generator "dl")

  471.   endif()

  472. endfunction()

  473. 

  474. # dpf__ensure_sources_non_empty

  475. # ------------------------------------------------------------------------------

  476. #

  477. # Ensure the given source list contains at least one file.

  478. # The function appends an empty source file to the list if necessary.

  479. # This is useful when CMake does not permit to add targets without sources.

  480. #

  481. function(dpf__ensure_sources_non_empty VAR)

  482.   if(NOT "" STREQUAL "${${VAR}}")

  483.     return()

  484.   endif()

  485.   set(_file "${CMAKE_CURRENT_BINARY_DIR}/_dpf_empty.cpp")

  486.   if(NOT EXISTS "${_file}")

  487.     file(WRITE "${_file}" "")

  488.   endif()

  489.   set("${VAR}" "${_file}" PARENT_SCOPE)

  490. endfunction()

  491. 

  492. # dpf__create_dummy_source_list

  493. # ------------------------------------------------------------------------------

  494. #

  495. # Create a dummy source list which is equivalent to compiling nothing.

  496. # This is only for compatibility with older CMake versions, which refuse to add

  497. # targets without any sources.

  498. #

  499. macro(dpf__create_dummy_source_list VAR)

  500.   set("${VAR}")

  501.   if(CMAKE_VERSION VERSION_LESS "3.11")

  502.     dpf__ensure_sources_non_empty("${VAR}")

  503.   endif()

  504. endmacro()

  505. 

  506. # dpf__warn_once

  507. # ------------------------------------------------------------------------------

  508. #

  509. # Prints a warning message once only.

  510. #

  511. function(dpf__warn_once_only TOKEN MESSAGE)

  512.   get_property(_warned GLOBAL PROPERTY "dpf__have_warned_${TOKEN}")

  513.   if(NOT _warned)

  514.     set_property(GLOBAL PROPERTY "dpf__have_warned_${TOKEN}" TRUE)

  515.     message(WARNING "${MESSAGE}")

  516.   endif()

  517. endfunction()