falkTX
/
Carla
mirror of https://github.com/falkTX/Carla
1
0
Fork 0
Code Releases 43 Activity
Audio plugin host https://kx.studio/carla
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
6504 Commits
17 Branches
116MB
Tree: 39033669f8
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '39033669f8'
${ noResults }
Carla/meson.build

715 lines
20KB
Raw Blame History 

  1. project (

  2.   'carla', ['c', 'cpp',],

  3.   license: 'GPL-2.0-or-later',

  4.   default_options: [

  5.     'cpp_std=c++14',

  6.     'buildtype=debugoptimized',

  7.     'warning_level=1',

  8.     ],

  9.   # see also source/frontend/carla_shared.py and source/includes/CarlaDefines.h

  10.   version: '2.5.1',

  11.   )

  12. 

  13. pkgconfig_mod = import ('pkgconfig')

  14. 

  15. is_darwin = false

  16. is_linux = false

  17. is_freebsd = false

  18. is_windows = false

  19. bin_suffix = ''

  20. lib_suffix = '.so'

  21. 

  22. if host_machine.system() == 'darwin'

  23.   is_darwin = true

  24.   lib_suffix = '.dylib'

  25. elif host_machine.system() == 'linux'

  26.   is_linux = true

  27. elif host_machine.system() == 'freebsd'

  28.   is_freebsd = true

  29. elif host_machine.system() == 'windows'

  30.   is_windows = true

  31.   bin_suffix = '.exe'

  32.   lib_suffix = '.dll'

  33. else

  34.   error ('unknown host system ' + host_machine.system ())

  35. endif

  36. 

  37. if is_darwin

  38.   add_languages ('objc')

  39. endif

  40. 

  41. cpp = meson.get_compiler('cpp')

  42. is_gcc = cpp.get_id () == 'gcc'

  43. 

  44. # === Dependencies ===

  45. 

  46. add_project_arguments (

  47.   '-DREAL_BUILD',

  48.   '-DCARLA_LIB_EXT="' + lib_suffix + '"',

  49.   '-DHAVE_FLUIDSYNTH=1',

  50.   '-DHAVE_LIBLO=1',

  51.   '-DUSING_JUCE',

  52.   '-DJUCE_APP_CONFIG_HEADER="AppConfig.h"',

  53.   '-mtune=generic',

  54.   '-msse',

  55.   '-msse2',

  56.   '-mfpmath=sse',

  57.   language: [ 'c', 'cpp', ],

  58.   )

  59. 

  60. if is_linux or is_freebsd

  61.   add_project_arguments (

  62.     '-DHAVE_X11=1',

  63.     '-ffast-math',

  64.     language: ['c', 'cpp',],

  65.     )

  66. endif

  67. 

  68. if is_windows

  69.   add_project_arguments (

  70.     '-D_WIN32_WINNT=0x0600',

  71.     language: ['c', 'cpp',],

  72.     )

  73. endif

  74. 

  75. if get_option ('buildtype') == 'debug'

  76.   add_project_arguments (

  77.     '-DDEBUG',

  78.     language: ['c', 'cpp',],

  79.     )

  80. endif

  81. 

  82. # === Libraries ===

  83. 

  84. carla_engine_plugin_srcs = []

  85. carla_plugin_srcs = []

  86. native_plugins_srcs = []

  87. 

  88. source_backend_inc = include_directories ('source/backend')

  89. source_includes_inc = include_directories ('source/includes')

  90. source_includes_vst3sdk_inc = include_directories ('source/includes/vst3sdk')

  91. source_modules_inc = include_directories ('source/modules')

  92. source_utils_inc = include_directories ('source/utils')

  93. source_inc = include_directories ('source')

  94. 

  95. lilv_config_inc = include_directories ('source/modules/lilv/config')

  96. 

  97. serd_lib = static_library ('serd',

  98.   'source/modules/lilv/serd.c',

  99.   include_directories: [

  100.     'source/modules/lilv/serd-0.24.0',

  101.     lilv_config_inc,

  102.     ],

  103.   gnu_symbol_visibility: 'inlineshidden',

  104.   )

  105. serd_dep = declare_dependency (

  106.   include_directories: 'source/modules/lilv/serd-0.24.0',

  107.   link_with: serd_lib)

  108. 

  109. sord_lib = static_library ('sord',

  110.   'source/modules/lilv/sord.c',

  111.   include_directories: [

  112.     'source/modules/lilv/sord-0.16.0',

  113.     'source/modules/lilv/sord-0.16.0/src',

  114.     lilv_config_inc,

  115.     ],

  116.   dependencies: serd_dep,

  117.   gnu_symbol_visibility: 'inlineshidden',

  118.   )

  119. sord_dep = declare_dependency (

  120.   include_directories: 'source/modules/lilv/sord-0.16.0',

  121.   dependencies: serd_dep,

  122.   link_with: sord_lib)

  123. 

  124. sratom_lib = static_library ('sratom',

  125.   'source/modules/lilv/sratom.c',

  126.   include_directories: [

  127.     'source/modules/lilv/sratom-0.6.0',

  128.     lilv_config_inc,

  129.     source_includes_inc,

  130.     ],

  131.   gnu_symbol_visibility: 'inlineshidden',

  132.   dependencies: sord_dep,

  133.   )

  134. sratom_dep = declare_dependency (

  135.   include_directories: 'source/modules/lilv/sratom-0.6.0',

  136.   dependencies: sord_dep,

  137.   link_with: sratom_lib)

  138. 

  139. lilv_lib = static_library ('lilv',

  140.   'source/modules/lilv/lilv.c',

  141.   include_directories: [

  142.     'source/modules/lilv/lilv-0.24.0',

  143.     'source/modules/lilv/lilv-0.24.0/src',

  144.     lilv_config_inc,

  145.     source_includes_inc,

  146.     ],

  147.   dependencies: sratom_dep,

  148.   gnu_symbol_visibility: 'inlineshidden',

  149.   )

  150. 

  151. rtmempool_lib = static_library ('rtmempool',

  152.   'source/modules/rtmempool/rtmempool.c',

  153.   include_directories: [

  154.     source_includes_inc,

  155.     ],

  156.   )

  157. 

  158. audio_decoder_srcs = [

  159.   'source/modules/audio_decoder/ad_dr_mp3.c',

  160.   'source/modules/audio_decoder/ad_ffmpeg.c',

  161.   'source/modules/audio_decoder/ad_minimp3.c',

  162.   'source/modules/audio_decoder/ad_plugin.c',

  163.   'source/modules/audio_decoder/ad_soundfile.c',

  164.   ]

  165. audio_decoder_lib = static_library ('audio_decoder',

  166.   audio_decoder_srcs,

  167.   include_directories: [

  168.     source_includes_inc,

  169.     ],

  170.   )

  171. 

  172. sfzero_lib = static_library ('sfzero',

  173.   'source/modules/sfzero/SFZero.cpp',

  174.   include_directories: [

  175.     source_includes_inc,

  176.     source_modules_inc,

  177.     source_utils_inc,

  178.     ],

  179.   link_with: audio_decoder_lib,

  180.   dependencies: [

  181.     dependency ('threads'),

  182.     ],

  183.   )

  184. 

  185. water_lib = static_library ('water',

  186.   'source/modules/water/water.cpp',

  187.   include_directories: [

  188.     source_includes_inc,

  189.     source_utils_inc,

  190.     ],

  191.   gnu_symbol_visibility: 'inlineshidden',

  192.   )

  193. 

  194. ysfx_flags = [

  195.   '-fsigned-char',

  196.   '-DEELSCRIPT_NO_NET',

  197.   '-DEELSCRIPT_NO_LICE',

  198.   '-DNSEEL_ATOF=ysfx_wdl_atof',

  199.   '-DWDL_FFT_REALSIZE=8',

  200.   '-DWDL_LINEPARSE_ATOF=ysfx_wdl_atof',

  201.   '-DYSFX_API=',

  202.   '-DYSFX_NO_STANDARD_MUTEX',

  203.   '-Wno-sign-compare',

  204.   '-Wno-unused-function',

  205.   '-Wno-unused-parameter',

  206.   ]

  207. 

  208. if is_windows

  209.   ysfx_flags += [

  210.     '-DNOMINMAX',

  211.     ]

  212. elif is_darwin

  213. else

  214.   ysfx_flags += [

  215.     '-DSWELL_LICE_GDI',

  216.     '-DSWELL_FONTCONFIG',

  217.     '-DSWELL_FREETYPE',

  218.     ]

  219. endif

  220. 

  221. ysfx_srcs = [

  222.   'source/modules/ysfx/sources/lice_stb/lice_stb_bmp.cpp',

  223.   'source/modules/ysfx/sources/lice_stb/lice_stb_gif.cpp',

  224.   'source/modules/ysfx/sources/lice_stb/lice_stb_jpg.cpp',

  225.   'source/modules/ysfx/sources/lice_stb/lice_stb_loaders.cpp',

  226.   'source/modules/ysfx/sources/lice_stb/lice_stb_png.cpp',

  227.   'source/modules/ysfx/sources/lice_stb/lice_stb_write.cpp',

  228.   'source/modules/ysfx/sources/ysfx.cpp',

  229.   'source/modules/ysfx/sources/ysfx_api_eel.cpp',

  230.   'source/modules/ysfx/sources/ysfx_api_file.cpp',

  231.   'source/modules/ysfx/sources/ysfx_api_gfx.cpp',

  232.   'source/modules/ysfx/sources/ysfx_api_reaper.cpp',

  233.   'source/modules/ysfx/sources/ysfx_audio_flac.cpp',

  234.   'source/modules/ysfx/sources/ysfx_audio_wav.cpp',

  235.   'source/modules/ysfx/sources/ysfx_config.cpp',

  236.   'source/modules/ysfx/sources/ysfx_eel_utils.cpp',

  237.   'source/modules/ysfx/sources/ysfx_midi.cpp',

  238.   'source/modules/ysfx/sources/ysfx_parse.cpp',

  239.   'source/modules/ysfx/sources/ysfx_parse_menu.cpp',

  240.   'source/modules/ysfx/sources/ysfx_preset.cpp',

  241.   'source/modules/ysfx/sources/ysfx_reader.cpp',

  242.   'source/modules/ysfx/sources/ysfx_utils.cpp',

  243.   'source/modules/ysfx/sources/ysfx_utils_fts.cpp',

  244.   'source/modules/ysfx/thirdparty/WDL/source/WDL/fft.c',

  245.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-caltab.c',

  246.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-cfunc.c',

  247.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-compiler.c',

  248.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-eval.c',

  249.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-lextab.c',

  250.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-ram.c',

  251.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/nseel-yylex.c',

  252.   'source/modules/ysfx/thirdparty/WDL/source/WDL/eel2/y.tab.c',

  253.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice.cpp',

  254.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_arc.cpp',

  255.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_colorspace.cpp',

  256.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_image.cpp',

  257.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_line.cpp',

  258.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_palette.cpp',

  259.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_texgen.cpp',

  260.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_text.cpp',

  261.   'source/modules/ysfx/thirdparty/WDL/source/WDL/lice/lice_textnew.cpp',

  262.   ]

  263. 

  264. if is_gcc

  265.   ysfx_srcs += [

  266.     'source/modules/ysfx/sources/eel2-gas/sources/asm-nseel-x64-sse.S',

  267.     ]

  268. endif

  269. 

  270. if is_windows

  271.   ysfx_srcs += [

  272.     'source/modules/ysfx/thirdparty/WDL/source/WDL/win32_utf8.c',

  273.     ]

  274. else # windows

  275.   ysfx_srcs += [

  276.     'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-ini.cpp',

  277.     'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell.cpp',

  278.     ]

  279.   if is_darwin

  280.     ysfx_srcs += [

  281.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-appstub.mm',

  282.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-dlg.mm',

  283.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-gdi.mm',

  284.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-kb.mm',

  285.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-menu.mm',

  286.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-misc.mm',

  287.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-miscdlg.mm',

  288.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-modstub.mm',

  289.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-wnd.mm',

  290.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swellappmain.mm',

  291.       ]

  292.   else # macos

  293.     ysfx_srcs += [

  294.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-appstub-generic.cpp',

  295.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-dlg-generic.cpp',

  296.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-gdi-generic.cpp',

  297.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-gdi-lice.cpp',

  298.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-generic-gdk.cpp',

  299.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-generic-headless.cpp',

  300.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-kb-generic.cpp',

  301.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-menu-generic.cpp',

  302.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-misc-generic.cpp',

  303.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-miscdlg-generic.cpp',

  304.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-modstub-generic.cpp',

  305.       'source/modules/ysfx/thirdparty/WDL/source/WDL/swell/swell-wnd-generic.cpp',

  306.       ]

  307.   endif # macos

  308. endif # windows

  309. 

  310. ysfx_lib = static_library ('ysfx',

  311.   ysfx_srcs,

  312.   cpp_args: ysfx_flags,

  313.   include_directories: [

  314.     'source/modules/ysfx/include',

  315.     'source/modules/ysfx/sources',

  316.     'source/modules/ysfx/thirdparty/WDL/source',

  317.     'source/modules/ysfx/thirdparty/dr_libs',

  318.     'source/modules/ysfx/thirdparty/stb',

  319.     ],

  320.   dependencies: [

  321.     dependency('threads'),

  322.     dependency('fontconfig'),

  323.     dependency('freetype2'),

  324.     ],

  325.   gnu_symbol_visibility: 'inlineshidden',

  326.   )

  327. 

  328. zita_resampler_srcs = [

  329.   'source/modules/zita-resampler/cresampler.cc',

  330.   'source/modules/zita-resampler/resampler-table.cc',

  331.   'source/modules/zita-resampler/resampler.cc',

  332.   'source/modules/zita-resampler/vresampler.cc',

  333.   ]

  334. zita_resampler_lib = static_library ('zita_resampler',

  335.   zita_resampler_srcs,

  336.   include_directories: [

  337.     source_includes_inc,

  338.     ],

  339.   )

  340. 

  341. juce_core_lib = static_library ('juce_core',

  342.   'source/modules/juce_core/juce_core.cpp',

  343.   include_directories: [

  344.     source_modules_inc,

  345.     ],

  346.   gnu_symbol_visibility: 'inlineshidden',

  347.   )

  348. 

  349. juce_data_structures_lib = static_library ('juce_data_structures',

  350.   'source/modules/juce_data_structures/juce_data_structures.cpp',

  351.   include_directories: [

  352.     source_modules_inc,

  353.     source_includes_vst3sdk_inc,

  354.     ],

  355.   cpp_args: [

  356.     '-DRELEASE',

  357.     ],

  358.   gnu_symbol_visibility: 'inlineshidden',

  359.   )

  360. 

  361. juce_gui_extra_lib = static_library ('juce_gui_extra',

  362.   'source/modules/juce_gui_extra/juce_gui_extra.cpp',

  363.   include_directories: [

  364.     source_modules_inc,

  365.     source_includes_vst3sdk_inc,

  366.     ],

  367.   cpp_args: [

  368.     '-DRELEASE',

  369.     ],

  370.   gnu_symbol_visibility: 'inlineshidden',

  371.   )

  372. 

  373. # needed for older mingw, crashes on optimized float operations

  374. juce_audio_basics_args = []

  375. if is_windows

  376.   juce_audio_basics_args += [

  377.     '-mpreferred-stack-boundary=2',

  378.     ]

  379. endif

  380. 

  381. juce_audio_basics_lib = static_library ('juce_audio_basics',

  382.   'source/modules/juce_audio_basics/juce_audio_basics.cpp',

  383.   include_directories: [

  384.     source_modules_inc,

  385.     ],

  386.   cpp_args: juce_audio_basics_args,

  387.   gnu_symbol_visibility: 'inlineshidden',

  388.   )

  389. 

  390. juce_audio_processors_lib = static_library ('juce_audio_processors',

  391.   'source/modules/juce_audio_processors/juce_audio_processors.cpp',

  392.   include_directories: [

  393.     source_modules_inc,

  394.     source_includes_vst3sdk_inc,

  395.     ],

  396.   cpp_args: [

  397.     '-DRELEASE',

  398.     ],

  399.   link_with: [

  400.     juce_data_structures_lib,

  401.     juce_gui_extra_lib,

  402.     ],

  403.   gnu_symbol_visibility: 'inlineshidden',

  404.   )

  405. 

  406. juce_events_lib = static_library ('juce_events',

  407.   'source/modules/juce_events/juce_events.cpp',

  408.   include_directories: [

  409.     source_modules_inc,

  410.     ],

  411.   link_with: [

  412.     juce_core_lib,

  413.     ],

  414.   gnu_symbol_visibility: 'inlineshidden',

  415.   )

  416. 

  417. juce_graphics_deps = []

  418. if is_linux

  419.   juce_graphics_deps += dependency ('freetype2')

  420. endif

  421. 

  422. juce_graphics_lib = static_library ('juce_graphics',

  423.   'source/modules/juce_graphics/juce_graphics.cpp',

  424.   include_directories: [

  425.     source_modules_inc,

  426.     source_includes_vst3sdk_inc,

  427.     ],

  428.   cpp_args: [

  429.     '-DRELEASE',

  430.     ],

  431.   dependencies: [

  432.     juce_graphics_deps,

  433.     ],

  434.   gnu_symbol_visibility: 'inlineshidden',

  435.   )

  436. 

  437. juce_gui_basics_lib = static_library ('juce_gui_basics',

  438.   'source/modules/juce_gui_basics/juce_gui_basics.cpp',

  439.   include_directories: [

  440.     source_modules_inc,

  441.     ],

  442.   gnu_symbol_visibility: 'inlineshidden',

  443.   )

  444. 

  445. carla_juce_lib = static_library ('carla_juce',

  446.   'source/modules/carla_juce/carla_juce.cpp',

  447.   include_directories: [

  448.     source_includes_inc,

  449.     source_modules_inc,

  450.     source_utils_inc,

  451.     ],

  452.   link_with: [

  453.     juce_events_lib,

  454.     ],

  455.   gnu_symbol_visibility: 'inlineshidden',

  456.   )

  457. 

  458. source_utils_srcs = [

  459.   'source/utils/CarlaPipeUtils.cpp',

  460.   ]

  461. source_utils_lib = static_library ('source_utils',

  462.   source_utils_srcs,

  463.   include_directories: [

  464.     source_includes_inc,

  465.     source_modules_inc,

  466.     source_utils_inc,

  467.     ],

  468.   link_with: [

  469.     water_lib,

  470.     ],

  471.   )

  472. 

  473. jackbridge_srcs = [

  474.   'source/jackbridge/JackBridge1.cpp',

  475.   'source/jackbridge/JackBridge2.cpp',

  476.   'source/jackbridge/JackBridge3.cpp',

  477.   'source/jackbridge/JackBridgeExport.cpp',

  478.   ]

  479. jackbridge_lib = static_library ('jackbridge',

  480.   jackbridge_srcs,

  481.   include_directories: [

  482.     source_includes_inc,

  483.     source_utils_inc,

  484.     ],

  485.   )

  486. 

  487. backend_utils_srcs = [

  488.   'source/backend/utils/CachedPlugins.cpp',

  489.   'source/backend/utils/Information.cpp',

  490.   'source/backend/utils/JUCE.cpp',

  491.   'source/backend/utils/PipeClient.cpp',

  492.   'source/backend/utils/System.cpp',

  493.   'source/backend/utils/Windows.cpp',

  494.   ]

  495. backend_utils_lib = static_library ('backend_utils',

  496.   backend_utils_srcs,

  497.   include_directories: [

  498.     source_backend_inc,

  499.     source_includes_inc,

  500.     source_modules_inc,

  501.     source_utils_inc,

  502.     source_inc,

  503.     ],

  504.   )

  505. 

  506. carla_engine_srcs = [

  507.   'source/backend/engine/CarlaEngine.cpp',

  508.   'source/backend/engine/CarlaEngineClient.cpp',

  509.   'source/backend/engine/CarlaEngineData.cpp',

  510.   'source/backend/engine/CarlaEngineGraph.cpp',

  511.   'source/backend/engine/CarlaEngineInternal.cpp',

  512.   'source/backend/engine/CarlaEngineNative.cpp',

  513.   'source/backend/engine/CarlaEnginePorts.cpp',

  514.   'source/backend/engine/CarlaEngineRunner.cpp',

  515.   'source/backend/engine/CarlaEngineDummy.cpp',

  516.   ]

  517. 

  518. backend_engine_lib = static_library ('carla_engine',

  519.   carla_engine_srcs,

  520.   include_directories: [

  521.     source_backend_inc,

  522.     source_includes_inc,

  523.     source_modules_inc,

  524.     source_utils_inc,

  525.     source_inc,

  526.     ],

  527.   link_with: [

  528.     water_lib,

  529.     jackbridge_lib,

  530.     ],

  531.   )

  532. 

  533. backend_plugin_srcs = files([

  534.   'source/backend/plugin/CarlaPlugin.cpp',

  535.   'source/backend/plugin/CarlaPluginAU.cpp',

  536.   'source/backend/plugin/CarlaPluginBridge.cpp',

  537.   'source/backend/plugin/CarlaPluginCLAP.cpp',

  538.   'source/backend/plugin/CarlaPluginFluidSynth.cpp',

  539.   'source/backend/plugin/CarlaPluginInternal.cpp',

  540.   'source/backend/plugin/CarlaPluginJack.cpp',

  541.   'source/backend/plugin/CarlaPluginJSFX.cpp',

  542.   'source/backend/plugin/CarlaPluginJuce.cpp',

  543.   'source/backend/plugin/CarlaPluginLADSPADSSI.cpp',

  544.   'source/backend/plugin/CarlaPluginLV2.cpp',

  545.   'source/backend/plugin/CarlaPluginNative.cpp',

  546.   'source/backend/plugin/CarlaPluginSFZero.cpp',

  547.   'source/backend/plugin/CarlaPluginVST2.cpp',

  548.   'source/backend/plugin/CarlaPluginVST3.cpp',

  549.   ])

  550. 

  551. backend_plugin_lib = static_library ('backend_plugin',

  552.   backend_plugin_srcs,

  553.   include_directories: [

  554.     source_backend_inc,

  555.     source_includes_inc,

  556.     source_modules_inc,

  557.     source_utils_inc,

  558.     source_inc,

  559.     ],

  560.   link_with: [

  561.     water_lib,

  562.     jackbridge_lib,

  563.     rtmempool_lib,

  564.     ysfx_lib,

  565.     ],

  566.   dependencies: [

  567.     dependency ('threads'),

  568.     ],

  569.   )

  570. 

  571. carla_discovery_exe = executable ('carla-discovery-native',

  572.   'source/discovery/carla-discovery.cpp',

  573.   include_directories: [

  574.     source_backend_inc,

  575.     source_includes_inc,

  576.     source_modules_inc,

  577.     source_utils_inc,

  578.     source_inc,

  579.     ],

  580.   link_with: [

  581.     carla_juce_lib,

  582.     backend_plugin_lib,

  583.     water_lib,

  584.     lilv_lib,

  585.     juce_audio_basics_lib,

  586.     juce_audio_processors_lib,

  587.     juce_graphics_lib,

  588.     juce_gui_basics_lib,

  589.     ],

  590.   dependencies: [

  591.     dependency ('fluidsynth'),

  592.     ],

  593.   install: true,

  594.   install_dir: get_option('libdir') / 'carla',

  595.   )

  596. 

  597. source_native_plugins_srcs = [

  598.   'source/native-plugins/audio-file.cpp',

  599.   'source/native-plugins/audio-gain.c',

  600.   'source/native-plugins/bypass.c',

  601.   'source/native-plugins/cv-to-audio.c',

  602.   'source/native-plugins/lfo.c',

  603.   'source/native-plugins/midi-to-cv.c',

  604.   'source/native-plugins/midi-channel-ab.c',

  605.   'source/native-plugins/midi-channelize.c',

  606.   'source/native-plugins/midi-channel-filter.c',

  607.   'source/native-plugins/midi-file.cpp',

  608.   'source/native-plugins/midi-gain.c',

  609.   'source/native-plugins/midi-join.c',

  610.   'source/native-plugins/midi-split.c',

  611.   'source/native-plugins/midi-through.c',

  612.   'source/native-plugins/midi-transpose.c',

  613.   ]

  614. 

  615. source_native_plugins_lib = static_library ('source_native_plugins',

  616.   source_native_plugins_srcs,

  617.   include_directories: [

  618.     source_includes_inc,

  619.     source_modules_inc,

  620.     source_utils_inc,

  621.     ],

  622.   link_with: [

  623.     zita_resampler_lib,

  624.     ],

  625.   )

  626. 

  627. carla_plugin_deps = [

  628.   dependency ('fluidsynth'),

  629.   dependency ('liblo'),

  630.   dependency ('threads'),

  631.   ]

  632. if is_linux or is_freebsd

  633.   carla_plugin_deps += [

  634.     dependency ('x11'),

  635.     dependency ('xcursor'),

  636.     dependency ('xext'),

  637.     ]

  638. endif

  639. 

  640. carla_host_plugin_srcs = [

  641.   'source/plugin/carla-host-plugin.cpp',

  642.   'source/native-plugins/_all.c',

  643.   'source/native-plugins/_data.cpp',

  644.   'source/backend/engine/CarlaEngineOsc.cpp',

  645.   'source/backend/engine/CarlaEngineOscSend.cpp',

  646.   'source/backend/engine/CarlaEngineOscHandlers.cpp',

  647.   'source/backend/engine/CarlaEngineNative.cpp',

  648.   'source/backend/plugin/CarlaPlugin.cpp',

  649.   'source/utils/CarlaDssiUtils.cpp',

  650.   'source/utils/CarlaPluginUI.cpp',

  651.   'source/utils/CarlaStateUtils.cpp',

  652.   'source/utils/CarlaProcessUtils.cpp',

  653.   ]

  654. 

  655. carla_host_plugin_lib = both_libraries ('carla_host-plugin',

  656.   carla_host_plugin_srcs,

  657.   include_directories: [

  658.     source_backend_inc,

  659.     source_includes_inc,

  660.     source_modules_inc,

  661.     source_utils_inc,

  662.     ],

  663.   cpp_args: [

  664.     '-DCARLA_PLUGIN_UI_CLASS_PREFIX=Plugin',

  665.     ],

  666.   dependencies: carla_plugin_deps,

  667.   link_with: [

  668.     lilv_lib,

  669.     backend_plugin_lib,

  670.     backend_engine_lib,

  671.     source_utils_lib,

  672.     source_native_plugins_lib,

  673.     ysfx_lib,

  674.     water_lib,

  675.     jackbridge_lib,

  676.     sfzero_lib,

  677.     carla_juce_lib,

  678.     juce_audio_basics_lib,

  679.     juce_audio_processors_lib,

  680.     juce_graphics_lib,

  681.     juce_gui_basics_lib,

  682.     ],

  683.   gnu_symbol_visibility: 'hidden',

  684.   install: true,

  685.   install_dir: get_option('libdir') / 'carla',

  686.   )

  687. 

  688. carla_host_plugin_dep = declare_dependency (

  689.   link_with: carla_host_plugin_lib)

  690. 

  691. pkgconfig_mod.generate (

  692.   carla_host_plugin_lib,

  693.   subdirs: 'carla',

  694.   extra_cflags: [

  695.     '-DREAL_BUILD',

  696.     '-I${includedir}/carla/includes',

  697.     ],

  698.   filebase: 'carla-host-plugin',

  699.   name: 'carla-host-plugin',

  700.   install_dir: get_option('libdir') / 'pkgconfig',

  701.   description: 'Carla Host as Native Plugin')

  702. 

  703. install_headers (

  704.   'source/includes/CarlaDefines.h',

  705.   'source/includes/CarlaMIDI.h',

  706.   'source/includes/CarlaNative.h',

  707.   'source/includes/CarlaNativePlugin.h',

  708.   subdir: 'carla/includes')

  709. 

  710. install_headers (

  711.   'source/backend/CarlaBackend.h',

  712.   'source/backend/CarlaHost.h',

  713.   'source/backend/CarlaUtils.h',

  714.   subdir: 'carla')