jackaudio
/
jack1
mirror of https://github.com/jackaudio/jack1
1
0
Fork 0
Code Releases 19 Activity
jack1 codebase
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1597 Commits
4 Branches
6.5MB
Tree: b92015cfae
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'b92015cfae'
${ noResults }
jack1/configure.ac

971 lines
30KB
Raw Blame History 

  1. dnl Process this file with autoconf to produce a configure script.

  2. dnl $Id$

  3. 

  4. AC_INIT(jackd/jackd.c)

  5. 

  6. 

  7. dnl

  8. dnl Check for existing JACK installs

  9. dnl 

  10. 

  11. AC_MSG_CHECKING([existing, conflicting JACK installs])

  12. not_overwriting=0

  13. installs=

  14. for dir in /usr/lib /usr/local/lib /opt/lib ; do

  15.     if test -d $dir ; then

  16. 	if test $(find $dir/ -name 'libjack.so.*' 2>/dev/null | wc -l) -gt 0 ; then

  17. 	    if echo $prefix/lib | grep -vs $dir >/dev/null 2>&1 ; then

  18. 		not_overwriting=$(expr $not_overwriting + 1)

  19. 	    fi

  20. 	    installs="$installs $dir"

  21. 	fi	    

  22.     fi

  23. done

  24. 

  25. if test $not_overwriting -gt 0 ; then

  26.     echo 

  27.     echo

  28.     echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"

  29.     echo "You appear to have at least one existing installation of JACK."

  30.     echo

  31.     echo "Complete or partial JACK installs exist in:$installs"

  32.     echo 

  33.     echo "Installing this version will leave at least one of these"

  34.     echo "existing installations installed and this will probably break"

  35.     echo "JACK on your machine. "

  36.     echo

  37.     echo "Before building, you should first remove the existing JACK"

  38.     echo "installation(s). "

  39.     echo

  40.     echo "Alternatively use ./configure --prefix=... to force overwriting"

  41.     echo "the existing install."

  42.     echo

  43.     echo "WARNING: ON ANY DEBIAN-DERIVED DISTRIBUTION (Debian, Ubuntu etc)"

  44.     echo "CHANGING THE INSTALLATION PREFIX WILL NOT PRODUCE A WORKING JACK"

  45.     echo "INSTALL. Please contact the distribution packager for JACK and"

  46.     echo "ask them to fix their packaging."

  47.     echo "!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!"

  48.     exit 1

  49. fi

  50. 

  51. AC_CONFIG_AUX_DIR(config)

  52. AC_CANONICAL_BUILD

  53. 

  54. dnl ---

  55. dnl HOWTO: updating the JACK version number

  56. dnl

  57. dnl major version = ask on jackit-devel :)

  58. dnl minor version = incremented when any of the public or internal

  59. dnl                 interfaces are changed

  60. dnl micro version = incremented when implementation-only

  61. dnl                 changes are made

  62. dnl ---

  63. JACK_MAJOR_VERSION=0

  64. JACK_MINOR_VERSION=124

  65. JACK_MICRO_VERSION=0

  66. 

  67. dnl ---

  68. dnl HOWTO: updating the jack protocol version

  69. dnl

  70. dnl increment the protocol version whenever a change is

  71. dnl made to the way libjack communicates with jackd

  72. dnl that would break applications statically linked with an older

  73. dnl version of libjack. NOTE: statically linking to libjack

  74. dnl is a huge mistake.

  75. dnl ---

  76. JACK_PROTOCOL_VERSION=25

  77. 

  78. dnl ---

  79. dnl HOWTO: updating the libjack interface version

  80. dnl

  81. dnl current = incremented whenever the public libjack API is changed 

  82. dnl revision = incremented when the libjack implementation is changed

  83. dnl age = current libjack is both source and binary compatible with

  84. dnl       libjack interfaces current,current-1,...,current-age

  85. dnl

  86. dnl Note! see libtool documentation for detailed documentation

  87. dnl

  88. dnl Note Also! until we reach CURRENT>=1, the rules are somewhat

  89. dnl slacker than this, and closer to those for the JACK version

  90. dnl number.

  91. dnl ---

  92. JACK_API_CURRENT=0

  93. JACK_API_REVISION=28

  94. JACK_API_AGE=0

  95. 

  96. AC_SUBST(JACK_MAJOR_VERSION)

  97. AC_SUBST(JACK_MINOR_VERSION)

  98. AC_SUBST(JACK_MICRO_VERSION)

  99. 

  100. AC_SUBST(JACK_PROTOCOL_VERSION)

  101. AC_DEFINE_UNQUOTED(PROTOCOL_VERSION, "$JACK_PROTOCOL_VERSION", [Protocol version])

  102. 

  103. AC_SUBST(JACK_API_MAJOR_VERSION)

  104. AC_SUBST(JACK_API_MINOR_VERSION)

  105. AC_SUBST(JACK_API_MICRO_VERSION)

  106. 

  107. JACK_SO_VERSION=${JACK_API_CURRENT}:${JACK_API_REVISION}:${JACK_API_AGE}

  108. 

  109. JACK_VERSION=$JACK_MAJOR_VERSION.$JACK_MINOR_VERSION.${JACK_MICRO_VERSION}${BETA}

  110. JACK_RELEASE=$JACK_MAJOR_VERSION-$JACK_MINOR_VERSION-${JACK_MICRO_VERSION}${BETA}

  111. 

  112. AC_SUBST(JACK_SO_VERSION)

  113. AC_SUBST(JACK_VERSION)

  114. AC_SUBST(JACK_RELEASE)

  115. 

  116. AM_INIT_AUTOMAKE(jack-audio-connection-kit,${JACK_VERSION})

  117. 

  118. dnl

  119. dnl save any user-provided CFLAGS so we can forget

  120. dnl about any nonsense that configure generates

  121. dnl 

  122. 

  123. ORIGINAL_CFLAGS="$CFLAGS"

  124. 

  125. AM_CONFIG_HEADER(config.h)

  126. AC_ENABLE_STATIC(no)

  127. AC_ENABLE_SHARED(yes)

  128. AC_PROG_CC

  129. AC_PROG_CXX

  130. AC_PROG_LD

  131. AM_PROG_LIBTOOL

  132. AC_PROG_LN_S

  133. AM_PROG_CC_C_O

  134. AC_C_BIGENDIAN

  135. 

  136. dnl

  137. dnl now use those user-provided CFLAGS

  138. dnl and dump whatever nonsense configure generated

  139. dnl while looking for a compiler

  140. dnl

  141. 

  142. CFLAGS="$ORIGINAL_CFLAGS"

  143. 

  144. AC_MSG_CHECKING([platform dependencies])

  145. 

  146. HOST_DEFAULT_TMP_DIR=/dev/shm

  147. case "${host_os}" in

  148.   freebsd*)

  149.     # current FreeBSD header files conflict with the OSS driver's

  150.     # barrier code, this may be fixed in 5.3, stay tuned.

  151.     USE_BARRIER="no"

  152.     ;;

  153.   openbsd*)

  154.     # pthread_barrier* not implemented

  155.     USE_BARRIER="no"

  156.     # need small realtime stack

  157.     JACK_THREAD_STACK_TOUCH=10000

  158.     ;;

  159.   darwin*)

  160.     JACK_THREAD_STACK_TOUCH=10000	# need small realtime stack

  161.     JACK_CPP_VARARGS_BROKEN=1

  162.     JACK_DO_NOT_MLOCK=1

  163.     JACK_USE_MACH_THREADS=1

  164.     OS_LDFLAGS="-framework CoreAudio -framework CoreServices -framework AudioUnit"

  165.     TRY_POSIX_SHM=yes			# POSIX shm works better

  166.     HOST_DEFAULT_TMP_DIR=/tmp

  167.     ;;

  168. esac

  169. 

  170. AC_SUBST(OS_LDFLAGS)

  171. 

  172. #

  173. # We need to establish suitable defaults for a 64-bit OS

  174. libnn=lib

  175. case "${host_os}" in

  176.     linux*)

  177.     case "${host_cpu}" in

  178. 	x86_64|mips64|ppc64|sparc64|s390x)

  179.         libnn=lib64

  180. 	;;

  181.     esac

  182.     ;;

  183.     solaris*)

  184.     ## libnn=lib/sparcv9 ## on 64-bit only, but that's compiler-specific

  185.     ;;  

  186. esac

  187. 

  188. ## take care not to  override the command-line setting

  189. if test "${libdir}" = '${exec_prefix}/lib'; then

  190.   libdir='${exec_prefix}/'${libnn}

  191. fi

  192. 

  193. # system-dependent config.h values

  194. test "x$JACK_THREAD_STACK_TOUCH" = "x" && JACK_THREAD_STACK_TOUCH=500000

  195. AC_DEFINE_UNQUOTED(JACK_THREAD_STACK_TOUCH,

  196. 	[$JACK_THREAD_STACK_TOUCH],

  197. 	[Guaranteed size of realtime stack])

  198. if test "x$JACK_CPP_VARARGS_BROKEN" != "x"; then

  199.     AC_DEFINE_UNQUOTED(JACK_CPP_VARARGS_BROKEN,

  200. 	[$JACK_CPP_VARARGS_BROKEN],

  201. 	[CPP has a broken varargs implementation])

  202. fi

  203. if test "x$JACK_USE_MACH_THREADS" != "x"; then

  204.     AC_DEFINE_UNQUOTED(JACK_USE_MACH_THREADS,

  205. 	[$JACK_USE_MACH_THREADS],

  206. 	[Use MACH threads where possible])

  207. fi

  208. 

  209. # headers

  210. AC_CHECK_HEADERS(string.h strings.h alloca.h db.h)

  211. AC_CHECK_HEADERS(getopt.h, [], [

  212.     for d in /Developer/SDKs/MacOSX10.3.0.sdk/usr/include/ ; do

  213. 	AC_CHECK_HEADERS($d/getopt.h, [], [CFLAGS="$CFLAGS -I$d"])

  214.     done])

  215. AC_CHECK_HEADER(/usr/include/nptl/pthread.h,

  216. 	[CFLAGS="$CFLAGS -I/usr/include/nptl"])

  217. 

  218. # functions and libraries

  219. AC_CHECK_FUNC(getopt_long, [],

  220.     AC_MSG_ERROR([*** JACK requires GNU getopt_long]))

  221. AC_CHECK_FUNC(gethostent, [], AC_CHECK_LIB(nsl, gethostent))

  222. AC_CHECK_FUNC(setsockopt, [], AC_CHECK_LIB(socket, setsockopt))

  223. AC_CHECK_FUNC(connect, [], AC_CHECK_LIB(inet, connect))

  224. AC_CHECK_FUNC(dlopen, [], 

  225.     AC_CHECK_LIB(dl, dlopen, [],

  226. 	AC_MSG_ERROR([*** JACK requires dynamic load support])))

  227. AC_CHECK_FUNC(pthread_create, [],

  228.     AC_CHECK_LIB(pthread, pthread_create, [],

  229. 	AC_MSG_ERROR([*** JACK requires POSIX threads support])))

  230. AC_CHECK_FUNCS(on_exit atexit)

  231. AC_CHECK_FUNCS(posix_memalign)

  232. AC_CHECK_LIB(m, sin)

  233. AC_CHECK_LIB(db, db_create)

  234. 

  235. echo -n "Checking for ppoll()... "

  236. AC_EGREP_CPP( ppoll,

  237. [

  238. #define _GNU_SOURCE

  239. #include <poll.h>

  240. ], [

  241.     	AC_DEFINE(HAVE_PPOLL,1,"Whether ppoll is available")

  242. 	echo "yes"

  243.    ],[

  244.     	AC_DEFINE(HAVE_PPOLL,0,"Whether ppoll is available")

  245. 	echo "no"

  246.    ] )

  247. 

  248. 	 

  249. 

  250. AC_CHECK_FUNC(clock_gettime, 

  251.        [

  252.            AC_DEFINE(HAVE_CLOCK_GETTIME,0,"Whether or not clock_gettime can be found in system libraries")

  253.        ], 

  254.        #

  255.        # if not found, check librt specifically

  256.        #

  257.        AC_CHECK_LIB(rt, clock_gettime, 

  258.            [

  259.               AC_DEFINE(HAVE_CLOCK_GETTIME,1,"Whether or not clock_gettime can be found in system libraries")

  260. 	      OS_LDFLAGS="$OS_LDFLAGS -lrt"

  261. 	   ])

  262. )	  

  263. 

  264. # should we use mlockall() on this platform?

  265. if test "x$JACK_DO_NOT_MLOCK" = "x"; then

  266.     AC_CHECK_HEADER(sys/mman.h,

  267.         [AC_CHECK_FUNC(mlockall,

  268. 	    [AC_DEFINE(USE_MLOCK, 1, [Use POSIX memory locking])])])

  269. fi

  270. 

  271. # look for system support for POSIX shm API

  272. AC_ARG_ENABLE(posix-shm,

  273. 	AC_HELP_STRING([--enable-posix-shm], [use POSIX shm API (default=auto)]),

  274. 	[TRY_POSIX_SHM=$enableval])

  275. if test "x$TRY_POSIX_SHM" = "xyes"

  276. then

  277. 	AC_CHECK_FUNC(shm_open, [],

  278. 		AC_CHECK_LIB(rt, shm_open, [], [TRY_POSIX_SHM=no]))

  279. fi

  280. AC_MSG_CHECKING([shared memory support])

  281. if test "x$TRY_POSIX_SHM" = "xyes"

  282. then

  283. 	AC_MSG_RESULT([POSIX shm_open().])

  284. 	AC_DEFINE(USE_POSIX_SHM,1,[Use POSIX shared memory interface])

  285. 	JACK_SHM_TYPE='"POSIX"'

  286. 	USE_POSIX_SHM="true"

  287. else

  288. 	AC_MSG_RESULT([System V shmget().])

  289. 	JACK_SHM_TYPE='"System V"'

  290. 	USE_POSIX_SHM="false"

  291. fi

  292. AC_DEFINE_UNQUOTED(JACK_SHM_TYPE, [$JACK_SHM_TYPE],

  293. 	[JACK shared memory type])

  294. AM_CONDITIONAL(USE_POSIX_SHM, $USE_POSIX_SHM)

  295. 

  296. JACK_CORE_CFLAGS="-I\$(top_srcdir)/config -I\$(top_srcdir) \

  297. -I\$(top_srcdir) -I\$(top_srcdir)/include \ 

  298. -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -Wall"

  299. 

  300. JACK_LIBC_HELPER_FLAGS=

  301. AC_ARG_ENABLE(ancient_libc,

  302. 	AC_HELP_STRING([--enable-ancient-libc],[Add required CFLAGS for libc versions too old to expose PThread R/W Lock and other modern code]),

  303. 	JACK_LIBC_HELPER_FLAGS="-D_XOPEN_SOURCE=600 -D_BSD_SOURCE",

  304. 	JACK_LIBC_HELPER_FLAGS=""

  305. 	)

  306. 	 

  307. JACK_CORE_CFLAGS="$JACK_CORE_CFLAGS $JACK_LIBC_HELPER_FLAGS"   

  308. 

  309. case $build_os in

  310.      # we need weak linkage which appeared in 10.2, but lets ask for 10.4 anyway

  311.      darwin*) JACK_CORE_CFLAGS="$JACK_CORE_CFLAGS -mmacosx-version-min=10.4" ;;

  312. esac    

  313. 

  314. AC_ARG_WITH(cpu-target,

  315.             [  --with-cpu-target=cpu-type    explicit, overriding argument for gcc -march= flag])

  316. 

  317. 

  318. dnl

  319. dnl figure out how best to optimize

  320. dnl JOQ: this should be done via config/configure.hosts

  321. dnl

  322. 

  323. dnl ----------------------------------------------------------------------

  324. 

  325. if test "$build_cpu" = "powerpc64" ; then

  326. 

  327.     AC_ARG_ENABLE(cell,

  328. 	AC_HELP_STRING([--enable-cell],[enable Cell BE support (default=no)]),,

  329. 	[ enable_cell=no ])

  330. 

  331.     if test "x$enable_cell" = xyes; then

  332.         AC_DEFINE(ENABLE_CELLBE, 1, [Define to 1 if you need support for the Cell BE.])

  333.     fi

  334. 

  335. fi

  336. 

  337. if test "build_cpu" = "powerpc" -o "$build_cpu" = "powerpc64" ; then

  338. 

  339.     AC_DEFINE(POWERPC, 1, "Are we running a ppc CPU?")

  340.     

  341. ############################

  342. # Check for Altivec assembly

  343. ############################

  344. 

  345.     AC_ARG_ENABLE(altivec,

  346. 	AC_HELP_STRING([--enable-altivec],[enable Altivec support (default=auto)]),,

  347. 	[ enable_altivec=yes ])

  348.     

  349.     if test "x$enable_altivec" = xyes; then

  350. 	

  351. 	AC_MSG_CHECKING(whether we can compile Altivec code)

  352. 	

  353. 	AC_COMPILE_IFELSE([asm ("vand %v0, %v0, %v0");],

  354. 	    AC_DEFINE(USE_ALTIVEC, 1, [Define to 1 if Altivec assembly is available.])

  355. 	    AC_DEFINE(HAVE_ALTIVEC_LINUX, 1, "Is there Altivec Support ?")

  356. 	    ALTIVEC_OPT_FLAGS="-maltivec -mabi=altivec"

  357. 	    AC_MSG_RESULT(yes)

  358. 	    ,

  359. 	    enable_altivec=no

  360. 	    AC_MSG_RESULT(no)

  361. 	    AC_MSG_WARN([The assembler does not support the Altivec command set.])

  362. 	)

  363. 	

  364.     fi

  365. 

  366.     dnl -mcpu=7450 does not reliably work with gcc 3.*

  367.     

  368.     JACK_OPT_CFLAGS="-O2 -mcpu=7400 $ALTIVEC_OPT_FLAGS -mhard-float -mpowerpc-gfxopt"

  369. 

  370.     if test "$build_cpu" = "powerpc64"; then

  371. 	JACK_OPT_CFLAGS="-O2 -mcpu=powerpc64 $ALTIVEC_OPT_FLAGS -mhard-float" 

  372.     fi

  373. 

  374. elif echo $build_cpu | egrep '(i.86|x86_64)' >/dev/null; then

  375. 

  376.     dnl Check for SSE usability

  377.     

  378.     if test -r /proc/cpuinfo ; then

  379. 	procflags=`grep '^flags' /proc/cpuinfo`

  380. 	if echo $procflags | grep -s sse ; then

  381. 	    cpu_supports_sse=yes

  382. 	fi

  383.     else

  384. 	# this is not linux, but assume that if the processor

  385. 	# is x86 then is supports SSE

  386.         cpu_supports_sse=yes

  387. 	AC_MSG_WARN([Assuming your x86/x86_64 system can support SSE. Use --disable-sse if this is not the case])

  388.     fi

  389.     

  390.     AC_ARG_ENABLE(optimization-by-compiler,

  391. 	AC_HELP_STRING([--enable-optimization-by-compiler],[use compiler (NOT processor) capabilities to determine optimization flags (default=no)]),

  392. 	optimization_by_compiler=yes,

  393. 	optimization_by_compiler=no

  394.     )

  395.     

  396.     AC_ARG_ENABLE(optimization-by-cpu,

  397. 	AC_HELP_STRING([--enable-optimization-by-cpu],[use processor capabilities to determine optimization flags (default=yes)]),,

  398. 	optimization_by_cpu=yes

  399.     )

  400.     

  401.     AC_ARG_ENABLE(sse,

  402. 	AC_HELP_STRING([--enable-sse],[enable SSE support (default=auto)]),,

  403. 	enable_sse=yes)

  404.     

  405. 

  406.     if test "x$enable_sse" = xyes; then

  407. 	

  408. 	AC_MSG_CHECKING(whether we can compile SSE code)

  409. 	

  410. 	AC_COMPILE_IFELSE([asm ("movntps %xmm0, 0");],

  411. 	    [

  412. 		if test x$optimization_by_cpu = xyes ; then

  413. 		    if test x$cpu_supports_sse = xyes ; then

  414. 			SSE_FLAGS="-msse -mfpmath=sse"

  415. 		    fi

  416. 		else 

  417. 		    SSE_FLAGS="-msse -mfpmath=sse"

  418. 		fi

  419. 		

  420. 		AC_MSG_RESULT(yes)

  421. 		],

  422. 	    [

  423. 		enable_sse=no

  424. 		AC_MSG_RESULT(no)

  425. 		AC_MSG_WARN([The assembler does not support the SSE command set.]) 

  426. 		])

  427.     fi

  428.     

  429.     AC_DEFINE(x86, 1, "Nope it's intel")

  430.     COMMON_X86_OPT_FLAGS="-O3 -fomit-frame-pointer -ffast-math -funroll-loops"

  431. 

  432. dnl

  433. dnl its a little sad that OS X doesn't make it possible to identify 

  434. dnl the build_cpu a little more precisely. on os x we always get "i386"

  435. dnl as the CPU type. we miss out on some possible optimizations as 

  436. dnl a result. oh well.

  437. dnl     

  438.     

  439.     if test x$with_cpu_target != x ; then

  440.         JACK_OPT_CFLAGS="-march=$with_cpu_target -mtune=$with_cpu_target"

  441.     else

  442.         case ${host_os} in

  443. 	    darwin*) # apple gcc, not GNU

  444. 	             JACK_OPT_CFLAGS="-mtune=generic" ;;

  445. 	          *) # any other gcc

  446. 		     JACK_OPT_CFLAGS="-march=native -mtune=native" ;;

  447. 	esac

  448.     fi

  449. 

  450. dnl

  451. dnl do not add h/w specific flags if asked to let compiler

  452. dnl to the optimization

  453. dnl    

  454. 

  455.     if test x$optimization_by_compiler != xyes ; then

  456.         JACK_OPT_CFLAGS="$COMMON_X86_OPT_FLAGS $JACK_OPT_CFLAGS $SSE_FLAGS"

  457.     else

  458.        JACK_OPT_CFLAGS="$COMMON_X86_OPT_FLAGS"

  459.     fi

  460. 

  461. fi

  462. 

  463. AC_ARG_ENABLE(dynsimd,

  464. 	AC_HELP_STRING([--enable-dynsimd],[enable dynamic SIMD selection (default=no)]),,

  465.     enable_dynsimd=no)

  466. 

  467. if test "x$enable_dynsimd" = xyes; then

  468. 	AC_DEFINE(USE_DYNSIMD, 1, [Define to 1 to use dynamic SIMD selection.])

  469. 	dnl This needs update once there's more than x86/x86-64 supported

  470. 	SIMD_CFLAGS="-O -msse -msse2 -m3dnow"

  471. 	AC_SUBST(SIMD_CFLAGS)

  472. fi

  473. 

  474. AC_ARG_ENABLE(optimize,

  475.     AC_HELP_STRING([--enable-optimize],

  476. 	[optimize code, based on CPU or compiler, as separately selected (default=no)]),

  477.     [ if test x$enable_optimize != xno ; then

  478. 	AC_MSG_WARN([optimization in use.........................])

  479.       else

  480.         # no optimization, so lets get debugging symbols instead

  481. 	JACK_OPT_CFLAGS="-g"

  482. 	AC_MSG_WARN([no optimization.........................])

  483.       fi 

  484.     ],

  485.     [

  486.         # no optimization, so lets get debugging symbols instead

  487. 	JACK_OPT_CFLAGS="-g"

  488. 	AC_MSG_WARN([no optimization.........................])

  489.     ]

  490. )

  491. 

  492. JACK_CFLAGS="$JACK_CORE_CFLAGS $JACK_OPT_CFLAGS"

  493. 

  494. dnl

  495. dnl most makefiles use JACK_CFLAGS, but simd code needs JACK_CORE_CFLAGS

  496. dnl

  497. 

  498. AC_SUBST(JACK_CFLAGS)

  499. AC_SUBST(JACK_CORE_CFLAGS)

  500. 

  501. dnl

  502. dnl use JACK_CFLAGS for jackd compilation

  503. dnl 

  504. 

  505. CFLAGS="$CFLAGS $JACK_CFLAGS"

  506. 

  507. # allow buffer resizing unless --disable-resize specified

  508. buffer_resizing=yes

  509. AC_ARG_ENABLE(resize,

  510. 	AC_HELP_STRING([--enable-resize], [enable buffer resizing feature (default=yes)]),

  511.         [ 

  512. 	  if test x$enable_resize = xno ; then

  513. 	  	buffer_resizing=no

  514. 	  fi

  515. 	 ]

  516. )

  517. 

  518. if test x$buffer_resizing != xno; then 

  519.    AC_DEFINE(DO_BUFFER_RESIZE,,[Enable buffer resizing])

  520. fi

  521. 

  522. AC_ARG_ENABLE(valgrind-clean,

  523. 	AC_HELP_STRING([--enable-valgrind-clean],[spend a few extra CPU cycles avoiding unnecessary valgrind warnings (default=no)]),

  524.         [ 

  525. 	  if test x$enable_valgrind_clean != xno ; then

  526. 	     AC_DEFINE(VALGRIND_CLEAN,,[clean up for valgrind])

  527.           fi

  528.         ]

  529. )

  530. 

  531. AC_ARG_ENABLE(debug,

  532. 	AC_HELP_STRING([--enable-debug],

  533. 		[enable debugging messages in jackd and libjack (default=no)]),

  534.         [ 

  535. 	  if test x$enable_debug != xno ; then

  536. 	     AC_DEFINE(DEBUG_ENABLED,,[Enable debugging messages])

  537.           fi

  538.         ]

  539. )

  540. 

  541. AC_ARG_ENABLE(timestamps,

  542. 	AC_HELP_STRING([--enable-timestamps],

  543. 		[allow clients to use the JACK timestamp API (JACK developers only) (default=no)]),

  544.         [ 

  545. 	  if test x$enable_timestamps != xno ; then

  546. 	  	AC_DEFINE(WITH_TIMESTAMPS,,[Enable JACK timestamp API])

  547.           fi

  548.         ]		

  549. )

  550. 

  551. AC_ARG_ENABLE(preemption-check,

  552. 	AC_HELP_STRING([--enable-preemption-check],

  553. 		[check for inappropriate realtime preemption (requires a specially built Linux kernel) (default=no)]),

  554. 		[

  555. 		  if test x$enable_preemption_check != xno ; then

  556. 			echo checking for realtime preemption bugs

  557. 			AC_DEFINE(DO_PREEMPTION_CHECKING,,

  558. 				[check realtime preemption])

  559. 		  fi

  560. 		])

  561. 

  562. USE_CAPABILITIES=false

  563. 

  564. AC_ARG_ENABLE(capabilities,

  565. 	AC_HELP_STRING([--enable-capabilities],[!!! LINUX 2.4 KERNELS ONLY !!! use libcap to gain realtime scheduling priviledges]),

  566.               [ if test "x$enable_capabilities" != "xno" ; then

  567.                     AC_CHECK_LIB(cap, capgetp,

  568.                                  [AC_CHECK_HEADER(sys/capability.h,

  569.                                                   [HAVE_CAPABILITIES=true],

  570.                                                   [AC_MSG_WARN([*** no kernel support for capabilities])

  571.                                                    HAVE_CAPABILITIES=false]

  572.                                   )],

  573.                                  [AC_MSG_WARN([*** no libcap present])

  574.                                   HAVE_CAPABILITIES=false]

  575.                     )

  576.                     if test "x$HAVE_CAPABILITIES" = "xtrue"; then

  577.                         AC_CHECK_PROG(HAVE_CAPABILITIES, md5sum, true, false)

  578.                     fi

  579.                     if test "x$HAVE_CAPABILITIES" = "xfalse"; then

  580.                         AC_MSG_WARN([*** required program md5sum not found])

  581.                     fi

  582.                     if test "x$HAVE_CAPABILITIES" = "xfalse"; then

  583.                         AC_MSG_ERROR([*** Capabilities support not present. Run configure again without --enable-capabilities.])

  584.                     fi

  585.                     USE_CAPABILITIES=true

  586.                     AC_DEFINE(USE_CAPABILITIES,,[Enable POSIX 1.e capabilities support])

  587.                 fi

  588.               ]

  589. )

  590. 

  591. with_oldtrans=yes

  592. AC_ARG_ENABLE(oldtrans,

  593. 	AC_HELP_STRING([--disable-oldtrans],[remove old transport interfaces (default=yes)]),

  594.               [ if test "x$enable_oldtrans" = "xno" ; then

  595. 		    with_oldtrans=no

  596. 		fi 

  597. 	      ]

  598. )

  599. if test "x$with_oldtrans" != "xno" ; then

  600. 	AC_DEFINE(OLD_TRANSPORT,,[Include old transport interfaces])

  601. fi

  602. 

  603. STRIPPED_JACKD=false

  604. AC_ARG_ENABLE(stripped-jackd,

  605. 	AC_HELP_STRING([--enable-stripped-jackd],[strip jack before computing its md5 sum (useful only with Linux 2.4 kernel)]),

  606.               [ if test "x$USE_CAPABILITIES" != "xtrue" ; then	    

  607.                     AC_MSG_WARN([*** capabilities not enabled, stripped jackd has no effect])

  608.                 elif test "x$enable_stripped_jackd" != "xno"; then

  609.                     STRIPPED_JACKD=true		    

  610.                 fi  

  611.               ]	

  612. )

  613. 

  614. # plugins go in the addon dir.

  615. 

  616. ADDON_DIR='${libdir}/jack'

  617. AC_SUBST(ADDON_DIR)

  618. AS_AC_EXPAND(ADDON_DIR_EXPANDED,${libdir}/jack)

  619. AC_DEFINE_UNQUOTED(ADDON_DIR,"$ADDON_DIR_EXPANDED",[Directory for plugins])

  620. 

  621. AC_ARG_WITH(html-dir,

  622. 		AC_HELP_STRING([--with-html-dir=PATH],[where to install the html documentation]))

  623. 

  624. if test "x$with_html_dir" = "x" ; then

  625.     HTML_DIR='${pkgdatadir}'

  626. else

  627.     HTML_DIR=$with_html_dir

  628. fi

  629. 

  630. AC_SUBST(HTML_DIR)

  631. 

  632. 

  633. # allow specifying default tmpdir

  634. AC_ARG_WITH(default-tmpdir,

  635.             AC_HELP_STRING([--with-default-tmpdir],[where jackd and clients will put tmp files (default=/dev/shm)]))

  636. 

  637. if test "x$with_default_tmpdir" = "x" ; then

  638. 	DEFAULT_TMP_DIR=$HOST_DEFAULT_TMP_DIR

  639. else

  640. 	DEFAULT_TMP_DIR=$with_default_tmpdir

  641. fi

  642. 

  643. AC_SUBST(DEFAULT_TMP_DIR)

  644. AC_DEFINE_UNQUOTED(DEFAULT_TMP_DIR,"$DEFAULT_TMP_DIR",[Default tmp directory])

  645. 

  646. # Check for barrier functions in the pthreads library.  The default

  647. # option setting may be OS-dependent, otherwise it's "yes".

  648. test "x$USE_BARRIER" = "x" && USE_BARRIER="yes"

  649. AC_ARG_WITH(barrier,

  650. 	AC_HELP_STRING([--without-barrier],

  651. 		       [avoid using pthread barrier functions (only used by OSS driver)]),

  652. 	[ USE_BARRIER=$withval ])

  653. if test "x$USE_BARRIER" = "xyes"; then

  654. 	AC_CHECK_LIB([pthread], [pthread_barrier_init],

  655. 		AC_DEFINE(USE_BARRIER, 1, [Use pthread barrier functions]))

  656. fi

  657. 

  658. HAVE_UUID=false

  659. PKG_CHECK_MODULES(UUID,uuid > 1.0,[HAVE_UUID=true], [true])

  660. if test x$HAVE_UUID = xfalse ; then

  661.       AC_MSG_ERROR([*** You do not have libuuid installed])

  662. else

  663.         CFLAGS="$CFLAGS $UUID_CFLAGS"

  664.         LIBS="$LIBS $UUID_LIBS"

  665. fi

  666. 

  667. # some example-clients need libsndfile

  668. HAVE_SNDFILE=false

  669. PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0,[HAVE_SNDFILE=true], [true])

  670. if test x$HAVE_SNDFILE = xfalse; then

  671.              AC_MSG_WARN([*** the jackrec example client will not be built])

  672. fi

  673. 

  674. # NetJack backend and internal client need libsamplerate

  675. HAVE_SAMPLERATE=false

  676. PKG_CHECK_MODULES(SAMPLERATE, samplerate >= 0.1.2,[HAVE_SAMPLERATE=true], [true])

  677. if test x$HAVE_SAMPLERATE = xfalse; then

  678.         AC_MSG_WARN([*** the NetJack backend and internal client will not be built])

  679.     	AC_DEFINE(HAVE_SAMPLERATE,0,"Whether libsamplerate is available")

  680. else

  681. 	NETJACK_CFLAGS="$NETJACK_CFLAGS $SAMPLERATE_CFLAGS"

  682. 	NETJACK_LIBS="$NETJACK_LIBS $SAMPLERATE_LIBS"

  683.     	AC_DEFINE(HAVE_SAMPLERATE,1,"Whether libsamplerate is available")

  684. fi

  685. 

  686. # Celt low-latency audio codec. netjack transmission via internet.

  687. HAVE_CELT=false

  688. PKG_CHECK_MODULES(CELT, celt >= 0.8.0,[HAVE_CELT=true], [true])

  689. if test x$HAVE_CELT = xfalse; then

  690. 	PKG_CHECK_MODULES(CELT, celt >= 0.7.0,[HAVE_CELT=true], [true])

  691. 	if test x$HAVE_CELT = xfalse; then

  692. 		PKG_CHECK_MODULES(CELT, celt >= 0.5.0,[HAVE_CELT=true], [true])

  693. 		if test x$HAVE_CELT = xfalse; then

  694. 			AC_DEFINE(HAVE_CELT,0,"Whether CELT is available")

  695. 			AC_MSG_RESULT(no)

  696. 			AC_MSG_WARN([*** NetJack will not be built with celt support])

  697. 		else

  698. 			AC_DEFINE(HAVE_CELT,1,"Whether CELT is available")

  699. 			AC_DEFINE(HAVE_CELT_API_0_5,1,"Whether CELT API is 0.5 API")

  700. 			AC_DEFINE(HAVE_CELT_API_0_7,0,"Whether CELT API is 0.7 API")

  701. 			AC_DEFINE(HAVE_CELT_API_0_8,0,"Whether CELT API is 0.8 API")

  702. 			AC_MSG_RESULT(yes (0.5))

  703. 			NETJACK_LIBS="$NETJACK_LIBS $CELT_LIBS"

  704. 		fi

  705. 	else

  706. 		AC_DEFINE(HAVE_CELT,1,"Whether CELT is available")

  707. 		AC_MSG_RESULT(yes (0.7))

  708. 		AC_DEFINE(HAVE_CELT_API_0_5,0,"Whether CELT API is 0.5 API")

  709. 		AC_DEFINE(HAVE_CELT_API_0_7,1,"Whether CELT API is 0.7 API")

  710. 		AC_DEFINE(HAVE_CELT_API_0_8,0,"Whether CELT API is 0.8 API")

  711. 		NETJACK_LIBS="$NETJACK_LIBS $CELT_LIBS"

  712. 	fi

  713. else

  714. 		AC_DEFINE(HAVE_CELT,1,"Whether CELT is available")

  715. 		AC_MSG_RESULT(yes (0.7))

  716. 		AC_DEFINE(HAVE_CELT_API_0_5,0,"Whether CELT API is 0.5 API")

  717. 		AC_DEFINE(HAVE_CELT_API_0_7,0,"Whether CELT API is 0.7 API")

  718. 		AC_DEFINE(HAVE_CELT_API_0_8,1,"Whether CELT API is 0.8 API")

  719. 		NETJACK_LIBS="$NETJACK_LIBS $CELT_LIBS"

  720. fi

  721. 

  722. AC_SUBST(NETJACK_LIBS)

  723. AC_SUBST(NETJACK_CFLAGS)

  724. 

  725. # Note: A bug in pkg-config causes problems if the first occurence of

  726. # PKG_CHECK_MODULES can be disabled. So, if you're going to use

  727. # PKG_CHECK_MODULES inside a --disable-whatever check, you need to

  728. # do it somewhere *below* this comment.

  729. 

  730. # Check which backend drivers can be built.  The last one successfully

  731. # configured becomes the default JACK driver; so the order of

  732. # precedence is: alsa, sun, oss, coreaudio, portaudio, dummy.

  733. 

  734. JACK_DEFAULT_DRIVER=\"dummy\"

  735. 

  736. AC_ARG_ENABLE(portaudio,

  737. 	AC_HELP_STRING([--enable-portaudio],[build PortAudio driver]),

  738.    TRY_PORTAUDIO=$enableval , TRY_PORTAUDIO=no)

  739. 

  740. HAVE_PA="false"

  741. if test "x$TRY_PORTAUDIO" = "xyes"

  742. then

  743. 	# check for portaudio V18

  744. 	AC_CHECK_LIB(portaudio, Pa_Initialize,

  745. 		[ AC_CHECK_HEADERS(portaudio.h,

  746. 			[ HAVE_PA="true"

  747. 			  PA_LIBS=-lportaudio

  748. 			  JACK_DEFAULT_DRIVER=\"portaudio\"

  749. 			])

  750. 		])

  751. 	AC_SUBST(PA_LIBS)

  752. fi

  753. AM_CONDITIONAL(HAVE_PA, $HAVE_PA)

  754. 

  755. AC_ARG_ENABLE(coreaudio, AC_HELP_STRING([--disable-coreaudio], [ignore CoreAudio driver]),

  756. 			TRY_COREAUDIO=$enableval , TRY_COREAUDIO=yes )

  757. HAVE_COREAUDIO="false"

  758. if test "x$TRY_COREAUDIO" = "xyes"

  759. then

  760. 	# check for coreaudio

  761. 	AC_CHECK_HEADERS(CoreAudio/CoreAudio.h,

  762. 		[ HAVE_COREAUDIO="true"

  763. 		  JACK_DEFAULT_DRIVER=\"coreaudio\"

  764. 		])

  765. fi

  766. AM_CONDITIONAL(HAVE_COREAUDIO, $HAVE_COREAUDIO)

  767. 

  768. AC_ARG_ENABLE(oss, AC_HELP_STRING([--disable-oss],[ignore OSS driver ]),

  769. 			TRY_OSS=$enableval , TRY_OSS=yes ) 

  770. HAVE_OSS="false"

  771. if test "x$TRY_OSS" = "xyes"

  772. then

  773. 	# check for Open Sound System

  774. 	AC_CHECK_HEADER([sys/soundcard.h],

  775. 	     [HAVE_OSS="true"

  776.               JACK_DEFAULT_DRIVER=\"oss\"])

  777. fi

  778. AM_CONDITIONAL(HAVE_OSS, $HAVE_OSS)

  779. 

  780. AC_ARG_ENABLE(sun, AC_HELP_STRING([--disable-sun],[ignore Sun driver ]),

  781. 			TRY_SUN=$enableval , TRY_SUN=yes ) 

  782. HAVE_SUN="false"

  783. if test "x$TRY_SUN" = "xyes"

  784. then

  785. 	# check for Sun audio API

  786. 	AC_CHECK_HEADER([sys/audioio.h],

  787. 	     [HAVE_SUN="true"

  788.               JACK_DEFAULT_DRIVER=\"sun\"])

  789. fi

  790. AM_CONDITIONAL(HAVE_SUN, $HAVE_SUN)

  791. 

  792. AC_ARG_ENABLE(freebob, AC_HELP_STRING([--disable-freebob],[ignore FreeBob driver ]),

  793. 			TRY_FREEBOB=$enableval , TRY_FREEBOB=yes ) 

  794. HAVE_FREEBOB="false"

  795. if test "x$TRY_FREEBOB" = "xyes"

  796. then

  797. 	# check for FreeBob libraries

  798. 	PKG_CHECK_MODULES(LIBFREEBOB, libfreebob >= 1.0.0,

  799. 	     [HAVE_FREEBOB="true"

  800.               JACK_DEFAULT_DRIVER=\"freebob\"

  801. 	     ], AC_MSG_RESULT([no]))

  802. 

  803. 	AC_SUBST([LIBFREEBOB_CFLAGS])

  804. 	AC_SUBST([LIBFREEBOB_LIBS])

  805. 

  806. fi

  807. AM_CONDITIONAL(HAVE_FREEBOB,$HAVE_FREEBOB)

  808. 

  809. AC_ARG_ENABLE(firewire, AC_HELP_STRING([--disable-firewire],[ignore FireWire driver (FFADO)]),

  810. 			TRY_FIREWIRE=$enableval , TRY_FIREWIRE=yes ) 

  811. HAVE_FIREWIRE="false"

  812. if test "x$TRY_FIREWIRE" = "xyes"

  813. then

  814. 	# check for FFADO libraries

  815. 	PKG_CHECK_MODULES(LIBFFADO, libffado >= 1.999.17,

  816. 	     [HAVE_FIREWIRE="true"

  817.               JACK_DEFAULT_DRIVER=\"firewire\"

  818. 	     ], AC_MSG_RESULT([no]))

  819. 

  820. 	AC_SUBST([LIBFFADO_CFLAGS])

  821. 	AC_SUBST([LIBFFADO_LIBS])

  822. 

  823. fi

  824. AM_CONDITIONAL(HAVE_FIREWIRE,$HAVE_FIREWIRE)

  825. 

  826. AC_ARG_ENABLE(alsa, AC_HELP_STRING([--disable-alsa],[ignore ALSA driver ]),

  827. 			TRY_ALSA=$enableval , TRY_ALSA=yes ) 

  828. HAVE_ALSA="false"

  829. if test "x$TRY_ALSA" = "xyes"

  830. then

  831. 	# check for ALSA >= 1.0.18

  832. 	PKG_CHECK_MODULES(ALSA, alsa >= 1.0.18,

  833. 	     [HAVE_ALSA="true"

  834.               ALSA_LIBS=-lasound

  835.               JACK_DEFAULT_DRIVER=\"alsa\"

  836.              ], AC_MSG_RESULT([no - cannot find ALSA 1.0.18 or later]), [-lm]

  837. 	)

  838. 	AC_SUBST(ALSA_LIBS)

  839. fi

  840. AM_CONDITIONAL(HAVE_ALSA, $HAVE_ALSA)

  841. 

  842. HAVE_ALSA_MIDI=$HAVE_ALSA

  843. AM_CONDITIONAL(HAVE_ALSA_MIDI, $HAVE_ALSA_MIDI)

  844. 

  845. if test "$JACK_DEFAULT_DRIVER" = \"dummy\"; then

  846.   AC_MSG_WARN([Only the dummy driver can be built])

  847. fi

  848. AC_DEFINE_UNQUOTED(JACK_DEFAULT_DRIVER,

  849. 	[$JACK_DEFAULT_DRIVER],

  850. 	[Default JACK driver])

  851. 

  852. JACK_SEMAPHORE_KEY=0x282929

  853. AC_DEFINE_UNQUOTED(JACK_SEMAPHORE_KEY,

  854. 	  [$JACK_SEMAPHORE_KEY],

  855. 	  [ an integer constant used as the semaphore and SysV SHM key. see libjack/shm.c for usage])

  856. AC_SUBST(JACK_SEMAPHORE_KEY)

  857. 

  858. # On some systems, readline depends on termcap or ncurses.  But, the

  859. # MacOSX linker complains bitterly if these libraries are explicitly

  860. # referenced.  

  861. #

  862. # AC_CHECK_LIB() foolishly assumes that checking a library for an entry

  863. # point always returns the same result regardless of any dependent

  864. # libraries specified.  The `unset ac_cv_lib_readline_readline' erases

  865. # the cached result to work around this problem.

  866. READLINE_DEPS=""

  867. HAVE_READLINE=true

  868. AC_CHECK_LIB(readline, readline, [:],

  869.     [unset ac_cv_lib_readline_readline

  870.      AC_CHECK_LIB(readline, readline, [READLINE_DEPS="-ltermcap"],

  871.         [unset ac_cv_lib_readline_readline

  872. 	 AC_CHECK_LIB(readline, readline,

  873. 	    [READLINE_DEPS="-lncurses"], [HAVE_READLINE=false], "-lncurses")],

  874. 	"-ltermcap")])

  875. AC_CHECK_HEADER(readline/chardefs.h, [], [HAVE_READLINE=false])

  876. if test x$HAVE_READLINE = xfalse; then

  877. 	AC_MSG_WARN([*** the jack_transport example client will not be built])

  878. fi

  879. AC_SUBST(READLINE_DEPS)

  880. 

  881. # you need doxygen to make dist.

  882. AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, true, false)

  883. if test $HAVE_DOXYGEN = "false"; then

  884.              AC_MSG_WARN([*** doxygen not found, docs will not be built])

  885. fi

  886. 

  887. AM_CONDITIONAL(HAVE_SNDFILE, $HAVE_SNDFILE)

  888. AM_CONDITIONAL(HAVE_CELT, $HAVE_CELT)

  889. AM_CONDITIONAL(HAVE_SAMPLERATE, $HAVE_SAMPLERATE)

  890. AM_CONDITIONAL(HAVE_READLINE, $HAVE_READLINE)

  891. AM_CONDITIONAL(HAVE_DOXYGEN, $HAVE_DOXYGEN)

  892. AM_CONDITIONAL(USE_CAPABILITIES, $USE_CAPABILITIES)

  893. AM_CONDITIONAL(STRIPPED_JACKD, $STRIPPED_JACKD)

  894. AM_CONDITIONAL(HAVE_PPOLL, $HAVE_PPOLL)

  895. 

  896. AC_OUTPUT(

  897. Makefile

  898. config/Makefile

  899. config/cpu/Makefile

  900. config/cpu/alpha/Makefile

  901. config/cpu/cris/Makefile

  902. config/cpu/generic/Makefile

  903. config/cpu/i386/Makefile

  904. config/cpu/i486/Makefile

  905. config/cpu/ia64/Makefile

  906. config/cpu/m68k/Makefile

  907. config/cpu/mips/Makefile

  908. config/cpu/powerpc/Makefile

  909. config/cpu/s390/Makefile

  910. config/os/Makefile

  911. config/os/generic/Makefile

  912. config/os/gnu-linux/Makefile

  913. config/os/macosx/Makefile

  914. config/sysdeps/Makefile

  915. doc/Makefile

  916. doc/reference.doxygen

  917. drivers/Makefile

  918. drivers/alsa/Makefile

  919. drivers/alsa-midi/Makefile

  920. drivers/dummy/Makefile

  921. drivers/oss/Makefile

  922. drivers/sun/Makefile

  923. drivers/portaudio/Makefile

  924. drivers/coreaudio/Makefile

  925. drivers/freebob/Makefile

  926. drivers/firewire/Makefile

  927. drivers/netjack/Makefile

  928. example-clients/Makefile

  929. tools/Makefile

  930. tools/alsa_midi/Makefile

  931. man/Makefile

  932. jack.pc

  933. jack.spec

  934. jackd/Makefile

  935. jackd/jackd.1

  936. include/version.h

  937. include/Makefile

  938. libjack/Makefile

  939. python/Makefile

  940. )

  941. 

  942. dnl

  943. dnl Output summary message

  944. dnl

  945. 

  946. echo

  947. echo $PACKAGE $VERSION :

  948. echo

  949. echo \| Build with ALSA support............................... : $HAVE_ALSA

  950. echo \| Build with old FireWire \(FreeBob\) support............. : $HAVE_FREEBOB

  951. echo \| Build with new FireWire \(FFADO\) support............... : $HAVE_FIREWIRE

  952. echo \| Build with OSS support................................ : $HAVE_OSS

  953. echo \| Build with Sun audio support.......................... : $HAVE_SUN

  954. echo \| Build with CoreAudio support.......................... : $HAVE_COREAUDIO

  955. echo \| Build with PortAudio support.......................... : $HAVE_PA

  956. echo \| Build with Celt support............................... : $HAVE_CELT

  957. echo \| Build with dynamic buffer size support................ : $buffer_resizing

  958. echo \| Compiler optimization flags........................... : $JACK_OPT_CFLAGS

  959. echo \| Compiler full flags................................... : $CFLAGS

  960. echo \| Install dir for libjack + backends.................... : $libdir/jack

  961. echo \|

  962. echo \| Default driver backend................................ : $JACK_DEFAULT_DRIVER

  963. echo \| Shared memory interface............................... : $JACK_SHM_TYPE

  964. echo \| IPC Temporary directory............................... : $DEFAULT_TMP_DIR

  965. echo \| Install prefix........................................ : $prefix

  966. echo \| Default tmp dir....................................... : $DEFAULT_TMP_DIR

  967. echo

  968. 

  969. 

  970.