jackaudio
/
jack1
mirror of https://github.com/jackaudio/jack1
1
0
Fork 0
Code Releases 19 Activity
jack1 codebase
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1482 Commits
4 Branches
7.7MB
Tree: f0d10e8cbe
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'f0d10e8cbe'
${ noResults }
jack1/configure.ac

1007 lines
31KB
Raw Blame History 

  1. dnl Process this file with autoconf to produce a configure script.

  2. dnl $Id$

  3. 

  4. AC_INIT(jackd/jackd.c)

  5. 

  6. 

  7. dnl

  8. dnl Check for existing JACK installs

  9. dnl 

  10. 

  11. AC_MSG_CHECKING([existing, conflicting JACK installs])

  12. not_overwriting=0

  13. installs=

  14. for dir in /usr/lib /usr/local/lib /opt/lib ; do

  15.     if test -d $dir ; then

  16. 	if test $(find $dir/ -name 'libjack.so.*' 2>/dev/null | wc -l) -gt 0 ; then

  17. 	    if echo $prefix/lib | grep -vs $dir >/dev/null 2>&1 ; then

  18. 		not_overwriting=$(expr $not_overwriting + 1)

  19. 	    fi

  20. 	    installs="$installs $dir"

  21. 	fi	    

  22.     fi

  23. done

  24. 

  25. if test $not_overwriting -gt 0 ; then

  26.     echo 

  27.     echo

  28.     echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"

  29.     echo "You appear to have at least one existing installation of JACK."

  30.     echo

  31.     echo "Complete or partial JACK installs exist in:$installs"

  32.     echo 

  33.     echo "Installing this version will leave at least one of these"

  34.     echo "existing installations installed and this will probably break"

  35.     echo "JACK on your machine. "

  36.     echo

  37.     echo "Before building, you should first remove the existing JACK"

  38.     echo "installation(s). "

  39.     echo

  40.     echo "Alternatively use ./configure --prefix=... to force overwriting"

  41.     echo "the existing install."

  42.     echo

  43.     echo "WARNING: ON ANY DEBIAN-DERIVED DISTRIBUTION (Debian, Ubuntu etc)"

  44.     echo "CHANGING THE INSTALLATION PREFIX WILL NOT PRODUCE A WORKING JACK"

  45.     echo "INSTALL. Please contact the distribution packager for JACK and"

  46.     echo "ask them to fix their packaging."

  47.     echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"

  48.     exit 1

  49. fi

  50. 

  51. AC_CONFIG_AUX_DIR(config)

  52. AC_CANONICAL_BUILD

  53. 

  54. dnl ---

  55. dnl HOWTO: updating the JACK version number

  56. dnl

  57. dnl major version = ask on jackit-devel :)

  58. dnl minor version = incremented when any of the public or internal

  59. dnl                 interfaces are changed

  60. dnl micro version = incremented when implementation-only

  61. dnl                 changes are made

  62. dnl ---

  63. JACK_MAJOR_VERSION=0

  64. JACK_MINOR_VERSION=121

  65. JACK_MICRO_VERSION=2

  66. 

  67. dnl ---

  68. dnl HOWTO: updating the jack protocol version

  69. dnl

  70. dnl increment the protocol version whenever a change is

  71. dnl made to the way libjack communicates with jackd

  72. dnl that would break applications statically linked with an older

  73. dnl version of libjack. NOTE: statically linking to libjack

  74. dnl is a huge mistake.

  75. dnl ---

  76. JACK_PROTOCOL_VERSION=24

  77. 

  78. dnl ---

  79. dnl HOWTO: updating the libjack interface version

  80. dnl

  81. dnl current = incremented whenever the public libjack API is changed 

  82. dnl revision = incremented when the libjack implementation is changed

  83. dnl age = current libjack is both source and binary compatible with

  84. dnl       libjack interfaces current,current-1,...,current-age

  85. dnl

  86. dnl Note! see libtool documentation for detailed documentation

  87. dnl

  88. dnl Note Also! until we reach CURRENT>=1, the rules are somewhat

  89. dnl slacker than this, and closer to those for the JACK version

  90. dnl number.

  91. dnl ---

  92. JACK_API_CURRENT=0

  93. JACK_API_REVISION=28

  94. JACK_API_AGE=0

  95. 

  96. AC_SUBST(JACK_MAJOR_VERSION)

  97. AC_SUBST(JACK_MINOR_VERSION)

  98. AC_SUBST(JACK_MICRO_VERSION)

  99. 

  100. AC_SUBST(JACK_PROTOCOL_VERSION)

  101. AC_DEFINE_UNQUOTED(PROTOCOL_VERSION, "$JACK_PROTOCOL_VERSION", [Protocol version])

  102. 

  103. AC_SUBST(JACK_API_MAJOR_VERSION)

  104. AC_SUBST(JACK_API_MINOR_VERSION)

  105. AC_SUBST(JACK_API_MICRO_VERSION)

  106. 

  107. JACK_SO_VERSION=${JACK_API_CURRENT}:${JACK_API_REVISION}:${JACK_API_AGE}

  108. 

  109. JACK_VERSION=$JACK_MAJOR_VERSION.$JACK_MINOR_VERSION.${JACK_MICRO_VERSION}${BETA}

  110. JACK_RELEASE=$JACK_MAJOR_VERSION-$JACK_MINOR_VERSION-${JACK_MICRO_VERSION}${BETA}

  111. 

  112. AC_SUBST(JACK_SO_VERSION)

  113. AC_SUBST(JACK_VERSION)

  114. AC_SUBST(JACK_RELEASE)

  115. 

  116. AM_INIT_AUTOMAKE(jack-audio-connection-kit,${JACK_VERSION})

  117. 

  118. dnl

  119. dnl save any user-provided CFLAGS so we can forget

  120. dnl about any nonsense that configure generates

  121. dnl 

  122. 

  123. ORIGINAL_CFLAGS="$CFLAGS"

  124. 

  125. AM_CONFIG_HEADER(config.h)

  126. AC_ENABLE_STATIC(no)

  127. AC_ENABLE_SHARED(yes)

  128. AC_PROG_CC

  129. AC_PROG_CXX

  130. AC_PROG_LD

  131. AM_PROG_LIBTOOL

  132. AC_PROG_LN_S

  133. AM_PROG_CC_C_O

  134. AC_C_BIGENDIAN

  135. 

  136. dnl

  137. dnl now use those user-provided CFLAGS

  138. dnl and dump whatever nonsense configure generated

  139. dnl while looking for a compiler

  140. dnl

  141. 

  142. CFLAGS="$ORIGINAL_CFLAGS"

  143. 

  144. AC_MSG_CHECKING([platform dependencies])

  145. 

  146. HOST_DEFAULT_TMP_DIR=/dev/shm

  147. case "${host_os}" in

  148.   freebsd*)

  149.     # current FreeBSD header files conflict with the OSS driver's

  150.     # barrier code, this may be fixed in 5.3, stay tuned.

  151.     USE_BARRIER="no"

  152.     ;;

  153.   openbsd*)

  154.     # pthread_barrier* not implemented

  155.     USE_BARRIER="no"

  156.     # need small realtime stack

  157.     JACK_THREAD_STACK_TOUCH=10000

  158.     ;;

  159.   darwin*)

  160.     JACK_THREAD_STACK_TOUCH=10000	# need small realtime stack

  161.     JACK_CPP_VARARGS_BROKEN=1

  162.     JACK_DO_NOT_MLOCK=1

  163.     JACK_USE_MACH_THREADS=1

  164.     OS_LDFLAGS="-framework CoreAudio -framework CoreServices -framework AudioUnit"

  165.     TRY_POSIX_SHM=yes			# POSIX shm works better

  166.     HOST_DEFAULT_TMP_DIR=/tmp

  167.     ;;

  168. esac

  169. 

  170. AC_SUBST(OS_LDFLAGS)

  171. 

  172. #

  173. # We need to establish suitable defaults for a 64-bit OS

  174. libnn=lib

  175. case "${host_os}" in

  176.     linux*)

  177.     case "${host_cpu}" in

  178. 	x86_64|mips64|ppc64|sparc64|s390x)

  179.         libnn=lib64

  180. 	;;

  181.     esac

  182.     ;;

  183.     solaris*)

  184.     ## libnn=lib/sparcv9 ## on 64-bit only, but that's compiler-specific

  185.     ;;  

  186. esac

  187. 

  188. ## take care not to  override the command-line setting

  189. if test "${libdir}" = '${exec_prefix}/lib'; then

  190.   libdir='${exec_prefix}/'${libnn}

  191. fi

  192. 

  193. # system-dependent config.h values

  194. test "x$JACK_THREAD_STACK_TOUCH" = "x" && JACK_THREAD_STACK_TOUCH=500000

  195. AC_DEFINE_UNQUOTED(JACK_THREAD_STACK_TOUCH,

  196. 	[$JACK_THREAD_STACK_TOUCH],

  197. 	[Guaranteed size of realtime stack])

  198. if test "x$JACK_CPP_VARARGS_BROKEN" != "x"; then

  199.     AC_DEFINE_UNQUOTED(JACK_CPP_VARARGS_BROKEN,

  200. 	[$JACK_CPP_VARARGS_BROKEN],

  201. 	[CPP has a broken varargs implementation])

  202. fi

  203. if test "x$JACK_USE_MACH_THREADS" != "x"; then

  204.     AC_DEFINE_UNQUOTED(JACK_USE_MACH_THREADS,

  205. 	[$JACK_USE_MACH_THREADS],

  206. 	[Use MACH threads where possible])

  207. fi

  208. 

  209. # headers

  210. AC_CHECK_HEADERS(string.h strings.h alloca.h)

  211. AC_CHECK_HEADERS(getopt.h, [], [

  212.     for d in /Developer/SDKs/MacOSX10.3.0.sdk/usr/include/ ; do

  213. 	AC_CHECK_HEADERS($d/getopt.h, [], [CFLAGS="$CFLAGS -I$d"])

  214.     done])

  215. AC_CHECK_HEADER(/usr/include/nptl/pthread.h,

  216. 	[CFLAGS="$CFLAGS -I/usr/include/nptl"])

  217. 

  218. # functions and libraries

  219. AC_CHECK_FUNC(getopt_long, [],

  220.     AC_MSG_ERROR([*** JACK requires GNU getopt_long]))

  221. AC_CHECK_FUNC(gethostent, [], AC_CHECK_LIB(nsl, gethostent))

  222. AC_CHECK_FUNC(setsockopt, [], AC_CHECK_LIB(socket, setsockopt))

  223. AC_CHECK_FUNC(connect, [], AC_CHECK_LIB(inet, connect))

  224. AC_CHECK_FUNC(dlopen, [], 

  225.     AC_CHECK_LIB(dl, dlopen, [],

  226. 	AC_MSG_ERROR([*** JACK requires dynamic load support])))

  227. AC_CHECK_FUNC(pthread_create, [],

  228.     AC_CHECK_LIB(pthread, pthread_create, [],

  229. 	AC_MSG_ERROR([*** JACK requires POSIX threads support])))

  230. AC_CHECK_FUNCS(on_exit atexit)

  231. AC_CHECK_FUNCS(posix_memalign)

  232. AC_CHECK_LIB(m, sin)

  233. 

  234. echo -n "Checking for ppoll()... "

  235. AC_EGREP_CPP( ppoll,

  236. [

  237. #define _GNU_SOURCE

  238. #include <poll.h>

  239. ], [

  240.     	AC_DEFINE(HAVE_PPOLL,1,"Whether ppoll is available")

  241. 	echo "yes"

  242.    ],[

  243.     	AC_DEFINE(HAVE_PPOLL,0,"Whether ppoll is available")

  244. 	echo "no"

  245.    ] )

  246. 

  247. 	 

  248. 

  249. AC_CHECK_FUNC(clock_gettime, 

  250.        [

  251.            AC_DEFINE(HAVE_CLOCK_GETTIME,0,"Whether or not clock_gettime can be found in system libraries")

  252.        ], 

  253.        #

  254.        # if not found, check librt specifically

  255.        #

  256.        AC_CHECK_LIB(rt, clock_gettime, 

  257.            [

  258.               AC_DEFINE(HAVE_CLOCK_GETTIME,1,"Whether or not clock_gettime can be found in system libraries")

  259. 	      OS_LDFLAGS="$OS_LDFLAGS -lrt"

  260. 	   ])

  261. )	  

  262. 

  263. # should we use mlockall() on this platform?

  264. if test "x$JACK_DO_NOT_MLOCK" = "x"; then

  265.     AC_CHECK_HEADER(sys/mman.h,

  266.         [AC_CHECK_FUNC(mlockall,

  267. 	    [AC_DEFINE(USE_MLOCK, 1, [Use POSIX memory locking])])])

  268. fi

  269. 

  270. # look for system support for POSIX shm API

  271. AC_ARG_ENABLE(posix-shm,

  272. 	AC_HELP_STRING([--enable-posix-shm], [use POSIX shm API (default=auto)]),

  273. 	[TRY_POSIX_SHM=$enableval])

  274. if test "x$TRY_POSIX_SHM" = "xyes"

  275. then

  276. 	AC_CHECK_FUNC(shm_open, [],

  277. 		AC_CHECK_LIB(rt, shm_open, [], [TRY_POSIX_SHM=no]))

  278. fi

  279. AC_MSG_CHECKING([shared memory support])

  280. if test "x$TRY_POSIX_SHM" = "xyes"

  281. then

  282. 	AC_MSG_RESULT([POSIX shm_open().])

  283. 	AC_DEFINE(USE_POSIX_SHM,1,[Use POSIX shared memory interface])

  284. 	JACK_SHM_TYPE='"POSIX"'

  285. 	USE_POSIX_SHM="true"

  286. else

  287. 	AC_MSG_RESULT([System V shmget().])

  288. 	JACK_SHM_TYPE='"System V"'

  289. 	USE_POSIX_SHM="false"

  290. fi

  291. AC_DEFINE_UNQUOTED(JACK_SHM_TYPE, [$JACK_SHM_TYPE],

  292. 	[JACK shared memory type])

  293. AM_CONDITIONAL(USE_POSIX_SHM, $USE_POSIX_SHM)

  294. 

  295. JACK_CORE_CFLAGS="-I\$(top_srcdir)/config -I\$(top_srcdir) \

  296. -I\$(top_srcdir) -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -Wall"

  297. 

  298. JACK_LIBC_HELPER_FLAGS=

  299. AC_ARG_ENABLE(ancient_libc,

  300. 	AC_HELP_STRING([--enable-ancient-libc],[Add required CFLAGS for libc versions too old to expose PThread R/W Lock and other modern code]),

  301. 	JACK_LIBC_HELPER_FLAGS="-D_XOPEN_SOURCE=600 -D_BSD_SOURCE",

  302. 	JACK_LIBC_HELPER_FLAGS=""

  303. 	)

  304. 	 

  305. JACK_CORE_CFLAGS="$JACK_CORE_CFLAGS $JACK_LIBC_HELPER_FLAGS"   

  306. 

  307. case $build_os in

  308.      # we need weak linkage which appeared in 10.2, but lets ask for 10.4 anyway

  309.      darwin*) JACK_CORE_CFLAGS="$JACK_CORE_CFLAGS -mmacosx-version-min=10.4" ;;

  310. esac    

  311. 

  312. AC_ARG_WITH(cpu-target,

  313.             [  --with-cpu-target=cpu-type    explicit, overriding argument for gcc -march= flag])

  314. 

  315. 

  316. dnl

  317. dnl figure out how best to optimize

  318. dnl JOQ: this should be done via config/configure.hosts

  319. dnl

  320. 

  321. dnl ----------------------------------------------------------------------

  322. 

  323. if test "$build_cpu" = "powerpc64" ; then

  324. 

  325.     AC_ARG_ENABLE(cell,

  326. 	AC_HELP_STRING([--enable-cell],[enable Cell BE support (default=no)]),,

  327. 	[ enable_cell=no ])

  328. 

  329.     if test "x$enable_cell" = xyes; then

  330.         AC_DEFINE(ENABLE_CELLBE, 1, [Define to 1 if you need support for the Cell BE.])

  331.     fi

  332. 

  333. fi

  334. 

  335. if test "build_cpu" = "powerpc" -o "$build_cpu" = "powerpc64" ; then

  336. 

  337.     AC_DEFINE(POWERPC, 1, "Are we running a ppc CPU?")

  338.     

  339. ############################

  340. # Check for Altivec assembly

  341. ############################

  342. 

  343.     AC_ARG_ENABLE(altivec,

  344. 	AC_HELP_STRING([--enable-altivec],[enable Altivec support (default=auto)]),,

  345. 	[ enable_altivec=yes ])

  346.     

  347.     if test "x$enable_altivec" = xyes; then

  348. 	

  349. 	AC_MSG_CHECKING(whether we can compile Altivec code)

  350. 	

  351. 	AC_COMPILE_IFELSE([asm ("vand %v0, %v0, %v0");],

  352. 	    AC_DEFINE(USE_ALTIVEC, 1, [Define to 1 if Altivec assembly is available.])

  353. 	    AC_DEFINE(HAVE_ALTIVEC_LINUX, 1, "Is there Altivec Support ?")

  354. 	    ALTIVEC_OPT_FLAGS="-maltivec -mabi=altivec"

  355. 	    AC_MSG_RESULT(yes)

  356. 	    ,

  357. 	    enable_altivec=no

  358. 	    AC_MSG_RESULT(no)

  359. 	    AC_MSG_WARN([The assembler does not support the Altivec command set.])

  360. 	)

  361. 	

  362.     fi

  363. 

  364.     dnl -mcpu=7450 does not reliably work with gcc 3.*

  365.     

  366.     JACK_OPT_CFLAGS="-O2 -mcpu=7400 $ALTIVEC_OPT_FLAGS -mhard-float -mpowerpc-gfxopt"

  367. 

  368.     if test "$build_cpu" = "powerpc64"; then

  369. 	JACK_OPT_CFLAGS="-O2 -mcpu=powerpc64 $ALTIVEC_OPT_FLAGS -mhard-float" 

  370.     fi

  371. 

  372. elif echo $build_cpu | egrep '(i.86|x86_64)' >/dev/null; then

  373. 

  374.     dnl Check for MMX/SSE assembly

  375.     

  376.     if test -r /proc/cpuinfo ; then

  377. 	procflags=`grep '^flags' /proc/cpuinfo`

  378. 	if echo $procflags | grep -s mmx ; then

  379. 	    cpu_supports_mmx=yes

  380. 	fi

  381. 	if echo $procflags | grep -s sse ; then

  382. 	    cpu_supports_sse=yes

  383. 	fi

  384.     else

  385. 	# this is not linux, but assume that if the processor

  386. 	# is x86 then is supports SSE and not MMX

  387.         cpu_supports_sse=yes

  388. 	AC_MSG_WARN([Assuming your x86/x86_64 system can support SSE. Use --disable-sse if this is not the case])

  389.         cpu_supports_mmx=no

  390. 	AC_MSG_WARN([Assuming your x86/x86_64 system does not need to use MMX. Use --enable-mmx if this is not the case])

  391.     fi

  392.     

  393.     AC_ARG_ENABLE(optimization-by-compiler,

  394. 	AC_HELP_STRING([--enable-optimization-by-compiler],[use compiler (NOT processor) capabilities to determine optimization flags (default=no)]),

  395. 	optimization_by_compiler=yes,

  396. 	optimization_by_compiler=no

  397.     )

  398.     

  399.     AC_ARG_ENABLE(optimization-by-cpu,

  400. 	AC_HELP_STRING([--enable-optimization-by-cpu],[use processor capabilities to determine optimization flags (default=yes)]),,

  401. 	optimization_by_cpu=yes

  402.     )

  403.     

  404.     AC_ARG_ENABLE(mmx,

  405. 	AC_HELP_STRING([--enable-mmx],[enable MMX support (default=auto)]),,

  406. 	enable_mmx=yes)

  407.     

  408.     AC_ARG_ENABLE(sse,

  409. 	AC_HELP_STRING([--enable-sse],[enable SSE support (default=auto)]),,

  410. 	enable_sse=$enable_mmx)

  411.     

  412.     if test "x$enable_mmx" = xyes; then

  413. 	

  414. 	AC_MSG_CHECKING(whether we can compile MMX code)

  415. 	

  416. 	AC_COMPILE_IFELSE([asm ("movq 0, %mm0");],

  417. 	    

  418. 	    AC_DEFINE(USE_MMX, 1, [Define to 1 if MMX assembly is available.])

  419. 	    AC_MSG_RESULT(yes)

  420. 	    

  421. 	    if test x$optimization_by_cpu = xyes ; then

  422. 		if test x$cpu_supports_mmx = xyes ; then

  423. 		    MMX_FLAGS="-mmmx"

  424. 		fi

  425. 	    else 

  426. 		MMX_FLAGS="-mmmx"

  427. 	    fi

  428. 	    

  429. 	    AC_MSG_RESULT(yes)

  430. 	    ,

  431. 	    enable_mmx=no

  432. 	    AC_MSG_RESULT(no)

  433. 	    AC_MSG_WARN([The assembler does not support the MMX command set.])

  434. 	)

  435.     fi

  436. 

  437.     if test "x$enable_sse" = xyes; then

  438. 	

  439. 	AC_MSG_CHECKING(whether we can compile SSE code)

  440. 	

  441. 	AC_COMPILE_IFELSE([asm ("movntps %xmm0, 0");],

  442. 	    [

  443. 		if test x$optimization_by_cpu = xyes ; then

  444. 		    if test x$cpu_supports_sse = xyes ; then

  445. 			SSE_FLAGS="-msse -mfpmath=sse"

  446. 			MMX_FLAGS=""

  447. 		    fi

  448. 		else 

  449. 		    SSE_FLAGS="-msse -mfpmath=sse"

  450. 		    MMX_FLAGS=""

  451. 		fi

  452. 		

  453. 		AC_MSG_RESULT(yes)

  454. 		],

  455. 	    [

  456. 		enable_sse=no

  457. 		AC_MSG_RESULT(no)

  458. 		AC_MSG_WARN([The assembler does not support the SSE command set.]) 

  459. 		])

  460.     fi

  461.     

  462.     AC_DEFINE(x86, 1, "Nope it's intel")

  463.     COMMON_X86_OPT_FLAGS="-O3 -fomit-frame-pointer -ffast-math -funroll-loops"

  464. 

  465. dnl

  466. dnl its a little sad that OS X doesn't make it possible to identify 

  467. dnl the build_cpu a little more precisely. on os x we always get "i386"

  468. dnl as the CPU type. we miss out on some possible optimizations as 

  469. dnl a result. oh well.

  470. dnl     

  471.     

  472.     if test x$with_cpu_target != x ; then

  473.         JACK_OPT_CFLAGS="-march=$with_cpu_target"

  474.     else

  475.         if test "$build_cpu" = "i586"; then

  476. 	   JACK_OPT_CFLAGS="-march=i586 "

  477. 	elif test "$build_cpu" = "i686"; then

  478. 	    JACK_OPT_CFLAGS="-march=i686"

  479. 	elif test "$build_cpu" = "x86_64"; then

  480. 	    JACK_OPT_CFLAGS="-march=k8"

  481. 	else

  482. 	    :

  483. 	fi

  484.     fi

  485. 

  486. dnl

  487. dnl do not add h/w specific flags if asked to let compiler

  488. dnl to the optimization

  489. dnl    

  490. 

  491.     if test x$optimization_by_compiler != xyes ; then

  492.         JACK_OPT_CFLAGS="$COMMON_X86_OPT_FLAGS $JACK_OPT_CFLAGS $MMX_FLAGS $SSE_FLAGS"

  493.     else

  494.        JACK_OPT_CFLAGS="$COMMON_X86_OPT_FLAGS"

  495.     fi

  496. 

  497. fi

  498. 

  499. AC_ARG_ENABLE(dynsimd,

  500. 	AC_HELP_STRING([--enable-dynsimd],[enable dynamic SIMD selection (default=no)]),,

  501.     enable_dynsimd=no)

  502. 

  503. if test "x$enable_dynsimd" = xyes; then

  504. 	AC_DEFINE(USE_DYNSIMD, 1, [Define to 1 to use dynamic SIMD selection.])

  505. 	dnl This needs update once there's more than x86/x86-64 supported

  506. 	SIMD_CFLAGS="-O -msse -msse2 -m3dnow"

  507. 	AC_SUBST(SIMD_CFLAGS)

  508. fi

  509. 

  510. AC_ARG_ENABLE(optimize,

  511.     AC_HELP_STRING([--enable-optimize],

  512. 	[optimize code, based on CPU or compiler, as separately selected (default=no)]),

  513.     [ if test x$enable_optimize != xno ; then

  514. 	AC_MSG_WARN([optimization in use.........................])

  515.       else

  516.         # no optimization, so lets get debugging symbols instead

  517. 	JACK_OPT_CFLAGS="-g"

  518. 	AC_MSG_WARN([no optimization.........................])

  519.       fi 

  520.     ],

  521.     [

  522.         # no optimization, so lets get debugging symbols instead

  523. 	JACK_OPT_CFLAGS="-g"

  524. 	AC_MSG_WARN([no optimization.........................])

  525.     ]

  526. )

  527. 

  528. JACK_CFLAGS="$JACK_CORE_CFLAGS $JACK_OPT_CFLAGS"

  529. 

  530. dnl

  531. dnl most makefiles use JACK_CFLAGS, but simd code needs JACK_CORE_CFLAGS

  532. dnl

  533. 

  534. AC_SUBST(JACK_CFLAGS)

  535. AC_SUBST(JACK_CORE_CFLAGS)

  536. 

  537. dnl

  538. dnl use JACK_CFLAGS for jackd compilation

  539. dnl 

  540. 

  541. CFLAGS="$CFLAGS $JACK_CFLAGS"

  542. 

  543. # allow buffer resizing unless --disable-resize specified

  544. buffer_resizing=yes

  545. AC_ARG_ENABLE(resize,

  546. 	AC_HELP_STRING([--enable-resize], [enable buffer resizing feature (default=yes)]),

  547.         [ 

  548. 	  if test x$enable_resize = xno ; then

  549. 	  	buffer_resizing=no

  550. 	  fi

  551. 	 ]

  552. )

  553. 

  554. if test x$buffer_resizing != xno; then 

  555.    AC_DEFINE(DO_BUFFER_RESIZE,,[Enable buffer resizing])

  556. fi

  557. 

  558. AC_ARG_ENABLE(valgrind-clean,

  559. 	AC_HELP_STRING([--enable-valgrind-clean],[spend a few extra CPU cycles avoiding unnecessary valgrind warnings (default=no)]),

  560.         [ 

  561. 	  if test x$enable_valgrind_clean != xno ; then

  562. 	     AC_DEFINE(VALGRIND_CLEAN,,[clean up for valgrind])

  563.           fi

  564.         ]

  565. )

  566. 

  567. AC_ARG_ENABLE(ensure-mlock,

  568. 	AC_HELP_STRING([--enable-ensure-mlock], [server should fail if unable to lock memory (default=no)]),

  569.         [ 

  570. 	  if test x$enable_ensure_mlock != xno ; then

  571. 	  	AC_DEFINE(ENSURE_MLOCK,,[Ensure that memory locking succeeds])

  572. 	  fi

  573. 	]

  574. )

  575. 

  576. AC_ARG_ENABLE(debug,

  577. 	AC_HELP_STRING([--enable-debug],

  578. 		[enable debugging messages in jackd and libjack (default=no)]),

  579.         [ 

  580. 	  if test x$enable_debug != xno ; then

  581. 	     AC_DEFINE(DEBUG_ENABLED,,[Enable debugging messages])

  582.           fi

  583.         ]

  584. )

  585. 

  586. AC_ARG_ENABLE(timestamps,

  587. 	AC_HELP_STRING([--enable-timestamps],

  588. 		[allow clients to use the JACK timestamp API (JACK developers only) (default=no)]),

  589.         [ 

  590. 	  if test x$enable_timestamps != xno ; then

  591. 	  	AC_DEFINE(WITH_TIMESTAMPS,,[Enable JACK timestamp API])

  592.           fi

  593.         ]		

  594. )

  595. 

  596. AC_ARG_ENABLE(preemption-check,

  597. 	AC_HELP_STRING([--enable-preemption-check],

  598. 		[check for inappropriate realtime preemption (requires a specially built Linux kernel) (default=no)]),

  599. 		[

  600. 		  if test x$enable_preemption_check != xno ; then

  601. 			echo checking for realtime preemption bugs

  602. 			AC_DEFINE(DO_PREEMPTION_CHECKING,,

  603. 				[check realtime preemption])

  604. 		  fi

  605. 		])

  606. 

  607. USE_CAPABILITIES=false

  608. 

  609. AC_ARG_ENABLE(capabilities,

  610. 	AC_HELP_STRING([--enable-capabilities],[!!! LINUX 2.4 KERNELS ONLY !!! use libcap to gain realtime scheduling priviledges]),

  611.               [ if test "x$enable_capabilities" != "xno" ; then

  612.                     AC_CHECK_LIB(cap, capgetp,

  613.                                  [AC_CHECK_HEADER(sys/capability.h,

  614.                                                   [HAVE_CAPABILITIES=true],

  615.                                                   [AC_MSG_WARN([*** no kernel support for capabilities])

  616.                                                    HAVE_CAPABILITIES=false]

  617.                                   )],

  618.                                  [AC_MSG_WARN([*** no libcap present])

  619.                                   HAVE_CAPABILITIES=false]

  620.                     )

  621.                     if test "x$HAVE_CAPABILITIES" = "xtrue"; then

  622.                         AC_CHECK_PROG(HAVE_CAPABILITIES, md5sum, true, false)

  623.                     fi

  624.                     if test "x$HAVE_CAPABILITIES" = "xfalse"; then

  625.                         AC_MSG_WARN([*** required program md5sum not found])

  626.                     fi

  627.                     if test "x$HAVE_CAPABILITIES" = "xfalse"; then

  628.                         AC_MSG_ERROR([*** Capabilities support not present. Run configure again without --enable-capabilities.])

  629.                     fi

  630.                     USE_CAPABILITIES=true

  631.                     AC_DEFINE(USE_CAPABILITIES,,[Enable POSIX 1.e capabilities support])

  632.                 fi

  633.               ]

  634. )

  635. 

  636. with_oldtrans=yes

  637. AC_ARG_ENABLE(oldtrans,

  638. 	AC_HELP_STRING([--disable-oldtrans],[remove old transport interfaces (default=yes)]),

  639.               [ if test "x$enable_oldtrans" = "xno" ; then

  640. 		    with_oldtrans=no

  641. 		fi 

  642. 	      ]

  643. )

  644. if test "x$with_oldtrans" != "xno" ; then

  645. 	AC_DEFINE(OLD_TRANSPORT,,[Include old transport interfaces])

  646. fi

  647. 

  648. STRIPPED_JACKD=false

  649. AC_ARG_ENABLE(stripped-jackd,

  650. 	AC_HELP_STRING([--enable-stripped-jackd],[strip jack before computing its md5 sum (useful only with Linux 2.4 kernel)]),

  651.               [ if test "x$USE_CAPABILITIES" != "xtrue" ; then	    

  652.                     AC_MSG_WARN([*** capabilities not enabled, stripped jackd has no effect])

  653.                 elif test "x$enable_stripped_jackd" != "xno"; then

  654.                     STRIPPED_JACKD=true		    

  655.                 fi  

  656.               ]	

  657. )

  658. 

  659. # plugins go in the addon dir.

  660. 

  661. ADDON_DIR='${libdir}/jack'

  662. AC_SUBST(ADDON_DIR)

  663. AS_AC_EXPAND(ADDON_DIR_EXPANDED,${libdir}/jack)

  664. AC_DEFINE_UNQUOTED(ADDON_DIR,"$ADDON_DIR_EXPANDED",[Directory for plugins])

  665. 

  666. AC_ARG_WITH(html-dir,

  667. 		AC_HELP_STRING([--with-html-dir=PATH],[where to install the html documentation]))

  668. 

  669. if test "x$with_html_dir" = "x" ; then

  670.     HTML_DIR='${pkgdatadir}'

  671. else

  672.     HTML_DIR=$with_html_dir

  673. fi

  674. 

  675. AC_SUBST(HTML_DIR)

  676. 

  677. 

  678. # allow specifying default tmpdir

  679. AC_ARG_WITH(default-tmpdir,

  680.             AC_HELP_STRING([--with-default-tmpdir],[where jackd and clients will put tmp files (default=/dev/shm)]))

  681. 

  682. if test "x$with_default_tmpdir" = "x" ; then

  683. 	DEFAULT_TMP_DIR=$HOST_DEFAULT_TMP_DIR

  684. else

  685. 	DEFAULT_TMP_DIR=$with_default_tmpdir

  686. fi

  687. 

  688. AC_SUBST(DEFAULT_TMP_DIR)

  689. AC_DEFINE_UNQUOTED(DEFAULT_TMP_DIR,"$DEFAULT_TMP_DIR",[Default tmp directory])

  690. 

  691. # Check for barrier functions in the pthreads library.  The default

  692. # option setting may be OS-dependent, otherwise it's "yes".

  693. test "x$USE_BARRIER" = "x" && USE_BARRIER="yes"

  694. AC_ARG_WITH(barrier,

  695. 	AC_HELP_STRING([--without-barrier],

  696. 		       [avoid using pthread barrier functions (only used by OSS driver)]),

  697. 	[ USE_BARRIER=$withval ])

  698. if test "x$USE_BARRIER" = "xyes"; then

  699. 	AC_CHECK_LIB([pthread], [pthread_barrier_init],

  700. 		AC_DEFINE(USE_BARRIER, 1, [Use pthread barrier functions]))

  701. fi

  702. 

  703. # some example-clients need libsndfile

  704. HAVE_SNDFILE=false

  705. PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0,[HAVE_SNDFILE=true], [true])

  706. if test x$HAVE_SNDFILE = xfalse; then

  707.              AC_MSG_WARN([*** the jackrec example client will not be built])

  708. fi

  709. 

  710. # NetJack backend and internal client need libsamplerate

  711. HAVE_SAMPLERATE=false

  712. PKG_CHECK_MODULES(SAMPLERATE, samplerate >= 0.1.2,[HAVE_SAMPLERATE=true], [true])

  713. if test x$HAVE_SAMPLERATE = xfalse; then

  714.         AC_MSG_WARN([*** the NetJack backend and internal client will not be built])

  715.     	AC_DEFINE(HAVE_SAMPLERATE,0,"Whether libsamplerate is available")

  716. else

  717. 	NETJACK_CFLAGS="$NETJACK_CFLAGS $SAMPLERATE_CFLAGS"

  718. 	NETJACK_LIBS="$NETJACK_LIBS $SAMPLERATE_LIBS"

  719.     	AC_DEFINE(HAVE_SAMPLERATE,1,"Whether libsamplerate is available")

  720. fi

  721. 

  722. # Celt low-latency audio codec. netjack transmission via internet.

  723. HAVE_CELT=false

  724. PKG_CHECK_MODULES(CELT, celt >= 0.8.0,[HAVE_CELT=true], [true])

  725. if test x$HAVE_CELT = xfalse; then

  726. 	PKG_CHECK_MODULES(CELT, celt >= 0.7.0,[HAVE_CELT=true], [true])

  727. 	if test x$HAVE_CELT = xfalse; then

  728. 		PKG_CHECK_MODULES(CELT, celt >= 0.5.0,[HAVE_CELT=true], [true])

  729. 		if test x$HAVE_CELT = xfalse; then

  730. 			AC_DEFINE(HAVE_CELT,0,"Whether CELT is available")

  731. 			AC_MSG_RESULT(no)

  732. 			AC_MSG_WARN([*** NetJack will not be built with celt support])

  733. 		else

  734. 			AC_DEFINE(HAVE_CELT,1,"Whether CELT is available")

  735. 			AC_DEFINE(HAVE_CELT_API_0_5,1,"Whether CELT API is 0.5 API")

  736. 			AC_DEFINE(HAVE_CELT_API_0_7,0,"Whether CELT API is 0.7 API")

  737. 			AC_DEFINE(HAVE_CELT_API_0_8,0,"Whether CELT API is 0.8 API")

  738. 			AC_MSG_RESULT(yes (0.5))

  739. 			NETJACK_LIBS="$NETJACK_LIBS $CELT_LIBS"

  740. 		fi

  741. 	else

  742. 		AC_DEFINE(HAVE_CELT,1,"Whether CELT is available")

  743. 		AC_MSG_RESULT(yes (0.7))

  744. 		AC_DEFINE(HAVE_CELT_API_0_5,0,"Whether CELT API is 0.5 API")

  745. 		AC_DEFINE(HAVE_CELT_API_0_7,1,"Whether CELT API is 0.7 API")

  746. 		AC_DEFINE(HAVE_CELT_API_0_8,0,"Whether CELT API is 0.8 API")

  747. 		NETJACK_LIBS="$NETJACK_LIBS $CELT_LIBS"

  748. 	fi

  749. else

  750. 		AC_DEFINE(HAVE_CELT,1,"Whether CELT is available")

  751. 		AC_MSG_RESULT(yes (0.7))

  752. 		AC_DEFINE(HAVE_CELT_API_0_5,0,"Whether CELT API is 0.5 API")

  753. 		AC_DEFINE(HAVE_CELT_API_0_7,0,"Whether CELT API is 0.7 API")

  754. 		AC_DEFINE(HAVE_CELT_API_0_8,1,"Whether CELT API is 0.8 API")

  755. 		NETJACK_LIBS="$NETJACK_LIBS $CELT_LIBS"

  756. fi

  757. 

  758. AC_SUBST(NETJACK_LIBS)

  759. AC_SUBST(NETJACK_CFLAGS)

  760. 

  761. # Note: A bug in pkg-config causes problems if the first occurence of

  762. # PKG_CHECK_MODULES can be disabled. So, if you're going to use

  763. # PKG_CHECK_MODULES inside a --disable-whatever check, you need to

  764. # do it somewhere *below* this comment.

  765. 

  766. # Check which backend drivers can be built.  The last one successfully

  767. # configured becomes the default JACK driver; so the order of

  768. # precedence is: alsa, sun, oss, coreaudio, portaudio, dummy.

  769. 

  770. JACK_DEFAULT_DRIVER=\"dummy\"

  771. 

  772. AC_ARG_ENABLE(portaudio,

  773. 	AC_HELP_STRING([--enable-portaudio],[build PortAudio driver]),

  774.    TRY_PORTAUDIO=$enableval , TRY_PORTAUDIO=no)

  775. 

  776. HAVE_PA="false"

  777. if test "x$TRY_PORTAUDIO" = "xyes"

  778. then

  779. 	# check for portaudio V18

  780. 	AC_CHECK_LIB(portaudio, Pa_Initialize,

  781. 		[ AC_CHECK_HEADERS(portaudio.h,

  782. 			[ HAVE_PA="true"

  783. 			  PA_LIBS=-lportaudio

  784. 			  JACK_DEFAULT_DRIVER=\"portaudio\"

  785. 			])

  786. 		])

  787. 	AC_SUBST(PA_LIBS)

  788. fi

  789. AM_CONDITIONAL(HAVE_PA, $HAVE_PA)

  790. 

  791. AC_ARG_ENABLE(coreaudio, AC_HELP_STRING([--disable-coreaudio], [ignore CoreAudio driver]),

  792. 			TRY_COREAUDIO=$enableval , TRY_COREAUDIO=yes )

  793. HAVE_COREAUDIO="false"

  794. if test "x$TRY_COREAUDIO" = "xyes"

  795. then

  796. 	# check for coreaudio

  797. 	AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,

  798. 		[ HAVE_COREAUDIO="true"

  799. 		  JACK_DEFAULT_DRIVER=\"coreaudio\"

  800. 		])

  801. fi

  802. AM_CONDITIONAL(HAVE_COREAUDIO, $HAVE_COREAUDIO)

  803. 

  804. AC_ARG_ENABLE(oss, AC_HELP_STRING([--disable-oss],[ignore OSS driver ]),

  805. 			TRY_OSS=$enableval , TRY_OSS=yes ) 

  806. HAVE_OSS="false"

  807. if test "x$TRY_OSS" = "xyes"

  808. then

  809. 	# check for Open Sound System

  810. 	AC_CHECK_HEADER([sys/soundcard.h],

  811. 	     [HAVE_OSS="true"

  812.               JACK_DEFAULT_DRIVER=\"oss\"])

  813. fi

  814. AM_CONDITIONAL(HAVE_OSS, $HAVE_OSS)

  815. 

  816. AC_ARG_ENABLE(sun, AC_HELP_STRING([--disable-sun],[ignore Sun driver ]),

  817. 			TRY_SUN=$enableval , TRY_SUN=yes ) 

  818. HAVE_SUN="false"

  819. if test "x$TRY_SUN" = "xyes"

  820. then

  821. 	# check for Sun audio API

  822. 	AC_CHECK_HEADER([sys/audioio.h],

  823. 	     [HAVE_SUN="true"

  824.               JACK_DEFAULT_DRIVER=\"sun\"])

  825. fi

  826. AM_CONDITIONAL(HAVE_SUN, $HAVE_SUN)

  827. 

  828. AC_ARG_ENABLE(freebob, AC_HELP_STRING([--disable-freebob],[ignore FreeBob driver ]),

  829. 			TRY_FREEBOB=$enableval , TRY_FREEBOB=yes ) 

  830. HAVE_FREEBOB="false"

  831. if test "x$TRY_FREEBOB" = "xyes"

  832. then

  833. 	# check for FreeBob libraries

  834. 	PKG_CHECK_MODULES(LIBFREEBOB, libfreebob >= 1.0.0,

  835. 	     [HAVE_FREEBOB="true"

  836.               JACK_DEFAULT_DRIVER=\"freebob\"

  837. 	     ], AC_MSG_RESULT([no]))

  838. 

  839. 	AC_SUBST([LIBFREEBOB_CFLAGS])

  840. 	AC_SUBST([LIBFREEBOB_LIBS])

  841. 

  842. fi

  843. AM_CONDITIONAL(HAVE_FREEBOB,$HAVE_FREEBOB)

  844. 

  845. AC_ARG_ENABLE(firewire, AC_HELP_STRING([--disable-firewire],[ignore FireWire driver (FFADO)]),

  846. 			TRY_FIREWIRE=$enableval , TRY_FIREWIRE=yes ) 

  847. HAVE_FIREWIRE="false"

  848. if test "x$TRY_FIREWIRE" = "xyes"

  849. then

  850. 	# check for FFADO libraries

  851. 	PKG_CHECK_MODULES(LIBFFADO, libffado >= 1.999.17,

  852. 	     [HAVE_FIREWIRE="true"

  853.               JACK_DEFAULT_DRIVER=\"firewire\"

  854. 	     ], AC_MSG_RESULT([no]))

  855. 

  856. 	AC_SUBST([LIBFFADO_CFLAGS])

  857. 	AC_SUBST([LIBFFADO_LIBS])

  858. 

  859. fi

  860. AM_CONDITIONAL(HAVE_FIREWIRE,$HAVE_FIREWIRE)

  861. 

  862. AC_ARG_ENABLE(alsa, AC_HELP_STRING([--disable-alsa],[ignore ALSA driver ]),

  863. 			TRY_ALSA=$enableval , TRY_ALSA=yes ) 

  864. HAVE_ALSA="false"

  865. if test "x$TRY_ALSA" = "xyes"

  866. then

  867. 	# check for ALSA >= 1.0.18

  868. 	PKG_CHECK_MODULES(ALSA, alsa >= 1.0.18,

  869. 	     [HAVE_ALSA="true"

  870.               ALSA_LIBS=-lasound

  871.               JACK_DEFAULT_DRIVER=\"alsa\"

  872.              ], AC_MSG_RESULT([no - cannot find ALSA 1.0.18 or later]), [-lm]

  873. 	)

  874. 	AC_SUBST(ALSA_LIBS)

  875. fi

  876. AM_CONDITIONAL(HAVE_ALSA, $HAVE_ALSA)

  877. 

  878. HAVE_ALSA_MIDI=$HAVE_ALSA

  879. AM_CONDITIONAL(HAVE_ALSA_MIDI, $HAVE_ALSA_MIDI)

  880. 

  881. if test "$JACK_DEFAULT_DRIVER" = \"dummy\"; then

  882.   AC_MSG_WARN([Only the dummy driver can be built])

  883. fi

  884. AC_DEFINE_UNQUOTED(JACK_DEFAULT_DRIVER,

  885. 	[$JACK_DEFAULT_DRIVER],

  886. 	[Default JACK driver])

  887. 

  888. JACK_SEMAPHORE_KEY=0x282929

  889. AC_DEFINE_UNQUOTED(JACK_SEMAPHORE_KEY,

  890. 	  [$JACK_SEMAPHORE_KEY],

  891. 	  [ an integer constant used as the semaphore and SysV SHM key. see libjack/shm.c for usage])

  892. AC_SUBST(JACK_SEMAPHORE_KEY)

  893. 

  894. # On some systems, readline depends on termcap or ncurses.  But, the

  895. # MacOSX linker complains bitterly if these libraries are explicitly

  896. # referenced.  

  897. #

  898. # AC_CHECK_LIB() foolishly assumes that checking a library for an entry

  899. # point always returns the same result regardless of any dependent

  900. # libraries specified.  The `unset ac_cv_lib_readline_readline' erases

  901. # the cached result to work around this problem.

  902. READLINE_DEPS=""

  903. HAVE_READLINE=true

  904. AC_CHECK_LIB(readline, readline, [:],

  905.     [unset ac_cv_lib_readline_readline

  906.      AC_CHECK_LIB(readline, readline, [READLINE_DEPS="-ltermcap"],

  907.         [unset ac_cv_lib_readline_readline

  908. 	 AC_CHECK_LIB(readline, readline,

  909. 	    [READLINE_DEPS="-lncurses"], [HAVE_READLINE=false], "-lncurses")],

  910. 	"-ltermcap")])

  911. AC_CHECK_HEADER(readline/chardefs.h, [], [HAVE_READLINE=false])

  912. if test x$HAVE_READLINE = xfalse; then

  913. 	AC_MSG_WARN([*** the jack_transport example client will not be built])

  914. fi

  915. AC_SUBST(READLINE_DEPS)

  916. 

  917. # you need doxygen to make dist.

  918. AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, true, false)

  919. if test $HAVE_DOXYGEN = "false"; then

  920.              AC_MSG_WARN([*** doxygen not found, docs will not be built])

  921. fi

  922. 

  923. AM_CONDITIONAL(HAVE_SNDFILE, $HAVE_SNDFILE)

  924. AM_CONDITIONAL(HAVE_CELT, $HAVE_CELT)

  925. AM_CONDITIONAL(HAVE_SAMPLERATE, $HAVE_SAMPLERATE)

  926. AM_CONDITIONAL(HAVE_READLINE, $HAVE_READLINE)

  927. AM_CONDITIONAL(HAVE_DOXYGEN, $HAVE_DOXYGEN)

  928. AM_CONDITIONAL(USE_CAPABILITIES, $USE_CAPABILITIES)

  929. AM_CONDITIONAL(STRIPPED_JACKD, $STRIPPED_JACKD)

  930. AM_CONDITIONAL(HAVE_PPOLL, $HAVE_PPOLL)

  931. 

  932. AC_OUTPUT(

  933. Makefile

  934. config/Makefile

  935. config/cpu/Makefile

  936. config/cpu/alpha/Makefile

  937. config/cpu/cris/Makefile

  938. config/cpu/generic/Makefile

  939. config/cpu/i386/Makefile

  940. config/cpu/i486/Makefile

  941. config/cpu/ia64/Makefile

  942. config/cpu/m68k/Makefile

  943. config/cpu/mips/Makefile

  944. config/cpu/powerpc/Makefile

  945. config/cpu/s390/Makefile

  946. config/os/Makefile

  947. config/os/generic/Makefile

  948. config/os/gnu-linux/Makefile

  949. config/os/macosx/Makefile

  950. config/sysdeps/Makefile

  951. doc/Makefile

  952. doc/reference.doxygen

  953. drivers/Makefile

  954. drivers/alsa/Makefile

  955. drivers/alsa-midi/Makefile

  956. drivers/a2j/Makefile

  957. drivers/dummy/Makefile

  958. drivers/oss/Makefile

  959. drivers/sun/Makefile

  960. drivers/portaudio/Makefile

  961. drivers/coreaudio/Makefile

  962. drivers/freebob/Makefile

  963. drivers/firewire/Makefile

  964. drivers/netjack/Makefile

  965. example-clients/Makefile

  966. tools/Makefile

  967. man/Makefile

  968. jack.pc

  969. jack.spec

  970. jack/Makefile

  971. jack/version.h

  972. jackd/Makefile

  973. jackd/jackd.1

  974. libjack/Makefile

  975. python/Makefile

  976. )

  977. 

  978. dnl

  979. dnl Output summary message

  980. dnl

  981. 

  982. echo

  983. echo $PACKAGE $VERSION :

  984. echo

  985. echo \| Build with ALSA support............................... : $HAVE_ALSA

  986. echo \| Build with old FireWire \(FreeBob\) support............. : $HAVE_FREEBOB

  987. echo \| Build with new FireWire \(FFADO\) support............... : $HAVE_FIREWIRE

  988. echo \| Build with OSS support................................ : $HAVE_OSS

  989. echo \| Build with Sun audio support.......................... : $HAVE_SUN

  990. echo \| Build with CoreAudio support.......................... : $HAVE_COREAUDIO

  991. echo \| Build with PortAudio support.......................... : $HAVE_PA

  992. echo \| Build with Celt support............................... : $HAVE_CELT

  993. echo \| Build with dynamic buffer size support................ : $buffer_resizing

  994. echo \| Compiler optimization flags........................... : $JACK_OPT_CFLAGS

  995. echo \| Compiler full flags................................... : $CFLAGS

  996. echo \| Install dir for libjack + backends.................... : $libdir/jack

  997. echo \|

  998. echo \| Default driver backend................................ : $JACK_DEFAULT_DRIVER

  999. echo \| Shared memory interface............................... : $JACK_SHM_TYPE

  1000. echo \| IPC Temporary directory............................... : $DEFAULT_TMP_DIR

  1001. echo \| Install prefix........................................ : $prefix

  1002. echo \| Default tmp dir....................................... : $DEFAULT_TMP_DIR

  1003. echo

  1004. 

  1005. 

  1006.