falkTX
/
Carla
mirror of https://github.com/falkTX/Carla
1
0
Fork 0
Code Releases 43 Activity
Audio plugin host https://kx.studio/carla
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
6755 Commits
17 Branches
116MB
Tree: 7b111e7e35
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '7b111e7e35'
${ noResults }
Carla/cmake/CMakeLists.txt

851 lines
24KB
Raw Blame History 

  1. cmake_minimum_required(VERSION 3.15)

  2. project(carla)

  3. 

  4. set(CMAKE_POLICY_DEFAULT_CMP0025 NEW)

  5. set(CMAKE_POLICY_DEFAULT_CMP0063 NEW)

  6. set(CMAKE_POLICY_DEFAULT_CMP0069 NEW)

  7. 

  8. set(CMAKE_C_STANDARD 11)

  9. set(CMAKE_CXX_STANDARD 11)

  10. 

  11. set(CMAKE_C_VISIBILITY_PRESET hidden)

  12. set(CMAKE_CXX_VISIBILITY_PRESET hidden)

  13. set(CMAKE_VISIBILITY_INLINES_HIDDEN TRUE)

  14. 

  15. set_property(GLOBAL PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)

  16. 

  17. #######################################################################################################################

  18. # build options

  19. 

  20. set(CARLA_USE_JACK TRUE CACHE BOOL "Enable JACK")

  21. set(CARLA_USE_OSC TRUE CACHE BOOL "Enable OSC")

  22. 

  23. #######################################################################################################################

  24. # required dependencies

  25. 

  26. find_package(Threads REQUIRED)

  27. 

  28. if(NOT (APPLE OR HAIKU OR WIN32))

  29.   set(CARLA_LIBDL dl)

  30.   set(CARLA_LIBM m)

  31.   set(CARLA_LIBRT rt)

  32. endif()

  33. 

  34. #######################################################################################################################

  35. # optional dependencies

  36. 

  37. find_package(PkgConfig)

  38. 

  39. # homebrew does not support universal binaries, disable external deps if it is in use

  40. if(APPLE)

  41.   find_program(HOMEBREW brew)

  42.   if (HOMEBREW)

  43.     set(PKGCONFIG_FOUND FALSE)

  44.     mark_as_advanced(PKGCONFIG_FOUND)

  45.   endif()

  46. endif()

  47. 

  48. if(PKGCONFIG_FOUND)

  49.   pkg_check_modules(FLUIDSYNTH IMPORTED_TARGET fluidsynth)

  50.   pkg_check_modules(SNDFILE IMPORTED_TARGET sndfile)

  51. else()

  52.   set(FLUIDSYNTH_FOUND FALSE)

  53.   set(LIBLO_FOUND FALSE)

  54.   set(SNDFILE_FOUND FALSE)

  55. endif()

  56. 

  57. if(PKGCONFIG_FOUND AND CARLA_USE_OSC)

  58.   pkg_check_modules(LIBLO IMPORTED_TARGET liblo)

  59. else()

  60.   set(LIBLO_FOUND FALSE)

  61. endif()

  62. 

  63. if(PKGCONFIG_FOUND AND NOT WIN32)

  64.   pkg_check_modules(LIBMAGIC IMPORTED_TARGET libmagic)

  65. else()

  66.   set(LIBMAGIC_FOUND FALSE)

  67. endif()

  68. 

  69. if(PKGCONFIG_FOUND AND NOT (APPLE OR WIN32))

  70.   pkg_check_modules(X11 IMPORTED_TARGET x11)

  71. else()

  72.   set(X11_FOUND FALSE)

  73. endif()

  74. 

  75. add_library(carla-none INTERFACE)

  76. 

  77. if(NOT FLUIDSYNTH_FOUND)

  78.   add_library(PkgConfig::FLUIDSYNTH ALIAS carla-none)

  79. endif()

  80. 

  81. if(NOT LIBLO_FOUND)

  82.   add_library(PkgConfig::LIBLO ALIAS carla-none)

  83. endif()

  84. 

  85. if(NOT LIBMAGIC_FOUND)

  86.   add_library(PkgConfig::LIBMAGIC ALIAS carla-none)

  87. endif()

  88. 

  89. if(NOT SNDFILE_FOUND)

  90.   add_library(PkgConfig::SNDFILE ALIAS carla-none)

  91. endif()

  92. 

  93. if(NOT X11_FOUND)

  94.   add_library(PkgConfig::X11 ALIAS carla-none)

  95. endif()

  96. 

  97. #######################################################################################################################

  98. # utilities

  99. 

  100. function(set_common_target_properties TARGET)

  101.   target_compile_definitions(${TARGET}

  102.     PRIVATE

  103.       BUILDING_CARLA

  104.       HAVE_YSFX

  105.       $<$<BOOL:${CARLA_USE_JACK}>:HAVE_JACK>

  106.       $<$<BOOL:${FLUIDSYNTH_FOUND}>:HAVE_FLUIDSYNTH>

  107.       $<$<BOOL:${LIBLO_FOUND}>:HAVE_LIBLO>

  108.       $<$<BOOL:${LIBMAGIC_FOUND}>:HAVE_LIBMAGIC>

  109.       $<$<BOOL:${SNDFILE_FOUND}>:HAVE_SNDFILE>

  110.       $<$<BOOL:${X11_FOUND}>:HAVE_X11>

  111.   )

  112. 

  113.   target_compile_options(${TARGET}

  114.     PRIVATE

  115.       $<$<BOOL:${MSVC}>:/wd4244 /wd4267 /wd4273>

  116.   )

  117. 

  118.   if(CMAKE_C_COMPILER_ID MATCHES "GNU")

  119.     target_link_options(${TARGET}

  120.       PRIVATE

  121.         -Wl,--no-undefined

  122.     )

  123.   endif()

  124. 

  125.   set_property(TARGET ${TARGET} PROPERTY POSITION_INDEPENDENT_CODE ON)

  126. 

  127.   if(APPLE)

  128.     set_property(TARGET ${TARGET} PROPERTY APPEND OSX_ARCHITECTURES arm64)

  129.     set_property(TARGET ${TARGET} PROPERTY APPEND OSX_ARCHITECTURES x86_64)

  130.   endif()

  131. endfunction()

  132. 

  133. #######################################################################################################################

  134. # audio_decoder

  135. 

  136. add_library(carla-audio-decoder STATIC)

  137. add_library(carla::audio-decoder ALIAS carla-audio-decoder)

  138. 

  139. set_common_target_properties(carla-audio-decoder)

  140. 

  141. target_include_directories(carla-audio-decoder

  142.   PRIVATE

  143.     ../source/includes

  144.     ../source/modules

  145.     ../source/utils

  146. )

  147. 

  148. target_link_libraries(carla-audio-decoder

  149.   PRIVATE

  150.     PkgConfig::SNDFILE

  151. )

  152. 

  153. target_sources(carla-audio-decoder

  154.   PRIVATE

  155.     ../source/modules/audio_decoder/ad_dr_mp3.c

  156.     ../source/modules/audio_decoder/ad_ffmpeg.c

  157.     ../source/modules/audio_decoder/ad_minimp3.c

  158.     ../source/modules/audio_decoder/ad_plugin.c

  159.     ../source/modules/audio_decoder/ad_soundfile.c

  160. )

  161. 

  162. #######################################################################################################################

  163. # jackbridge

  164. 

  165. add_library(carla-jackbridge STATIC)

  166. add_library(carla::jackbridge ALIAS carla-jackbridge)

  167. 

  168. set_common_target_properties(carla-jackbridge)

  169. 

  170. target_include_directories(carla-jackbridge

  171.   PRIVATE

  172.     ../source/includes

  173.     ../source/utils

  174. )

  175. 

  176. target_link_libraries(carla-jackbridge

  177.   PRIVATE

  178.     ${CARLA_LIBDL}

  179.     ${CARLA_LIBRT}

  180. )

  181. 

  182. target_sources(carla-jackbridge

  183.   PRIVATE

  184.     ../source/jackbridge/JackBridge1.cpp

  185.     ../source/jackbridge/JackBridge2.cpp

  186. )

  187. 

  188. #######################################################################################################################

  189. # lilv

  190. 

  191. # serd

  192. add_library(carla-lilv_serd STATIC)

  193. 

  194. set_common_target_properties(carla-lilv_serd)

  195. 

  196. target_compile_options(carla-lilv_serd

  197.   PRIVATE

  198.     $<$<BOOL:${MSVC}>:/wd4005 /wd4090 /wd4133>

  199.     $<$<C_COMPILER_ID:GNU>:-Wno-format-overflow>

  200.     $<$<C_COMPILER_ID:GNU>:-Wno-implicit-fallthrough>

  201. )

  202. 

  203. target_include_directories(carla-lilv_serd

  204.   PRIVATE

  205.     ../source/includes

  206.     ../source/modules/lilv/config

  207.     ../source/modules/lilv/serd-0.24.0

  208. )

  209. 

  210. target_sources(carla-lilv_serd

  211.   PRIVATE

  212.     ../source/modules/lilv/serd.c

  213. )

  214. 

  215. # sord

  216. add_library(carla-lilv_sord STATIC)

  217. 

  218. set_common_target_properties(carla-lilv_sord)

  219. 

  220. target_compile_options(carla-lilv_sord

  221.   PRIVATE

  222.     $<$<BOOL:${MSVC}>:/wd4005 /wd4090 /wd4133>

  223.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-unused-parameter>

  224.     # workaround compiler bug, see https://gcc.gnu.org/bugzilla/show_bug.cgi?id=109585

  225.     $<$<C_COMPILER_ID:GNU>:-fno-strict-aliasing>

  226. )

  227. 

  228. target_include_directories(carla-lilv_sord

  229.   PRIVATE

  230.     ../source/includes

  231.     ../source/modules/lilv/config

  232.     ../source/modules/lilv/sord-0.16.0

  233.     ../source/modules/lilv/sord-0.16.0/src

  234. )

  235. 

  236. target_link_libraries(carla-lilv_sord

  237.   PRIVATE

  238.     carla-lilv_serd

  239. )

  240. 

  241. target_sources(carla-lilv_sord

  242.   PRIVATE

  243.     ../source/modules/lilv/sord.c

  244. )

  245. 

  246. # sratom

  247. add_library(carla-lilv_sratom STATIC)

  248. 

  249. set_common_target_properties(carla-lilv_sratom)

  250. 

  251. target_compile_options(carla-lilv_sratom

  252.   PRIVATE

  253.     $<$<BOOL:${MSVC}>:/wd4005 /wd4090 /wd4133>

  254. )

  255. 

  256. target_include_directories(carla-lilv_sratom

  257.   PRIVATE

  258.     ../source/includes

  259.     ../source/modules/lilv/config

  260.     ../source/modules/lilv/sratom-0.6.0

  261. )

  262. 

  263. target_link_libraries(carla-lilv_sratom

  264.   PRIVATE

  265.     carla-lilv_serd

  266. )

  267. 

  268. target_sources(carla-lilv_sratom

  269.   PRIVATE

  270.     ../source/modules/lilv/sratom.c

  271. )

  272. 

  273. # lilv

  274. add_library(carla-lilv_lilv STATIC)

  275. 

  276. set_common_target_properties(carla-lilv_lilv)

  277. 

  278. target_compile_options(carla-lilv_lilv

  279.   PRIVATE

  280.     $<$<BOOL:${MSVC}>:/wd4005 /wd4090 /wd4133>

  281.     $<$<C_COMPILER_ID:AppleClang>:-Wno-incompatible-pointer-types-discards-qualifiers>

  282.     $<$<C_COMPILER_ID:GNU>:-Wno-deprecated-declarations>

  283.     $<$<C_COMPILER_ID:GNU>:-Wno-discarded-qualifiers>

  284.     $<$<C_COMPILER_ID:GNU>:-Wno-format-overflow>

  285.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-unused-parameter>

  286. )

  287. 

  288. target_include_directories(carla-lilv_lilv

  289.   PRIVATE

  290.     ../source/includes

  291.     ../source/modules/lilv/config

  292.     ../source/modules/lilv/lilv-0.24.0

  293.     ../source/modules/lilv/lilv-0.24.0/src

  294. )

  295. 

  296. target_link_libraries(carla-lilv_lilv

  297.   PRIVATE

  298.     carla-lilv_serd

  299.     carla-lilv_sord

  300.     carla-lilv_sratom

  301. )

  302. 

  303. target_sources(carla-lilv_lilv

  304.   PRIVATE

  305.     ../source/modules/lilv/lilv.c

  306. )

  307. 

  308. # combined target

  309. add_library(carla-lilv INTERFACE)

  310. add_library(carla::lilv ALIAS carla-lilv)

  311. 

  312. target_link_libraries(carla-lilv

  313.   INTERFACE

  314.     carla-lilv_serd

  315.     carla-lilv_sord

  316.     carla-lilv_sratom

  317.     carla-lilv_lilv

  318.     ${CARLA_LIBDL}

  319.     ${CARLA_LIBM}

  320.     ${CARLA_LIBRT}

  321. )

  322. 

  323. #######################################################################################################################

  324. # native-plugins

  325. 

  326. add_library(carla-native-plugins STATIC)

  327. add_library(carla::native-plugins ALIAS carla-native-plugins)

  328. 

  329. set_common_target_properties(carla-native-plugins)

  330. 

  331. target_include_directories(carla-native-plugins

  332.   PRIVATE

  333.     ../source/includes

  334.     ../source/modules

  335.     ../source/utils

  336. )

  337. 

  338. target_sources(carla-native-plugins

  339.   PRIVATE

  340.     ../source/native-plugins/_all.c

  341.     ../source/native-plugins/_data.cpp

  342.     ../source/native-plugins/audio-gain.c

  343.     ../source/native-plugins/bypass.c

  344.     ../source/native-plugins/cv-to-audio.c

  345.     ../source/native-plugins/lfo.c

  346.     ../source/native-plugins/midi-channel-filter.c

  347.     ../source/native-plugins/midi-channel-ab.c

  348.     ../source/native-plugins/midi-channelize.c

  349.     ../source/native-plugins/midi-gain.c

  350.     ../source/native-plugins/midi-join.c

  351.     ../source/native-plugins/midi-split.c

  352.     ../source/native-plugins/midi-to-cv.c

  353.     ../source/native-plugins/midi-through.c

  354.     ../source/native-plugins/midi-transpose.c

  355.     ../source/native-plugins/audio-file.cpp

  356.     ../source/native-plugins/midi-file.cpp

  357.     # these rely on PyQt, skip them

  358.     # ../source/native-plugins/bigmeter.cpp

  359.     # ../source/native-plugins/midi-pattern.cpp

  360.     # ../source/native-plugins/notes.cpp

  361.     # ../source/native-plugins/xycontroller.cpp

  362. )

  363. 

  364. #######################################################################################################################

  365. # rtmempool

  366. 

  367. add_library(carla-rtmempool STATIC)

  368. add_library(carla::rtmempool ALIAS carla-rtmempool)

  369. 

  370. set_common_target_properties(carla-rtmempool)

  371. 

  372. target_include_directories(carla-rtmempool

  373.   PRIVATE

  374.     ../source/includes

  375.     ../source/utils

  376. )

  377. 

  378. target_link_libraries(carla-rtmempool

  379.   PRIVATE

  380.     ${CARLA_LIBDL}

  381.     ${CARLA_LIBRT}

  382. )

  383. 

  384. target_sources(carla-rtmempool

  385.   PRIVATE

  386.     ../source/modules/rtmempool/rtmempool.c

  387. )

  388. 

  389. #######################################################################################################################

  390. # sfzero

  391. 

  392. add_library(carla-sfzero STATIC)

  393. add_library(carla::sfzero ALIAS carla-sfzero)

  394. 

  395. set_common_target_properties(carla-sfzero)

  396. 

  397. target_include_directories(carla-sfzero

  398.   PRIVATE

  399.     ../source/includes

  400.     ../source/modules

  401.     ../source/utils

  402. )

  403. 

  404. target_link_libraries(carla-sfzero

  405.   PRIVATE

  406.     carla-audio-decoder

  407. )

  408. 

  409. target_sources(carla-sfzero

  410.   PRIVATE

  411.     ../source/modules/sfzero/SFZero.cpp

  412. )

  413. 

  414. #######################################################################################################################

  415. # water

  416. 

  417. add_library(carla-water STATIC)

  418. add_library(carla::water ALIAS carla-water)

  419. 

  420. set_common_target_properties(carla-water)

  421. 

  422. target_compile_options(carla-water

  423.   PRIVATE

  424.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-deprecated-copy>

  425. )

  426. 

  427. target_include_directories(carla-water

  428.   PRIVATE

  429.     ../source/includes

  430.     ../source/utils

  431. )

  432. 

  433. target_link_libraries(carla-water

  434.   PRIVATE

  435.     $<$<BOOL:${APPLE}>:$<LINK_LIBRARY:FRAMEWORK,AppKit.framework>>

  436.     $<$<BOOL:${WIN32}>:comdlg32>

  437.     $<$<BOOL:${WIN32}>:ole32>

  438.     $<$<BOOL:${WIN32}>:winmm>

  439.     ${CARLA_LIBDL}

  440.     ${CARLA_LIBRT}

  441. )

  442. 

  443. target_sources(carla-water

  444.   PRIVATE

  445.     ../source/modules/water/water.cpp

  446. )

  447. 

  448. #######################################################################################################################

  449. # water-files

  450. 

  451. add_library(carla-water-files STATIC)

  452. add_library(carla::water-files ALIAS carla-water-files)

  453. 

  454. set_common_target_properties(carla-water-files)

  455. 

  456. target_compile_options(carla-water-files

  457.   PRIVATE

  458.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-deprecated-copy>

  459. )

  460. 

  461. target_include_directories(carla-water-files

  462.   PRIVATE

  463.     ../source/includes

  464.     ../source/utils

  465. )

  466. 

  467. target_link_libraries(carla-water-files

  468.   PRIVATE

  469.     $<$<BOOL:${APPLE}>:$<LINK_LIBRARY:FRAMEWORK,AppKit.framework>>

  470.     $<$<BOOL:${WIN32}>:ole32>

  471.     $<$<BOOL:${WIN32}>:winmm>

  472.     ${CARLA_LIBDL}

  473. )

  474. 

  475. target_sources(carla-water-files

  476.   PRIVATE

  477.     ../source/modules/water/water.files.cpp

  478. )

  479. 

  480. #######################################################################################################################

  481. # ysfx

  482. 

  483. add_library(carla-ysfx STATIC)

  484. add_library(carla::ysfx ALIAS carla-ysfx)

  485. 

  486. set_common_target_properties(carla-ysfx)

  487. 

  488. # YSFX_FTS_LACKS_LFS_SUPPORT

  489. 

  490. target_compile_definitions(carla-ysfx

  491.   PRIVATE

  492.     EEL_TARGET_PORTABLE

  493.     EELSCRIPT_NO_NET

  494.     EELSCRIPT_NO_LICE

  495.     NSEEL_ATOF=ysfx_wdl_atof

  496.     WDL_FFT_REALSIZE=8

  497.     WDL_LINEPARSE_ATOF=ysfx_wdl_atof

  498.     WDL_WIN32_UTF8_NO_UI_IMPL

  499.     YSFX_API=

  500.     YSFX_NO_GFX

  501.     YSFX_NO_STANDARD_MUTEX

  502.     $<$<BOOL:${WIN32}>:NOMINMAX>

  503.     $<$<NOT:$<BOOL:${MINGW}>>:_FILE_OFFSET_BITS=64>

  504. )

  505. 

  506. # NOTE ugly -U /U due to cmake not supporting `target_remove_definitions`

  507. # see https://gitlab.kitware.com/cmake/cmake/-/issues/19796

  508. 

  509. target_compile_options(carla-ysfx

  510.   PRIVATE

  511.     $<$<BOOL:${MINGW}>:-UUNICODE>

  512.     $<$<BOOL:${MINGW}>:-U_UNICODE>

  513.     $<$<BOOL:${MSVC}>:/wd4297>

  514.     $<$<BOOL:${MSVC}>:/UUNICODE>

  515.     $<$<BOOL:${MSVC}>:/U_UNICODE>

  516.     $<$<C_COMPILER_ID:GNU>:-Wno-extra>

  517.     $<$<C_COMPILER_ID:GNU>:-Wno-ignored-attributes>

  518.     $<$<C_COMPILER_ID:GNU>:-Wno-unused-function>

  519.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-fsigned-char>

  520.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-sign-compare>

  521.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-unused-parameter>

  522.     $<$<AND:$<COMPILE_LANGUAGE:C>,$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>>:-Wno-missing-field-initializers>

  523.     $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CXX_COMPILER_ID:GNU>>:-Wno-deprecated-copy>

  524. )

  525. 

  526. target_include_directories(carla-ysfx

  527.   PRIVATE

  528.     ../source/modules/ysfx/include

  529.     ../source/modules/ysfx/sources

  530.     ../source/modules/ysfx/thirdparty/dr_libs

  531.     ../source/modules/ysfx/thirdparty/stb

  532.     ../source/modules/ysfx/thirdparty/WDL/source

  533. )

  534. 

  535. target_link_libraries(carla-ysfx

  536.   PRIVATE

  537. )

  538. 

  539. target_sources(carla-ysfx

  540.   PRIVATE

  541.     ../source/modules/ysfx/sources/ysfx.cpp

  542.     ../source/modules/ysfx/sources/ysfx_api_eel.cpp

  543.     ../source/modules/ysfx/sources/ysfx_api_file.cpp

  544.     ../source/modules/ysfx/sources/ysfx_api_gfx.cpp

  545.     ../source/modules/ysfx/sources/ysfx_api_reaper.cpp

  546.     ../source/modules/ysfx/sources/ysfx_audio_flac.cpp

  547.     ../source/modules/ysfx/sources/ysfx_audio_wav.cpp

  548.     ../source/modules/ysfx/sources/ysfx_config.cpp

  549.     ../source/modules/ysfx/sources/ysfx_eel_utils.cpp

  550.     ../source/modules/ysfx/sources/ysfx_midi.cpp

  551.     ../source/modules/ysfx/sources/ysfx_parse.cpp

  552.     ../source/modules/ysfx/sources/ysfx_reader.cpp

  553.     ../source/modules/ysfx/sources/ysfx_utils.cpp

  554.     ../source/modules/ysfx/sources/ysfx_utils_fts.cpp

  555.     ../source/modules/ysfx/sources/eel2-gas/sources/asm-nseel-x64-sse.S

  556.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-caltab.c

  557.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-cfunc.c

  558.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-compiler.c

  559.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-eval.c

  560.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-lextab.c

  561.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-ram.c

  562.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-yylex.c

  563.     ../source/modules/ysfx/thirdparty/WDL/source/WDL/fft.c

  564.     $<$<BOOL:${WIN32}>:../source/modules/ysfx/thirdparty/WDL/source/WDL/win32_utf8.c>

  565. )

  566. 

  567. #######################################################################################################################

  568. # zita-resampler

  569. 

  570. add_library(carla-zita-resampler STATIC)

  571. add_library(carla::zita-resampler ALIAS carla-zita-resampler)

  572. 

  573. set_common_target_properties(carla-zita-resampler)

  574. 

  575. target_include_directories(carla-zita-resampler

  576.   PRIVATE

  577.     ../source/includes

  578. )

  579. 

  580. target_sources(carla-zita-resampler

  581.   PRIVATE

  582.     ../source/modules/zita-resampler/cresampler.cc

  583.     ../source/modules/zita-resampler/resampler-table.cc

  584.     ../source/modules/zita-resampler/resampler.cc

  585.     ../source/modules/zita-resampler/vresampler.cc

  586. )

  587. 

  588. #######################################################################################################################

  589. # carla bridge

  590. 

  591. add_executable(carla-bridge-native)

  592. 

  593. set_common_target_properties(carla-bridge-native)

  594. 

  595. target_compile_definitions(carla-bridge-native

  596.   PRIVATE

  597.     BUILD_BRIDGE

  598.     CARLA_LIB_EXT="${CMAKE_SHARED_LIBRARY_SUFFIX}"

  599. )

  600. 

  601. # FIXME

  602. target_compile_options(carla-bridge-native

  603.   PRIVATE

  604.     $<$<C_COMPILER_ID:AppleClang>:-Wno-unused-but-set-variable>

  605.     $<$<C_COMPILER_ID:GNU>:-Wno-format-truncation>

  606.     $<$<C_COMPILER_ID:GNU>:-Wno-stringop-overflow>

  607.     $<$<C_COMPILER_ID:GNU>:-Wno-unused-parameter>

  608.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-unused-parameter>

  609. )

  610. 

  611. target_include_directories(carla-bridge-native

  612.   PRIVATE

  613.     ../source

  614.     ../source/backend

  615.     ../source/backend/engine

  616.     ../source/backend/plugin

  617.     ../source/includes

  618.     ../source/modules

  619.     ../source/utils

  620. )

  621. 

  622. target_link_libraries(carla-bridge-native

  623.   PRIVATE

  624.     carla-audio-decoder

  625.     carla-jackbridge

  626.     carla-lilv

  627.     carla-native-plugins

  628.     carla-rtmempool

  629.     carla-sfzero

  630.     carla-water

  631.     carla-ysfx

  632.     carla-zita-resampler

  633.     PkgConfig::FLUIDSYNTH

  634.     PkgConfig::LIBLO

  635.     PkgConfig::LIBMAGIC

  636.     PkgConfig::X11

  637.     ${CMAKE_THREAD_LIBS_INIT}

  638. )

  639. 

  640. target_sources(carla-bridge-native

  641.   PRIVATE

  642.     ../source/bridges-plugin/CarlaBridgePlugin.cpp

  643.     ../source/backend/CarlaStandalone.cpp

  644.     ../source/backend/engine/CarlaEngine.cpp

  645.     ../source/backend/engine/CarlaEngineBridge.cpp

  646.     ../source/backend/engine/CarlaEngineClient.cpp

  647.     ../source/backend/engine/CarlaEngineDummy.cpp

  648.     ../source/backend/engine/CarlaEngineData.cpp

  649.     ../source/backend/engine/CarlaEngineGraph.cpp

  650.     ../source/backend/engine/CarlaEngineInternal.cpp

  651.     ../source/backend/engine/CarlaEnginePorts.cpp

  652.     ../source/backend/engine/CarlaEngineRunner.cpp

  653.     ../source/backend/plugin/CarlaPlugin.cpp

  654.     ../source/backend/plugin/CarlaPluginBridge.cpp

  655.     ../source/backend/plugin/CarlaPluginInternal.cpp

  656.     ../source/backend/plugin/CarlaPluginAU.cpp

  657.     ../source/backend/plugin/CarlaPluginCLAP.cpp

  658.     ../source/backend/plugin/CarlaPluginFluidSynth.cpp

  659.     ../source/backend/plugin/CarlaPluginJuce.cpp

  660.     ../source/backend/plugin/CarlaPluginJSFX.cpp

  661.     ../source/backend/plugin/CarlaPluginLADSPADSSI.cpp

  662.     ../source/backend/plugin/CarlaPluginLV2.cpp

  663.     ../source/backend/plugin/CarlaPluginNative.cpp

  664.     ../source/backend/plugin/CarlaPluginSFZero.cpp

  665.     ../source/backend/plugin/CarlaPluginVST2.cpp

  666.     ../source/backend/plugin/CarlaPluginVST3.cpp

  667.     $<$<BOOL:${CARLA_USE_JACK}>:../source/backend/engine/CarlaEngineJack.cpp>

  668.     $<$<BOOL:${CARLA_USE_JACK}>:../source/backend/plugin/CarlaPluginJack.cpp>

  669. )

  670. 

  671. #######################################################################################################################

  672. # carla discovery

  673. 

  674. add_executable(carla-discovery-native)

  675. 

  676. set_common_target_properties(carla-discovery-native)

  677. 

  678. target_include_directories(carla-discovery-native

  679.   PRIVATE

  680.     ../source/backend

  681.     ../source/includes

  682.     ../source/modules

  683.     ../source/utils

  684. )

  685. 

  686. target_link_libraries(carla-discovery-native

  687.   PRIVATE

  688.     carla-lilv

  689.     carla-water-files

  690.     carla-ysfx

  691.     PkgConfig::FLUIDSYNTH

  692.     ${CMAKE_THREAD_LIBS_INIT}

  693. )

  694. 

  695. target_sources(carla-discovery-native

  696.   PRIVATE

  697.     ../source/discovery/carla-discovery.cpp

  698. )

  699. 

  700. #######################################################################################################################

  701. # carla standalone

  702. 

  703. add_library(carla-standalone SHARED)

  704. add_library(carla::standalone ALIAS carla-standalone)

  705. 

  706. set_common_target_properties(carla-standalone)

  707. 

  708. set_target_properties(carla-standalone

  709.   PROPERTIES

  710.     OUTPUT_NAME carla_standalone2

  711. )

  712. 

  713. target_compile_definitions(carla-standalone

  714.   PRIVATE

  715.     CARLA_LIB_EXT="${CMAKE_SHARED_LIBRARY_SUFFIX}"

  716. )

  717. 

  718. # FIXME

  719. target_compile_options(carla-standalone

  720.   PRIVATE

  721.     $<$<C_COMPILER_ID:AppleClang>:-Wno-unused-but-set-variable>

  722.     $<$<C_COMPILER_ID:GNU>:-Wno-format-truncation>

  723.     $<$<C_COMPILER_ID:GNU>:-Wno-stringop-overflow>

  724.     $<$<C_COMPILER_ID:GNU>:-Wno-error=cpp>

  725.     $<$<STREQUAL:${CMAKE_C_COMPILER_FRONTEND_VARIANT},GNU>:-Wno-unused-parameter>

  726. )

  727. 

  728. target_include_directories(carla-standalone

  729.   PRIVATE

  730.     ../source

  731.     ../source/backend

  732.     ../source/includes

  733.     ../source/modules

  734.     ../source/utils

  735. )

  736. 

  737. target_link_libraries(carla-standalone

  738.   PRIVATE

  739.     carla-jackbridge

  740.     carla-lilv

  741.     carla-native-plugins

  742.     carla-rtmempool

  743.     carla-sfzero

  744.     carla-water

  745.     carla-ysfx

  746.     carla-zita-resampler

  747.     PkgConfig::FLUIDSYNTH

  748.     PkgConfig::LIBLO

  749.     PkgConfig::LIBMAGIC

  750.     PkgConfig::X11

  751.     ${CMAKE_THREAD_LIBS_INIT}

  752. )

  753. 

  754. target_sources(carla-standalone

  755.   PRIVATE

  756.     ../source/backend/CarlaStandalone.cpp

  757.     ../source/backend/CarlaStandaloneNSM.cpp

  758.     ../source/backend/engine/CarlaEngine.cpp

  759.     ../source/backend/engine/CarlaEngineClient.cpp

  760.     ../source/backend/engine/CarlaEngineDummy.cpp

  761.     ../source/backend/engine/CarlaEngineData.cpp

  762.     ../source/backend/engine/CarlaEngineGraph.cpp

  763.     ../source/backend/engine/CarlaEngineInternal.cpp

  764.     ../source/backend/engine/CarlaEngineNative.cpp

  765.     ../source/backend/engine/CarlaEngineOsc.cpp

  766.     ../source/backend/engine/CarlaEngineOscHandlers.cpp

  767.     ../source/backend/engine/CarlaEngineOscSend.cpp

  768.     ../source/backend/engine/CarlaEnginePorts.cpp

  769.     ../source/backend/engine/CarlaEngineRunner.cpp

  770.     ../source/backend/plugin/CarlaPlugin.cpp

  771.     ../source/backend/plugin/CarlaPluginBridge.cpp

  772.     ../source/backend/plugin/CarlaPluginInternal.cpp

  773.     ../source/backend/plugin/CarlaPluginAU.cpp

  774.     ../source/backend/plugin/CarlaPluginCLAP.cpp

  775.     ../source/backend/plugin/CarlaPluginFluidSynth.cpp

  776.     ../source/backend/plugin/CarlaPluginJuce.cpp

  777.     ../source/backend/plugin/CarlaPluginJSFX.cpp

  778.     ../source/backend/plugin/CarlaPluginLADSPADSSI.cpp

  779.     ../source/backend/plugin/CarlaPluginLV2.cpp

  780.     ../source/backend/plugin/CarlaPluginNative.cpp

  781.     ../source/backend/plugin/CarlaPluginSFZero.cpp

  782.     ../source/backend/plugin/CarlaPluginVST2.cpp

  783.     ../source/backend/plugin/CarlaPluginVST3.cpp

  784.     $<$<BOOL:${CARLA_USE_JACK}>:../source/backend/engine/CarlaEngineJack.cpp>

  785.     $<$<BOOL:${CARLA_USE_JACK}>:../source/backend/plugin/CarlaPluginJack.cpp>

  786. )

  787. 

  788. #######################################################################################################################

  789. # carla utils

  790. 

  791. add_library(carla-utils SHARED)

  792. add_library(carla::utils ALIAS carla-utils)

  793. 

  794. set_common_target_properties(carla-utils)

  795. 

  796. set_target_properties(carla-standalone

  797.   PROPERTIES

  798.     OUTPUT_NAME carla_utils

  799. )

  800. 

  801. target_include_directories(carla-utils

  802.   PRIVATE

  803.     ../source

  804.     ../source/backend

  805.     ../source/includes

  806.     ../source/modules

  807.     ../source/utils

  808. )

  809. 

  810. target_link_libraries(carla-utils

  811.   PRIVATE

  812.     carla-jackbridge

  813.     carla-lilv

  814.     carla-water-files

  815.     carla-ysfx

  816.     PkgConfig::FLUIDSYNTH

  817.     PkgConfig::X11

  818.     ${CMAKE_THREAD_LIBS_INIT}

  819. )

  820. 

  821. target_sources(carla-utils

  822.   PRIVATE

  823.     ../source/backend/utils/CachedPlugins.cpp

  824.     ../source/backend/utils/CarlaUtils.cpp

  825.     ../source/backend/utils/Information.cpp

  826.     ../source/backend/utils/JUCE.cpp

  827.     ../source/backend/utils/PipeClient.cpp

  828.     ../source/backend/utils/PluginDiscovery.cpp

  829.     ../source/backend/utils/System.cpp

  830.     ../source/backend/utils/Windows.cpp

  831. )

  832. 

  833. #######################################################################################################################

  834. 

  835. if (APPLE)

  836.   set_source_files_properties(

  837.     ../source/backend/CarlaStandalone.cpp

  838.     ../source/backend/plugin/CarlaPluginCLAP.cpp

  839.     ../source/backend/plugin/CarlaPluginVST2.cpp

  840.     ../source/backend/plugin/CarlaPluginVST3.cpp

  841.     ../source/backend/utils/CarlaUtils.cpp

  842.     ../source/backend/utils/Windows.cpp

  843.     ../source/bridges-plugin/CarlaBridgePlugin.cpp

  844.     ../source/discovery/carla-discovery.cpp

  845.     ../source/modules/water/water.cpp

  846.     ../source/modules/water/water.files.cpp

  847.     PROPERTIES COMPILE_FLAGS -ObjC++)

  848. endif()

  849. 

  850. #######################################################################################################################