non
/
ntk
mirror of https://github.com/original-male/ntk
1
0
Fork 0
Code Releases 2 Activity
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
14 Commits
1 Branch
8.9MB
Tree: beaa050cfb
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'beaa050cfb'
${ noResults }
ntk/configure.in

1386 lines
38KB
Raw Blame History 

  1. dnl -*- sh -*-

  2. dnl the "configure" script is made from this by running GNU "autoconf"

  3. dnl

  4. dnl "$Id: configure.in 8511 2011-03-06 16:54:58Z manolo $"

  5. dnl

  6. dnl Configuration script for the Fast Light Tool Kit (FLTK).

  7. dnl

  8. dnl Copyright 1998-2010 by Bill Spitzak and others.

  9. dnl

  10. dnl This library is free software; you can redistribute it and/or

  11. dnl modify it under the terms of the GNU Library General Public

  12. dnl License as published by the Free Software Foundation; either

  13. dnl version 2 of the License, or (at your option) any later version.

  14. dnl

  15. dnl This library is distributed in the hope that it will be useful,

  16. dnl but WITHOUT ANY WARRANTY; without even the implied warranty of

  17. dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

  18. dnl Library General Public License for more details.

  19. dnl

  20. dnl You should have received a copy of the GNU Library General Public

  21. dnl License along with this library; if not, write to the Free Software

  22. dnl Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307

  23. dnl USA.

  24. dnl

  25. dnl Please report all bugs and problems on the following page:

  26. dnl

  27. dnl      http://www.fltk.org/str.php

  28. dnl

  29. 

  30. dnl We need at least autoconf 2.50...

  31. AC_PREREQ(2.50)

  32. 

  33. dnl Required file in package...

  34. AC_INIT(src/Fl.cxx)

  35. 

  36. dnl So --with-archflags option is used during "checking size of long"

  37. if test `uname` = Darwin; then

  38.   if test "x$with_archflags" != x ; then

  39.     CFLAGS="$CFLAGS $with_archflags"

  40.   fi

  41.   USEMMFILES="Yes"

  42. else

  43.   USEMMFILES="No"

  44. fi

  45. AC_SUBST(USEMMFILES)

  46. 

  47. dnl FLTK library versions...

  48. FL_MAJOR_VERSION=1

  49. FL_MINOR_VERSION=3

  50. FL_PATCH_VERSION=0

  51. FL_API_VERSION=${FL_MAJOR_VERSION}.${FL_MINOR_VERSION}

  52. 

  53. AC_SUBST(FL_MAJOR_VERSION)

  54. AC_SUBST(FL_MINOR_VERSION)

  55. AC_SUBST(FL_PATCH_VERSION)

  56. AC_SUBST(FL_API_VERSION)

  57. 

  58. dnl Get the operating system and version number...

  59. uname=`uname`

  60. uversion=`uname -r | sed -e '1,$s/[[^0-9]]//g'`

  61. if test "x$uname" = xIRIX64; then

  62.     uname="IRIX"

  63. fi

  64. if test "x$uname" = x; then

  65.     # Older MinGW doesn't provide any output when uname is run, even with "-s".

  66.     # Current MinGW (as of Jan. 2011) however does, so this is not necessary anymore...

  67.     uname="MINGW"

  68. fi

  69. 

  70. dnl Do not automatically add "-g" to compiler options...

  71. ARCHFLAGS="${ARCHFLAGS:=}"

  72. CFLAGS="${CFLAGS:=}"

  73. CPPFLAGS="${CPPFLAGS:=}"

  74. CXXFLAGS="${CXXFLAGS:=}"

  75. DSOFLAGS="${DSOFLAGS:=}"

  76. LDFLAGS="${LDFLAGS:=}"

  77. OPTIM="${OPTIM:=}"

  78. 

  79. AC_SUBST(ARCHFLAGS)

  80. AC_SUBST(OPTIM)

  81. 

  82. dnl in case of cross-compiling mingw32 under linux we must change uname for Win32 GUI

  83. dnl run ./configure --host=i686-pc-ming32 try use X11 without change uname

  84. if test "x$cross_compiling" != xno ; then

  85.   case $host_alias in

  86.     *mingw*)

  87.     uname=MINGW

  88.     ;;

  89.   esac

  90. fi

  91. 

  92. dnl OS-specific pre-tests...

  93. dnl uname_GUI equals $uname unless we target Cygwin in combination with X11.

  94. uname_GUI=$uname

  95. case $uname in

  96.     CYGWIN*)

  97.         # Handle Cygwin option *first*, before all other tests.

  98. 	AC_ARG_ENABLE(cygwin, [  --enable-cygwin         use the Cygwin libraries [(default=no)]])

  99. 	AC_ARG_ENABLE(x11,    [  --enable-x11            use Cygwin with X11 [(default=no)]])

  100. 	if test x$enable_cygwin != xyes; then

  101. 	    # NOTE: We can't use ARCHFLAGS for this, since it does not work

  102. 	    #       with some of the function tests - Cygwin uses a

  103. 	    #       different C library...

  104. 	    CFLAGS="$CFLAGS -mno-cygwin"

  105. 	    CPPFLAGS="$CPPFLAGS -mno-cygwin"

  106. 	    CXXFLAGS="$CXXFLAGS -mno-cygwin"

  107. 	    LDFLAGS="$LDFLAGS -mno-cygwin"

  108. 	    DSOFLAGS="$DSOFLAGS -mno-cygwin"

  109. 	else

  110. 	    # we target Cygwin in combination with X11

  111. 	    if test x$enable_x11 = xyes; then

  112. 		uname_GUI="X11$uname"

  113. 	    fi

  114. 	fi

  115. 	;;

  116. esac

  117. 

  118. dnl Define the libraries and link options we will need.

  119. LINKFLTK="../lib/libfltk.a"

  120. LINKFLTKFORMS="../lib/libfltk_forms.a"

  121. LINKFLTKGL="../lib/libfltk_gl.a"

  122. LINKFLTKIMG="../lib/libfltk_images.a"

  123. GLDEMOS="gldemos"

  124. 

  125. LIBEXT=".a"

  126. LIBNAME="../lib/libfltk.a"

  127. FLLIBNAME="../lib/libfltk_forms.a"

  128. GLLIBNAME="../lib/libfltk_gl.a"

  129. IMGLIBNAME="../lib/libfltk_images.a"

  130. 

  131. LIBBASENAME="libfltk.a"

  132. FLLIBBASENAME="libfltk_forms.a"

  133. GLLIBBASENAME="libfltk_gl.a"

  134. IMGLIBBASENAME="libfltk_images.a"

  135. 

  136. dnl Check for Cairo library unless disabled...

  137. CAIRODIR=""

  138. CAIROFLAGS=""

  139. LINKFLTKCAIRO=""

  140. FLTKCAIROOPTION=""

  141. CAIROLIBS=""

  142. 

  143. AC_ARG_ENABLE(cairoext,[  --enable-cairoext       use fltk code instrumentation for cairo extended use (default=no)])

  144. AC_ARG_ENABLE(cairo,[  --enable-cairo          use lib Cairo  (default=no)])

  145. 

  146. if test x$enable_cairoext = xyes; then

  147. 	  AC_DEFINE(FLTK_USE_CAIRO)

  148. 	  AC_DEFINE(FLTK_HAVE_CAIRO)

  149. 	  dnl FIXME This part should be fixed so configure do not depend on

  150. 	  dnl we do not rely on pkg-config .

  151. 	  CAIRODIR="cairo"

  152.           CAIROFLAGS="`pkg-config --cflags cairo`"

  153.           CAIROLIBS="-lcairo -lpixman-1"

  154.           CXXFLAGS="$CAIROFLAGS $CXXFLAGS"

  155. 	  LIBS="$CAIROLIBS $LIBS" 

  156. 	  dnl $LINKFLTKCAIRO 

  157. 	  LINKFLTK+=" $LINKFLTKCAIRO"

  158. else 

  159.     if test x$enable_cairo = xyes; then

  160. 	  AC_DEFINE(FLTK_HAVE_CAIRO)

  161. 	  dnl FIXME This part should be fixed so configure do not depend on

  162. 	  dnl we do not rely on pkg-config .

  163. 	  CAIRODIR="cairo"

  164.           CAIROFLAGS="`pkg-config --cflags cairo`"

  165.           CAIROLIBS="-lcairo -lpixman-1"

  166.           CXXFLAGS="$CAIROFLAGS $CXXFLAGS"

  167.     fi

  168. fi

  169. 

  170. AC_SUBST(CAIRODIR)

  171. AC_SUBST(CAIROFLAGS)

  172. AC_SUBST(CAIROLIBS)

  173. AC_SUBST(LINKFLTKCAIRO)

  174. AC_SUBST(FLTKCAIROOPTION)

  175. 

  176. 

  177. AC_SUBST(FLLIBNAME)

  178. AC_SUBST(GLDEMOS)

  179. AC_SUBST(GLLIBNAME)

  180. AC_SUBST(IMGLIBNAME)

  181. AC_SUBST(CAIROLIBNAME)

  182. AC_SUBST(LIBEXT)

  183. AC_SUBST(LIBNAME)

  184. AC_SUBST(LINKFLTK)

  185. AC_SUBST(LINKFLTKFORMS)

  186. AC_SUBST(LINKFLTKGL)

  187. AC_SUBST(LINKFLTKIMG)

  188. 

  189. AC_SUBST(LIBBASENAME)

  190. AC_SUBST(FLLIBBASENAME)

  191. AC_SUBST(GLLIBBASENAME)

  192. AC_SUBST(IMGLIBBASENAME)

  193. AC_SUBST(CAIROLIBBASENAME)

  194. 

  195. dnl Handle compile-time options...

  196. AC_ARG_ENABLE(debug, [  --enable-debug          turn on debugging [default=no]])

  197. if test x$enable_debug = xyes; then

  198.     DEBUGFLAG="-g "

  199. else

  200.     DEBUGFLAG=""

  201. fi

  202. 

  203. AC_ARG_ENABLE(cp936, [  --enable-cp936          turn on CP936 [default=no]])

  204. if test x$enable_cp936 = xyes; then

  205.     CFLAGS="$CFLAGS -DCP936"

  206. fi

  207. 

  208. 

  209. AC_ARG_ENABLE(gl, [  --enable-gl             turn on OpenGL support [default=yes]])

  210. 

  211. AC_ARG_ENABLE(shared, [  --enable-shared         turn on shared libraries [default=no]])

  212. if test x$enable_shared = xyes; then

  213.     PICFLAG=1

  214.     SHAREDSUFFIX=""

  215.     FLUID="fluid-shared"

  216. 

  217.     case $uname in

  218. 	Darwin*)

  219.             DSONAME="libfltk.$FL_API_VERSION.dylib"

  220.             FLDSONAME="libfltk_forms.$FL_API_VERSION.dylib"

  221.             GLDSONAME="libfltk_gl.$FL_API_VERSION.dylib"

  222.             IMGDSONAME="libfltk_images.$FL_API_VERSION.dylib"

  223. 	    DSOCOMMAND="\$(CXX) \$(ARCHFLAGS) \$(DSOFLAGS) -dynamiclib -lc -o"

  224. 	    ;;

  225. 

  226. 	SunOS* | UNIX_S*)

  227.             DSONAME="libfltk.so.$FL_API_VERSION"

  228.             FLDSONAME="libfltk_forms.so.$FL_API_VERSION"

  229.             GLDSONAME="libfltk_gl.so.$FL_API_VERSION"

  230.             IMGDSONAME="libfltk_images.so.$FL_API_VERSION"

  231. 	    DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -h \$@ \$(LDLIBS) -G $DEBUGFLAG -o"

  232. 	    if test "x$libdir" != "x/usr/lib"; then

  233. 		    DSOLINK="-R$libdir"

  234.             fi

  235. 	    ;;

  236. 	HP-UX*)

  237.             DSONAME="libfltk.sl.$FL_API_VERSION"

  238.             FLDSONAME="libfltk_forms.sl.$FL_API_VERSION"

  239.             GLDSONAME="libfltk_gl.sl.$FL_API_VERSION"

  240.             IMGDSONAME="libfltk_images.sl.$FL_API_VERSION"

  241. 	    DSOCOMMAND="ld \$(DSOFLAGS) -b -z +h \$@ $DEBUGFLAG -o"

  242. 	    if test "x$libdir" != "x/usr/lib"; then

  243. 		    DSOLINK="-Wl,-rpath,$libdir"

  244.             fi

  245. 	    ;;

  246. 	IRIX*)

  247.             DSONAME="libfltk.so.$FL_API_VERSION"

  248.             FLDSONAME="libfltk_forms.so.$FL_API_VERSION"

  249.             GLDSONAME="libfltk_gl.so.$FL_API_VERSION"

  250.             IMGDSONAME="libfltk_images.so.$FL_API_VERSION"

  251.             DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -Wl,-soname,\$@,-set_version,sgi1.1 \$(LDLIBS) -shared $DEBUGFLAG -o"

  252. 	    if test "x$libdir" != "x/usr/lib" -a "x$libdir" != "x/usr/lib32" -a "x$libdir" != "x/usr/lib64"; then

  253. 		    DSOLINK="-Wl,-rpath,$libdir"

  254.             fi

  255. 	    ;;

  256. 	OSF1*)

  257.             DSONAME="libfltk.so.$FL_API_VERSION"

  258.             FLDSONAME="libfltk_forms.so.$FL_API_VERSION"

  259.             GLDSONAME="libfltk_gl.so.$FL_API_VERSION"

  260.             IMGDSONAME="libfltk_images.so.$FL_API_VERSION"

  261.             DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -Wl,-soname,\$@ \$(LDLIBS) -shared $DEBUGFLAG -o"

  262. 	    if test "x$libdir" != "x/usr/lib" -a "x$libdir" != "x/usr/lib32"; then

  263. 		    DSOLINK="-Wl,-rpath,$libdir"

  264.             fi

  265. 	    ;;

  266. 	Linux* | *BSD*)

  267.             DSONAME="libfltk.so.$FL_API_VERSION"

  268.             FLDSONAME="libfltk_forms.so.$FL_API_VERSION"

  269.             GLDSONAME="libfltk_gl.so.$FL_API_VERSION"

  270.             IMGDSONAME="libfltk_images.so.$FL_API_VERSION"

  271.             DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -Wl,-soname,\$@ \$(LDLIBS) -shared -fPIC $DEBUGFLAG -o"

  272. 	    if test "x$libdir" != "x/usr/lib" -a "x$libdir" != "x/usr/lib64"; then

  273. 		    DSOLINK="-Wl,-rpath,$libdir"

  274.             fi

  275. 	    ;;

  276. 	AIX*)

  277.             DSONAME="libfltk_s.a"

  278.             FLDSONAME="libfltk_forms_s.a"

  279.             GLDSONAME="libfltk_gl_s.a"

  280.             IMGDSONAME="libfltk_images_s.a"

  281.             DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -Wl,-bexpall,-bM:SRE,-bnoentry -o"

  282.             SHAREDSUFFIX="_s"

  283.             ;;

  284.         CYGWIN* | MINGW*)

  285. 	    PICFLAG=0

  286. 	    if test x$enable_cygwin != xyes; then

  287. 		DSONAME="mgwfltknox-$FL_API_VERSION.dll"

  288. 		FLDSONAME="mgwfltknox_forms-$FL_API_VERSION.dll"

  289. 		GLDSONAME="mgwfltknox_gl-$FL_API_VERSION.dll"

  290. 		IMGDSONAME="mgwfltknox_images-$FL_API_VERSION.dll"

  291. 		CAIRODSONAME="mgwfltknox_cairo-$FL_API_VERSION.dll"

  292. 	    else

  293. 		if test x$enable_x11 = xyes; then

  294. 		    DSONAME="cygfltk-$FL_API_VERSION.dll"

  295. 		    FLDSONAME="cygfltk_forms-$FL_API_VERSION.dll"

  296. 		    GLDSONAME="cygfltk_gl-$FL_API_VERSION.dll"

  297. 		    IMGDSONAME="cygfltk_images-$FL_API_VERSION.dll"

  298. 		else

  299. 		    DSONAME="cygfltknox-$FL_API_VERSION.dll"

  300. 		    FLDSONAME="cygfltknox_forms-$FL_API_VERSION.dll"

  301. 		    GLDSONAME="cygfltknox_gl-$FL_API_VERSION.dll"

  302. 		    IMGDSONAME="cygfltknox_images-$FL_API_VERSION.dll"

  303. 		    CAIRODSONAME="cygfltknox_cairo-$FL_API_VERSION.dll"

  304. 		fi

  305. 	    fi

  306. 	    #-----------------------------------------------------------

  307. 	    # -Wl,--enable-runtime-pseudo-reloc: See str 1585

  308. 	    # appears to be necessary for older binutils versions < 2.16

  309. 	    #-----------------------------------------------------------

  310.             LDFLAGS="$LDFLAGS -Wl,--enable-auto-import -Wl,--enable-runtime-pseudo-reloc"

  311. 	    DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -shared \

  312. 	    	-Wl,--whole-archive -Wl,--export-all-symbols \

  313. 		-Wl,--enable-runtime-pseudo-reloc -Wl,--enable-auto-import \

  314. 		-Wl,--enable-auto-image-base -o \$@"

  315. 	    ;;

  316. 	*)

  317.             AC_MSG_WARN(Shared libraries may not be supported.  Trying -shared option with compiler.)

  318.             DSONAME="libfltk.so.$FL_API_VERSION"

  319.             FLDSONAME="libfltk_forms.so.$FL_API_VERSION"

  320.             GLDSONAME="libfltk_gl.so.$FL_API_VERSION"

  321.             IMGDSONAME="libfltk_images.so.$FL_API_VERSION"

  322.             DSOCOMMAND="\$(CXX) \$(DSOFLAGS) -Wl,-soname,\$@ \$(LDLIBS) -shared $DEBUGFLAG -o"

  323. 	    ;;

  324.     esac

  325. 

  326.     LINKSHARED="-L../src $FLTKCAIROOPTION -lfltk_images$SHAREDSUFFIX -lfltk_forms$SHAREDSUFFIX -lfltk$SHAREDSUFFIX"

  327. else

  328.     DSOCOMMAND="echo"

  329.     DSOLINK=""

  330.     DSONAME=""

  331.     FLDSONAME=""

  332.     GLDSONAME=""

  333.     IMGDSONAME=""

  334.     CAIRODSONAME=""

  335.     PICFLAG=0

  336.     SHAREDSUFFIX=""

  337.     FLUID="fluid"

  338.     LINKSHARED="$LINKFLTKCAIRO ../lib/libfltk_images.a ../lib/libfltk_forms.a ../lib/libfltk.a"

  339. fi

  340. 

  341. AC_SUBST(DSOCOMMAND)

  342. AC_SUBST(DSOFLAGS)

  343. AC_SUBST(DSOLINK)

  344. AC_SUBST(DSONAME)

  345. AC_SUBST(FLDSONAME)

  346. AC_SUBST(GLDSONAME)

  347. AC_SUBST(IMGDSONAME)

  348. AC_SUBST(CAIRODSONAME)

  349. AC_SUBST(SHAREDSUFFIX)

  350. AC_SUBST(LINKSHARED)

  351. AC_SUBST(FLUID)

  352. 

  353. AC_ARG_ENABLE(threads, [  --enable-threads        enable multi-threading support (default=yes)])

  354. 

  355. AC_ARG_WITH(optim, [  --with-optim="flags"    use custom optimization flags])

  356. 

  357. AC_ARG_WITH(archflags, [  --with-archflags="flags"

  358.                           use custom architecture flags 

  359. 			  (possible Mac OS X values include -arch i386, -arch x86_64, -arch ppc)],

  360.     ARCHFLAGS="$withval")

  361. case $uname in

  362.     Darwin*)

  363. # QD is not supported anymore since 1.3

  364. 	AC_DEFINE(__APPLE_QUARTZ__)

  365. 	;;

  366. esac

  367. 

  368. dnl Find commands...

  369. AC_PROG_CC

  370. AC_PROG_CXX

  371. AC_PROG_INSTALL

  372. case $uname in

  373.     OSF1*)

  374. 	INSTALL="`pwd`/install-sh -c"

  375. 	;;

  376. esac

  377. if test "$INSTALL" = "$ac_install_sh"; then

  378.     # Use full path to install-sh script...

  379.     INSTALL="`pwd`/install-sh -c"

  380. fi

  381. AC_PATH_PROG(NROFF,nroff)

  382. if test "x$NROFF" = "x:"; then

  383.     # Try groff instead of nroff...

  384.     AC_PATH_PROG(GROFF,groff)

  385.     if test "x$GROFF" = "x:"; then

  386.         NROFF="echo"

  387.     else

  388.         NROFF="$GROFF -T ascii"

  389.     fi

  390. fi

  391. AC_PATH_PROG(HTMLDOC,htmldoc)

  392. AC_PATH_PROG(DOXYDOC,doxygen)

  393. 

  394. dnl How do we make libraries?

  395. AC_PROG_RANLIB

  396. AC_PATH_TOOL(AR, ar)

  397. 

  398. if test "x$AR" = "x:"; then

  399.     AC_MSG_ERROR(Configure could not find the library archiver, aborting.)

  400. fi

  401. 

  402. if test "x$RANLIB" != "x:"; then

  403.     LIBCOMMAND="$AR cr"

  404. else

  405.     LIBCOMMAND="$AR crs"

  406. fi

  407. 

  408. AC_SUBST(LIBCOMMAND)

  409. 

  410. dnl how to compile (Windows) resource files

  411. dnl this will only be used to compile resources for Windows .exe files

  412. AC_PATH_TOOL(RC,windres)

  413. 

  414. dnl Architecture checks...

  415. if test "$uname" != Darwin; then

  416.   AC_C_BIGENDIAN

  417. fi

  418. 

  419. AC_CHECK_SIZEOF(short, 2)

  420. AC_CHECK_SIZEOF(int, 4)

  421. AC_CHECK_SIZEOF(long, 4)

  422. if test $ac_cv_sizeof_short -eq 2; then

  423.     AC_DEFINE(U16,unsigned short)

  424. fi

  425. if test $ac_cv_sizeof_int -eq 4; then

  426.     AC_DEFINE(U32,unsigned)

  427. else

  428.     if test $ac_cv_sizeof_long -eq 4; then

  429.         AC_DEFINE(U32,unsigned long)

  430.     fi

  431. fi

  432. if test "$uname" != Darwin; then

  433. 	if test $ac_cv_sizeof_int -eq 8; then

  434. 		AC_DEFINE(U64,unsigned)

  435. 	else

  436. 		if test $ac_cv_sizeof_long -eq 8; then

  437. 			AC_DEFINE(U64,unsigned long)

  438. 		fi

  439. 	fi

  440. fi

  441. 

  442. dnl Does the C++ compiler support the bool type?

  443. AC_CACHE_CHECK(whether the compiler recognizes bool as a built-in type,

  444.     ac_cv_cxx_bool,[

  445. 	AC_LANG_SAVE

  446. 	AC_LANG_CPLUSPLUS

  447. 	AC_TRY_COMPILE([

  448. 	    int f(int  x){return 1;}

  449. 	    int f(char x){return 1;}

  450. 	    int f(bool x){return 1;}

  451. 	],[

  452. 	    bool b = true;

  453. 	    return f(b);

  454. 	], ac_cv_cxx_bool=yes, ac_cv_cxx_bool=no)

  455. 	AC_LANG_RESTORE

  456.     ])

  457. 

  458. if test "$ac_cv_cxx_bool" != yes; then

  459.     CXXFLAGS="-Dbool=char -Dfalse=0 -Dtrue=1 $CXXFLAGS"

  460. fi

  461. 

  462. dnl Standard headers and functions...

  463. AC_HEADER_DIRENT

  464. AC_CHECK_HEADER(sys/select.h,AC_DEFINE(HAVE_SYS_SELECT_H))

  465. AC_CHECK_HEADER(sys/stdtypes.h,AC_DEFINE(HAVE_SYS_SELECT_H))

  466. 

  467. dnl Do we have the POSIX compatible scandir() prototype?

  468. AC_CACHE_CHECK([whether we have the POSIX compatible scandir() prototype],

  469.     ac_cv_cxx_scandir_posix,[

  470. 	AC_LANG_SAVE

  471. 	AC_LANG_CPLUSPLUS

  472. 	AC_TRY_COMPILE([

  473. 	  #include <dirent.h>

  474. 	  int func (const char *d, dirent ***list, void *sort) {

  475. 	    int n = scandir(d, list, 0, (int(*)(const dirent **, const dirent **))sort);

  476. 	  }

  477. 	],[

  478. 	], ac_cv_cxx_scandir_posix=yes, ac_cv_cxx_scandir_posix=no)

  479. 	AC_LANG_RESTORE

  480.     ])

  481. 

  482. dnl Define both HAVE_SCANDIR... macros, if the POSIX compatible function is

  483. dnl available. Otherwise: check, whether any scandir prototype is available,

  484. dnl but don't use it on SunOS and QNX because of an incompatibility in pre-Y2K

  485. dnl SunOS scandir versions. We assume, though, that the POSIX compatible

  486. dnl version on newer SunOS/Solaris versions works as expected.

  487. if test "$ac_cv_cxx_scandir_posix" = yes; then

  488.     AC_DEFINE(HAVE_SCANDIR)

  489.     AC_DEFINE(HAVE_SCANDIR_POSIX)

  490. else

  491.     AC_CHECK_FUNC(scandir,

  492. 	if test "x$uname" = xSunOS -o "x$uname" = xQNX; then

  493.             AC_MSG_WARN(Not using $uname scandir emulation function.)

  494. 	else

  495.             AC_DEFINE(HAVE_SCANDIR)

  496.         fi)

  497. fi

  498. 

  499. AC_CHECK_FUNC(vsnprintf,[

  500.     case "$uname" in

  501.     	HP-UX*)

  502. 	    if test "$uversion" = "1020"; then

  503. 	        AC_MSG_WARN(Not using built-in vsnprintf function because you are running HP-UX 10.20.)

  504. 	    else

  505.         	AC_DEFINE(HAVE_VSNPRINTF)

  506. 	    fi

  507. 	    ;;

  508. 

  509.     	OSF1*)

  510. 	    if test "$uversion" = "40"; then

  511.                 AC_MSG_WARN(Not using built-in vsnprintf function because you are running Tru64 4.0.)

  512. 	    else

  513.         	AC_DEFINE(HAVE_VSNPRINTF)

  514. 	    fi

  515. 	    ;;

  516. 

  517.         *)

  518.             AC_DEFINE(HAVE_VSNPRINTF)

  519. 	    ;;

  520.     esac])

  521. AC_CHECK_FUNC(snprintf,[

  522.     case "$uname" in

  523.     	HP-UX*)

  524. 	    if test "$uversion" = "1020"; then

  525. 	        AC_MSG_WARN(Not using built-in snprintf function because you are running HP-UX 10.20.)

  526. 	    else

  527.         	AC_DEFINE(HAVE_SNPRINTF)

  528. 	    fi

  529. 	    ;;

  530. 

  531.     	OSF1*)

  532. 	    if test "$uversion" = "40"; then

  533.                 AC_MSG_WARN(Not using built-in snprintf function because you are running Tru64 4.0.)

  534. 	    else

  535.         	AC_DEFINE(HAVE_SNPRINTF)

  536. 	    fi

  537. 	    ;;

  538. 

  539.         *)

  540.             AC_DEFINE(HAVE_SNPRINTF)

  541. 	    ;;

  542.     esac])

  543. AC_CHECK_HEADER(strings.h, AC_DEFINE(HAVE_STRINGS_H))

  544. AC_CHECK_FUNCS(strcasecmp strlcat strlcpy)

  545. 

  546. AC_CHECK_HEADER(locale.h, AC_DEFINE(HAVE_LOCALE_H))

  547. AC_CHECK_FUNCS(localeconv)

  548. 

  549. dnl FLTK library uses math library functions...

  550. AC_SEARCH_LIBS(pow, m)

  551. 

  552. dnl Check for largefile support...

  553. AC_SYS_LARGEFILE

  554. 

  555. dnl Define largefile options as needed...

  556. LARGEFILE=""

  557. if test x$enable_largefile != xno; then

  558. 	LARGEFILE="-D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"

  559. 

  560. 	if test x$ac_cv_sys_large_files = x1; then

  561. 		LARGEFILE="$LARGEFILE -D_LARGE_FILES"

  562. 	fi

  563. 

  564. 	if test x$ac_cv_sys_file_offset_bits = x64; then

  565. 		LARGEFILE="$LARGEFILE -D_FILE_OFFSET_BITS=64"

  566. 	fi

  567. fi

  568. AC_SUBST(LARGEFILE)

  569. 

  570. dnl Check for "long long" support...

  571. AC_CACHE_CHECK(for long long int, ac_cv_c_long_long,

  572. 	[if test "$GCC" = yes; then

  573. 		ac_cv_c_long_long=yes

  574. 	else

  575. 		AC_TRY_COMPILE(,[long long int i;],

  576. 			ac_cv_c_long_long=yes,

  577. 			ac_cv_c_long_long=no)

  578. 	fi])

  579. 

  580. if test $ac_cv_c_long_long = yes; then

  581. 	AC_DEFINE(HAVE_LONG_LONG)

  582. fi

  583. 

  584. AC_CHECK_FUNC(strtoll, AC_DEFINE(HAVE_STRTOLL))

  585. 

  586. dnl Check for dlopen/dlsym...

  587. AC_SEARCH_LIBS(dlsym, dl, AC_DEFINE(HAVE_DLSYM))

  588. AC_CHECK_HEADER(dlfcn.h, AC_DEFINE(HAVE_DLFCN_H))

  589. 

  590. dnl Check for audio libraries...

  591. AUDIOLIBS=""

  592. 

  593. case $uname in

  594.     CYGWIN* | MINGW*)

  595. 	dnl Cygwin environment...

  596. 	AUDIOLIBS="-lwinmm"

  597. 	;;

  598. 

  599.     Darwin*)

  600. 	AUDIOLIBS="-framework CoreAudio"

  601. 	;;

  602. 

  603.     *)

  604. 	AC_CHECK_HEADER(alsa/asoundlib.h,

  605. 	    AC_DEFINE(HAVE_ALSA_ASOUNDLIB_H)

  606. 	    AUDIOLIBS="-lasound")

  607.         ;;

  608. esac

  609. 

  610. AC_SUBST(AUDIOLIBS)

  611. 

  612. dnl Check for image libraries...

  613. SAVELIBS="$LIBS"

  614. IMAGELIBS=""

  615. STATICIMAGELIBS=""

  616. 

  617. AC_SUBST(IMAGELIBS)

  618. AC_SUBST(STATICIMAGELIBS)

  619. 

  620. # Handle the JPEG lib linking mode (use fltk local or system lib)

  621. # If --enable-(resp. --disable-)localjpeg parameter is not set by user

  622. # Then we check the JPEG lib usability, with result in sysjpeglib_ok variable

  623. AC_ARG_ENABLE(localjpeg, [  --enable-localjpeg      use local JPEG library, default=auto])

  624. # Check for System lib use if automatic mode or --disable-localjpeg is requested

  625. sysjpeglib_ok=no

  626. sysjpeginc_ok=no

  627. if test x$enable_localjpeg != xyes; then

  628.     AC_CHECK_LIB(jpeg,jpeg_CreateCompress,

  629. 	[AC_CHECK_HEADER(jpeglib.h,

  630. 	    sysjpeginc_ok=yes)

  631. 	    if test x$sysjpeginc_ok = xyes; then

  632. 		sysjpeglib_ok=yes

  633. 		fi])

  634. fi

  635. # Now set the jpeg lib and include flags according to the requested mode and availability 

  636. if test x$enable_localjpeg = xyes -o x$sysjpeglib_ok = xno; then

  637.     JPEGINC="-I../jpeg"

  638.     JPEG="jpeg"

  639.     IMAGELIBS="-lfltk_jpeg $IMAGELIBS"

  640.     STATICIMAGELIBS="\$libdir/libfltk_jpeg.a $STATICIMAGELIBS"

  641.     AC_DEFINE(HAVE_LIBJPEG)

  642.     #ac_cv_lib_jpeg_jpeg_CreateCompress=no # from ima: should not be necessary

  643.     # Finally, warn user if system lib was requested but not found

  644.     if test x$enable_localjpeg = xno; then

  645. 	AC_MSG_WARN(Cannot find system jpeg lib or header: choosing the local lib mode.)

  646.     fi

  647. else

  648.     JPEGINC=""

  649.     JPEG=""

  650.     IMAGELIBS="-ljpeg $IMAGELIBS"

  651.     STATICIMAGELIBS="-ljpeg $STATICIMAGELIBS"

  652.     AC_DEFINE(HAVE_LIBJPEG)

  653. fi

  654. 

  655. # Handle the ZLIB lib linking mode (use fltk local or system lib)

  656. # If --enable-(resp. --disable-)localzlib parameter is not set by user

  657. # Then we check the ZLIB lib usability, with result in syszlib_ok variable

  658. AC_ARG_ENABLE(localzlib, [  --enable-localzlib      use local ZLIB library, default=auto])

  659. # Check for System lib use if automatic mode or --disable-localzlib is requested

  660. syszlib_ok=no

  661. syszinc_ok=no

  662. if test x$enable_localzlib != xyes; then

  663.     AC_CHECK_LIB(z,gzgets,

  664. 	[AC_CHECK_HEADER(zlib.h, 

  665. 		syszinc_ok=yes)

  666. 	if test x$syszinc_ok = xyes; then

  667. 	    syszlib_ok=yes

  668. 	    fi])

  669. fi

  670. # Now set the Z lib and include flags according to the requested mode and availability 

  671. if test x$enable_localzlib = xyes -o x$syszlib_ok = xno ; then

  672.     ZLIBINC="-I../zlib"

  673.     ZLIB="zlib"

  674.     LIBS="-lfltk_z $LIBS"

  675.     IMAGELIBS="-lfltk_z $IMAGELIBS"

  676.     STATICIMAGELIBS="\$libdir/libfltk_z.a $STATICIMAGELIBS"

  677.     AC_DEFINE(HAVE_LIBZ)

  678.     ac_cv_lib_z_gzgets=no # fc: is still necessary ?

  679.     # Finally, warn user if system lib was requested but not found

  680.     if test x$enable_localzlib = xno; then

  681. 	AC_MSG_WARN(Cannot find system z lib or header: choosing the local lib mode.)

  682.     fi

  683. else

  684.     ZLIBINC=""

  685.     ZLIB=""

  686.     LIBS="-lz $LIBS"

  687.     IMAGELIBS="-lz $IMAGELIBS"

  688.     STATICIMAGELIBS="-lz $STATICIMAGELIBS"

  689.     AC_DEFINE(HAVE_LIBZ)

  690. fi

  691. 

  692. # Handle the PNG lib linking mode (use fltk local or system lib)

  693. # If --enable-(resp. --disable-)localpng parameter is not set by user

  694. # Then we check the png lib usability with result in syspng_lib variable

  695. AC_ARG_ENABLE(localpng, [  --enable-localpng       use local PNG library, default=auto])

  696. 

  697. # Now check if system lib is usable, we check Lib AND include availability with inc variant,

  698. # but only, if the builtin lib is not requested

  699. syspnglib_ok=no

  700. syspnginc_ok=no

  701. if test x$enable_localpng != xyes; then

  702.   AC_CHECK_LIB(png, png_read_info, 

  703.     [AC_CHECK_HEADER(png.h, 

  704. 	AC_DEFINE(HAVE_PNG_H)

  705. 	syspnginc_ok=yes)

  706.     AC_CHECK_HEADER(libpng/png.h, 

  707. 	AC_DEFINE(HAVE_LIBPNG_PNG_H)

  708. 	syspnginc_ok=yes)

  709.     if test x$syspnginc_ok = xyes; then

  710. 	syspnglib_ok=yes

  711.     fi])

  712. fi

  713. 

  714. # The following is executed if the lib was not found usable or if local lib is required explicitly

  715. if test x$enable_localpng = xyes -o x$syspnglib_ok = xno ; then

  716.     PNGINC="-I../png"

  717.     PNG="png"

  718.     IMAGELIBS="-lfltk_png $IMAGELIBS"

  719.     STATICIMAGELIBS="\$libdir/libfltk_png.a $STATICIMAGELIBS"

  720.     AC_DEFINE(HAVE_LIBPNG)

  721.     AC_DEFINE(HAVE_PNG_H)

  722.     AC_DEFINE(HAVE_PNG_GET_VALID)

  723.     AC_DEFINE(HAVE_PNG_SET_TRNS_TO_ALPHA)

  724.     # Finally, warn user if system lib was requested but not found

  725.     if test x$enable_localpng = xno; then

  726. 	AC_MSG_WARN(Cannot find system png lib or header: choosing the local lib mode.)

  727.     fi

  728. else

  729.     PNGINC=""

  730.     PNG=""

  731.     IMAGELIBS="-lpng $IMAGELIBS"

  732.     STATICIMAGELIBS="-lpng $STATICIMAGELIBS"

  733.     AC_DEFINE(HAVE_LIBPNG)

  734.     AC_CHECK_LIB(png,png_get_valid, AC_DEFINE(HAVE_PNG_GET_VALID))

  735.     AC_CHECK_LIB(png,png_set_tRNS_to_alpha, AC_DEFINE(HAVE_PNG_SET_TRNS_TO_ALPHA))

  736. fi

  737. 

  738. AC_SUBST(JPEG)

  739. AC_SUBST(JPEGINC)

  740. AC_SUBST(PNG)

  741. AC_SUBST(PNGINC)

  742. AC_SUBST(ZLIB)

  743. AC_SUBST(ZLIBINC)

  744. 

  745. dnl Restore original LIBS settings...

  746. LIBS="$SAVELIBS"

  747. 

  748. dnl See if we need a .exe extension on executables...

  749. AC_EXEEXT

  750. 

  751. dnl Check for pthreads for multi-threaded apps...

  752. have_pthread=no

  753. PTHREAD_FLAGS=""

  754. 

  755. dnl Test whether we want to check for pthreads. We must not do it on Windows

  756. dnl unless we run under Cygwin with --enable-cygwin, since we always use

  757. dnl native threads on Windows (even if libpthread is available)

  758. check_pthread=yes

  759. case $uname in

  760.     MINGW*)

  761. 	check_pthread=no

  762. 	;;

  763.     CYGWIN*)

  764. 	if test "x$enable_cygwin" != xyes; then

  765. 	    check_pthread=no

  766. 	fi

  767. 	;;

  768.     *)

  769. 	;;

  770. esac

  771. 

  772. if test "x$enable_threads" != xno -a x$check_pthread = xyes; then

  773.     AC_CHECK_HEADER(pthread.h, AC_DEFINE(HAVE_PTHREAD_H))

  774. 

  775.     if test x$ac_cv_header_pthread_h = xyes; then

  776. 	dnl Check various threading options for the platforms we support

  777. 	for flag in -lpthreads -lpthread -pthread; do

  778.             AC_MSG_CHECKING([for pthread_create using $flag])

  779. 	    SAVELIBS="$LIBS"

  780. 	    LIBS="$flag $LIBS"

  781.             AC_TRY_LINK([#include <pthread.h>],

  782. 		[pthread_create(0, 0, 0, 0);],

  783.         	have_pthread=yes,

  784. 		LIBS="$SAVELIBS")

  785.             AC_MSG_RESULT([$have_pthread])

  786. 

  787. 	    if test $have_pthread = yes; then

  788. 	        AC_DEFINE(HAVE_PTHREAD)

  789. 		PTHREAD_FLAGS="-D_THREAD_SAFE -D_REENTRANT"

  790. 

  791. 		# Solaris requires -D_POSIX_PTHREAD_SEMANTICS to

  792. 		# be POSIX-compliant... :(

  793. 		if test $uname = SunOS; then

  794. 		    PTHREAD_FLAGS="$PTHREAD_FLAGS -D_POSIX_PTHREAD_SEMANTICS"

  795. 		fi

  796. 		break

  797. 	    fi

  798. 	done

  799.     fi

  800. fi

  801. 

  802. AC_SUBST(PTHREAD_FLAGS)

  803. 

  804. dnl Define OS-specific stuff...

  805. HLINKS=

  806. OSX_ONLY=:

  807. THREADS=

  808. 

  809. AC_ARG_WITH(links, [  --with-links            make header links for common misspellings (default=no)])

  810. 

  811. INSTALL_DESKTOP=""

  812. UNINSTALL_DESKTOP=""

  813. 

  814. case $uname_GUI in

  815.     CYGWIN* | MINGW*)

  816. 	dnl Cygwin environment, using windows GDI ...

  817. 	# Recent versions of Cygwin are seriously broken and the size

  818. 	# checks don't work because the shell puts out \r\n instead of

  819. 	# \n.  Here we just force U32 to be defined to "unsigned"...

  820.         AC_DEFINE(U32,unsigned)

  821. 	CFLAGS="-mwindows -DWIN32 -DUSE_OPENGL32 $CFLAGS"

  822. 	CXXFLAGS="-mwindows -DWIN32 -DUSE_OPENGL32 $CXXFLAGS"

  823. 	LDFLAGS="-mwindows $LDFLAGS"

  824. 	DSOFLAGS="-mwindows $DSOFLAGS"

  825. 	LIBS="$LIBS -lole32 -luuid -lcomctl32"

  826. 	if test "x$with_optim" = x; then

  827. 	    dnl Avoid -Os optimization on Cygwin/MinGW

  828. 	    with_optim="-O3"

  829. 	fi

  830. 

  831. 	if test x$enable_gl != xno; then

  832. 	    AC_CHECK_HEADER(GL/gl.h,

  833. 	        AC_DEFINE(HAVE_GL)

  834. 		GLLIB="-lopengl32")

  835. 	    AC_CHECK_HEADER(GL/glu.h,

  836.         	AC_DEFINE(HAVE_GL_GLU_H)

  837. 		GLLIB="-lglu32 $GLLIB")

  838. 	else

  839. 	    LINKFLTKGL=""

  840. 	    GLLIBNAME=""

  841. 	    GLDSONAME=""

  842. 	    GLDEMOS=""

  843. 	fi

  844. 

  845. 	if test "x$enable_threads" != xno; then

  846. 	    if test x$have_pthread = xyes; then

  847. 		AC_DEFINE(HAVE_PTHREAD)

  848. 	    fi

  849.         fi

  850. 

  851. 	THREADS="threads$EXEEXT"

  852. 

  853. 	# Don't make symlinks since Windows is not case sensitive.

  854. 	if test "x$with_links" != xyes; then

  855. 		HLINKS="#"

  856. 	fi

  857. 	;;

  858. 

  859.     Darwin*)

  860.         # MacOS X uses Cocoa for graphics.

  861.         LIBS="$LIBS -framework Cocoa"

  862. 

  863. 	if test x$have_pthread = xyes; then

  864. 	    AC_DEFINE(HAVE_PTHREAD)

  865. 	    THREADS="threads$EXEEXT"

  866. 	fi

  867. 

  868. 	if test x$enable_gl != xno; then

  869.             AC_DEFINE(HAVE_GL)

  870.             AC_DEFINE(HAVE_GL_GLU_H)

  871.             GLLIB="-framework AGL -framework OpenGL -framework ApplicationServices"

  872.         else

  873. 	    LINKFLTKGL=""

  874. 	    GLLIBNAME=""

  875. 	    GLDSONAME=""

  876. 	    GLDEMOS=""

  877.         fi

  878. 

  879. 	# Don't make symlinks because HFS+ is not case sensitive...

  880. 	if test "x$with_links" != xyes; then

  881. 		HLINKS="#"

  882. 	fi

  883. 

  884. 	# Some steps are only done for OS X package management

  885. 	OSX_ONLY=

  886. 

  887. 	# Install/Uninstall FLUID application

  888. 	INSTALL_DESKTOP="install-osx"

  889. 	UNINSTALL_DESKTOP="uninstall-osx"

  890. 	;;

  891. 

  892.     *)

  893. 	# All others are UNIX/X11...

  894. 	# This includes Cygwin target combined with X11

  895. 	if test x$have_pthread = xyes; then

  896. 	    AC_DEFINE(HAVE_PTHREAD)

  897. 	    THREADS="threads$EXEEXT"

  898. 	fi

  899. 

  900. 	dnl Check for X11...

  901. 	AC_PATH_XTRA

  902. 

  903. 	if test x$no_x = xyes; then

  904. 	    AC_MSG_ERROR(Configure could not find required X11 libraries, aborting.)

  905. 	fi

  906. 

  907. 	if test "x$X_PRE_LIBS" != x; then

  908. 	    AC_MSG_WARN(Ignoring libraries \"$X_PRE_LIBS\" requested by configure.)

  909. 	fi

  910. 

  911. 	LIBS="$LIBS -lX11 $X_EXTRA_LIBS"

  912. 	CFLAGS="$CFLAGS $X_CFLAGS"

  913. 	CXXFLAGS="$CXXFLAGS $X_CFLAGS"

  914. 	LDFLAGS="$X_LIBS $LDFLAGS"

  915. 	DSOFLAGS="$X_LIBS $DSOFLAGS"

  916. 	AC_DEFINE(USE_X11)

  917. 	if test "x$x_includes" != x; then

  918. 	    ac_cpp="$ac_cpp -I$x_includes"

  919. 	fi

  920. 

  921. 	dnl Check for OpenGL unless disabled...

  922. 	GLLIB=

  923. 

  924. 	if test x$enable_gl != xno; then

  925. 	    AC_SEARCH_LIBS(dlopen, dl)

  926. 	    AC_CHECK_HEADER(GL/gl.h,

  927. 		AC_CHECK_LIB(GL, glXMakeCurrent, AC_DEFINE(HAVE_GL) GLLIB="-lGL",

  928. 		    AC_CHECK_LIB(MesaGL,glXMakeCurrent, AC_DEFINE(HAVE_GL) GLLIB=" -lMesaGL",,

  929. 			-lm),

  930. 		    -lm)

  931. 		AC_CHECK_LIB(GL, glXGetProcAddressARB,

  932. 		             AC_DEFINE(HAVE_GLXGETPROCADDRESSARB),, -lm)

  933. 	    )

  934. 	    AC_CHECK_HEADER(GL/glu.h,

  935.         	AC_DEFINE(HAVE_GL_GLU_H)

  936. 		if test x$ac_cv_lib_GL_glXMakeCurrent = xyes; then

  937. 		    GLLIB="-lGLU $GLLIB"

  938. 		fi

  939. 		if test x$ac_cv_lib_MesaGL_glXMakeCurrent = xyes; then

  940. 		    GLLIB="-lMesaGLU $GLLIB"

  941. 		fi

  942. 	    )

  943. 

  944. 	    if test x$ac_cv_lib_GL_glXMakeCurrent != xyes -a x$ac_cv_lib_MesaGL_glXMakeCurrent != xyes; then

  945. 		    LINKFLTKGL=""

  946. 		    GLLIBNAME=""

  947. 		    GLDSONAME=""

  948. 		    GLDEMOS=""

  949. 	    fi

  950. 	else

  951. 	    LINKFLTKGL=""

  952. 	    GLLIBNAME=""

  953. 	    GLDSONAME=""

  954. 	    GLDEMOS=""

  955. 	fi

  956. 

  957. 	dnl Check for Xinerama support unless disabled...

  958.         AC_ARG_ENABLE(xinerama, [  --enable-xinerama       turn on Xinerama support [default=yes]])

  959. 

  960. 	if test x$enable_xinerama != xno; then

  961. 	    AC_CHECK_LIB(Xinerama,XineramaIsActive,

  962. 		    AC_DEFINE(HAVE_XINERAMA)

  963. 		    LIBS="-lXinerama $LIBS")

  964. 	fi

  965. 

  966. 	dnl Check for the Xft library unless disabled...

  967.         AC_ARG_ENABLE(xft, [  --enable-xft            turn on Xft support [default=yes]])

  968. 

  969. 	if test x$enable_xft != xno; then

  970.             AC_PATH_PROG(FTCONFIG,freetype-config)

  971. 

  972. 	    if test "x$FTCONFIG" != x; then

  973. 	        CPPFLAGS="`$FTCONFIG --cflags` $CPPFLAGS"

  974. 	        CXXFLAGS="`$FTCONFIG --cflags` $CXXFLAGS"

  975. 

  976. 	        AC_CHECK_LIB(fontconfig, FcPatternCreate)

  977. 		AC_CHECK_HEADER(X11/Xft/Xft.h,

  978. 		    AC_CHECK_LIB(Xft, XftDrawCreate,

  979. 			AC_DEFINE(USE_XFT)

  980. 			LIBS="-lXft $LIBS"))

  981. 	    fi

  982. 	fi

  983. 

  984. 	dnl Check for overlay visuals...

  985. 	AC_PATH_PROG(XPROP, xprop)

  986. 	AC_CACHE_CHECK(for X overlay visuals, ac_cv_have_overlay,

  987. 	    if test "x$XPROP" != x; then

  988. 		if $XPROP -root 2>/dev/null | grep -c "SERVER_OVERLAY_VISUALS" >/dev/null; then

  989.         	    ac_cv_have_overlay=yes

  990. 		else

  991.         	    ac_cv_have_overlay=no

  992. 		fi

  993. 	    else

  994.         	ac_cv_have_overlay=no

  995. 	    fi)

  996. 

  997.         if test x$ac_cv_have_overlay = xyes; then

  998. 	    AC_DEFINE(HAVE_OVERLAY)

  999. 	fi

  1000. 

  1001. 	# Make symlinks since UNIX/Linux is case sensitive,

  1002. 	# but Cygwin in general not.

  1003. 	case $uname in

  1004. 	    CYGWIN*)

  1005. 		HLINKS="#"

  1006. 	    ;;

  1007. 	    *)

  1008. 	    ;;

  1009. 	esac

  1010. 	# Make symlinks since UNIX/Linux is case sensitive,

  1011. 	# but only if explicitly configured (default=no)

  1012. 	if test "x$with_links" != xyes; then

  1013. 		HLINKS="#"

  1014. 	fi

  1015. 

  1016. 	# Install/Uninstall FLUID application support files

  1017. 	INSTALL_DESKTOP="install-linux"

  1018. 	UNINSTALL_DESKTOP="uninstall-linux"

  1019. 	;;

  1020. esac

  1021. 

  1022. AC_SUBST(GLDEMOS)

  1023. AC_SUBST(GLLIB)

  1024. AC_SUBST(HLINKS)

  1025. AC_SUBST(OSX_ONLY)

  1026. AC_SUBST(THREADS)

  1027. 

  1028. AC_SUBST(INSTALL_DESKTOP)

  1029. AC_SUBST(UNINSTALL_DESKTOP)

  1030. 

  1031. dnl Figure out the appropriate formatted man page extension...

  1032. case "$uname" in

  1033.     *BSD* | Darwin*)

  1034. 	# *BSD

  1035. 	CAT1EXT=0

  1036. 	CAT3EXT=0

  1037. 	CAT6EXT=0

  1038. 	;;

  1039.     IRIX*)

  1040. 	# SGI IRIX

  1041. 	CAT1EXT=z

  1042. 	CAT3EXT=z

  1043. 	CAT6EXT=z

  1044. 	;;

  1045.     *)

  1046. 	# All others

  1047. 	CAT1EXT=1

  1048. 	CAT3EXT=3

  1049. 	CAT6EXT=6

  1050. 	;;

  1051. esac

  1052. 

  1053. AC_SUBST(CAT1EXT)

  1054. AC_SUBST(CAT3EXT)

  1055. AC_SUBST(CAT6EXT)

  1056. 

  1057. dnl Fix "mandir" variable...

  1058. if test "$mandir" = "\${prefix}/man" -a "$prefix" = "/usr"; then

  1059.     case "$uname" in

  1060.         *BSD* | Darwin* | Linux*)

  1061.             # *BSD, Darwin, and Linux

  1062.             mandir="\${prefix}/share/man"

  1063.             ;;

  1064.         IRIX*)

  1065.             # SGI IRIX

  1066.             mandir="\${prefix}/share/catman"

  1067.             ;;

  1068.     esac

  1069. fi

  1070. 

  1071. dnl Fix "libdir" variable...

  1072. if test "$prefix" = NONE; then

  1073.     prefix=/usr/local

  1074. fi

  1075. 

  1076. if test "$exec_prefix" = NONE; then

  1077.     exec_prefix="\${prefix}"

  1078. fi

  1079. 

  1080. if test "$uname" = "IRIX" -a $uversion -ge 62 -a "$libdir" = "\${exec_prefix}/lib" -a "$exec_prefix" = "\${prefix}" -a "$prefix" = "/usr"; then

  1081.     libdir="/usr/lib32"

  1082. fi

  1083. 

  1084. dnl Define the command used to update the dependencies (this option

  1085. dnl mainly for FLTK core developers - not necessary for users)

  1086. MAKEDEPEND="\$(CXX) -M"

  1087. AC_SUBST(MAKEDEPEND)

  1088. 

  1089. dnl Add warnings to compiler switches:

  1090. dnl do this last so messing with switches does not break tests

  1091. 

  1092. if test -n "$GCC"; then

  1093.     # Show all standard warnings + unused variables, conversion errors,

  1094.     # and inlining problems when compiling...

  1095.     OPTIM="-Wall -Wunused -Wno-format-y2k $OPTIM"

  1096. 

  1097.     # The following additional warnings are useful for tracking down problems...

  1098.     #OPTIM="-Wshadow -Wconversion $OPTIM"

  1099. 

  1100.     # We know that Carbon is deprecated on OS X 10.4. To avoid hundreds of warnings

  1101.     # we will temporarily disable 'deprecated' warnings on OS X.

  1102.     if test "$uname" = "Darwin" -a $uversion -ge 800; then

  1103.         OPTIM="-Wno-deprecated-declarations $OPTIM"

  1104.     fi

  1105. 

  1106.     # Set the default compiler optimizations...

  1107.     if test -z "$DEBUGFLAG"; then

  1108.     	#

  1109. 	# Note: Can't use -fomit-frame-pointer - prevents tools like

  1110. 	#       libsafe from working!

  1111.         #

  1112. 	#       Don't use -fforce-mem, -fforce-addr, or -fcaller-saves.

  1113. 	#       They all seem to make either no difference or enlarge

  1114. 	#       the code by a few hundred bytes.

  1115.         #

  1116. 	#       "-Os" seems to be the best compromise between speed and

  1117. 	#       code size.  "-O3" and higher seem to make no effective

  1118. 	#       difference in the speed of the code, but does bloat the

  1119. 	#       library 10+%.

  1120. 	#

  1121. 

  1122.         if test "x$with_optim" != x; then

  1123. 	    OPTIM="$with_optim $OPTIM"

  1124. 	else

  1125.             OPTIM="-Os $OPTIM"

  1126. 	fi

  1127.     fi

  1128. 

  1129.     # Generate position-independent code when needed...

  1130.     if test $PICFLAG = 1; then

  1131.     	OPTIM="$OPTIM -fPIC"

  1132.     fi

  1133. 

  1134.     # See if GCC supports -fno-exceptions...

  1135.     AC_MSG_CHECKING(if GCC supports -fno-exceptions)

  1136.     OLDCFLAGS="$CFLAGS"

  1137.     CFLAGS="$CFLAGS -fno-exceptions"

  1138.     AC_TRY_COMPILE(,,

  1139. 	OPTIM="$OPTIM -fno-exceptions"

  1140. 	AC_MSG_RESULT(yes),

  1141. 	AC_MSG_RESULT(no))

  1142.     CFLAGS="$OLDCFLAGS"

  1143. 

  1144.     # See if GCC supports -fno-strict-aliasing...

  1145.     AC_MSG_CHECKING(if GCC supports -fno-strict-aliasing)

  1146.     OLDCFLAGS="$CFLAGS"

  1147.     CFLAGS="$CFLAGS -fno-strict-aliasing"

  1148.     AC_TRY_COMPILE(,,

  1149. 	OPTIM="$OPTIM -fno-strict-aliasing"

  1150. 	AC_MSG_RESULT(yes),

  1151. 	AC_MSG_RESULT(no))

  1152.     CFLAGS="$OLDCFLAGS"

  1153. 

  1154.     # See if we are running Solaris; if so, try the -fpermissive option...

  1155.     # This option is required on some versions of Solaris to work around

  1156.     # bugs in the X headers up through Solaris 7.

  1157.     #

  1158.     # Unlike the other compiler/optimization settings, this one is placed

  1159.     # in CFLAGS and CXXFLAGS so that fltk-config will provide the option

  1160.     # to clients - otherwise client apps will not compile properly...

  1161.     if test "$uname" = SunOS; then

  1162. 	AC_MSG_CHECKING(if GCC supports -fpermissive)

  1163. 

  1164. 	OLDCFLAGS="$CFLAGS"

  1165. 	CFLAGS="$CFLAGS -fpermissive"

  1166. 	AC_TRY_COMPILE(,,

  1167. 	    CXXFLAGS="$CXXFLAGS -fpermissive"

  1168. 	    AC_MSG_RESULT(yes),

  1169. 	    CFLAGS="$OLDCFLAGS"

  1170. 	    AC_MSG_RESULT(no))

  1171.     fi

  1172. else

  1173.     case "$uname" in

  1174.         IRIX*)

  1175. 	    # Running some flavor of IRIX; see which version and

  1176. 	    # set things up according...

  1177. 	    if test "$uversion" -ge 62; then

  1178. 	        # We are running IRIX 6.2 or higher; uncomment the following

  1179. 		# lines if you don't have IDO 7.2 or higher:

  1180. 		#

  1181. 		#     CXX="CC -n32 -mips3"

  1182. 		#     CC="cc -n32 -mips3"

  1183. 		#     LD="ld -n32 -mips3"

  1184. 		#     MAKEDEPEND="CC -M"

  1185. 

  1186. 		if test "x`grep abi=n32 /etc/compiler.defaults`" = x; then

  1187. 			AC_MSG_WARN(FOR BEST RESULTS BEFORE COMPILING: setenv SGI_ABI \"-n32 -mips3\")

  1188. 		fi

  1189. 

  1190.         	OPTIM="-fullwarn $OPTIM"

  1191. 	    fi

  1192. 	    if test -z "$DEBUGFLAG"; then

  1193.         	if test "x$with_optim" != x; then

  1194. 		    OPTIM="$with_optim $OPTIM"

  1195. 		else

  1196.         	    OPTIM="-O2 $OPTIM"

  1197. 		    if test $uversion -gt 62; then

  1198.         	        OPTIM="-OPT:Olimit=4000 $OPTIM"

  1199. 	            fi

  1200. 		fi

  1201. 	    fi

  1202. 	    ;;

  1203. 	HP-UX*)

  1204. 	    # Running HP-UX; these options should work for the HP compilers.

  1205. 	    if test -z "$DEBUGFLAG"; then

  1206.         	if test "x$with_optim" != x; then

  1207. 		    OPTIM="$with_optim $OPTIM"

  1208. 		else

  1209.         	    OPTIM="+O2 $OPTIM"

  1210. 		fi

  1211. 	    fi

  1212. 

  1213. 	    if test $PICFLAG = 1; then

  1214. 		OPTIM="+z $OPTIM"

  1215. 	    fi

  1216. 

  1217. 	    CXXFLAGS="$CXXFLAGS +W336,501,736,740,749,829"

  1218. 	    ;;

  1219. 	OSF1*)

  1220. 	    # Running Digital/Tru64 UNIX; these options should work for the

  1221. 	    # Digital/Compaq/NewHP compilers.

  1222. 	    if test -z "$DEBUGFLAG"; then

  1223.         	if test "x$with_optim" != x; then

  1224. 		    OPTIM="$with_optim $OPTIM"

  1225. 		else

  1226.         	    OPTIM="-O2 $OPTIM"

  1227. 		fi

  1228. 	    fi

  1229. 	    ;;

  1230. 	SunOS*)

  1231. 	    # Solaris

  1232. 	    if test -z "$DEBUGFLAG"; then

  1233.         	if test "x$with_optim" != x; then

  1234. 		    OPTIM="$with_optim $OPTIM"

  1235. 		else

  1236.         	    OPTIM="-xO3 $OPTIM"

  1237. 		fi

  1238. 	    fi

  1239. 

  1240. 	    if test $PICFLAG = 1; then

  1241. 		OPTIM="-KPIC $OPTIM"

  1242. 	    fi

  1243. 	    ;;

  1244. 	AIX*)

  1245. 	    if test -z "$DEBUGFLAG"; then

  1246.         	if test "x$with_optim" != x; then

  1247. 		    OPTIM="$with_optim $OPTIM"

  1248. 		else

  1249.         	    OPTIM="-O2 $OPTIM"

  1250. 		fi

  1251. 	    fi

  1252. 

  1253. 	    AC_MSG_WARN(The AIX C and C++ compilers are known not to correctly compile the FLTK library.)

  1254. 	    ;;

  1255. 	*)

  1256. 	    # Running some other operating system; inform the user they

  1257. 	    # should contribute the necessary options via the STR form..

  1258. 	    AC_MSG_WARN(Building FLTK with default compiler optimizations)

  1259. 	    AC_MSG_WARN(Send the FLTK developers your uname and compiler options via http://www.fltk.org/str.php)

  1260. 	    ;;

  1261.     esac

  1262. fi

  1263. 

  1264. OPTIM="$DEBUGFLAG $OPTIM"

  1265. 

  1266. dnl Take archflags away from CFLAGS (makefiles use ARCHFLAGS explicitly)

  1267. if test `uname` = Darwin; then

  1268.   if test "x$with_archflags" != x ; then

  1269.     CFLAGS="`echo $CFLAGS | sed -e "s/$with_archflags//g"`"

  1270.   fi

  1271. fi

  1272. 

  1273. dnl Define the FLTK documentation directory...

  1274. case $uname in

  1275.   MINGW*)

  1276.      # Determine the path where MSys has /usr installed

  1277.  	msyspath=`mount | grep '\/usr' | grep -v '\/usr\/bin' | cut -d ' ' -f -1 | sed -e 's/\\\/\// g'`

  1278.      # Then substitute that in the WIN32 path instead of /usr

  1279.  	AC_DEFINE_UNQUOTED(FLTK_DOCDIR, "$msyspath/local/share/doc/fltk")

  1280.     ;;

  1281.   *)

  1282.     if test x$prefix = xNONE; then

  1283. 	AC_DEFINE_UNQUOTED(FLTK_DOCDIR, "/usr/local/share/doc/fltk")

  1284.     else

  1285. 	AC_DEFINE_UNQUOTED(FLTK_DOCDIR, "$prefix/share/doc/fltk")

  1286.     fi

  1287.     ;;

  1288. esac

  1289. 

  1290. dnl Define the FLTK data directory...

  1291. if test x$prefix = xNONE; then

  1292.     AC_DEFINE_UNQUOTED(FLTK_DATADIR, "/usr/local/share/fltk")

  1293. else

  1294.     AC_DEFINE_UNQUOTED(FLTK_DATADIR, "$prefix/share/fltk")

  1295. fi

  1296. 

  1297. dnl Summarize results of configure tests...

  1298. echo ""

  1299. echo "Configuration Summary"

  1300. echo "-------------------------------------------------------------------------"

  1301. 

  1302. case $uname_GUI in

  1303.     CYGWIN* | MINGW*)

  1304.         graphics="GDI"

  1305. 	;;

  1306.     Darwin*)

  1307.         graphics="Quartz"

  1308.         ;;

  1309.     *)

  1310.         graphics="X11"

  1311. 	if test x$enable_xft != xno; then

  1312. 	    graphics="$graphics+Xft"

  1313. 	fi

  1314. 	if test x$enable_xinerama != xno; then

  1315. 	    graphics="$graphics+Xinerama"

  1316. 	fi

  1317.         ;;

  1318. esac

  1319. 

  1320. echo "    Directories: prefix=$prefix"

  1321. echo "                 bindir=$bindir"

  1322. echo "                 datadir=$datadir"

  1323. echo "                 datarootdir=$datarootdir"

  1324. echo "                 exec_prefix=$exec_prefix"

  1325. echo "                 includedir=$includedir"

  1326. echo "                 libdir=$libdir"

  1327. echo "                 mandir=$mandir"

  1328. case $uname in

  1329.   MINGW*)

  1330.     echo "                 MSys docpath=$msyspath/local/share/doc/fltk"

  1331.   ;;

  1332. esac

  1333. echo "       Graphics: $graphics"

  1334. 

  1335. if test x$JPEG = x; then

  1336.     echo "Image Libraries: JPEG=System"

  1337. else

  1338.     echo "Image Libraries: JPEG=Builtin"

  1339. fi

  1340. if test x$PNG = x; then

  1341.     echo "                 PNG=System"

  1342. else

  1343.     echo "                 PNG=Builtin"

  1344. fi

  1345. if test x$ZLIB = x; then

  1346.     echo "                 ZLIB=System"

  1347. else

  1348.     echo "                 ZLIB=Builtin"

  1349. fi

  1350. if test x$enable_cairo = xyes; then

  1351.     echo "                 CAIRO=lib"

  1352. fi

  1353. if test x$enable_cairoext = xyes; then

  1354.     echo "                 CAIRO=internal_use"

  1355. fi

  1356. 

  1357. 

  1358. if test x$enable_largefile != xno; then

  1359.     echo "    Large Files: YES"

  1360. else

  1361.     echo "    Large Files: NO"

  1362. fi

  1363. 

  1364. if test x$GLDEMOS = x; then

  1365.     echo "         OpenGL: NO"

  1366. else

  1367.     echo "         OpenGL: YES"

  1368. fi

  1369. 

  1370. if test x$THREADS = x; then

  1371.     echo "        Threads: NO"

  1372. else

  1373.     echo "        Threads: YES"

  1374. fi

  1375. 

  1376. dnl Write all of the files...

  1377. AC_CONFIG_HEADER(config.h:configh.in)

  1378. AC_OUTPUT(makeinclude fltk.list fltk-config fltk.spec FL/Makefile)

  1379. 

  1380. dnl Make sure the fltk-config script is executable...

  1381. chmod +x fltk-config

  1382. 

  1383. dnl

  1384. dnl End of "$Id: configure.in 8511 2011-03-06 16:54:58Z manolo $".

  1385. dnl