VCVRack
/
Rack
mirror of https://github.com/VCVRack/Rack.git
1
0
Fork 0
Code Issues 0 Releases 38 Wiki Activity
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
1119 Commits
4 Branches
537MB
Tree: 9a4a89b234
Branches Tags
${ item.name }
Create branch ${ searchTerm }
from '9a4a89b234'
${ noResults }
Rack/installer.nsi

128 lines
3.5KB
Raw Blame History 

  1. 

  2. !include "MUI2.nsh"

  3. 

  4. Name "VCV Rack"

  5. OutFile "Rack-setup.exe"

  6. SetCompressor "bzip2"

  7. CRCCheck On

  8. 

  9. ;Default installation folder

  10. InstallDir "$PROGRAMFILES\VCV"

  11. 

  12. ;Get installation folder from registry if available

  13. InstallDirRegKey HKCU "Software\VCV Rack" ""

  14. 

  15. ;Request admin permissions so we can install to Program Files and add a registry entry

  16. RequestExecutionLevel admin

  17. 

  18. 

  19. 

  20. !define MUI_ICON "icon.ico"

  21. 

  22. !define MUI_HEADERIMAGE

  23. !define MUI_HEADERIMAGE_BITMAP "installer-banner.bmp" ; 150x57

  24. ; !define MUI_WELCOMEFINISHPAGE_BITMAP "${NSISDIR}\Contrib\Graphics\Wizard\win.bmp" ; 164x314

  25. ; !define MUI_UNWELCOMEFINISHPAGE_BITMAP  "${NSISDIR}\Contrib\Graphics\Wizard\win.bmp" ; 164x314

  26. !define MUI_COMPONENTSPAGE_NODESC

  27. 

  28. 

  29. ; Pages

  30. 

  31. !insertmacro MUI_PAGE_COMPONENTS

  32. !insertmacro MUI_PAGE_DIRECTORY

  33. 

  34. Var VST_64_DIR

  35. !define MUI_DIRECTORYPAGE_VARIABLE $VST_64_DIR

  36. !define MUI_DIRECTORYPAGE_TEXT_TOP "Bridge 64-bit VST plugin install directory"

  37. !define MUI_PAGE_CUSTOMFUNCTION_PRE VST_64_DIR_PRE

  38. !insertmacro MUI_PAGE_DIRECTORY

  39. 

  40. Var VST_32_DIR

  41. !define MUI_DIRECTORYPAGE_VARIABLE $VST_32_DIR

  42. !define MUI_DIRECTORYPAGE_TEXT_TOP "Bridge 32-bit VST plugin install directory"

  43. !define MUI_PAGE_CUSTOMFUNCTION_PRE VST_32_DIR_PRE

  44. !insertmacro MUI_PAGE_DIRECTORY

  45. 

  46. !insertmacro MUI_PAGE_INSTFILES

  47. 

  48. !insertmacro MUI_UNPAGE_CONFIRM

  49. !insertmacro MUI_UNPAGE_INSTFILES

  50. 

  51. !insertmacro MUI_LANGUAGE "English"

  52. 

  53. 

  54. ; Sections

  55. 

  56. Section "VCV Rack" VCVRACK

  57. 	SectionIn RO

  58. 	SetOutPath "$INSTDIR"

  59. 

  60. 	CreateDirectory $OUTDIR

  61. 	File /r /x "Bridge" "dist\Rack"

  62. 

  63. 	;Store installation folder

  64. 	WriteRegStr HKCU "Software\VCV Rack" "" $INSTDIR

  65. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VCV Rack" "DisplayName" "VCV Rack"

  66. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VCV Rack" "UninstallString" "$\"$INSTDIR\UninstallRack.exe$\""

  67. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VCV Rack" "QuietUninstallString" "$\"$INSTDIR\UninstallRack.exe$\" /S"

  68. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VCV Rack" "InstallLocation" "$\"$INSTDIR$\""

  69. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VCV Rack" "Publisher" "VCV"

  70. 

  71. 	;Create uninstaller

  72. 	WriteUninstaller "$INSTDIR\UninstallRack.exe"

  73. 

  74. 	;Create shortcuts

  75. 	CreateDirectory "$SMPROGRAMS"

  76. 	; Set working directory of shortcut

  77. 	SetOutPath "$INSTDIR\Rack"

  78. 	CreateShortcut "$SMPROGRAMS\VCV Rack.lnk" "$INSTDIR\Rack\Rack.exe"

  79. SectionEnd

  80. 

  81. 

  82. Section "Bridge 64-bit VST plugin" VST_64

  83. 	StrCpy $OUTDIR $VST_64_DIR

  84. 	CreateDirectory $OUTDIR

  85. 	File "dist\Rack\Bridge\VCV-Bridge-64.dll"

  86. 	File "dist\Rack\Bridge\VCV-Bridge-fx-64.dll"

  87. SectionEnd

  88. 

  89. 

  90. Section "Bridge 32-bit VST plugin" VST_32

  91. 	StrCpy $OUTDIR $VST_32_DIR

  92. 	CreateDirectory $OUTDIR

  93. 	File "dist\Rack\Bridge\VCV-Bridge-32.dll"

  94. 	File "dist\Rack\Bridge\VCV-Bridge-fx-32.dll"

  95. SectionEnd

  96. 

  97. 

  98. Section "Uninstall"

  99. 	RMDir /r "$INSTDIR\Rack"

  100. 	Delete "$INSTDIR\UninstallRack.exe"

  101. 	RMDir "$INSTDIR"

  102. 

  103. 	Delete "$SMPROGRAMS\VCV Rack.lnk"

  104. 

  105. 	DeleteRegKey /ifempty HKCU "Software\VCV Rack"

  106. 	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VCV Rack"

  107. SectionEnd

  108. 

  109. 

  110. ; Functions

  111. 

  112. Function VST_64_DIR_PRE

  113. 	${Unless} ${SectionIsSelected} ${VST_64}

  114. 		Abort

  115. 	${EndUnless}

  116. FunctionEnd

  117. 

  118. Function VST_32_DIR_PRE

  119. 	${Unless} ${SectionIsSelected} ${VST_32}

  120. 		Abort

  121. 	${EndUnless}

  122. FunctionEnd

  123. 

  124. Function .onInit

  125. 	StrCpy $VST_64_DIR "$PROGRAMFILES\Steinberg\VSTPlugins"

  126. 	StrCpy $VST_32_DIR "$PROGRAMFILES (x86)\Steinberg\VSTPlugins"

  127. FunctionEnd