rtaudio/configure.ac

# Process this file with autoconf to produce a configure script.
AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
AC_CONFIG_AUX_DIR(config)
AC_CONFIG_SRCDIR(RtAudio.cpp)
AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])

# libtool version: current:revision:age
#
# If the library source code has changed at all since the last update, then
# increment revision (`c:r:a' becomes `c:r+1:a').
#
# If any interfaces have been added, removed, or changed since the last update,
# increment current, and set revision to 0.
#
# If any interfaces have been added since the last public release, then
# increment age.
#
# If any interfaces have been removed since the last public release, then set
# age to 0.
m4_define([lt_current], 6)
m4_define([lt_revision], 0)
m4_define([lt_age], 0)

m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])

SO_VERSION=lt_version_info
AC_SUBST(SO_VERSION)
AC_SUBST(api)
AC_SUBST(req)

api=""
req=""
use_asio=""


# configure flags
AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug],[enable various debug output])])
AC_ARG_WITH(jack, [AS_HELP_STRING([--with-jack], [choose JACK server support (mac and linux only)])])
AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa], [choose native ALSA API support (linux only)])])
AC_ARG_WITH(pulse, [AS_HELP_STRING([--with-pulse], [choose PulseAudio API support (linux only)])])
AC_ARG_WITH(oss, [AS_HELP_STRING([--with-oss], [choose OSS API support (unixes)])])
AC_ARG_WITH(core, [AS_HELP_STRING([--with-core], [choose CoreAudio API support (mac only)])])
AC_ARG_WITH(asio, [AS_HELP_STRING([--with-asio], [choose ASIO API support (win32 only)])])
AC_ARG_WITH(ds, [AS_HELP_STRING([--with-ds], [choose DirectSound API support (win32 only)])])
AC_ARG_WITH(wasapi, [AS_HELP_STRING([--with-wasapi], [choose Windows Audio Session API support (win32 only)])])

# Check version number coherency between RtAudio.h and configure.ac
AC_MSG_CHECKING([that version numbers are coherent])
RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
AS_IF([test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],[
   AC_MSG_RESULT([no])
   AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])
   ],[
   AC_MSG_RESULT([yes])
])
# Enable some nice automake features if they are available
m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

# Fill GXX with something before test.
GXX="no"
# if the user did not provide any CXXFLAGS, we can override them
AS_IF([test "x$CXXFLAGS" = "x" ], [override_cxx=yes], [override_cxx=no])
AS_IF([test "x$CFLAGS" = "x" ], [override_c=yes], [override_c=no])

# Checks for programs.
AC_PROG_CXX(g++ CC c++ cxx)
AM_PROG_AR
AC_PATH_PROG(AR, ar, no)
AS_IF([test "x${AR}" = "xno" ], [
    AC_MSG_ERROR([Could not find ar - needed to create a library])
])

# Initialize libtool
LT_INIT([win32-dll])
AC_CONFIG_MACRO_DIR([m4])

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(sys/ioctl.h unistd.h)

# Check compiler and use -Wall if gnu
AS_IF([test "x${GXX}" = "xyes" ], [
  CXXFLAGS="-Wall -Wextra ${CXXFLAGS}"
  AS_IF([ test "x${enable_debug}" = "xyes" ], [
    # Add -Werror in debug mode
    CXXFLAGS="-Werror ${CXXFLAGS}"
  ], [
    # hide private symbols in non-debug mode
    visibility="-fvisibility=hidden"
  ])
])

# Check for debug
AC_MSG_CHECKING([whether to compile debug version])
debugflags=""
AS_CASE([${enable_debug}],
  [ yes ], [
    AC_MSG_RESULT([yes])
    AC_DEFINE([__RTAUDIO_DEBUG__])
    debugflags="${debugflags} -g -O0"
    object_path=Debug
  ],
  [ no ], [
    AC_MSG_RESULT([no!])
    debugflags="${debugflags} -O3"
  ], [
    AC_MSG_RESULT([no])
  ])

# For debugging and optimization ... overwrite default because it has both -g and -O2
AS_IF([test "x$debugflags" != x],
  AS_IF([test "x$override_cxx" = "xyes" ], CXXFLAGS="$CXXFLAGS $debugflags", CXXFLAGS="$debugflags $CXXFLAGS")
  AS_IF([test "x$override_c" = "xyes" ], CFLAGS="$CFLAGS $debugflags", CFLAGS="$debugflags $CFLAGS")
  )


