falkTX
/
FFmpeg
mirror of https://github.com/falkTX/FFmpeg.git
1
0
Fork 0
Code Issues 0 Releases 338 Wiki Activity
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
39028 Commits
32 Branches
310MB
Tree: f5fbbbc022
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from 'f5fbbbc022'
${ noResults }
FFmpeg/libavcodec/x86/h264_deblock.asm

1069 lines
28KB
Raw Blame History 

  1. ;*****************************************************************************

  2. ;* MMX/SSE2/AVX-optimized H.264 deblocking code

  3. ;*****************************************************************************

  4. ;* Copyright (C) 2005-2011 x264 project

  5. ;*

  6. ;* Authors: Loren Merritt <lorenm@u.washington.edu>

  7. ;*          Jason Garrett-Glaser <darkshikari@gmail.com>

  8. ;*          Oskar Arvidsson <oskar@irock.se>

  9. ;*

  10. ;* This file is part of Libav.

  11. ;*

  12. ;* Libav is free software; you can redistribute it and/or

  13. ;* modify it under the terms of the GNU Lesser General Public

  14. ;* License as published by the Free Software Foundation; either

  15. ;* version 2.1 of the License, or (at your option) any later version.

  16. ;*

  17. ;* Libav is distributed in the hope that it will be useful,

  18. ;* but WITHOUT ANY WARRANTY; without even the implied warranty of

  19. ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

  20. ;* Lesser General Public License for more details.

  21. ;*

  22. ;* You should have received a copy of the GNU Lesser General Public

  23. ;* License along with Libav; if not, write to the Free Software

  24. ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA

  25. ;******************************************************************************

  26. 

  27. %include "libavutil/x86/x86util.asm"

  28. 

  29. SECTION_RODATA

  30. 

  31. pb_A1: times 16 db 0xA1

  32. pb_3_1: times 4 db 3, 1

  33. 

  34. SECTION .text

  35. 

  36. cextern pb_0

  37. cextern pb_1

  38. cextern pb_3

  39. 

  40. ; expands to [base],...,[base+7*stride]

  41. %define PASS8ROWS(base, base3, stride, stride3) \

  42.     [base], [base+stride], [base+stride*2], [base3], \

  43.     [base3+stride], [base3+stride*2], [base3+stride3], [base3+stride*4]

  44. 

  45. %define PASS8ROWS(base, base3, stride, stride3, offset) \

  46.     PASS8ROWS(base+offset, base3+offset, stride, stride3)

  47. 

  48. ; in: 8 rows of 4 bytes in %4..%11

  49. ; out: 4 rows of 8 bytes in m0..m3

  50. %macro TRANSPOSE4x8_LOAD 11

  51.     movh       m0, %4

  52.     movh       m2, %5

  53.     movh       m1, %6

  54.     movh       m3, %7

  55.     punpckl%1  m0, m2

  56.     punpckl%1  m1, m3

  57.     mova       m2, m0

  58.     punpckl%2  m0, m1

  59.     punpckh%2  m2, m1

  60. 

  61.     movh       m4, %8

  62.     movh       m6, %9

  63.     movh       m5, %10

  64.     movh       m7, %11

  65.     punpckl%1  m4, m6

  66.     punpckl%1  m5, m7

  67.     mova       m6, m4

  68.     punpckl%2  m4, m5

  69.     punpckh%2  m6, m5

  70. 

  71.     punpckh%3  m1, m0, m4

  72.     punpckh%3  m3, m2, m6

  73.     punpckl%3  m0, m4

  74.     punpckl%3  m2, m6

  75. %endmacro

  76. 

  77. ; in: 4 rows of 8 bytes in m0..m3

  78. ; out: 8 rows of 4 bytes in %1..%8

  79. %macro TRANSPOSE8x4B_STORE 8

  80.     punpckhdq  m4, m0, m0

  81.     punpckhdq  m5, m1, m1

  82.     punpckhdq  m6, m2, m2

  83. 

  84.     punpcklbw  m0, m1

  85.     punpcklbw  m2, m3

  86.     punpcklwd  m1, m0, m2

  87.     punpckhwd  m0, m2

  88.     movh       %1, m1

  89.     punpckhdq  m1, m1

  90.     movh       %2, m1

  91.     movh       %3, m0

  92.     punpckhdq  m0, m0

  93.     movh       %4, m0

  94. 

  95.     punpckhdq  m3, m3

  96.     punpcklbw  m4, m5

  97.     punpcklbw  m6, m3

  98.     punpcklwd  m5, m4, m6

  99.     punpckhwd  m4, m6

  100.     movh       %5, m5

  101.     punpckhdq  m5, m5

  102.     movh       %6, m5

  103.     movh       %7, m4

  104.     punpckhdq  m4, m4

  105.     movh       %8, m4

  106. %endmacro

  107. 

  108. %macro TRANSPOSE4x8B_LOAD 8

  109.     TRANSPOSE4x8_LOAD bw, wd, dq, %1, %2, %3, %4, %5, %6, %7, %8

  110. %endmacro

  111. 

  112. %macro SBUTTERFLY3 4

  113.     punpckh%1  %4, %2, %3

  114.     punpckl%1  %2, %3

  115. %endmacro

  116. 

  117. ; in: 8 rows of 8 (only the middle 6 pels are used) in %1..%8

  118. ; out: 6 rows of 8 in [%9+0*16] .. [%9+5*16]

  119. %macro TRANSPOSE6x8_MEM 9

  120.     RESET_MM_PERMUTATION

  121.     movq  m0, %1

  122.     movq  m1, %2

  123.     movq  m2, %3

  124.     movq  m3, %4

  125.     movq  m4, %5

  126.     movq  m5, %6

  127.     movq  m6, %7

  128.     SBUTTERFLY bw, 0, 1, 7

  129.     SBUTTERFLY bw, 2, 3, 7

  130.     SBUTTERFLY bw, 4, 5, 7

  131.     movq  [%9+0x10], m3

  132.     SBUTTERFLY3 bw, m6, %8, m7

  133.     SBUTTERFLY wd, 0, 2, 3

  134.     SBUTTERFLY wd, 4, 6, 3

  135.     punpckhdq m0, m4

  136.     movq  [%9+0x00], m0

  137.     SBUTTERFLY3 wd, m1, [%9+0x10], m3

  138.     SBUTTERFLY wd, 5, 7, 0

  139.     SBUTTERFLY dq, 1, 5, 0

  140.     SBUTTERFLY dq, 2, 6, 0

  141.     punpckldq m3, m7

  142.     movq  [%9+0x10], m2

  143.     movq  [%9+0x20], m6

  144.     movq  [%9+0x30], m1

  145.     movq  [%9+0x40], m5

  146.     movq  [%9+0x50], m3

  147.     RESET_MM_PERMUTATION

  148. %endmacro

  149. 

  150. ; in: 8 rows of 8 in %1..%8

  151. ; out: 8 rows of 8 in %9..%16

  152. %macro TRANSPOSE8x8_MEM 16

  153.     RESET_MM_PERMUTATION

  154.     movq  m0, %1

  155.     movq  m1, %2

  156.     movq  m2, %3

  157.     movq  m3, %4

  158.     movq  m4, %5

  159.     movq  m5, %6

  160.     movq  m6, %7

  161.     SBUTTERFLY bw, 0, 1, 7

  162.     SBUTTERFLY bw, 2, 3, 7

  163.     SBUTTERFLY bw, 4, 5, 7

  164.     SBUTTERFLY3 bw, m6, %8, m7

  165.     movq  %9,  m5

  166.     SBUTTERFLY wd, 0, 2, 5

  167.     SBUTTERFLY wd, 4, 6, 5

  168.     SBUTTERFLY wd, 1, 3, 5

  169.     movq  %11, m6

  170.     movq  m6,  %9

  171.     SBUTTERFLY wd, 6, 7, 5

  172.     SBUTTERFLY dq, 0, 4, 5

  173.     SBUTTERFLY dq, 1, 6, 5

  174.     movq  %9,  m0

  175.     movq  %10, m4

  176.     movq  %13, m1

  177.     movq  %14, m6

  178.     SBUTTERFLY3 dq, m2, %11, m0

  179.     SBUTTERFLY dq, 3, 7, 4

  180.     movq  %11, m2

  181.     movq  %12, m0

  182.     movq  %15, m3

  183.     movq  %16, m7

  184.     RESET_MM_PERMUTATION

  185. %endmacro

  186. 

  187. ; out: %4 = |%1-%2|>%3

  188. ; clobbers: %5

  189. %macro DIFF_GT 5

  190. %if avx_enabled == 0

  191.     mova    %5, %2

  192.     mova    %4, %1

  193.     psubusb %5, %1

  194.     psubusb %4, %2

  195. %else

  196.     psubusb %5, %2, %1

  197.     psubusb %4, %1, %2

  198. %endif

  199.     por     %4, %5

  200.     psubusb %4, %3

  201. %endmacro

  202. 

  203. ; out: %4 = |%1-%2|>%3

  204. ; clobbers: %5

  205. %macro DIFF_GT2 5

  206. %if ARCH_X86_64

  207.     psubusb %5, %2, %1

  208.     psubusb %4, %1, %2

  209. %else

  210.     mova    %5, %2

  211.     mova    %4, %1

  212.     psubusb %5, %1

  213.     psubusb %4, %2

  214. %endif

  215.     psubusb %5, %3

  216.     psubusb %4, %3

  217.     pcmpeqb %4, %5

  218. %endmacro

  219. 

  220. ; in: m0=p1 m1=p0 m2=q0 m3=q1 %1=alpha-1 %2=beta-1

  221. ; out: m5=beta-1, m7=mask, %3=alpha-1

  222. ; clobbers: m4,m6

  223. %macro LOAD_MASK 2-3

  224.     movd     m4, %1

  225.     movd     m5, %2

  226.     SPLATW   m4, m4

  227.     SPLATW   m5, m5

  228.     packuswb m4, m4  ; 16x alpha-1

  229.     packuswb m5, m5  ; 16x beta-1

  230. %if %0>2

  231.     mova     %3, m4

  232. %endif

  233.     DIFF_GT  m1, m2, m4, m7, m6 ; |p0-q0| > alpha-1

  234.     DIFF_GT  m0, m1, m5, m4, m6 ; |p1-p0| > beta-1

  235.     por      m7, m4

  236.     DIFF_GT  m3, m2, m5, m4, m6 ; |q1-q0| > beta-1

  237.     por      m7, m4

  238.     pxor     m6, m6

  239.     pcmpeqb  m7, m6

  240. %endmacro

  241. 

  242. ; in: m0=p1 m1=p0 m2=q0 m3=q1 m7=(tc&mask)

  243. ; out: m1=p0' m2=q0'

  244. ; clobbers: m0,3-6

  245. %macro DEBLOCK_P0_Q0 0

  246.     pcmpeqb m4, m4

  247.     pxor    m5, m1, m2   ; p0^q0

  248.     pxor    m3, m4

  249.     pand    m5, [pb_1]   ; (p0^q0)&1

  250.     pavgb   m3, m0       ; (p1 - q1 + 256)>>1

  251.     pxor    m4, m1

  252.     pavgb   m3, [pb_3]   ; (((p1 - q1 + 256)>>1)+4)>>1 = 64+2+(p1-q1)>>2

  253.     pavgb   m4, m2       ; (q0 - p0 + 256)>>1

  254.     pavgb   m3, m5

  255.     mova    m6, [pb_A1]

  256.     paddusb m3, m4       ; d+128+33

  257.     psubusb m6, m3

  258.     psubusb m3, [pb_A1]

  259.     pminub  m6, m7

  260.     pminub  m3, m7

  261.     psubusb m1, m6

  262.     psubusb m2, m3

  263.     paddusb m1, m3

  264.     paddusb m2, m6

  265. %endmacro

  266. 

  267. ; in: m1=p0 m2=q0

  268. ;     %1=p1 %2=q2 %3=[q2] %4=[q1] %5=tc0 %6=tmp

  269. ; out: [q1] = clip( (q2+((p0+q0+1)>>1))>>1, q1-tc0, q1+tc0 )

  270. ; clobbers: q2, tmp, tc0

  271. %macro LUMA_Q1 6

  272.     pavgb   %6, m1, m2

  273.     pavgb   %2, %6       ; avg(p2,avg(p0,q0))

  274.     pxor    %6, %3

  275.     pand    %6, [pb_1]   ; (p2^avg(p0,q0))&1

  276.     psubusb %2, %6       ; (p2+((p0+q0+1)>>1))>>1

  277.     psubusb %6, %1, %5

  278.     paddusb %5, %1

  279.     pmaxub  %2, %6

  280.     pminub  %2, %5

  281.     mova    %4, %2

  282. %endmacro

  283. 

  284. %if ARCH_X86_64

  285. ;-----------------------------------------------------------------------------

  286. ; void deblock_v_luma( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )

  287. ;-----------------------------------------------------------------------------

  288. %macro DEBLOCK_LUMA 0

  289. cglobal deblock_v_luma_8, 5,5,10

  290.     movd    m8, [r4] ; tc0

  291.     lea     r4, [r1*3]

  292.     dec     r2d        ; alpha-1

  293.     neg     r4

  294.     dec     r3d        ; beta-1

  295.     add     r4, r0     ; pix-3*stride

  296. 

  297.     mova    m0, [r4+r1]   ; p1

  298.     mova    m1, [r4+2*r1] ; p0

  299.     mova    m2, [r0]      ; q0

  300.     mova    m3, [r0+r1]   ; q1

  301.     LOAD_MASK r2d, r3d

  302. 

  303.     punpcklbw m8, m8

  304.     punpcklbw m8, m8 ; tc = 4x tc0[3], 4x tc0[2], 4x tc0[1], 4x tc0[0]

  305.     pcmpeqb m9, m9

  306.     pcmpeqb m9, m8

  307.     pandn   m9, m7

  308.     pand    m8, m9

  309. 

  310.     movdqa  m3, [r4] ; p2

  311.     DIFF_GT2 m1, m3, m5, m6, m7 ; |p2-p0| > beta-1

  312.     pand    m6, m9

  313.     psubb   m7, m8, m6

  314.     pand    m6, m8

  315.     LUMA_Q1 m0, m3, [r4], [r4+r1], m6, m4

  316. 

  317.     movdqa  m4, [r0+2*r1] ; q2

  318.     DIFF_GT2 m2, m4, m5, m6, m3 ; |q2-q0| > beta-1

  319.     pand    m6, m9

  320.     pand    m8, m6

  321.     psubb   m7, m6

  322.     mova    m3, [r0+r1]

  323.     LUMA_Q1 m3, m4, [r0+2*r1], [r0+r1], m8, m6

  324. 

  325.     DEBLOCK_P0_Q0

  326.     mova    [r4+2*r1], m1

  327.     mova    [r0], m2

  328.     RET

  329. 

  330. ;-----------------------------------------------------------------------------

  331. ; void deblock_h_luma( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )

  332. ;-----------------------------------------------------------------------------

  333. INIT_MMX cpuname

  334. cglobal deblock_h_luma_8, 5,9,0,0x60+16*WIN64

  335.     movsxd r7,  r1d

  336.     lea    r8,  [r7+r7*2]

  337.     lea    r6,  [r0-4]

  338.     lea    r5,  [r0-4+r8]

  339. %if WIN64

  340.     %define pix_tmp rsp+0x30 ; shadow space + r4

  341. %else

  342.     %define pix_tmp rsp

  343. %endif

  344. 

  345.     ; transpose 6x16 -> tmp space

  346.     TRANSPOSE6x8_MEM  PASS8ROWS(r6, r5, r7, r8), pix_tmp

  347.     lea    r6, [r6+r7*8]

  348.     lea    r5, [r5+r7*8]

  349.     TRANSPOSE6x8_MEM  PASS8ROWS(r6, r5, r7, r8), pix_tmp+8

  350. 

  351.     ; vertical filter

  352.     ; alpha, beta, tc0 are still in r2d, r3d, r4

  353.     ; don't backup r6, r5, r7, r8 because deblock_v_luma_sse2 doesn't use them

  354.     lea    r0, [pix_tmp+0x30]

  355.     mov    r1d, 0x10

  356. %if WIN64

  357.     mov    [rsp+0x20], r4

  358. %endif

  359.     call   deblock_v_luma_8

  360. 

  361.     ; transpose 16x4 -> original space  (only the middle 4 rows were changed by the filter)

  362.     add    r6, 2

  363.     add    r5, 2

  364.     movq   m0, [pix_tmp+0x18]

  365.     movq   m1, [pix_tmp+0x28]

  366.     movq   m2, [pix_tmp+0x38]

  367.     movq   m3, [pix_tmp+0x48]

  368.     TRANSPOSE8x4B_STORE  PASS8ROWS(r6, r5, r7, r8)

  369. 

  370.     shl    r7,  3

  371.     sub    r6,  r7

  372.     sub    r5,  r7

  373.     shr    r7,  3

  374.     movq   m0, [pix_tmp+0x10]

  375.     movq   m1, [pix_tmp+0x20]

  376.     movq   m2, [pix_tmp+0x30]

  377.     movq   m3, [pix_tmp+0x40]

  378.     TRANSPOSE8x4B_STORE  PASS8ROWS(r6, r5, r7, r8)

  379. 

  380.     RET

  381. %endmacro

  382. 

  383. INIT_XMM sse2

  384. DEBLOCK_LUMA

  385. INIT_XMM avx

  386. DEBLOCK_LUMA

  387. 

  388. %else

  389. 

  390. %macro DEBLOCK_LUMA 2

  391. ;-----------------------------------------------------------------------------

  392. ; void deblock_v8_luma( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )

  393. ;-----------------------------------------------------------------------------

  394. cglobal deblock_%1_luma_8, 5,5,8,2*%2

  395.     lea     r4, [r1*3]

  396.     dec     r2     ; alpha-1

  397.     neg     r4

  398.     dec     r3     ; beta-1

  399.     add     r4, r0 ; pix-3*stride

  400. 

  401.     mova    m0, [r4+r1]   ; p1

  402.     mova    m1, [r4+2*r1] ; p0

  403.     mova    m2, [r0]      ; q0

  404.     mova    m3, [r0+r1]   ; q1

  405.     LOAD_MASK r2, r3

  406. 

  407.     mov     r3, r4mp

  408.     pcmpeqb m3, m3

  409.     movd    m4, [r3] ; tc0

  410.     punpcklbw m4, m4

  411.     punpcklbw m4, m4 ; tc = 4x tc0[3], 4x tc0[2], 4x tc0[1], 4x tc0[0]

  412.     mova   [esp+%2], m4 ; tc

  413.     pcmpgtb m4, m3

  414.     mova    m3, [r4] ; p2

  415.     pand    m4, m7

  416.     mova   [esp], m4 ; mask

  417. 

  418.     DIFF_GT2 m1, m3, m5, m6, m7 ; |p2-p0| > beta-1

  419.     pand    m6, m4

  420.     pand    m4, [esp+%2] ; tc

  421.     psubb   m7, m4, m6

  422.     pand    m6, m4

  423.     LUMA_Q1 m0, m3, [r4], [r4+r1], m6, m4

  424. 

  425.     mova    m4, [r0+2*r1] ; q2

  426.     DIFF_GT2 m2, m4, m5, m6, m3 ; |q2-q0| > beta-1

  427.     pand    m6, [esp] ; mask

  428.     mova    m5, [esp+%2] ; tc

  429.     psubb   m7, m6

  430.     pand    m5, m6

  431.     mova    m3, [r0+r1]

  432.     LUMA_Q1 m3, m4, [r0+2*r1], [r0+r1], m5, m6

  433. 

  434.     DEBLOCK_P0_Q0

  435.     mova    [r4+2*r1], m1

  436.     mova    [r0], m2

  437.     RET

  438. 

  439. ;-----------------------------------------------------------------------------

  440. ; void deblock_h_luma( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )

  441. ;-----------------------------------------------------------------------------

  442. INIT_MMX cpuname

  443. cglobal deblock_h_luma_8, 0,5,8,0x60+HAVE_ALIGNED_STACK*12

  444.     mov    r0, r0mp

  445.     mov    r3, r1m

  446.     lea    r4, [r3*3]

  447.     sub    r0, 4

  448.     lea    r1, [r0+r4]

  449. %define pix_tmp esp+12*HAVE_ALIGNED_STACK

  450. 

  451.     ; transpose 6x16 -> tmp space

  452.     TRANSPOSE6x8_MEM  PASS8ROWS(r0, r1, r3, r4), pix_tmp

  453.     lea    r0, [r0+r3*8]

  454.     lea    r1, [r1+r3*8]

  455.     TRANSPOSE6x8_MEM  PASS8ROWS(r0, r1, r3, r4), pix_tmp+8

  456. 

  457.     ; vertical filter

  458.     lea    r0, [pix_tmp+0x30]

  459.     PUSH   dword r4m

  460.     PUSH   dword r3m

  461.     PUSH   dword r2m

  462.     PUSH   dword 16

  463.     PUSH   dword r0

  464.     call   deblock_%1_luma_8

  465. %ifidn %1, v8

  466.     add    dword [esp   ], 8 ; pix_tmp+0x38

  467.     add    dword [esp+16], 2 ; tc0+2

  468.     call   deblock_%1_luma_8

  469. %endif

  470.     ADD    esp, 20

  471. 

  472.     ; transpose 16x4 -> original space  (only the middle 4 rows were changed by the filter)

  473.     mov    r0, r0mp

  474.     sub    r0, 2

  475. 

  476.     movq   m0, [pix_tmp+0x10]

  477.     movq   m1, [pix_tmp+0x20]

  478.     lea    r1, [r0+r4]

  479.     movq   m2, [pix_tmp+0x30]

  480.     movq   m3, [pix_tmp+0x40]

  481.     TRANSPOSE8x4B_STORE  PASS8ROWS(r0, r1, r3, r4)

  482. 

  483.     lea    r0, [r0+r3*8]

  484.     lea    r1, [r1+r3*8]

  485.     movq   m0, [pix_tmp+0x18]

  486.     movq   m1, [pix_tmp+0x28]

  487.     movq   m2, [pix_tmp+0x38]

  488.     movq   m3, [pix_tmp+0x48]

  489.     TRANSPOSE8x4B_STORE  PASS8ROWS(r0, r1, r3, r4)

  490. 

  491.     RET

  492. %endmacro ; DEBLOCK_LUMA

  493. 

  494. INIT_MMX mmxext

  495. DEBLOCK_LUMA v8, 8

  496. INIT_XMM sse2

  497. DEBLOCK_LUMA v, 16

  498. INIT_XMM avx

  499. DEBLOCK_LUMA v, 16

  500. 

  501. %endif ; ARCH

  502. 

  503. 

  504. 

  505. %macro LUMA_INTRA_P012 4 ; p0..p3 in memory

  506. %if ARCH_X86_64

  507.     pavgb t0, p2, p1

  508.     pavgb t1, p0, q0

  509. %else

  510.     mova  t0, p2

  511.     mova  t1, p0

  512.     pavgb t0, p1

  513.     pavgb t1, q0

  514. %endif

  515.     pavgb t0, t1 ; ((p2+p1+1)/2 + (p0+q0+1)/2 + 1)/2

  516.     mova  t5, t1

  517. %if ARCH_X86_64

  518.     paddb t2, p2, p1

  519.     paddb t3, p0, q0

  520. %else

  521.     mova  t2, p2

  522.     mova  t3, p0

  523.     paddb t2, p1

  524.     paddb t3, q0

  525. %endif

  526.     paddb t2, t3

  527.     mova  t3, t2

  528.     mova  t4, t2

  529.     psrlw t2, 1

  530.     pavgb t2, mpb_0

  531.     pxor  t2, t0

  532.     pand  t2, mpb_1

  533.     psubb t0, t2 ; p1' = (p2+p1+p0+q0+2)/4;

  534. 

  535. %if ARCH_X86_64

  536.     pavgb t1, p2, q1

  537.     psubb t2, p2, q1

  538. %else

  539.     mova  t1, p2

  540.     mova  t2, p2

  541.     pavgb t1, q1

  542.     psubb t2, q1

  543. %endif

  544.     paddb t3, t3

  545.     psubb t3, t2 ; p2+2*p1+2*p0+2*q0+q1

  546.     pand  t2, mpb_1

  547.     psubb t1, t2

  548.     pavgb t1, p1

  549.     pavgb t1, t5 ; (((p2+q1)/2 + p1+1)/2 + (p0+q0+1)/2 + 1)/2

  550.     psrlw t3, 2

  551.     pavgb t3, mpb_0

  552.     pxor  t3, t1

  553.     pand  t3, mpb_1

  554.     psubb t1, t3 ; p0'a = (p2+2*p1+2*p0+2*q0+q1+4)/8

  555. 

  556.     pxor  t3, p0, q1

  557.     pavgb t2, p0, q1

  558.     pand  t3, mpb_1

  559.     psubb t2, t3

  560.     pavgb t2, p1 ; p0'b = (2*p1+p0+q0+2)/4

  561. 

  562.     pxor  t1, t2

  563.     pxor  t2, p0

  564.     pand  t1, mask1p

  565.     pand  t2, mask0

  566.     pxor  t1, t2

  567.     pxor  t1, p0

  568.     mova  %1, t1 ; store p0

  569. 

  570.     mova  t1, %4 ; p3

  571.     paddb t2, t1, p2

  572.     pavgb t1, p2

  573.     pavgb t1, t0 ; (p3+p2+1)/2 + (p2+p1+p0+q0+2)/4

  574.     paddb t2, t2

  575.     paddb t2, t4 ; 2*p3+3*p2+p1+p0+q0

  576.     psrlw t2, 2

  577.     pavgb t2, mpb_0

  578.     pxor  t2, t1

  579.     pand  t2, mpb_1

  580.     psubb t1, t2 ; p2' = (2*p3+3*p2+p1+p0+q0+4)/8

  581. 

  582.     pxor  t0, p1

  583.     pxor  t1, p2

  584.     pand  t0, mask1p

  585.     pand  t1, mask1p

  586.     pxor  t0, p1

  587.     pxor  t1, p2

  588.     mova  %2, t0 ; store p1

  589.     mova  %3, t1 ; store p2

  590. %endmacro

  591. 

  592. %macro LUMA_INTRA_SWAP_PQ 0

  593.     %define q1 m0

  594.     %define q0 m1

  595.     %define p0 m2

  596.     %define p1 m3

  597.     %define p2 q2

  598.     %define mask1p mask1q

  599. %endmacro

  600. 

  601. %macro DEBLOCK_LUMA_INTRA 1

  602.     %define p1 m0

  603.     %define p0 m1

  604.     %define q0 m2

  605.     %define q1 m3

  606.     %define t0 m4

  607.     %define t1 m5

  608.     %define t2 m6

  609.     %define t3 m7

  610. %if ARCH_X86_64

  611.     %define p2 m8

  612.     %define q2 m9

  613.     %define t4 m10

  614.     %define t5 m11

  615.     %define mask0 m12

  616.     %define mask1p m13

  617. %if WIN64

  618.     %define mask1q [rsp]

  619. %else

  620.     %define mask1q [rsp-24]

  621. %endif

  622.     %define mpb_0 m14

  623.     %define mpb_1 m15

  624. %else

  625.     %define spill(x) [esp+16*x]

  626.     %define p2 [r4+r1]

  627.     %define q2 [r0+2*r1]

  628.     %define t4 spill(0)

  629.     %define t5 spill(1)

  630.     %define mask0 spill(2)

  631.     %define mask1p spill(3)

  632.     %define mask1q spill(4)

  633.     %define mpb_0 [pb_0]

  634.     %define mpb_1 [pb_1]

  635. %endif

  636. 

  637. ;-----------------------------------------------------------------------------

  638. ; void deblock_v_luma_intra( uint8_t *pix, int stride, int alpha, int beta )

  639. ;-----------------------------------------------------------------------------

  640. %if WIN64

  641. cglobal deblock_%1_luma_intra_8, 4,6,16,0x10

  642. %else

  643. cglobal deblock_%1_luma_intra_8, 4,6,16,ARCH_X86_64*0x50-0x50

  644. %endif

  645.     lea     r4, [r1*4]

  646.     lea     r5, [r1*3] ; 3*stride

  647.     dec     r2d        ; alpha-1

  648.     jl .end

  649.     neg     r4

  650.     dec     r3d        ; beta-1

  651.     jl .end

  652.     add     r4, r0     ; pix-4*stride

  653.     mova    p1, [r4+2*r1]

  654.     mova    p0, [r4+r5]

  655.     mova    q0, [r0]

  656.     mova    q1, [r0+r1]

  657. %if ARCH_X86_64

  658.     pxor    mpb_0, mpb_0

  659.     mova    mpb_1, [pb_1]

  660.     LOAD_MASK r2d, r3d, t5 ; m5=beta-1, t5=alpha-1, m7=mask0

  661.     SWAP    7, 12 ; m12=mask0

  662.     pavgb   t5, mpb_0

  663.     pavgb   t5, mpb_1 ; alpha/4+1

  664.     movdqa  p2, [r4+r1]

  665.     movdqa  q2, [r0+2*r1]

  666.     DIFF_GT2 p0, q0, t5, t0, t3 ; t0 = |p0-q0| > alpha/4+1

  667.     DIFF_GT2 p0, p2, m5, t2, t5 ; mask1 = |p2-p0| > beta-1

  668.     DIFF_GT2 q0, q2, m5, t4, t5 ; t4 = |q2-q0| > beta-1

  669.     pand    t0, mask0

  670.     pand    t4, t0

  671.     pand    t2, t0

  672.     mova    mask1q, t4

  673.     mova    mask1p, t2

  674. %else

  675.     LOAD_MASK r2d, r3d, t5 ; m5=beta-1, t5=alpha-1, m7=mask0

  676.     mova    m4, t5

  677.     mova    mask0, m7

  678.     pavgb   m4, [pb_0]

  679.     pavgb   m4, [pb_1] ; alpha/4+1

  680.     DIFF_GT2 p0, q0, m4, m6, m7 ; m6 = |p0-q0| > alpha/4+1

  681.     pand    m6, mask0

  682.     DIFF_GT2 p0, p2, m5, m4, m7 ; m4 = |p2-p0| > beta-1

  683.     pand    m4, m6

  684.     mova    mask1p, m4

  685.     DIFF_GT2 q0, q2, m5, m4, m7 ; m4 = |q2-q0| > beta-1

  686.     pand    m4, m6

  687.     mova    mask1q, m4

  688. %endif

  689.     LUMA_INTRA_P012 [r4+r5], [r4+2*r1], [r4+r1], [r4]

  690.     LUMA_INTRA_SWAP_PQ

  691.     LUMA_INTRA_P012 [r0], [r0+r1], [r0+2*r1], [r0+r5]

  692. .end:

  693.     RET

  694. 

  695. INIT_MMX cpuname

  696. %if ARCH_X86_64

  697. ;-----------------------------------------------------------------------------

  698. ; void deblock_h_luma_intra( uint8_t *pix, int stride, int alpha, int beta )

  699. ;-----------------------------------------------------------------------------

  700. cglobal deblock_h_luma_intra_8, 4,9,0,0x80

  701.     movsxd r7,  r1d

  702.     lea    r8,  [r7*3]

  703.     lea    r6,  [r0-4]

  704.     lea    r5,  [r0-4+r8]

  705. %if WIN64

  706.     %define pix_tmp rsp+0x20 ; shadow space

  707. %else

  708.     %define pix_tmp rsp

  709. %endif

  710. 

  711.     ; transpose 8x16 -> tmp space

  712.     TRANSPOSE8x8_MEM  PASS8ROWS(r6, r5, r7, r8), PASS8ROWS(pix_tmp, pix_tmp+0x30, 0x10, 0x30)

  713.     lea    r6, [r6+r7*8]

  714.     lea    r5, [r5+r7*8]

  715.     TRANSPOSE8x8_MEM  PASS8ROWS(r6, r5, r7, r8), PASS8ROWS(pix_tmp+8, pix_tmp+0x38, 0x10, 0x30)

  716. 

  717.     lea    r0,  [pix_tmp+0x40]

  718.     mov    r1,  0x10

  719.     call   deblock_v_luma_intra_8

  720. 

  721.     ; transpose 16x6 -> original space (but we can't write only 6 pixels, so really 16x8)

  722.     lea    r5, [r6+r8]

  723.     TRANSPOSE8x8_MEM  PASS8ROWS(pix_tmp+8, pix_tmp+0x38, 0x10, 0x30), PASS8ROWS(r6, r5, r7, r8)

  724.     shl    r7,  3

  725.     sub    r6,  r7

  726.     sub    r5,  r7

  727.     shr    r7,  3

  728.     TRANSPOSE8x8_MEM  PASS8ROWS(pix_tmp, pix_tmp+0x30, 0x10, 0x30), PASS8ROWS(r6, r5, r7, r8)

  729.     RET

  730. %else

  731. cglobal deblock_h_luma_intra_8, 2,4,8,0x80

  732.     lea    r3,  [r1*3]

  733.     sub    r0,  4

  734.     lea    r2,  [r0+r3]

  735.     %define pix_tmp rsp

  736. 

  737.     ; transpose 8x16 -> tmp space

  738.     TRANSPOSE8x8_MEM  PASS8ROWS(r0, r2, r1, r3), PASS8ROWS(pix_tmp, pix_tmp+0x30, 0x10, 0x30)

  739.     lea    r0,  [r0+r1*8]

  740.     lea    r2,  [r2+r1*8]

  741.     TRANSPOSE8x8_MEM  PASS8ROWS(r0, r2, r1, r3), PASS8ROWS(pix_tmp+8, pix_tmp+0x38, 0x10, 0x30)

  742. 

  743.     lea    r0,  [pix_tmp+0x40]

  744.     PUSH   dword r3m

  745.     PUSH   dword r2m

  746.     PUSH   dword 16

  747.     PUSH   r0

  748.     call   deblock_%1_luma_intra_8

  749. %ifidn %1, v8

  750.     add    dword [rsp], 8 ; pix_tmp+8

  751.     call   deblock_%1_luma_intra_8

  752. %endif

  753.     ADD    esp, 16

  754. 

  755.     mov    r1,  r1m

  756.     mov    r0,  r0mp

  757.     lea    r3,  [r1*3]

  758.     sub    r0,  4

  759.     lea    r2,  [r0+r3]

  760.     ; transpose 16x6 -> original space (but we can't write only 6 pixels, so really 16x8)

  761.     TRANSPOSE8x8_MEM  PASS8ROWS(pix_tmp, pix_tmp+0x30, 0x10, 0x30), PASS8ROWS(r0, r2, r1, r3)

  762.     lea    r0,  [r0+r1*8]

  763.     lea    r2,  [r2+r1*8]

  764.     TRANSPOSE8x8_MEM  PASS8ROWS(pix_tmp+8, pix_tmp+0x38, 0x10, 0x30), PASS8ROWS(r0, r2, r1, r3)

  765.     RET

  766. %endif ; ARCH_X86_64

  767. %endmacro ; DEBLOCK_LUMA_INTRA

  768. 

  769. INIT_XMM sse2

  770. DEBLOCK_LUMA_INTRA v

  771. INIT_XMM avx

  772. DEBLOCK_LUMA_INTRA v

  773. %if ARCH_X86_64 == 0

  774. INIT_MMX mmxext

  775. DEBLOCK_LUMA_INTRA v8

  776. %endif

  777. 

  778. INIT_MMX mmxext

  779. 

  780. %macro CHROMA_V_START 0

  781.     dec    r2d      ; alpha-1

  782.     dec    r3d      ; beta-1

  783.     mov    t5, r0

  784.     sub    t5, r1

  785.     sub    t5, r1

  786. %endmacro

  787. 

  788. %macro CHROMA_H_START 0

  789.     dec    r2d

  790.     dec    r3d

  791.     sub    r0, 2

  792.     lea    t6, [r1*3]

  793.     mov    t5, r0

  794.     add    r0, t6

  795. %endmacro

  796. 

  797. %define t5 r5

  798. %define t6 r6

  799. 

  800. ;-----------------------------------------------------------------------------

  801. ; void ff_deblock_v_chroma( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )

  802. ;-----------------------------------------------------------------------------

  803. cglobal deblock_v_chroma_8, 5,6

  804.     CHROMA_V_START

  805.     movq  m0, [t5]

  806.     movq  m1, [t5+r1]

  807.     movq  m2, [r0]

  808.     movq  m3, [r0+r1]

  809.     call ff_chroma_inter_body_mmxext

  810.     movq  [t5+r1], m1

  811.     movq  [r0], m2

  812.     RET

  813. 

  814. ;-----------------------------------------------------------------------------

  815. ; void ff_deblock_h_chroma( uint8_t *pix, int stride, int alpha, int beta, int8_t *tc0 )

  816. ;-----------------------------------------------------------------------------

  817. cglobal deblock_h_chroma_8, 5,7

  818. %if UNIX64

  819.     %define buf0 [rsp-24]

  820.     %define buf1 [rsp-16]

  821. %elif WIN64

  822.     sub   rsp, 16

  823.     %define buf0 [rsp]

  824.     %define buf1 [rsp+8]

  825. %else

  826.     %define buf0 r0m

  827.     %define buf1 r2m

  828. %endif

  829.     CHROMA_H_START

  830.     TRANSPOSE4x8_LOAD  bw, wd, dq, PASS8ROWS(t5, r0, r1, t6)

  831.     movq  buf0, m0

  832.     movq  buf1, m3

  833.     call ff_chroma_inter_body_mmxext

  834.     movq  m0, buf0

  835.     movq  m3, buf1

  836.     TRANSPOSE8x4B_STORE PASS8ROWS(t5, r0, r1, t6)

  837. %if WIN64

  838.     add   rsp, 16

  839. %endif

  840.     RET

  841. 

  842. ALIGN 16

  843. ff_chroma_inter_body_mmxext:

  844.     LOAD_MASK  r2d, r3d

  845.     movd       m6, [r4] ; tc0

  846.     punpcklbw  m6, m6

  847.     pand       m7, m6

  848.     DEBLOCK_P0_Q0

  849.     ret

  850. 

  851. 

  852. 

  853. ; in: %1=p0 %2=p1 %3=q1

  854. ; out: p0 = (p0 + q1 + 2*p1 + 2) >> 2

  855. %macro CHROMA_INTRA_P0 3

  856.     movq    m4, %1

  857.     pxor    m4, %3

  858.     pand    m4, [pb_1] ; m4 = (p0^q1)&1

  859.     pavgb   %1, %3

  860.     psubusb %1, m4

  861.     pavgb   %1, %2             ; dst = avg(p1, avg(p0,q1) - ((p0^q1)&1))

  862. %endmacro

  863. 

  864. %define t5 r4

  865. %define t6 r5

  866. 

  867. ;-----------------------------------------------------------------------------

  868. ; void ff_deblock_v_chroma_intra( uint8_t *pix, int stride, int alpha, int beta )

  869. ;-----------------------------------------------------------------------------

  870. cglobal deblock_v_chroma_intra_8, 4,5

  871.     CHROMA_V_START

  872.     movq  m0, [t5]

  873.     movq  m1, [t5+r1]

  874.     movq  m2, [r0]

  875.     movq  m3, [r0+r1]

  876.     call ff_chroma_intra_body_mmxext

  877.     movq  [t5+r1], m1

  878.     movq  [r0], m2

  879.     RET

  880. 

  881. ;-----------------------------------------------------------------------------

  882. ; void ff_deblock_h_chroma_intra( uint8_t *pix, int stride, int alpha, int beta )

  883. ;-----------------------------------------------------------------------------

  884. cglobal deblock_h_chroma_intra_8, 4,6

  885.     CHROMA_H_START

  886.     TRANSPOSE4x8_LOAD  bw, wd, dq, PASS8ROWS(t5, r0, r1, t6)

  887.     call ff_chroma_intra_body_mmxext

  888.     TRANSPOSE8x4B_STORE PASS8ROWS(t5, r0, r1, t6)

  889.     RET

  890. 

  891. ALIGN 16

  892. ff_chroma_intra_body_mmxext:

  893.     LOAD_MASK r2d, r3d

  894.     movq   m5, m1

  895.     movq   m6, m2

  896.     CHROMA_INTRA_P0  m1, m0, m3

  897.     CHROMA_INTRA_P0  m2, m3, m0

  898.     psubb  m1, m5

  899.     psubb  m2, m6

  900.     pand   m1, m7

  901.     pand   m2, m7

  902.     paddb  m1, m5

  903.     paddb  m2, m6

  904.     ret

  905. 

  906. ;-----------------------------------------------------------------------------

  907. ; void h264_loop_filter_strength(int16_t bs[2][4][4], uint8_t nnz[40],

  908. ;                                int8_t ref[2][40], int16_t mv[2][40][2],

  909. ;                                int bidir,    int edges,    int step,

  910. ;                                int mask_mv0, int mask_mv1, int field);

  911. ;

  912. ; bidir    is 0 or 1

  913. ; edges    is 1 or 4

  914. ; step     is 1 or 2

  915. ; mask_mv0 is 0 or 3

  916. ; mask_mv1 is 0 or 1

  917. ; field    is 0 or 1

  918. ;-----------------------------------------------------------------------------

  919. %macro loop_filter_strength_iteration 7 ; edges, step, mask_mv,

  920.                                         ; dir, d_idx, mask_dir, bidir

  921. %define edgesd    %1

  922. %define stepd     %2

  923. %define mask_mvd  %3

  924. %define dir       %4

  925. %define d_idx     %5

  926. %define mask_dir  %6

  927. %define bidir     %7

  928.     xor          b_idxd, b_idxd ; for (b_idx = 0; b_idx < edges; b_idx += step)

  929. %%.b_idx_loop:

  930. %if mask_dir == 0

  931.     pxor             m0, m0

  932. %endif

  933.     test         b_idxd, dword mask_mvd

  934.     jnz %%.skip_loop_iter                       ; if (!(b_idx & mask_mv))

  935. %if bidir == 1

  936.     movd             m2, [refq+b_idxq+d_idx+12] ; { ref0[bn] }

  937.     punpckldq        m2, [refq+b_idxq+d_idx+52] ; { ref0[bn], ref1[bn] }

  938.     pshufw           m0, [refq+b_idxq+12], 0x44 ; { ref0[b],  ref0[b]  }

  939.     pshufw           m1, [refq+b_idxq+52], 0x44 ; { ref1[b],  ref1[b]  }

  940.     pshufw           m3, m2, 0x4E               ; { ref1[bn], ref0[bn] }

  941.     psubb            m0, m2                     ; { ref0[b] != ref0[bn],

  942.                                                 ;   ref0[b] != ref1[bn] }

  943.     psubb            m1, m3                     ; { ref1[b] != ref1[bn],

  944.                                                 ;   ref1[b] != ref0[bn] }

  945. 

  946.     por              m0, m1

  947.     mova             m1, [mvq+b_idxq*4+(d_idx+12)*4]

  948.     mova             m2, [mvq+b_idxq*4+(d_idx+12)*4+mmsize]

  949.     mova             m3, m1

  950.     mova             m4, m2

  951.     psubw            m1, [mvq+b_idxq*4+12*4]

  952.     psubw            m2, [mvq+b_idxq*4+12*4+mmsize]

  953.     psubw            m3, [mvq+b_idxq*4+52*4]

  954.     psubw            m4, [mvq+b_idxq*4+52*4+mmsize]

  955.     packsswb         m1, m2

  956.     packsswb         m3, m4

  957.     paddb            m1, m6

  958.     paddb            m3, m6

  959.     psubusb          m1, m5 ; abs(mv[b] - mv[bn]) >= limit

  960.     psubusb          m3, m5

  961.     packsswb         m1, m3

  962. 

  963.     por              m0, m1

  964.     mova             m1, [mvq+b_idxq*4+(d_idx+52)*4]

  965.     mova             m2, [mvq+b_idxq*4+(d_idx+52)*4+mmsize]

  966.     mova             m3, m1

  967.     mova             m4, m2

  968.     psubw            m1, [mvq+b_idxq*4+12*4]

  969.     psubw            m2, [mvq+b_idxq*4+12*4+mmsize]

  970.     psubw            m3, [mvq+b_idxq*4+52*4]

  971.     psubw            m4, [mvq+b_idxq*4+52*4+mmsize]

  972.     packsswb         m1, m2

  973.     packsswb         m3, m4

  974.     paddb            m1, m6

  975.     paddb            m3, m6

  976.     psubusb          m1, m5 ; abs(mv[b] - mv[bn]) >= limit

  977.     psubusb          m3, m5

  978.     packsswb         m1, m3

  979. 

  980.     pshufw           m1, m1, 0x4E

  981.     por              m0, m1

  982.     pshufw           m1, m0, 0x4E

  983.     pminub           m0, m1

  984. %else ; bidir == 0

  985.     movd             m0, [refq+b_idxq+12]

  986.     psubb            m0, [refq+b_idxq+d_idx+12] ; ref[b] != ref[bn]

  987. 

  988.     mova             m1, [mvq+b_idxq*4+12*4]

  989.     mova             m2, [mvq+b_idxq*4+12*4+mmsize]

  990.     psubw            m1, [mvq+b_idxq*4+(d_idx+12)*4]

  991.     psubw            m2, [mvq+b_idxq*4+(d_idx+12)*4+mmsize]

  992.     packsswb         m1, m2

  993.     paddb            m1, m6

  994.     psubusb          m1, m5 ; abs(mv[b] - mv[bn]) >= limit

  995.     packsswb         m1, m1

  996.     por              m0, m1

  997. %endif ; bidir == 1/0

  998. 

  999. %%.skip_loop_iter:

  1000.     movd             m1, [nnzq+b_idxq+12]

  1001.     por              m1, [nnzq+b_idxq+d_idx+12] ; nnz[b] || nnz[bn]

  1002. 

  1003.     pminub           m1, m7

  1004.     pminub           m0, m7

  1005.     psllw            m1, 1

  1006.     pxor             m2, m2

  1007.     pmaxub           m1, m0

  1008.     punpcklbw        m1, m2

  1009.     movq [bsq+b_idxq+32*dir], m1

  1010. 

  1011.     add          b_idxd, dword stepd

  1012.     cmp          b_idxd, dword edgesd

  1013.     jl %%.b_idx_loop

  1014. %endmacro

  1015. 

  1016. INIT_MMX mmxext

  1017. cglobal h264_loop_filter_strength, 9, 9, 0, bs, nnz, ref, mv, bidir, edges, \

  1018.                                             step, mask_mv0, mask_mv1, field

  1019. %define b_idxq bidirq

  1020. %define b_idxd bidird

  1021.     cmp    dword fieldm, 0

  1022.     mova             m7, [pb_1]

  1023.     mova             m5, [pb_3]

  1024.     je .nofield

  1025.     mova             m5, [pb_3_1]

  1026. .nofield:

  1027.     mova             m6, m5

  1028.     paddb            m5, m5

  1029. 

  1030.     shl     dword stepd, 3

  1031.     shl    dword edgesd, 3

  1032. %if ARCH_X86_32

  1033. %define mask_mv0d mask_mv0m

  1034. %define mask_mv1d mask_mv1m

  1035. %endif

  1036.     shl dword mask_mv1d, 3

  1037.     shl dword mask_mv0d, 3

  1038. 

  1039.     cmp    dword bidird, 0

  1040.     jne .bidir

  1041.     loop_filter_strength_iteration edgesd, stepd, mask_mv1d, 1, -8,  0, 0

  1042.     loop_filter_strength_iteration     32,     8, mask_mv0d, 0, -1, -1, 0

  1043. 

  1044.     mova             m0, [bsq+mmsize*0]

  1045.     mova             m1, [bsq+mmsize*1]

  1046.     mova             m2, [bsq+mmsize*2]

  1047.     mova             m3, [bsq+mmsize*3]

  1048.     TRANSPOSE4x4W 0, 1, 2, 3, 4

  1049.     mova  [bsq+mmsize*0], m0

  1050.     mova  [bsq+mmsize*1], m1

  1051.     mova  [bsq+mmsize*2], m2

  1052.     mova  [bsq+mmsize*3], m3

  1053.     RET

  1054. 

  1055. .bidir:

  1056.     loop_filter_strength_iteration edgesd, stepd, mask_mv1d, 1, -8,  0, 1

  1057.     loop_filter_strength_iteration     32,     8, mask_mv0d, 0, -1, -1, 1

  1058. 

  1059.     mova             m0, [bsq+mmsize*0]

  1060.     mova             m1, [bsq+mmsize*1]

  1061.     mova             m2, [bsq+mmsize*2]

  1062.     mova             m3, [bsq+mmsize*3]

  1063.     TRANSPOSE4x4W 0, 1, 2, 3, 4

  1064.     mova  [bsq+mmsize*0], m0

  1065.     mova  [bsq+mmsize*1], m1

  1066.     mova  [bsq+mmsize*2], m2

  1067.     mova  [bsq+mmsize*3], m3

  1068.     RET