# Checks for functions
AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )

# Checks for doxygen
AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x ] )

# Copy doc files to build dir if necessary
AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )

# Checks for package options and external software
AC_CANONICAL_HOST

AC_MSG_CHECKING([for audio API])

AS_IF([test "x$with_jack" = "xyes"], [
  AC_MSG_RESULT([using JACK])
  AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR([JACK support requires the jack library!]))
  api="$api -D__UNIX_JACK__"
])


AS_CASE([$host],
  [*-*-netbsd*],
  AS_IF([test "x$api" = "x"], [
    AC_MSG_RESULT([using OSS])
    api="$api -D__LINUX_OSS__"
    AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
    AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
  ]),
  [*-*-freebsd*],
  AS_IF([test "x$api" = "x"], [
    AC_MSG_RESULT([using OSS])
    api="$api -D__LINUX_OSS__"
    AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
    AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
  ]),
  [*-*-linux*], [
  # Look for ALSA flag
  AS_IF([test "x$with_alsa" = "xyes"], [
    AC_MSG_RESULT([using ALSA])
    api="$api -D__LINUX_ALSA__"
    req="$req alsa"
    AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR([ALSA support requires the asound library!]))
  ])
  # Look for PULSE flag
  AS_IF([test "x$with_pulse" = "xyes"], [
    AC_MSG_RESULT([using PulseAudio])
    api="$api -D__LINUX_PULSE__"
    req="$req libpulse-simple"
    AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR([PulseAudio support requires the pulse-simple library!]))
  ])

  # Look for OSS flag
  AS_IF([test "x$with_oss" = "xyes"], [
    AC_MSG_RESULT([using OSS])
    api="$api -D__LINUX_OSS__"
  ])

  # If no audio api flags specified, use ALSA
  AS_IF([test "x$api" = "x" ], [
    AC_MSG_RESULT([using ALSA])
    api="${api} -D__LINUX_ALSA__"
    req="${req} alsa"
    AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR([ALSA support requires the asound library!]))
  ])
  AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
  ],
  [*-apple*],[
  # Look for Core flag
  AS_IF([test "x$with_core" = "xyes"], [
    AC_MSG_RESULT([using CoreAudio])
    api="$api -D__MACOSX_CORE__"
    AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR([CoreAudio header files not found!])] )
    LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"
  ])
  # If no audio api flags specified, use CoreAudio
  AS_IF([test "x$api" = "x" ], [
    AC_MSG_RESULT([using CoreAudio])
    api="${api} -D__MACOSX_CORE__"
    AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
      [],
      [AC_MSG_ERROR([CoreAudio header files not found!])] )
    LIBS="LIBS -framework CoreAudio -framework CoreFoundation"
  ])
  AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR([RtAudio requires the pthread library!]))
  ],
  [*-mingw32*],[
  AS_IF([test "x$with_asio" = "xyes" ], [
    AC_MSG_RESULT([using ASIO])
    api="$api -D__WINDOWS_ASIO__"
    use_asio=yes
  ])
  # Look for DirectSound flag
  AS_IF([test "x$with_ds" = "xyes" ], [
    AC_MSG_RESULT([using DirectSound])
    api="$api -D__WINDOWS_DS__"
    LIBS="-ldsound -lwinmm $LIBS"
  ])
  # Look for WASAPI flag
  AS_IF([test "x$with_wasapi" = "xyes"], [
    AC_MSG_RESULT([using WASAPI])
    api="$api -D__WINDOWS_WASAPI__"
    LIBS="-lwinmm -luuid -lksuser $LIBS"
  ])
  # If no audio api flags specified, use DS
  AS_IF([test "x$api" = "x" ], [
    AC_MSG_RESULT([using DirectSound])
    api="$api -D__WINDOWS_DS__"
    LIBS="-ldsound -lwinmm $LIBS"
  ])
  LIBS="-lole32 $LIBS"
  ],[
  AC_MSG_RESULT([none])
  # Default case for unknown realtime systems.
  AC_MSG_ERROR([Unknown system type for realtime support!])
  ]
)

AM_CONDITIONAL( ASIO, [test "x${use_asio}" = "xyes" ])

CPPFLAGS="$CPPFLAGS $api"

AC_OUTPUT